examples/declarative/animation/behaviors/wigglytext.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** Contact: http://www.qt-project.org/
   5 **
   6 ** This file is part of the examples of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:BSD$
   9 ** You may use this file under the terms of the BSD license as follows:
  10 **
  11 ** "Redistribution and use in source and binary forms, with or without
  12 ** modification, are permitted provided that the following conditions are
  13 ** met:
  14 **   * Redistributions of source code must retain the above copyright
  15 **     notice, this list of conditions and the following disclaimer.
  16 **   * Redistributions in binary form must reproduce the above copyright
  17 **     notice, this list of conditions and the following disclaimer in
  18 **     the documentation and/or other materials provided with the
  19 **     distribution.
  20 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  21 **     the names of its contributors may be used to endorse or promote
  22 **     products derived from this software without specific prior written
  23 **     permission.
  24 **
  25 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  26 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  27 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  28 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  29 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  30 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  31 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  32 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  33 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  34 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  35 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  36 **
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 2.0
  42
  43 Rectangle {
  44     id: container
  45
  46     property string text: "Drag this text..."
  47     property bool animated: true
  48
  49     width: 640; height: 480; color: "#474747"; focus: true
  50
  51     Keys.onPressed: {
  52         if (event.key == Qt.Key_Delete || event.key == Qt.Key_Backspace)
  53             container.remove()
  54         else if (event.text != "") {
  55             container.append(event.text)
  56         }
  57     }
  58
  59     function append(text) {
  60         container.animated = false
  61         var lastLetter = container.children[container.children.length - 1]
  62         var newLetter = letterComponent.createObject(container)
  63         newLetter.text = text
  64         newLetter.follow = lastLetter
  65         container.animated = true
  66     }
  67
  68     function remove() {
  69         if (container.children.length)
  70             container.children[container.children.length - 1].destroy()
  71     }
  72
  73     function doLayout() {
  74         var follow = null
  75         for (var i = 0; i < container.text.length; ++i) {
  76             var newLetter = letterComponent.createObject(container)
  77             newLetter.text = container.text[i]
  78             newLetter.follow = follow
  79             follow = newLetter
  80         }
  81     }
  82
  83     Component {
  84         id: letterComponent
  85         Text {
  86             id: letter
  87             property variant follow
  88
  89             x: follow ? follow.x + follow.width : container.width / 3
  90             y: follow ? follow.y : container.height / 2
  91
  92             font.pixelSize: 40; font.bold: true
  93             color: "#999999"; styleColor: "#222222"; style: Text.Raised
  94
  95             MouseArea {
  96                 anchors.fill: parent
  97                 drag.target: letter; drag.axis: Drag.XandYAxis
  98                 onPressed: letter.color = "#dddddd"
  99                 onReleased: letter.color = "#999999"
 100             }
 101
 102             Behavior on x { enabled: container.animated; SpringAnimation { spring: 3; damping: 0.3; mass: 1.0 } }
 103             Behavior on y { enabled: container.animated; SpringAnimation { spring: 3; damping: 0.3; mass: 1.0 } }
 104         }
 105     }
 106
 107     Component.onCompleted: doLayout()
 108 }