examples/declarative/animation/basics/color-animation.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: http://www.qt-project.org/
   6 **
   7 ** This file is part of the examples of the Qt Toolkit.
   8 **
   9 ** $QT_BEGIN_LICENSE:BSD$
  10 ** You may use this file under the terms of the BSD license as follows:
  11 **
  12 ** "Redistribution and use in source and binary forms, with or without
  13 ** modification, are permitted provided that the following conditions are
  14 ** met:
  15 **   * Redistributions of source code must retain the above copyright
  16 **     notice, this list of conditions and the following disclaimer.
  17 **   * Redistributions in binary form must reproduce the above copyright
  18 **     notice, this list of conditions and the following disclaimer in
  19 **     the documentation and/or other materials provided with the
  20 **     distribution.
  21 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  22 **     the names of its contributors may be used to endorse or promote
  23 **     products derived from this software without specific prior written
  24 **     permission.
  25 **
  26 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  27 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  28 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  29 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  30 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  31 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  32 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  33 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  34 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  35 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  36 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 2.0
  42 import QtQuick.Particles 2.0
  43
  44 Item {
  45     id: window
  46     width: 640; height: 480
  47
  48     // Let's draw the sky...
  49     Rectangle {
  50         anchors { left: parent.left; top: parent.top; right: parent.right; bottom: parent.verticalCenter }
  51         gradient: Gradient {
  52             GradientStop {
  53                 position: 0.0
  54                 SequentialAnimation on color {
  55                     loops: Animation.Infinite
  56                     ColorAnimation { from: "DeepSkyBlue"; to: "#0E1533"; duration: 5000 }
  57                     ColorAnimation { from: "#0E1533"; to: "DeepSkyBlue"; duration: 5000 }
  58                 }
  59             }
  60             GradientStop {
  61                 position: 1.0
  62                 SequentialAnimation on color {
  63                     loops: Animation.Infinite
  64                     ColorAnimation { from: "SkyBlue"; to: "#437284"; duration: 5000 }
  65                     ColorAnimation { from: "#437284"; to: "SkyBlue"; duration: 5000 }
  66                 }
  67             }
  68         }
  69     }
  70
  71     // the sun, moon, and stars
  72     Item {
  73         width: parent.width; height: 2 * parent.height
  74         NumberAnimation on rotation { from: 0; to: 360; duration: 10000; loops: Animation.Infinite }
  75         Image {
  76             source: "images/sun.png"; y: 10; anchors.horizontalCenter: parent.horizontalCenter
  77             rotation: -3 * parent.rotation
  78         }
  79         Image {
  80             source: "images/moon.png"; y: parent.height - 74; anchors.horizontalCenter: parent.horizontalCenter
  81             rotation: -parent.rotation
  82         }
  83         ParticleSystem {
  84             id: particlesystem
  85             x: 0; y: parent.height/2
  86             width: parent.width; height: parent.height/2
  87             ImageParticle {
  88                 source: "images/star.png"
  89                 groups: ["star"]
  90                 color: "#00333333"
  91                 SequentialAnimation on opacity {
  92                     loops: Animation.Infinite
  93                     NumberAnimation { from: 0; to: 1; duration: 5000 }
  94                     NumberAnimation { from: 1; to: 0; duration: 5000 }
  95                 }
  96             }
  97             Emitter {
  98                 group: "star"
  99                 anchors.fill: parent
 100                 emitRate: parent.width / 50
 101                 lifeSpan: 5000
 102             }
 103         }
 104     }
 105
 106     // ...and the ground.
 107     Rectangle {
 108         anchors { left: parent.left; top: parent.verticalCenter; right: parent.right; bottom: parent.bottom }
 109         gradient: Gradient {
 110             GradientStop {
 111                 position: 0.0
 112                 SequentialAnimation on color {
 113                     loops: Animation.Infinite
 114                     ColorAnimation { from: "ForestGreen"; to: "#001600"; duration: 5000 }
 115                     ColorAnimation { from: "#001600"; to: "ForestGreen"; duration: 5000 }
 116                 }
 117             }
 118             GradientStop { position: 1.0; color: "DarkGreen" }
 119         }
 120     }
 121 }