examples/declarative/particles/affectors/customaffector.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** Contact: http://www.qt-project.org/
   5 **
   6 ** This file is part of the examples of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:BSD$
   9 ** You may use this file under the terms of the BSD license as follows:
  10 **
  11 ** "Redistribution and use in source and binary forms, with or without
  12 ** modification, are permitted provided that the following conditions are
  13 ** met:
  14 **   * Redistributions of source code must retain the above copyright
  15 **     notice, this list of conditions and the following disclaimer.
  16 **   * Redistributions in binary form must reproduce the above copyright
  17 **     notice, this list of conditions and the following disclaimer in
  18 **     the documentation and/or other materials provided with the
  19 **     distribution.
  20 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  21 **     the names of its contributors may be used to endorse or promote
  22 **     products derived from this software without specific prior written
  23 **     permission.
  24 **
  25 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  26 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  27 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  28 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  29 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  30 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  31 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  32 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  33 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  34 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  35 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  36 **
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 2.0
  42 import QtQuick.Particles 2.0
  43
  44 Item {
  45     width: 360
  46     height: 600
  47
  48     Image {
  49         source: "../images/backgroundLeaves.jpg"
  50         anchors.fill: parent
  51     }
  52     ParticleSystem {
  53         id: sys
  54     }
  55     Emitter {
  56         system: sys
  57         width: parent.width
  58         emitRate: 4
  59         lifeSpan: 14000
  60         size: 80
  61         speed: PointDirection { y: 60 }
  62     }
  63     Wander {
  64         system: sys
  65         anchors.fill: parent
  66         anchors.bottomMargin: 100
  67         xVariance: 60
  68         pace: 60
  69     }
  70
  71     Affector {
  72         system: sys
  73         property real coefficient: 0.1
  74         property real speed: 1.5
  75         width: parent.width
  76         height: parent.height - 100
  77         onAffectParticles: {
  78         /*  //Linear movement
  79             if (particle.r == 0) {
  80                 particle.r = Math.random() > 0.5 ? -1 : 1;
  81             }else if (particle.r == 1) {
  82                 particle.rotation += speed * dt;
  83                 if(particle.rotation >= maxAngle)
  84                     particle.r = -1;
  85             }else if (particle.r == -1) {
  86                 particle.rotation -= speed * dt;
  87                 if(particle.rotation <= -1 * maxAngle)
  88                     particle.r = 1;
  89             }
  90         */
  91             //Wobbly movement
  92             for (var i=0; i<particles.length; i++) {
  93                 var particle = particles[i];
  94                 if (particle.r == 0.0) {
  95                     particle.r = Math.random() + 0.01;
  96                 }
  97                 particle.rotation += speed * particle.r * dt;
  98                 particle.r -= particle.rotation * coefficient;
  99                 if (particle.r == 0.0)
 100                     particle.r -= particle.rotation * 0.000001;
 101                 particle.update = 1;
 102             }
 103         }
 104     }
 105
 106     Affector {//Custom Friction, adds some 'randomness'
 107         system: sys
 108         //onceOff: true
 109         x: -60
 110         width: parent.width + 120
 111         height: 100
 112         anchors.bottom: parent.bottom
 113         onAffectParticles: {
 114             for (var i=0; i<particles.length; i++) {
 115                 var particle = particles[i];
 116                 var pseudoRand = (Math.floor(particle.t*1327) % 10) + 1;
 117                 var yslow = dt * pseudoRand * 0.5 + 1;
 118                 var xslow = dt * pseudoRand * 0.05 + 1;
 119                 if (particle.vy < 1)
 120                     particle.vy = 0;
 121                 else
 122                     particle.vy = (particle.vy / yslow);
 123                 if (particle.vx < 1)
 124                     particle.vx = 0;
 125                 else
 126                     particle.vx = (particle.vx / xslow);
 127                 particle.update = true;
 128             }
 129         }
 130     }
 131
 132     ImageParticle {
 133         anchors.fill: parent
 134         id: particles
 135         system: sys
 136         sprites: [Sprite {
 137                 source: "../images/realLeaf1.png"
 138                 frames: 1
 139                 frameDuration: 1
 140                 to: {"a":1, "b":1, "c":1, "d":1}
 141             }, Sprite {
 142                 name: "a"
 143                 source: "../images/realLeaf1.png"
 144                 frames: 1
 145                 frameDuration: 10000
 146             },
 147             Sprite {
 148                 name: "b"
 149                 source: "../images/realLeaf2.png"
 150                 frames: 1
 151                 frameDuration: 10000
 152             },
 153             Sprite {
 154                 name: "c"
 155                 source: "../images/realLeaf3.png"
 156                 frames: 1
 157                 frameDuration: 10000
 158             },
 159             Sprite {
 160                 name: "d"
 161                 source: "../images/realLeaf4.png"
 162                 frames: 1
 163                 frameDuration: 10000
 164             }
 165         ]
 166
 167         width: 100
 168         height: 100
 169         x: 20
 170         y: 20
 171         z:4
 172     }
 173 }