examples/declarative/animation/basics/property-animation.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: http://www.qt-project.org/
   6 **
   7 ** This file is part of the examples of the Qt Toolkit.
   8 **
   9 ** $QT_BEGIN_LICENSE:BSD$
  10 ** You may use this file under the terms of the BSD license as follows:
  11 **
  12 ** "Redistribution and use in source and binary forms, with or without
  13 ** modification, are permitted provided that the following conditions are
  14 ** met:
  15 **   * Redistributions of source code must retain the above copyright
  16 **     notice, this list of conditions and the following disclaimer.
  17 **   * Redistributions in binary form must reproduce the above copyright
  18 **     notice, this list of conditions and the following disclaimer in
  19 **     the documentation and/or other materials provided with the
  20 **     distribution.
  21 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  22 **     the names of its contributors may be used to endorse or promote
  23 **     products derived from this software without specific prior written
  24 **     permission.
  25 **
  26 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  27 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  28 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  29 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  30 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  31 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  32 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  33 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  34 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  35 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  36 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 2.0
  42
  43 Item {
  44     id: window
  45     width: 320; height: 480
  46
  47     // Let's draw the sky...
  48     Rectangle {
  49         anchors { left: parent.left; top: parent.top; right: parent.right; bottom: parent.verticalCenter }
  50         gradient: Gradient {
  51             GradientStop { position: 0.0; color: "DeepSkyBlue" }
  52             GradientStop { position: 1.0; color: "LightSkyBlue" }
  53         }
  54     }
  55
  56     // ...and the ground.
  57     Rectangle {
  58         anchors { left: parent.left; top: parent.verticalCenter; right: parent.right; bottom: parent.bottom }
  59         gradient: Gradient {
  60             GradientStop { position: 0.0; color: "ForestGreen" }
  61             GradientStop { position: 1.0; color: "DarkGreen" }
  62         }
  63     }
  64
  65     // The shadow for the smiley face
  66     Image {
  67         anchors.horizontalCenter: parent.horizontalCenter
  68         y: smiley.minHeight + 58
  69         source: "images/shadow.png"
  70
  71         // The scale property depends on the y position of the smiley face.
  72         scale: smiley.y * 0.5 / (smiley.minHeight - smiley.maxHeight)
  73     }
  74
  75     Image {
  76         id: smiley
  77         property int maxHeight: window.height / 3
  78         property int minHeight: 2 * window.height / 3
  79
  80         anchors.horizontalCenter: parent.horizontalCenter
  81         y: minHeight
  82         source: "images/face-smile.png"
  83
  84         // Animate the y property. Setting loops to Animation.Infinite makes the
  85         // animation repeat indefinitely, otherwise it would only run once.
  86         SequentialAnimation on y {
  87             loops: Animation.Infinite
  88
  89             // Move from minHeight to maxHeight in 300ms, using the OutExpo easing function
  90             NumberAnimation {
  91                 from: smiley.minHeight; to: smiley.maxHeight
  92                 easing.type: Easing.OutExpo; duration: 300
  93             }
  94
  95             // Then move back to minHeight in 1 second, using the OutBounce easing function
  96             NumberAnimation {
  97                 from: smiley.maxHeight; to: smiley.minHeight
  98                 easing.type: Easing.OutBounce; duration: 1000
  99             }
 100
 101             // Then pause for 500ms
 102             PauseAnimation { duration: 500 }
 103         }
 104     }
 105 }