examples/declarative/modelviews/visualdatamodel/sortedmodel.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: http://www.qt-project.org/
   6 **
   7 ** This file is part of the examples of the Qt Toolkit.
   8 **
   9 ** $QT_BEGIN_LICENSE:BSD$
  10 ** You may use this file under the terms of the BSD license as follows:
  11 **
  12 ** "Redistribution and use in source and binary forms, with or without
  13 ** modification, are permitted provided that the following conditions are
  14 ** met:
  15 **   * Redistributions of source code must retain the above copyright
  16 **     notice, this list of conditions and the following disclaimer.
  17 **   * Redistributions in binary form must reproduce the above copyright
  18 **     notice, this list of conditions and the following disclaimer in
  19 **     the documentation and/or other materials provided with the
  20 **     distribution.
  21 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  22 **     the names of its contributors may be used to endorse or promote
  23 **     products derived from this software without specific prior written
  24 **     permission.
  25 **
  26 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  27 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  28 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  29 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  30 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  31 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  32 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  33 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  34 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  35 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  36 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 2.0
  42
  43 Rectangle {
  44     width: 480; height: 640
  45
  46     Component {
  47         id: numberDelegate
  48
  49         Text {
  50             id: numberText
  51             anchors { left: parent.left; right: parent.right }
  52             text: number
  53
  54             horizontalAlignment: Text.AlignHCenter
  55             font.pixelSize: 18
  56
  57             Text {
  58                 anchors { left: parent.left; baseline: parent.baseline }
  59                 text: index
  60
  61                 horizontalAlignment: Text.AlignLeft
  62                 font.pixelSize: 12
  63             }
  64             Text {
  65                 anchors { right: parent.right; baseline: parent.baseline }
  66                 text: numberText.VisualDataModel.itemsIndex
  67
  68                 horizontalAlignment: Text.AlignRight
  69                 font.pixelSize: 12
  70             }
  71         }
  72     }
  73
  74     ListView {
  75         anchors {
  76             left: parent.left; top: parent.top;
  77             right: parent.horizontalCenter; bottom: button.top
  78             leftMargin: 2; topMargin: 2; rightMargin: 1; bottomMargin: 2
  79         }
  80
  81         model: ListModel {
  82             id: unsortedModel
  83         }
  84         delegate: numberDelegate
  85     }
  86     ListView {
  87         anchors {
  88             left: parent.horizontalCenter; top: parent.top;
  89             right: parent.right; bottom: button.top
  90             leftMargin: 1; topMargin: 2; rightMargin: 2; bottomMargin: 2
  91         }
  92         model: VisualDataModel {
  93             model: unsortedModel
  94             delegate: numberDelegate
  95
  96             items.onChanged: {
  97                 for (var i = 0; i < inserted.length; ++i) {
  98                     for (var j = inserted[i].index; j < inserted[i].index + inserted[i].count; ++j) {
  99                         var number = items.get(j).model.number
 100                         for (var l = 0, k = 0; l < unsortedModel.count; ++l) {
 101                             if (l == inserted[k].index) {
 102                                 l += inserted[k].count - 1
 103                                 ++k
 104                             } else if (number < items.get(l).model.number) {
 105                                 items.move(j, l, 1)
 106                                 break
 107                             }
 108                         }
 109                         inserted[i].index += 1;
 110                         inserted[i].count -= 1;
 111                     }
 112                 }
 113             }
 114         }
 115     }
 116
 117     Rectangle {
 118         id: button
 119
 120         anchors { left: parent.left; right: parent.right; bottom: parent.bottom; margins: 2 }
 121         height: moreText.implicitHeight + 4
 122
 123         color: "black"
 124
 125         Text {
 126             id: moreText
 127
 128             anchors.fill: parent
 129             text: "More"
 130             color: "white"
 131             font.pixelSize: 18
 132             horizontalAlignment: Text.AlignHCenter
 133             verticalAlignment: Text.AlignVCenter
 134         }
 135         MouseArea {
 136             anchors.fill: parent
 137
 138             onClicked: unsortedModel.append({ "number": Math.floor(Math.random() * 100) })
 139         }
 140     }
 141 }