examples/declarative/keyinteraction/focus/Core/GridMenu.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: http://www.qt-project.org/
   6 **
   7 ** This file is part of the examples of the Qt Toolkit.
   8 **
   9 ** $QT_BEGIN_LICENSE:BSD$
  10 ** You may use this file under the terms of the BSD license as follows:
  11 **
  12 ** "Redistribution and use in source and binary forms, with or without
  13 ** modification, are permitted provided that the following conditions are
  14 ** met:
  15 **   * Redistributions of source code must retain the above copyright
  16 **     notice, this list of conditions and the following disclaimer.
  17 **   * Redistributions in binary form must reproduce the above copyright
  18 **     notice, this list of conditions and the following disclaimer in
  19 **     the documentation and/or other materials provided with the
  20 **     distribution.
  21 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  22 **     the names of its contributors may be used to endorse or promote
  23 **     products derived from this software without specific prior written
  24 **     permission.
  25 **
  26 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  27 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  28 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  29 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  30 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  31 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  32 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  33 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  34 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  35 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  36 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 2.0
  42
  43 FocusScope {
  44     property alias interactive: gridView.interactive
  45
  46     onActiveFocusChanged: {
  47         if (activeFocus)
  48             mainView.state = ""
  49     }
  50
  51     Rectangle {
  52         anchors.fill: parent
  53         clip: true
  54         gradient: Gradient {
  55             GradientStop { position: 0.0; color: "#193441" }
  56             GradientStop { position: 1.0; color: Qt.darker("#193441") }
  57         }
  58
  59         GridView {
  60             id: gridView
  61             anchors.fill: parent; anchors.leftMargin: 20; anchors.rightMargin: 20
  62             cellWidth: 152; cellHeight: 152
  63             focus: true
  64             model: 12
  65
  66             KeyNavigation.down: listMenu
  67             KeyNavigation.left: contextMenu
  68
  69             delegate: Item {
  70                 id: container
  71                 width: GridView.view.cellWidth; height: GridView.view.cellHeight
  72
  73                 Rectangle {
  74                     id: content
  75                     color: "transparent"
  76                     smooth: true
  77                     anchors.fill: parent; anchors.margins: 20; radius: 10
  78
  79                     Rectangle { color: "#91AA9D"; anchors.fill: parent; anchors.margins: 3; radius: 8; smooth: true }
  80                     Image { source: "images/qt-logo.png"; anchors.centerIn: parent; smooth: true }
  81                 }
  82
  83                 MouseArea {
  84                     id: mouseArea
  85                     anchors.fill: parent
  86                     hoverEnabled: true
  87
  88                     onClicked: {
  89                         container.GridView.view.currentIndex = index
  90                         container.forceActiveFocus()
  91                     }
  92                 }
  93
  94                 states: State {
  95                     name: "active"; when: container.activeFocus
  96                     PropertyChanges { target: content; color: "#FCFFF5"; scale: 1.1 }
  97                 }
  98
  99                 transitions: Transition {
 100                     NumberAnimation { properties: "scale"; duration: 100 }
 101                 }
 102             }
 103         }
 104     }
 105 }