examples/declarative/modelviews/listview/highlightranges.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2011 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: Nokia Corporation (qt-info@nokia.com)
   6 **
   7 ** This file is part of the examples of the Qt Toolkit.
   8 **
   9 ** $QT_BEGIN_LICENSE:BSD$
  10 ** You may use this file under the terms of the BSD license as follows:
  11 **
  12 ** "Redistribution and use in source and binary forms, with or without
  13 ** modification, are permitted provided that the following conditions are
  14 ** met:
  15 **   * Redistributions of source code must retain the above copyright
  16 **     notice, this list of conditions and the following disclaimer.
  17 **   * Redistributions in binary form must reproduce the above copyright
  18 **     notice, this list of conditions and the following disclaimer in
  19 **     the documentation and/or other materials provided with the
  20 **     distribution.
  21 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  22 **     the names of its contributors may be used to endorse or promote
  23 **     products derived from this software without specific prior written
  24 **     permission.
  25 **
  26 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  27 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  28 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  29 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  30 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  31 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  32 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  33 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  34 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  35 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  36 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 1.0
  42 import "content"
  43
  44 Rectangle {
  45     id: root
  46     property int current: 0
  47     width: 600; height: 300
  48
  49     // This example shows the same model in three different ListView items,
  50     // with different highlight ranges. The highlight ranges are set by the
  51     // preferredHighlightBegin and preferredHighlightEnd properties in ListView.
  52     //
  53     // The first ListView does not set a highlight range, so its currentItem
  54     // can move freely within the visible area. If it moves outside the
  55     // visible area, the view is automatically scrolled to keep the current
  56     // item visible.
  57     //
  58     // The second ListView sets a highlight range which attempts to keep the
  59     // current item within the the bounds of the range. However,
  60     // items will not scroll beyond the beginning or end of the view,
  61     // forcing the highlight to move outside the range at the ends.
  62     //
  63     // The third ListView sets the highlightRangeMode to StrictlyEnforceRange
  64     // and sets a range smaller than the height of an item.  This
  65     // forces the current item to change when the view is flicked,
  66     // since the highlight is unable to move.
  67     //
  68     // All ListViews bind their currentIndex to the root.current property.
  69     // The first ListView sets root.current whenever its currentIndex changes
  70     // due to keyboard interaction.
  71     // Flicking the third ListView with the mouse also changes root.current.
  72
  73     ListView {
  74         id: list1
  75         width: 200; height: parent.height
  76         model: PetsModel {}
  77         delegate: petDelegate
  78
  79         highlight: Rectangle { color: "lightsteelblue" }
  80         currentIndex: root.current
  81         onCurrentIndexChanged: root.current = currentIndex
  82         focus: true
  83     }
  84
  85     ListView {
  86         id: list2
  87         x: list1.width
  88         width: 200; height: parent.height
  89         model: PetsModel {}
  90         delegate: petDelegate
  91
  92         highlight: Rectangle { color: "yellow" }
  93         currentIndex: root.current
  94         preferredHighlightBegin: 80; preferredHighlightEnd: 220
  95         highlightRangeMode: ListView.ApplyRange
  96     }
  97
  98     ListView {
  99         id: list3
 100         x: list1.width + list2.width
 101         width: 200; height: parent.height
 102         model: PetsModel {}
 103         delegate: petDelegate
 104
 105         highlight: Rectangle { color: "yellow" }
 106         currentIndex: root.current
 107         onCurrentIndexChanged: root.current = currentIndex
 108         preferredHighlightBegin: 125; preferredHighlightEnd: 125
 109         highlightRangeMode: ListView.StrictlyEnforceRange
 110     }
 111
 112     // The delegate for each list
 113     Component {
 114         id: petDelegate
 115         Column {
 116             width: 200
 117             Text { text: 'Name: ' + name }
 118             Text { text: 'Type: ' + type }
 119             Text { text: 'Age: ' + age }
 120         }
 121     }
 122 }