examples/declarative/modelviews/listview/sections.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: http://www.qt-project.org/
   6 **
   7 ** This file is part of the examples of the Qt Toolkit.
   8 **
   9 ** $QT_BEGIN_LICENSE:BSD$
  10 ** You may use this file under the terms of the BSD license as follows:
  11 **
  12 ** "Redistribution and use in source and binary forms, with or without
  13 ** modification, are permitted provided that the following conditions are
  14 ** met:
  15 **   * Redistributions of source code must retain the above copyright
  16 **     notice, this list of conditions and the following disclaimer.
  17 **   * Redistributions in binary form must reproduce the above copyright
  18 **     notice, this list of conditions and the following disclaimer in
  19 **     the documentation and/or other materials provided with the
  20 **     distribution.
  21 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  22 **     the names of its contributors may be used to endorse or promote
  23 **     products derived from this software without specific prior written
  24 **     permission.
  25 **
  26 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  27 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  28 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  29 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  30 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  31 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  32 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  33 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  34 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  35 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  36 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 // This example shows how a ListView can be separated into sections using
  42 // the ListView.section attached property.
  43
  44 import QtQuick 2.0
  45 import "content"
  46
  47 Rectangle {
  48     id: container
  49     width: 300
  50     height: 360
  51
  52     ListModel {
  53         id: animalsModel
  54         ListElement { name: "Ant"; size: "Tiny" }
  55         ListElement { name: "Flea"; size: "Tiny" }
  56         ListElement { name: "Parrot"; size: "Small" }
  57         ListElement { name: "Guinea pig"; size: "Small" }
  58         ListElement { name: "Rat"; size: "Small" }
  59         ListElement { name: "Butterfly"; size: "Small" }
  60         ListElement { name: "Dog"; size: "Medium" }
  61         ListElement { name: "Cat"; size: "Medium" }
  62         ListElement { name: "Pony"; size: "Medium" }
  63         ListElement { name: "Koala"; size: "Medium" }
  64         ListElement { name: "Horse"; size: "Large" }
  65         ListElement { name: "Tiger"; size: "Large" }
  66         ListElement { name: "Giraffe"; size: "Large" }
  67         ListElement { name: "Elephant"; size: "Huge" }
  68         ListElement { name: "Whale"; size: "Huge" }
  69     }
  70
  71 //! [0]
  72     // The delegate for each section header
  73     Component {
  74         id: sectionHeading
  75         Rectangle {
  76             width: container.width
  77             height: childrenRect.height
  78             color: "lightsteelblue"
  79
  80             Text {
  81                 text: section
  82                 font.bold: true
  83                 font.pixelSize: 20
  84             }
  85         }
  86     }
  87
  88     ListView {
  89         id: view
  90         anchors.top: parent.top
  91         anchors.bottom: buttonBar.top
  92         width: parent.width
  93         model: animalsModel
  94         delegate: Text { text: name; font.pixelSize: 18 }
  95
  96         section.property: "size"
  97         section.criteria: ViewSection.FullString
  98         section.delegate: sectionHeading
  99     }
 100 //! [0]
 101
 102     Row {
 103         id: buttonBar
 104         anchors.bottom: parent.bottom
 105         anchors.bottomMargin: 1
 106         spacing: 1
 107         ToggleButton {
 108             label: "CurrentLabelAtStart"
 109             onToggled: {
 110                 if (active)
 111                     view.section.labelPositioning |= ViewSection.CurrentLabelAtStart
 112                 else
 113                     view.section.labelPositioning &= ~ViewSection.CurrentLabelAtStart
 114             }
 115         }
 116         ToggleButton {
 117             label: "NextLabelAtEnd"
 118             onToggled: {
 119                 if (active)
 120                     view.section.labelPositioning |= ViewSection.NextLabelAtEnd
 121                 else
 122                     view.section.labelPositioning &= ~ViewSection.NextLabelAtEnd
 123             }
 124         }
 125     }
 126 }
 127