examples/declarative/qtquick1/cppextensions/qwidgets/qwidgets.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** Contact: http://www.qt-project.org/
   5 **
   6 ** This file is part of the examples of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:BSD$
   9 ** You may use this file under the terms of the BSD license as follows:
  10 **
  11 ** "Redistribution and use in source and binary forms, with or without
  12 ** modification, are permitted provided that the following conditions are
  13 ** met:
  14 **   * Redistributions of source code must retain the above copyright
  15 **     notice, this list of conditions and the following disclaimer.
  16 **   * Redistributions in binary form must reproduce the above copyright
  17 **     notice, this list of conditions and the following disclaimer in
  18 **     the documentation and/or other materials provided with the
  19 **     distribution.
  20 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  21 **     the names of its contributors may be used to endorse or promote
  22 **     products derived from this software without specific prior written
  23 **     permission.
  24 **
  25 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  26 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  27 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  28 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  29 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  30 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  31 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  32 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  33 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  34 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  35 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  36 **
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 1.0
  42 import "QWidgets" 1.0
  43
  44 Rectangle {
  45     id: window
  46
  47     property int margin: 30
  48
  49     width: 640; height: 480
  50     color: palette.window
  51
  52     SystemPalette { id: palette }
  53
  54     MyPushButton {
  55         id: button1
  56         x: margin; y: margin
  57         text: "Right"
  58         transformOriginPoint: Qt.point(width / 2, height / 2)
  59
  60         onClicked: window.state = "right"
  61     }
  62
  63     MyPushButton {
  64         id: button2
  65         x: margin; y: margin + 30
  66         text: "Bottom"
  67         transformOriginPoint: Qt.point(width / 2, height / 2)
  68
  69         onClicked: window.state = "bottom"
  70     }
  71
  72     MyPushButton {
  73         id: button3
  74         x: margin; y: margin + 60
  75         text: "Quit"
  76         transformOriginPoint: Qt.point(width / 2, height / 2)
  77
  78         onClicked: Qt.quit()
  79     }
  80
  81     states: [
  82         State {
  83             name: "right"
  84             PropertyChanges { target: button1; x: window.width - width - margin; text: "Left"; onClicked: window.state = "" }
  85             PropertyChanges { target: button2; x: window.width - width - margin }
  86             PropertyChanges { target: button3; x: window.width - width - margin }
  87             PropertyChanges { target: window; color: Qt.darker(palette.window) }
  88         },
  89         State {
  90             name: "bottom"
  91             PropertyChanges { target: button1; y: window.height - height - margin; rotation: 180 }
  92             PropertyChanges {
  93                 target: button2
  94                 x: button1.x + button1.width + 10; y: window.height - height - margin
  95                 rotation: 180
  96                 text: "Top"
  97                 onClicked: window.state = ""
  98             }
  99             PropertyChanges { target: button3; x: button2.x + button2.width + 10; y: window.height - height - margin;  rotation: 180 }
 100             PropertyChanges { target: window; color: Qt.lighter(palette.window) }
 101         }
 102     ]
 103
 104     transitions: Transition {
 105         ParallelAnimation {
 106             NumberAnimation { properties: "x,y,rotation"; duration: 600; easing.type: Easing.OutQuad }
 107             ColorAnimation { target: window; duration: 600 }
 108         }
 109     }
 110 }