examples/declarative/canvas/squircle/squircle.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: http://www.qt-project.org/
   6 **
   7 ** This file is part of the examples of the Qt Toolkit.
   8 **
   9 ** $QT_BEGIN_LICENSE:BSD$
  10 ** You may use this file under the terms of the BSD license as follows:
  11 **
  12 ** "Redistribution and use in source and binary forms, with or without
  13 ** modification, are permitted provided that the following conditions are
  14 ** met:
  15 **   * Redistributions of source code must retain the above copyright
  16 **     notice, this list of conditions and the following disclaimer.
  17 **   * Redistributions in binary form must reproduce the above copyright
  18 **     notice, this list of conditions and the following disclaimer in
  19 **     the documentation and/or other materials provided with the
  20 **     distribution.
  21 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  22 **     the names of its contributors may be used to endorse or promote
  23 **     products derived from this software without specific prior written
  24 **     permission.
  25 **
  26 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  27 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  28 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  29 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  30 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  31 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  32 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  33 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  34 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  35 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  36 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 2.0
  42 import "../contents"
  43 Item {
  44   id:container
  45   width:360
  46   height:600
  47
  48   Column {
  49     spacing:5
  50     anchors.fill:parent
  51     Text { font.pointSize:25; text:"Squircles"; anchors.horizontalCenter:parent.horizontalCenter}
  52     Image {
  53        anchors.horizontalCenter:parent.horizontalCenter
  54        source:"squircle.png"
  55        width:250
  56        height:25
  57     }
  58     Canvas {
  59         id:canvas
  60         width:360
  61         height:360
  62         smooth:true
  63         renderTarget:Canvas.Image
  64         renderInThread:false
  65
  66         property string strokeStyle:"blue"
  67         property string fillStyle:"steelblue"
  68         property int lineWidth:2
  69         property int nSize:nCtrl.value
  70         property real radius:rCtrl.value
  71         property bool fill:true
  72         property bool stroke:false
  73         property real px:xCtrl.value
  74         property real py:yCtrl.value
  75         property real alpha:alphaCtrl.value
  76
  77         onAlphaChanged:requestPaint();
  78         onRadiusChanged:requestPaint();
  79         onLineWidthChanged:requestPaint();
  80         onNSizeChanged:requestPaint();
  81         onFillChanged:requestPaint();
  82         onStrokeChanged:requestPaint();
  83         onPxChanged:requestPaint();
  84         onPyChanged:requestPaint();
  85
  86
  87         onPaint: squcirle();
  88
  89         function squcirle() {
  90           var ctx = canvas.getContext("2d");
  91           var N = canvas.nSize;
  92           var R = canvas.radius;
  93
  94           N=Math.abs(N);
  95           var M=N;
  96           if (N>100) M=100;
  97           if (N<0.00000000001) M=0.00000000001;
  98
  99           ctx.reset();
 100           ctx.globalAlpha =canvas.alpha;
 101           ctx.fillStyle = "gray";
 102           ctx.fillRect(0, 0, canvas.width, canvas.height);
 103
 104           ctx.strokeStyle = canvas.strokeStyle;
 105           ctx.fillStyle = canvas.fillStyle;
 106           ctx.lineWidth = canvas.lineWidth;
 107
 108           ctx.beginPath();
 109           var i = 0, x, y;
 110           for (i=0; i<(2*R+1); i++){
 111              x = Math.round(i-R) + canvas.px;
 112              y = Math.round(Math.pow(Math.abs(Math.pow(R,M)-Math.pow(Math.abs(i-R),M)),1/M)) + canvas.py;
 113
 114              if (i == 0)
 115                ctx.moveTo(x, y);
 116              else
 117                ctx.lineTo(x, y);
 118           }
 119
 120           for (i=(2*R); i<(4*R+1); i++){
 121             x =Math.round(3*R-i)+canvas.px;
 122             y = Math.round(-Math.pow(Math.abs(Math.pow(R,M)-Math.pow(Math.abs(3*R-i),M)),1/M)) + canvas.py;
 123             ctx.lineTo(x, y);
 124           }
 125           ctx.closePath();
 126           if (canvas.stroke) {
 127               ctx.stroke();
 128           }
 129
 130           if (canvas.fill) {
 131               ctx.fill();
 132           }
 133
 134           ctx.fillStyle = "yellow";
 135           ctx.font = "Helvetica  16px";
 136           ctx.fillText("|X-" + Math.round(canvas.px) + "|^" + N + " + |Y-"+Math.round(canvas.py)+"|^" + N + " = |" + Math.round(R) + "|^" + N, canvas.px - 125, canvas.py);
 137         }
 138     }
 139
 140     Rectangle {
 141         id:controls
 142         width:360
 143         height:160
 144         Column {
 145           spacing:3
 146           Slider {id:nCtrl; width:300; height:30; min:1; max:10; init:4; name:"N"}
 147           Slider {id:rCtrl; width:300; height:30; min:30; max:180; init:100; name:"Radius"}
 148           Slider {id:xCtrl; width:300; height:30; min:50; max:300; init:180; name:"X"}
 149           Slider {id:yCtrl; width:300; height:30; min:30; max:300; init:220; name:"Y"}
 150           Slider {id:alphaCtrl; width:300; height:30; min:0; max:1; init:1; name:"Alpha"}
 151         }
 152     }
 153   }
 154 }