driver/level3/CMakeLists.txt

   1 include_directories(${PROJECT_SOURCE_DIR})
   2
   3 # N.B. In the original makefile there was a BLOCKS define used in the compilation of these files but I don't see any evidence of it being set anywhere. -hpa
   4
   5 # loop through gemm.c defines
   6 set(GEMM_DEFINES NN NT TN TT)
   7 set(GEMM_COMPLEX_DEFINES RN CN RT CT NR TR RR CR NC TC RC CC)
   8 foreach (GEMM_DEFINE ${GEMM_DEFINES})
   9   string(TOLOWER ${GEMM_DEFINE} GEMM_DEFINE_LC)
  10   GenerateNamedObjects("gemm.c" "${GEMM_DEFINE}" "gemm_${GEMM_DEFINE_LC}" 0)
  11   if (SMP AND NOT USE_SIMPLE_THREADED_LEVEL3)
  12     GenerateNamedObjects("gemm.c" "${GEMM_DEFINE};THREADED_LEVEL3" "gemm_thread_${GEMM_DEFINE_LC}" 0)
  13   endif ()
  14 endforeach ()
  15
  16
  17 set(TRMM_TRSM_SOURCES
  18   trmm_L.c
  19   trmm_R.c
  20   trsm_L.c
  21   trsm_R.c)
  22
  23 foreach(trmm_trsm_source ${TRMM_TRSM_SOURCES})
  24   string(REGEX MATCH "[a-z]+_[A-Z]+" op_name ${trmm_trsm_source})
  25   GenerateCombinationObjects("${trmm_trsm_source}" "UPPER;UNIT" "L;N" "" 0 "${op_name}N")
  26   GenerateCombinationObjects("${trmm_trsm_source}" "UPPER;UNIT" "L;N" "TRANSA" 0 "${op_name}T")
  27 endforeach()
  28
  29 GenerateCombinationObjects("symm_k.c" "RSIDE;LOWER" "L;U" "NN" 1)
  30 GenerateCombinationObjects("syrk_k.c" "LOWER;TRANS" "U;N" "" 1)
  31 GenerateCombinationObjects("syr2k_k.c" "LOWER;TRANS" "U;N" "" 1)
  32 GenerateCombinationObjects("syrk_kernel.c" "LOWER" "U" "" 2)
  33 GenerateCombinationObjects("syr2k_kernel.c" "LOWER" "U" "" 2)
  34 if (SMP)
  35
  36   # N.B. these do NOT have a float type (e.g. DOUBLE) defined!
  37   GenerateNamedObjects("gemm_thread_m.c;gemm_thread_n.c;gemm_thread_mn.c;gemm_thread_variable.c;syrk_thread.c" "" "" 0 "" "" 1)
  38
  39   if (NOT USE_SIMPLE_THREADED_LEVEL3)
  40     GenerateCombinationObjects("syrk_k.c" "LOWER;TRANS" "U;N" "THREADED_LEVEL3" 2 "syrk_thread")
  41     GenerateCombinationObjects("symm_k.c" "RSIDE;LOWER" "L;U" "THREADED_LEVEL3;NN" 2 "symm_thread")
  42   endif ()
  43 endif ()
  44
  45 foreach (float_type ${FLOAT_TYPES})
  46   if (${float_type} STREQUAL "COMPLEX" OR ${float_type} STREQUAL "ZCOMPLEX")
  47     GenerateCombinationObjects("zherk_kernel.c" "LOWER;CONJ" "U;N" "HERK" 2 "herk_kernel" false ${float_type})
  48     # TRANS needs to be set/unset when CONJ is set/unset, so can't use it as a combination
  49     GenerateCombinationObjects("zherk_k.c" "LOWER" "U" "HERK" 3 "herk_N" false ${float_type})
  50     GenerateCombinationObjects("zherk_k.c" "LOWER" "U" "HERK;TRANS;CONJ" 3 "herk_C" false ${float_type})
  51
  52     # Need to set CONJ for trmm and trsm
  53     GenerateCombinationObjects("trmm_L.c" "UPPER;UNIT" "L;N" "CONJ" 0 "trmm_LR" false ${float_type})
  54     GenerateCombinationObjects("trmm_L.c" "UPPER;UNIT" "L;N" "TRANSA;CONJ" 0 "trmm_LC" false ${float_type})
  55     GenerateCombinationObjects("trmm_R.c" "UPPER;UNIT" "L;N" "CONJ" 0 "trmm_RR" false ${float_type})
  56     GenerateCombinationObjects("trmm_R.c" "UPPER;UNIT" "L;N" "TRANSA;CONJ" 0 "trmm_RC" false ${float_type})
  57     GenerateCombinationObjects("trsm_L.c" "UPPER;UNIT" "L;N" "CONJ" 0 "trsm_LR" false ${float_type})
  58     GenerateCombinationObjects("trsm_L.c" "UPPER;UNIT" "L;N" "TRANSA;CONJ" 0 "trsm_LC" false ${float_type})
  59     GenerateCombinationObjects("trsm_R.c" "UPPER;UNIT" "L;N" "CONJ" 0 "trsm_RR" false ${float_type})
  60     GenerateCombinationObjects("trsm_R.c" "UPPER;UNIT" "L;N" "TRANSA;CONJ" 0 "trsm_RC" false ${float_type})
  61
  62     #hemm
  63     GenerateCombinationObjects("zhemm_k.c" "LOWER" "U" "NN" 0 "hemm_L" false ${float_type})
  64     GenerateCombinationObjects("zhemm_k.c" "LOWER" "U" "NC;RSIDE" 0 "hemm_R" false ${float_type})
  65
  66     #her2k
  67     GenerateCombinationObjects("zher2k_kernel.c" "LOWER;CONJ" "U;N" "" 2 "her2k_kernel" false ${float_type})
  68     GenerateNamedObjects("zher2k_k.c" "HER2K" "her2k_UN" false "" "" false ${float_type})
  69     GenerateNamedObjects("zher2k_k.c" "HER2K;TRANS;CONJ" "her2k_UC" false "" "" false ${float_type})
  70     GenerateNamedObjects("zher2k_k.c" "HER2K;LOWER" "her2k_LN" false "" "" false ${float_type})
  71     GenerateNamedObjects("zher2k_k.c" "HER2K;LOWER;TRANS;CONJ" "her2k_LC" false "" "" false ${float_type})
  72
  73     if (SMP AND NOT USE_SIMPLE_THREADED_LEVEL3)
  74       #herk
  75       GenerateCombinationObjects("zherk_k.c" "LOWER" "U" "HERK;THREADED_LEVEL3" 3 "herk_thread_N" false ${float_type})
  76       GenerateCombinationObjects("zherk_k.c" "LOWER" "U" "HERK;THREADED_LEVEL3;TRANS;CONJ" 3 "herk_thread_C" false ${float_type})
  77
  78       #hemm
  79       GenerateCombinationObjects("zhemm_k.c" "LOWER" "U" "NN;THREADED_LEVEL3" 0 "hemm_thread_L" false ${float_type})
  80       GenerateCombinationObjects("zhemm_k.c" "LOWER" "U" "NC;RSIDE;THREADED_LEVEL3" 0 "hemm_thread_R" false ${float_type})
  81       #her2k
  82       GenerateNamedObjects("zher2k_k.c" "HER2K" "her2k_UN" false "" "" false ${float_type})
  83       GenerateNamedObjects("zher2k_k.c" "HER2K;TRANS;CONJ" "her2k_UC" false "" "" false ${float_type})
  84       GenerateNamedObjects("zher2k_k.c" "HER2K;LOWER" "her2k_LN" false "" "" false ${float_type})
  85       GenerateNamedObjects("zher2k_k.c" "HER2K;LOWER;TRANS;CONJ" "her2k_LC" false "" "" false ${float_type})
  86     endif()
  87
  88     # special gemm defines for complex
  89     foreach (gemm_define ${GEMM_COMPLEX_DEFINES})
  90       string(TOLOWER ${gemm_define} gemm_define_LC)
  91       GenerateNamedObjects("gemm.c" "${gemm_define}" "gemm_${gemm_define_LC}" false "" "" false ${float_type})
  92       if(USE_GEMM3M)
  93         GenerateNamedObjects("gemm3m.c" "${gemm_define}" "gemm3m_${gemm_define_LC}" false "" "" false ${float_type})
  94       endif()
  95       if (SMP AND NOT USE_SIMPLE_THREADED_LEVEL3)
  96         GenerateNamedObjects("gemm.c" "${gemm_define};THREADED_LEVEL3" "gemm_thread_${gemm_define_LC}" false "" "" false ${float_type})
  97         if(USE_GEMM3M)
  98           GenerateNamedObjects("gemm3m.c" "${gemm_define};THREADED_LEVEL3" "gemm3m_thread_${gemm_define_LC}" false "" "" false ${float_type})
  99         endif()
 100       endif ()
 101     endforeach ()
 102
 103     # for gemm3m
 104     if(USE_GEMM3M)
 105       foreach (GEMM_DEFINE ${GEMM_DEFINES})
 106         string(TOLOWER ${GEMM_DEFINE} GEMM_DEFINE_LC)
 107         GenerateNamedObjects("gemm3m.c" "${GEMM_DEFINE}" "gemm3m_${GEMM_DEFINE_LC}" false "" "" false ${float_type})
 108         if (SMP AND NOT USE_SIMPLE_THREADED_LEVEL3)
 109           GenerateNamedObjects("gemm3m.c" "${GEMM_DEFINE};THREADED_LEVEL3" "gemm3m_thread_${GEMM_DEFINE_LC}" false "" "" false ${float_type})
 110         endif ()
 111       endforeach ()
 112     endif()
 113   endif ()
 114 endforeach ()
 115
 116 #HPLOBJS =
 117 #       dgemm_nn.c dgemm_nt.c dgemm_tn.c dgemm_tt.c
 118 #       dtrsm_LNUU.c dtrsm_LNUN.c dtrsm_LNLU.c dtrsm_LNLN.c
 119 #       dtrsm_LTUU.c dtrsm_LTUN.c dtrsm_LTLU.c dtrsm_LTLN.c
 120 #       dtrsm_RNUU.c dtrsm_RNUN.c dtrsm_RNLU.c dtrsm_RNLN.c
 121 #       dtrsm_RTUU.c dtrsm_RTUN.c dtrsm_RTLU.c dtrsm_RTLN.c
 122 #
 123 #if (USE_SIMPLE_THREADED_LEVEL3)
 124 #  HPLOBJS += dgemm_thread_nn.c dgemm_thread_nt.c
 125 #          dgemm_thread_tn.c dgemm_thread_tt.c
 126 #endif
 127 #
 128
 129 add_library(driver_level3 OBJECT ${OPENBLAS_SRC})