examples/declarative/minehunt/MinehuntCore/Tile.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: http://www.qt-project.org/
   6 **
   7 ** This file is part of the QtDeclarative module of the Qt Toolkit.
   8 **
   9 ** $QT_BEGIN_LICENSE:LGPL$
  10 ** GNU Lesser General Public License Usage
  11 ** This file may be used under the terms of the GNU Lesser General Public
  12 ** License version 2.1 as published by the Free Software Foundation and
  13 ** appearing in the file LICENSE.LGPL included in the packaging of this
  14 ** file. Please review the following information to ensure the GNU Lesser
  15 ** General Public License version 2.1 requirements will be met:
  16 ** http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
  17 **
  18 ** In addition, as a special exception, Nokia gives you certain additional
  19 ** rights. These rights are described in the Nokia Qt LGPL Exception
  20 ** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
  21 **
  22 ** GNU General Public License Usage
  23 ** Alternatively, this file may be used under the terms of the GNU General
  24 ** Public License version 3.0 as published by the Free Software Foundation
  25 ** and appearing in the file LICENSE.GPL included in the packaging of this
  26 ** file. Please review the following information to ensure the GNU General
  27 ** Public License version 3.0 requirements will be met:
  28 ** http://www.gnu.org/copyleft/gpl.html.
  29 **
  30 ** Other Usage
  31 ** Alternatively, this file may be used in accordance with the terms and
  32 ** conditions contained in a signed written agreement between you and Nokia.
  33 **
  34 **
  35 **
  36 **
  37 **
  38 ** $QT_END_LICENSE$
  39 **
  40 ****************************************************************************/
  41
  42 import QtQuick 2.0
  43
  44 Flipable {
  45     id: flipable
  46     property int angle: 0
  47
  48     width: 40;  height: 40
  49     transform: Rotation { origin.x: 20; origin.y: 20; axis.x: 1; axis.z: 0; angle: flipable.angle }
  50
  51     front: Image {
  52         source: "pics/front.png"; width: 40; height: 40
  53
  54         Image {
  55             anchors.centerIn: parent
  56             source: "pics/flag.png"; opacity: modelData.hasFlag
  57
  58             Behavior on opacity { NumberAnimation {} }
  59         }
  60     }
  61
  62     back: Image {
  63         source: "pics/back.png"
  64         width: 40; height: 40
  65
  66         Text {
  67             anchors.centerIn: parent
  68             text: modelData.hint; color: "white"; font.bold: true
  69             opacity: !modelData.hasMine && modelData.hint > 0
  70         }
  71
  72         Image {
  73             anchors.centerIn: parent
  74             source: "pics/bomb.png"; opacity: modelData.hasMine
  75         }
  76
  77         Explosion { id: expl }
  78     }
  79
  80     states: State {
  81         name: "back"; when: modelData.flipped
  82         PropertyChanges { target: flipable; angle: 180 }
  83     }
  84
  85     property real pauseDur: 250
  86     transitions: Transition {
  87         SequentialAnimation {
  88             ScriptAction {
  89                 script: {
  90                     var ret = Math.abs(flipable.x - field.clickx)
  91                         + Math.abs(flipable.y - field.clicky);
  92                     if (modelData.hasMine && modelData.flipped)
  93                         pauseDur = ret * 3
  94                     else
  95                         pauseDur = ret
  96                 }
  97             }
  98             PauseAnimation {
  99                 duration: pauseDur
 100             }
 101             RotationAnimation { easing.type: Easing.InOutQuad }
 102             ScriptAction { script: if (modelData.hasMine && modelData.flipped) { expl.explode = true } }
 103         }
 104     }
 105
 106     MouseArea {
 107         anchors.fill: parent
 108         acceptedButtons: Qt.LeftButton | Qt.RightButton
 109         onClicked: {
 110             field.clickx = flipable.x
 111             field.clicky = flipable.y
 112             var row = Math.floor(index / 9)
 113             var col = index - (Math.floor(index / 9) * 9)
 114             if (mouse.button == undefined || mouse.button == Qt.RightButton) {
 115                 flag(row, col)
 116             } else {
 117                 flip(row, col)
 118             }
 119         }
 120         onPressAndHold: {
 121             field.clickx = flipable.x
 122             field.clicky = flipable.y
 123             var row = Math.floor(index / 9)
 124             var col = index - (Math.floor(index / 9) * 9)
 125             flag(row, col)
 126         }
 127     }
 128 }