examples/declarative/particles/plasmapatrol/content/Frigate.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: http://www.qt-project.org/
   6 **
   7 ** This file is part of the QtDeclarative module of the Qt Toolkit.
   8 **
   9 ** $QT_BEGIN_LICENSE:LGPL$
  10 ** GNU Lesser General Public License Usage
  11 ** This file may be used under the terms of the GNU Lesser General Public
  12 ** License version 2.1 as published by the Free Software Foundation and
  13 ** appearing in the file LICENSE.LGPL included in the packaging of this
  14 ** file. Please review the following information to ensure the GNU Lesser
  15 ** General Public License version 2.1 requirements will be met:
  16 ** http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
  17 **
  18 ** In addition, as a special exception, Nokia gives you certain additional
  19 ** rights. These rights are described in the Nokia Qt LGPL Exception
  20 ** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
  21 **
  22 ** GNU General Public License Usage
  23 ** Alternatively, this file may be used under the terms of the GNU General
  24 ** Public License version 3.0 as published by the Free Software Foundation
  25 ** and appearing in the file LICENSE.GPL included in the packaging of this
  26 ** file. Please review the following information to ensure the GNU General
  27 ** Public License version 3.0 requirements will be met:
  28 ** http://www.gnu.org/copyleft/gpl.html.
  29 **
  30 ** Other Usage
  31 ** Alternatively, this file may be used in accordance with the terms and
  32 ** conditions contained in a signed written agreement between you and Nokia.
  33 **
  34 **
  35 **
  36 **
  37 **
  38 ** $QT_END_LICENSE$
  39 **
  40 ****************************************************************************/
  41 import QtQuick 2.0
  42 import QtQuick.Particles 2.0
  43
  44 Item {
  45     id: container
  46     property int maxHP: 100
  47     property int hp: maxHP
  48     property real initialDodge: 0.2
  49     property real dodge: initialDodge
  50     onHpChanged: if(hp <= 0) target = container;
  51     property ParticleSystem system//TODO: Ship abstraction
  52     property Item target: container
  53     property string shipParticle: "default"//Per team colors?
  54     property int gunType: 0
  55     width: 128
  56     height: 128
  57     Emitter {
  58         system: container.system
  59         group: "frigateShield"
  60         anchors.centerIn: parent
  61         size: 92
  62         emitRate: 1
  63         lifeSpan: 4800
  64         enabled: hp > 0
  65     }
  66     Emitter {
  67         system: container.system
  68         group: container.shipParticle
  69         anchors.centerIn: parent
  70         width: 64
  71         height: 16
  72         shape: EllipseShape {}
  73
  74         size: 16
  75         sizeVariation: 8
  76         endSize: 8
  77         emitRate: hp > 0 ?  hp * 1 + 20 : 0
  78         lifeSpan: 1200
  79         maximumEmitted: (maxHP * 1 + 20)*2
  80     }
  81     Timer {
  82         id: fireControl
  83         property int next: Math.floor(Math.random() * 2) + 1
  84         interval: 800
  85         running: root.readySetGo
  86         repeat: true
  87         onTriggered: {
  88             if (next == 1) {
  89                 gun1.fireAt(container.target);
  90                 next = Math.floor(Math.random() * 2) + 1;
  91             } else if (next == 2) {
  92                 gun2.fireAt(container.target);
  93                 next = Math.floor(Math.random() * 2) + 1;
  94             }
  95         }
  96     }
  97
  98     Hardpoint {
  99         x: 128 - 32 - 12
 100         y: 64 - 12
 101         id: gun1
 102         system: container.system
 103         show: hp > 0
 104         hardpointType: gunType
 105     }
 106     Hardpoint {
 107         x: 0 + 32 - 12
 108         y: 64 - 12
 109         id: gun2
 110         system: container.system
 111         show: hp > 0
 112         hardpointType: gunType
 113     }
 114 }