examples/declarative/photoviewer/PhotoViewerCore/Tag.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** Contact: http://www.qt-project.org/
   5 **
   6 ** This file is part of the QtDeclarative module of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:LGPL$
   9 ** GNU Lesser General Public License Usage
  10 ** This file may be used under the terms of the GNU Lesser General Public
  11 ** License version 2.1 as published by the Free Software Foundation and
  12 ** appearing in the file LICENSE.LGPL included in the packaging of this
  13 ** file. Please review the following information to ensure the GNU Lesser
  14 ** General Public License version 2.1 requirements will be met:
  15 ** http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
  16 **
  17 ** In addition, as a special exception, Nokia gives you certain additional
  18 ** rights. These rights are described in the Nokia Qt LGPL Exception
  19 ** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
  20 **
  21 ** GNU General Public License Usage
  22 ** Alternatively, this file may be used under the terms of the GNU General
  23 ** Public License version 3.0 as published by the Free Software Foundation
  24 ** and appearing in the file LICENSE.GPL included in the packaging of this
  25 ** file. Please review the following information to ensure the GNU General
  26 ** Public License version 3.0 requirements will be met:
  27 ** http://www.gnu.org/copyleft/gpl.html.
  28 **
  29 ** Other Usage
  30 ** Alternatively, this file may be used in accordance with the terms and
  31 ** conditions contained in a signed written agreement between you and Nokia.
  32 **
  33 **
  34 **
  35 **
  36 **
  37 **
  38 ** $QT_END_LICENSE$
  39 **
  40 ****************************************************************************/
  41
  42 import QtQuick 2.0
  43
  44 Flipable {
  45     id: flipable
  46
  47     property alias frontLabel: frontButton.label
  48     property alias backLabel: backButton.label
  49
  50     property int angle: 0
  51     property int randomAngle: Math.random() * (2 * 6 + 1) - 6
  52     property bool flipped: false
  53
  54     signal frontClicked
  55     signal backClicked
  56     signal tagChanged(string tag)
  57
  58     front: EditableButton {
  59         id: frontButton; rotation: flipable.randomAngle
  60         anchors { centerIn: parent; verticalCenterOffset: -20 }
  61         onClicked: flipable.frontClicked()
  62         onLabelChanged: flipable.tagChanged(label)
  63     }
  64
  65     back: Button {
  66         id: backButton; tint: "red"; rotation: flipable.randomAngle
  67         anchors { centerIn: parent; verticalCenterOffset: -20 }
  68         onClicked: flipable.backClicked()
  69     }
  70
  71     transform: Rotation {
  72         origin.x: flipable.width / 2; origin.y: flipable.height / 2
  73         axis.x: 0; axis.y: 1; axis.z: 0
  74         angle: flipable.angle
  75     }
  76
  77     states: State {
  78         name: "back"; when: flipable.flipped
  79         PropertyChanges { target: flipable; angle: 180 }
  80     }
  81
  82     transitions: Transition {
  83         ParallelAnimation {
  84             NumberAnimation { properties: "angle"; duration: 400 }
  85             SequentialAnimation {
  86                 NumberAnimation { target: flipable; property: "scale"; to: 0.8; duration: 200 }
  87                 NumberAnimation { target: flipable; property: "scale"; to: 1.0; duration: 200 }
  88             }
  89         }
  90     }
  91 }