examples/declarative/draganddrop/views/gridview.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** Contact: http://www.qt-project.org/
   5 **
   6 ** This file is part of the examples of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:BSD$
   9 ** You may use this file under the terms of the BSD license as follows:
  10 **
  11 ** "Redistribution and use in source and binary forms, with or without
  12 ** modification, are permitted provided that the following conditions are
  13 ** met:
  14 **   * Redistributions of source code must retain the above copyright
  15 **     notice, this list of conditions and the following disclaimer.
  16 **   * Redistributions in binary form must reproduce the above copyright
  17 **     notice, this list of conditions and the following disclaimer in
  18 **     the documentation and/or other materials provided with the
  19 **     distribution.
  20 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  21 **     the names of its contributors may be used to endorse or promote
  22 **     products derived from this software without specific prior written
  23 **     permission.
  24 **
  25 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  26 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  27 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  28 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  29 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  30 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  31 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  32 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  33 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  34 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  35 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  36 **
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 2.0
  42
  43 GridView {
  44     id: root
  45     width: 360; height: 360
  46     cellWidth: 90; cellHeight: 90
  47
  48     model: VisualDataModel {
  49         id: visualModel
  50         model: ListModel {
  51             id: colorModel
  52             ListElement { color: "blue" }
  53             ListElement { color: "green" }
  54             ListElement { color: "red" }
  55             ListElement { color: "yellow" }
  56             ListElement { color: "orange" }
  57             ListElement { color: "purple" }
  58             ListElement { color: "cyan" }
  59             ListElement { color: "magenta" }
  60             ListElement { color: "chartreuse" }
  61             ListElement { color: "aquamarine" }
  62             ListElement { color: "indigo" }
  63             ListElement { color: "black" }
  64             ListElement { color: "chartreuse" }
  65             ListElement { color: "violet" }
  66             ListElement { color: "grey" }
  67             ListElement { color: "springgreen" }
  68         }
  69
  70         delegate: MouseArea {
  71             id: delegateRoot
  72
  73             property int visualIndex: VisualDataModel.itemsIndex
  74
  75             width: 90; height: 90
  76             drag.target: icon
  77
  78             Rectangle {
  79                 id: icon
  80                 width: 80; height: 80
  81                 anchors {
  82                     horizontalCenter: parent.horizontalCenter;
  83                     verticalCenter: parent.verticalCenter
  84                 }
  85                 color: model.color
  86                 radius: 3
  87
  88                 Drag.active: delegateRoot.pressed
  89                 Drag.source: delegateRoot
  90                 Drag.hotSpot.x: 40
  91                 Drag.hotSpot.y: 40
  92
  93                 states: [
  94                     State {
  95                         when: icon.Drag.active
  96                         ParentChange {
  97                             target: icon
  98                             parent: root
  99                         }
 100
 101                         AnchorChanges {
 102                             target: icon;
 103                             anchors.horizontalCenter: undefined;
 104                             anchors.verticalCenter: undefined
 105                         }
 106                     }
 107                 ]
 108             }
 109
 110             DropArea {
 111                 anchors { fill: parent; margins: 15 }
 112
 113                 onEntered: visualModel.items.move(drag.source.visualIndex, delegateRoot.visualIndex)
 114             }
 115         }
 116     }
 117 }