examples/declarative/canvas/roundedrect/roundedrect.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: http://www.qt-project.org/
   6 **
   7 ** This file is part of the examples of the Qt Toolkit.
   8 **
   9 ** $QT_BEGIN_LICENSE:BSD$
  10 ** You may use this file under the terms of the BSD license as follows:
  11 **
  12 ** "Redistribution and use in source and binary forms, with or without
  13 ** modification, are permitted provided that the following conditions are
  14 ** met:
  15 **   * Redistributions of source code must retain the above copyright
  16 **     notice, this list of conditions and the following disclaimer.
  17 **   * Redistributions in binary form must reproduce the above copyright
  18 **     notice, this list of conditions and the following disclaimer in
  19 **     the documentation and/or other materials provided with the
  20 **     distribution.
  21 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  22 **     the names of its contributors may be used to endorse or promote
  23 **     products derived from this software without specific prior written
  24 **     permission.
  25 **
  26 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  27 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  28 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  29 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  30 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  31 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  32 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  33 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  34 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  35 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  36 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 2.0
  42 import "../contents"
  43 Item {
  44   id:container
  45   width:360
  46   height:600
  47
  48   Column {
  49     spacing:5
  50     anchors.fill:parent
  51     Text { font.pointSize:25; text:"Rounded rectangle"; anchors.horizontalCenter:parent.horizontalCenter}
  52     Canvas {
  53         id:canvas
  54         width:360
  55         height:360
  56         smooth:true
  57         renderTarget:Canvas.Image
  58         renderInThread:false
  59
  60         property int radius: rCtrl.value
  61         property int rectx: rxCtrl.value
  62         property int recty: ryCtrl.value
  63         property int rectWidth: width - 2*rectx
  64         property int rectHeight: height - 2*recty
  65         property string strokeStyle:"blue"
  66         property string fillStyle:"steelblue"
  67         property int lineWidth:lineWidthCtrl.value
  68         property bool fill:true
  69         property bool stroke:true
  70         property real alpha:alphaCtrl.value
  71
  72         onLineWidthChanged:requestPaint();
  73         onFillChanged:requestPaint();
  74         onStrokeChanged:requestPaint();
  75         onRadiusChanged:requestPaint();
  76         onRectxChanged:requestPaint();
  77         onRectyChanged:requestPaint();
  78         onAlphaChanged:requestPaint();
  79
  80         onPaint: {
  81             var ctx = getContext("2d");
  82             ctx.reset();
  83             ctx.clearRect(0,0,canvas.width, canvas.height);
  84             ctx.strokeStyle = canvas.strokeStyle;
  85             ctx.lineWidth = canvas.lineWidth
  86             ctx.fillStyle = canvas.fillStyle
  87             ctx.globalAlpha = canvas.alpha
  88             ctx.beginPath();
  89             ctx.moveTo(rectx+radius,recty);                 // top side
  90             ctx.lineTo(rectx+rectWidth-radius,recty);
  91             // draw top right corner
  92             ctx.arcTo(rectx+rectWidth,recty,rectx+rectWidth,recty+radius,radius);
  93             ctx.lineTo(rectx+rectWidth,recty+rectHeight-radius);    // right side
  94             // draw bottom right corner
  95             ctx.arcTo(rectx+rectWidth,recty+rectHeight,rectx+rectWidth-radius,recty+rectHeight,radius);
  96             ctx.lineTo(rectx+radius,recty+rectHeight);              // bottom side
  97             // draw bottom left corner
  98             ctx.arcTo(rectx,recty+rectHeight,rectx,recty+rectHeight-radius,radius);
  99             ctx.lineTo(rectx,recty+radius);                 // left side
 100             // draw top left corner
 101             ctx.arcTo(rectx,recty,rectx+radius,recty,radius);
 102             ctx.closePath();
 103             if (canvas.fill)
 104                 ctx.fill();
 105             if (canvas.stroke)
 106                 ctx.stroke();
 107         }
 108     }
 109
 110     Rectangle {
 111         id:controls
 112         width:360
 113         height:160
 114         Column {
 115           spacing:3
 116           Slider {id:lineWidthCtrl; width:300; height:30; min:1; max:10; init:2; name:"Line width"}
 117           Slider {id:rxCtrl; width:300; height:30; min:5; max:30; init:10; name:"rectx"}
 118           Slider {id:ryCtrl; width:300; height:30; min:5; max:30; init:10; name:"recty"}
 119           Slider {id:rCtrl; width:300; height:30; min:10; max:100; init:40; name:"Radius"}
 120           Slider {id:alphaCtrl; width:300; height:30; min:0; max:1; init:1; name:"Alpha"}
 121         }
 122     }
 123   }
 124 }