examples/declarative/animation/behaviors/behavior-example.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** Contact: http://www.qt-project.org/
   5 **
   6 ** This file is part of the examples of the Qt Toolkit.
   7 **
   8 ** $QT_BEGIN_LICENSE:BSD$
   9 ** You may use this file under the terms of the BSD license as follows:
  10 **
  11 ** "Redistribution and use in source and binary forms, with or without
  12 ** modification, are permitted provided that the following conditions are
  13 ** met:
  14 **   * Redistributions of source code must retain the above copyright
  15 **     notice, this list of conditions and the following disclaimer.
  16 **   * Redistributions in binary form must reproduce the above copyright
  17 **     notice, this list of conditions and the following disclaimer in
  18 **     the documentation and/or other materials provided with the
  19 **     distribution.
  20 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  21 **     the names of its contributors may be used to endorse or promote
  22 **     products derived from this software without specific prior written
  23 **     permission.
  24 **
  25 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  26 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  27 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  28 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  29 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  30 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  31 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  32 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  33 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  34 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  35 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  36 **
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 2.0
  42
  43 Rectangle {
  44     width: 600; height: 400
  45     color: "#343434"
  46
  47     Rectangle {
  48         anchors.centerIn: parent
  49         width: 200; height: 200
  50         radius: 30
  51         color: "transparent"
  52         border.width: 4; border.color: "white"
  53
  54
  55         SideRect {
  56             id: leftRect
  57             anchors { verticalCenter: parent.verticalCenter; horizontalCenter: parent.left }
  58             text: "Left"
  59         }
  60
  61         SideRect {
  62             id: rightRect
  63             anchors { verticalCenter: parent.verticalCenter; horizontalCenter: parent.right }
  64             text: "Right"
  65         }
  66
  67         SideRect {
  68             id: topRect
  69             anchors { verticalCenter: parent.top; horizontalCenter: parent.horizontalCenter }
  70             text: "Top"
  71         }
  72
  73         SideRect {
  74             id: bottomRect
  75             anchors { verticalCenter: parent.bottom; horizontalCenter: parent.horizontalCenter }
  76             text: "Bottom"
  77         }
  78
  79
  80         Rectangle {
  81             id: focusRect
  82
  83             property string text
  84
  85             x: 62; y: 75; width: 75; height: 50
  86             radius: 6
  87             border.width: 4; border.color: "white"
  88             color: "firebrick"
  89
  90             // Set an 'elastic' behavior on the focusRect's x property.
  91             Behavior on x {
  92                 NumberAnimation { easing.type: Easing.OutElastic; easing.amplitude: 3.0; easing.period: 2.0; duration: 300 }
  93             }
  94
  95             // Set an 'elastic' behavior on the focusRect's y property.
  96             Behavior on y {
  97                 NumberAnimation { easing.type: Easing.OutElastic; easing.amplitude: 3.0; easing.period: 2.0; duration: 300 }
  98             }
  99
 100             Text {
 101                 id: focusText
 102                 text: focusRect.text
 103                 anchors.centerIn: parent
 104                 color: "white"
 105                 font.pixelSize: 16; font.bold: true
 106
 107                 // Set a behavior on the focusText's x property:
 108                 // Set the opacity to 0, set the new text value, then set the opacity back to 1.
 109                 Behavior on text {
 110                     SequentialAnimation {
 111                         NumberAnimation { target: focusText; property: "opacity"; to: 0; duration: 150 }
 112                         NumberAnimation { target: focusText; property: "opacity"; to: 1; duration: 150 }
 113                     }
 114                 }
 115             }
 116         }
 117     }
 118 }