examples/declarative/qtquick1/ui-components/flipable/content/Card.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** Contact: http://www.qt-project.org/
   5 **
   6 ** This file is part of the examples of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:BSD$
   9 ** You may use this file under the terms of the BSD license as follows:
  10 **
  11 ** "Redistribution and use in source and binary forms, with or without
  12 ** modification, are permitted provided that the following conditions are
  13 ** met:
  14 **   * Redistributions of source code must retain the above copyright
  15 **     notice, this list of conditions and the following disclaimer.
  16 **   * Redistributions in binary form must reproduce the above copyright
  17 **     notice, this list of conditions and the following disclaimer in
  18 **     the documentation and/or other materials provided with the
  19 **     distribution.
  20 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  21 **     the names of its contributors may be used to endorse or promote
  22 **     products derived from this software without specific prior written
  23 **     permission.
  24 **
  25 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  26 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  27 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  28 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  29 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  30 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  31 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  32 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  33 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  34 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  35 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  36 **
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 1.0
  42
  43 Flipable {
  44     id: container
  45
  46     property alias image: frontImage.source
  47     property bool flipped: true
  48     property int xAxis: 0
  49     property int yAxis: 0
  50     property int angle: 0
  51
  52     width: front.width; height: front.height
  53
  54     front: Image { id: frontImage; smooth: true }
  55     back: Image { source: "back.png"; smooth: true }
  56
  57     state: "back"
  58
  59     MouseArea { anchors.fill: parent; onClicked: container.flipped = !container.flipped }
  60
  61     transform: Rotation {
  62         id: rotation; origin.x: container.width / 2; origin.y: container.height / 2
  63         axis.x: container.xAxis; axis.y: container.yAxis; axis.z: 0
  64     }
  65
  66     states: State {
  67         name: "back"; when: container.flipped
  68         PropertyChanges { target: rotation; angle: container.angle }
  69     }
  70
  71     transitions: Transition {
  72         ParallelAnimation {
  73             NumberAnimation { target: rotation; properties: "angle"; duration: 600 }
  74             SequentialAnimation {
  75                 NumberAnimation { target: container; property: "scale"; to: 0.75; duration: 300 }
  76                 NumberAnimation { target: container; property: "scale"; to: 1.0; duration: 300 }
  77             }
  78         }
  79     }
  80 }