examples/declarative/qtquick1/modelviews/parallax/qml/ParallaxView.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** Contact: http://www.qt-project.org/
   5 **
   6 ** This file is part of the examples of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:BSD$
   9 ** You may use this file under the terms of the BSD license as follows:
  10 **
  11 ** "Redistribution and use in source and binary forms, with or without
  12 ** modification, are permitted provided that the following conditions are
  13 ** met:
  14 **   * Redistributions of source code must retain the above copyright
  15 **     notice, this list of conditions and the following disclaimer.
  16 **   * Redistributions in binary form must reproduce the above copyright
  17 **     notice, this list of conditions and the following disclaimer in
  18 **     the documentation and/or other materials provided with the
  19 **     distribution.
  20 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  21 **     the names of its contributors may be used to endorse or promote
  22 **     products derived from this software without specific prior written
  23 **     permission.
  24 **
  25 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  26 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  27 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  28 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  29 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  30 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  31 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  32 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  33 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  34 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  35 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  36 **
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 1.0
  42
  43 Item {
  44     id: root
  45
  46     property alias background: background.source
  47     property int currentIndex: 0
  48     default property alias content: visualModel.children
  49
  50     Image {
  51         id: background
  52         fillMode: Image.TileHorizontally
  53         x: -list.contentX / 2
  54         width: Math.max(list.contentWidth, parent.width)
  55     }
  56
  57     ListView {
  58         id: list
  59         anchors.fill: parent
  60
  61         currentIndex: root.currentIndex
  62         onCurrentIndexChanged: root.currentIndex = currentIndex
  63
  64         orientation: Qt.Horizontal
  65         boundsBehavior: Flickable.DragOverBounds
  66         model: VisualItemModel { id: visualModel }
  67
  68         highlightRangeMode: ListView.StrictlyEnforceRange
  69         snapMode: ListView.SnapOneItem
  70     }
  71
  72     ListView {
  73         id: selector
  74
  75         height: 50
  76         anchors.bottom: parent.bottom
  77         anchors.horizontalCenter: parent.horizontalCenter
  78         width: Math.min(count * 50, parent.width - 20)
  79         interactive: width == parent.width - 20
  80         orientation: Qt.Horizontal
  81
  82         currentIndex: root.currentIndex
  83         onCurrentIndexChanged: root.currentIndex = currentIndex
  84
  85         model: visualModel.children
  86         delegate: Item {
  87             width: 50; height: 50
  88             id: delegateRoot
  89
  90             Image {
  91                 id: image
  92                 source: modelData.icon
  93                 smooth: true
  94                 scale: 0.8
  95             }
  96
  97             MouseArea {
  98                 anchors.fill: parent
  99                 onClicked: { root.currentIndex = index }
 100             }
 101
 102             states: State {
 103                 name: "Selected"
 104                 when: delegateRoot.ListView.isCurrentItem == true
 105                 PropertyChanges {
 106                     target: image
 107                     scale: 1
 108                     y: -5
 109                 }
 110             }
 111             transitions: Transition {
 112                 NumberAnimation { properties: "scale,y" }
 113             }
 114         }
 115
 116         Rectangle {
 117             color: "#60FFFFFF"
 118             x: -10; y: -10; z: -1
 119             width: parent.width + 20; height: parent.height + 20
 120             radius: 10
 121         }
 122     }
 123 }