examples/declarative/animation/states/transitions.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2011 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: Nokia Corporation (qt-info@nokia.com)
   6 **
   7 ** This file is part of the examples of the Qt Toolkit.
   8 **
   9 ** $QT_BEGIN_LICENSE:BSD$
  10 ** You may use this file under the terms of the BSD license as follows:
  11 **
  12 ** "Redistribution and use in source and binary forms, with or without
  13 ** modification, are permitted provided that the following conditions are
  14 ** met:
  15 **   * Redistributions of source code must retain the above copyright
  16 **     notice, this list of conditions and the following disclaimer.
  17 **   * Redistributions in binary form must reproduce the above copyright
  18 **     notice, this list of conditions and the following disclaimer in
  19 **     the documentation and/or other materials provided with the
  20 **     distribution.
  21 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  22 **     the names of its contributors may be used to endorse or promote
  23 **     products derived from this software without specific prior written
  24 **     permission.
  25 **
  26 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  27 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  28 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  29 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  30 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  31 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  32 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  33 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  34 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  35 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  36 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 1.0
  42
  43 /*
  44     This is exactly the same as states.qml, except that we have appended
  45     a set of transitions to apply animations when the item changes
  46     between each state.
  47 */
  48
  49 Rectangle {
  50     id: page
  51     width: 640; height: 480
  52     color: "#343434"
  53
  54     Image {
  55         id: userIcon
  56         x: topLeftRect.x; y: topLeftRect.y
  57         source: "qt-logo.png"
  58     }
  59
  60     Rectangle {
  61         id: topLeftRect
  62
  63         anchors { left: parent.left; top: parent.top; leftMargin: 10; topMargin: 20 }
  64         width: 46; height: 54
  65         color: "Transparent"; border.color: "Gray"; radius: 6
  66
  67         // Clicking in here sets the state to the default state, returning the image to
  68         // its initial position
  69         MouseArea { anchors.fill: parent; onClicked: page.state = '' }
  70     }
  71
  72     Rectangle {
  73         id: middleRightRect
  74
  75         anchors { right: parent.right; verticalCenter: parent.verticalCenter; rightMargin: 20 }
  76         width: 46; height: 54
  77         color: "Transparent"; border.color: "Gray"; radius: 6
  78
  79         // Clicking in here sets the state to 'middleRight'
  80         MouseArea { anchors.fill: parent; onClicked: page.state = 'middleRight' }
  81     }
  82
  83     Rectangle {
  84         id: bottomLeftRect
  85
  86         anchors { left: parent.left; bottom: parent.bottom; leftMargin: 10; bottomMargin: 20 }
  87         width: 46; height: 54
  88         color: "Transparent"; border.color: "Gray"; radius: 6
  89
  90         // Clicking in here sets the state to 'bottomLeft'
  91         MouseArea { anchors.fill: parent; onClicked: page.state = 'bottomLeft' }
  92     }
  93
  94     states: [
  95         // In state 'middleRight', move the image to middleRightRect
  96         State {
  97             name: "middleRight"
  98             PropertyChanges { target: userIcon; x: middleRightRect.x; y: middleRightRect.y }
  99         },
 100
 101         // In state 'bottomLeft', move the image to bottomLeftRect
 102         State {
 103             name: "bottomLeft"
 104             PropertyChanges { target: userIcon; x: bottomLeftRect.x; y: bottomLeftRect.y  }
 105         }
 106     ]
 107
 108     // Transitions define how the properties change when the item moves between each state
 109     transitions: [
 110
 111         // When transitioning to 'middleRight' move x,y over a duration of 1 second,
 112         // with OutBounce easing function.
 113         Transition {
 114             from: "*"; to: "middleRight"
 115             NumberAnimation { properties: "x,y"; easing.type: Easing.OutBounce; duration: 1000 }
 116         },
 117
 118         // When transitioning to 'bottomLeft' move x,y over a duration of 2 seconds,
 119         // with InOutQuad easing function.
 120         Transition {
 121             from: "*"; to: "bottomLeft"
 122             NumberAnimation { properties: "x,y"; easing.type: Easing.InOutQuad; duration: 2000 }
 123         },
 124
 125         // For any other state changes move x,y linearly over duration of 200ms.
 126         Transition {
 127             NumberAnimation { properties: "x,y"; duration: 200 }
 128         }
 129     ]
 130 }