examples/declarative/animation/pathinterpolator/pathinterpolator.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: Nokia Corporation (qt-info@nokia.com)
   6 **
   7 ** This file is part of the examples of the Qt Toolkit.
   8 **
   9 ** $QT_BEGIN_LICENSE:BSD$
  10 ** You may use this file under the terms of the BSD license as follows:
  11 **
  12 ** "Redistribution and use in source and binary forms, with or without
  13 ** modification, are permitted provided that the following conditions are
  14 ** met:
  15 **   * Redistributions of source code must retain the above copyright
  16 **     notice, this list of conditions and the following disclaimer.
  17 **   * Redistributions in binary form must reproduce the above copyright
  18 **     notice, this list of conditions and the following disclaimer in
  19 **     the documentation and/or other materials provided with the
  20 **     distribution.
  21 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  22 **     the names of its contributors may be used to endorse or promote
  23 **     products derived from this software without specific prior written
  24 **     permission.
  25 **
  26 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  27 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  28 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  29 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  30 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  31 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  32 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  33 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  34 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  35 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  36 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 2.0
  42
  43 Rectangle {
  44     id: window
  45     width: 400
  46     height: 400
  47
  48     Canvas {
  49         id: canvas
  50         anchors.fill: parent
  51         smooth: true
  52
  53         onPaint: {
  54             context.strokeStyle = "black"
  55             context.path = motionPath.path
  56             context.stroke()
  57         }
  58     }
  59
  60     PathInterpolator {
  61         id: motionPath
  62
  63         path: Path {
  64             startX: 50; startY: 50
  65
  66             PathCubic {
  67                 x: window.width - 50
  68                 y: window.height - 50
  69
  70                 control1X: x; control1Y: 50
  71                 control2X: 50; control2Y: y
  72             }
  73
  74             onChanged: canvas.requestPaint()
  75         }
  76
  77         NumberAnimation on progress {
  78             id: progressAnim
  79             running: false
  80             from: 0; to: 1
  81             duration: 2000
  82             easing.type: Easing.InQuad
  83         }
  84     }
  85
  86     Rectangle {
  87         id: box
  88
  89         width: 50; height: 50
  90         border.width: 1
  91         smooth: true
  92
  93         //bind our attributes to follow the path as progress changes
  94         x: motionPath.x
  95         y: motionPath.y
  96         rotation: motionPath.angle
  97         transform: Translate { x: -box.width/2; y: -box.height/2 }
  98
  99         Text {
 100             anchors.centerIn: parent
 101             text: "Box"
 102         }
 103     }
 104
 105     MouseArea {
 106         anchors.fill: parent
 107         onClicked: progressAnim.restart()
 108     }
 109
 110     Text {
 111         text: "Click anywhere to animate along the path"
 112         anchors.horizontalCenter: parent.horizontalCenter
 113     }
 114 }