doc/CMakeLists.txt

   1 #
   2 #  CMake file for OpenCV docs
   3 #
   4
   5 file(GLOB FILES_TEX *.tex *.sty *.bib)
   6 file(GLOB FILES_TEX_PICS pics/*.png pics/*.jpg)
   7
   8 if(BUILD_DOCS AND HAVE_SPHINX)
   9
  10   project(opencv_docs)
  11
  12   set(DOC_LIST "${OpenCV_SOURCE_DIR}/doc/opencv-logo.png" "${OpenCV_SOURCE_DIR}/doc/opencv-logo2.png"
  13                "${OpenCV_SOURCE_DIR}/doc/opencv-logo-white.png" "${OpenCV_SOURCE_DIR}/doc/opencv.ico"
  14                "${OpenCV_SOURCE_DIR}/doc/haartraining.htm" "${OpenCV_SOURCE_DIR}/doc/license.txt"
  15                "${OpenCV_SOURCE_DIR}/doc/pattern.png" "${OpenCV_SOURCE_DIR}/doc/acircles_pattern.png")
  16
  17   set(OPTIONAL_DOC_LIST "")
  18
  19
  20   set(OPENCV2_BASE_MODULES core imgproc highgui video calib3d features2d objdetect ml flann gpu photo stitching nonfree contrib legacy)
  21
  22   # build lists of modules to be documented
  23   set(OPENCV2_MODULES "")
  24   set(OPENCV_MODULES "")
  25
  26   foreach(mod ${OPENCV_MODULES_BUILD} ${OPENCV_MODULES_DISABLED_USER} ${OPENCV_MODULES_DISABLED_AUTO} ${OPENCV_MODULES_DISABLED_FORCE})
  27     string(REGEX REPLACE "^opencv_" "" mod "${mod}")
  28     if("${OPENCV_MODULE_opencv_${mod}_LOCATION}" STREQUAL "${OpenCV_SOURCE_DIR}/modules/${mod}")
  29       list(APPEND OPENCV2_MODULES ${mod})
  30     else()
  31       list(APPEND OPENCV_MODULES ${mod})
  32     endif()
  33   endforeach()
  34   list(REMOVE_ITEM OPENCV2_MODULES ${OPENCV2_BASE_MODULES})
  35   ocv_list_sort(OPENCV2_MODULES)
  36   ocv_list_sort(OPENCV_MODULES)
  37
  38   # build lists of documentation files and generate table of contents for reference manual
  39   set(OPENCV_FILES_REF "")
  40   set(OPENCV_FILES_REF_PICT "")
  41   set(OPENCV_REFMAN_TOC "")
  42
  43   foreach(mod ${OPENCV2_BASE_MODULES} ${OPENCV2_MODULES} ${OPENCV_MODULES})
  44     file(GLOB_RECURSE _OPENCV_FILES_REF "${OPENCV_MODULE_opencv_${mod}_LOCATION}/doc/*.rst")
  45     file(GLOB_RECURSE _OPENCV_FILES_REF_PICT "${OPENCV_MODULE_opencv_${mod}_LOCATION}/doc/*.png" "${OPENCV_MODULE_opencv_${mod}_LOCATION}/doc/*.jpg")
  46     list(APPEND OPENCV_FILES_REF ${_OPENCV_FILES_REF})
  47     list(APPEND OPENCV_FILES_REF_PICT ${_OPENCV_FILES_REF_PICT})
  48
  49     set(toc_file "${OPENCV_MODULE_opencv_${mod}_LOCATION}/doc/${mod}.rst")
  50     if(EXISTS "${toc_file}")
  51       file(RELATIVE_PATH toc_file "${OpenCV_SOURCE_DIR}/modules" "${toc_file}")
  52       set(OPENCV_REFMAN_TOC "${OPENCV_REFMAN_TOC}   ${toc_file}\n")
  53     endif()
  54   endforeach()
  55
  56   file(GLOB_RECURSE _OPENCV_FILES_REF "${OpenCV_SOURCE_DIR}/platforms/android/service/doc/*.rst")
  57   file(GLOB_RECURSE _OPENCV_FILES_REF_PICT "${OpenCV_SOURCE_DIR}/platforms/android/service/doc/*.png" "${OpenCV_SOURCE_DIR}/platforms/android/service/doc/*.jpg")
  58   list(APPEND OPENCV_FILES_REF ${_OPENCV_FILES_REF})
  59   list(APPEND OPENCV_FILES_REF_PICT ${_OPENCV_FILES_REF_PICT})
  60
  61   configure_file("${OpenCV_SOURCE_DIR}/modules/refman.rst.in" "${OpenCV_SOURCE_DIR}/modules/refman.rst" IMMEDIATE @ONLY)
  62
  63   file(GLOB_RECURSE OPENCV_FILES_UG  user_guide/*.rst)
  64   file(GLOB_RECURSE OPENCV_FILES_TUT tutorials/*.rst)
  65   file(GLOB_RECURSE OPENCV_FILES_TUT_PICT tutorials/*.png tutorials/*.jpg)
  66
  67   set(OPENCV_DOC_DEPS conf.py ${OPENCV_FILES_REF} ${OPENCV_FILES_REF_PICT}
  68            ${OPENCV_FILES_UG} ${OPENCV_FILES_TUT} ${OPENCV_FILES_TUT_PICT})
  69
  70   if(PDFLATEX_COMPILER)
  71     add_custom_target(docs
  72       COMMAND ${SPHINX_BUILD} -b latex -c ${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/.. .
  73       COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_SOURCE_DIR}/pics ${CMAKE_CURRENT_BINARY_DIR}/doc/opencv1/pics
  74       COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_SOURCE_DIR}/mymath.sty ${CMAKE_CURRENT_BINARY_DIR}
  75       COMMAND ${PYTHON_EXECUTABLE} "${CMAKE_CURRENT_SOURCE_DIR}/patch_refman_latex.py" opencv2refman.tex
  76       COMMAND ${PYTHON_EXECUTABLE} "${CMAKE_CURRENT_SOURCE_DIR}/patch_refman_latex.py" opencv2manager.tex
  77       COMMAND ${CMAKE_COMMAND} -E echo "Generating opencv2refman.pdf"
  78       COMMAND ${PDFLATEX_COMPILER} -interaction=batchmode opencv2refman.tex
  79       COMMAND ${PDFLATEX_COMPILER} -interaction=batchmode opencv2refman.tex
  80       COMMAND ${CMAKE_COMMAND} -E echo "Generating opencv2manager.pdf"
  81       COMMAND ${PDFLATEX_COMPILER} -interaction=batchmode opencv2manager.tex
  82       COMMAND ${PDFLATEX_COMPILER} -interaction=batchmode opencv2manager.tex
  83       COMMAND ${CMAKE_COMMAND} -E echo "Generating opencv_user.pdf"
  84       COMMAND ${PDFLATEX_COMPILER} -interaction=batchmode opencv_user.tex
  85       COMMAND ${PDFLATEX_COMPILER} -interaction=batchmode opencv_user.tex
  86       COMMAND ${CMAKE_COMMAND} -E echo "Generating opencv_tutorials.pdf"
  87       COMMAND ${PDFLATEX_COMPILER} -interaction=batchmode opencv_tutorials.tex
  88       COMMAND ${PDFLATEX_COMPILER} -interaction=batchmode opencv_tutorials.tex
  89       COMMAND ${CMAKE_COMMAND} -E echo "Generating opencv_cheatsheet.pdf"
  90       COMMAND ${PDFLATEX_COMPILER} -interaction=batchmode "${CMAKE_CURRENT_SOURCE_DIR}/opencv_cheatsheet.tex"
  91       COMMAND ${PDFLATEX_COMPILER} -interaction=batchmode "${CMAKE_CURRENT_SOURCE_DIR}/opencv_cheatsheet.tex"
  92       DEPENDS ${OPENCV_DOC_DEPS}
  93       WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
  94       COMMENT "Generating the PDF Manuals"
  95       )
  96
  97     LIST(APPEND OPTIONAL_DOC_LIST "${CMAKE_BINARY_DIR}/doc/opencv2refman.pdf" "${CMAKE_BINARY_DIR}/doc/opencv2manager.pdf"
  98           "${CMAKE_BINARY_DIR}/doc/opencv_user.pdf" "${CMAKE_BINARY_DIR}/doc/opencv_tutorials.pdf" "${CMAKE_BINARY_DIR}/doc/opencv_cheatsheet.pdf")
  99
 100     if(ENABLE_SOLUTION_FOLDERS)
 101       set_target_properties(docs PROPERTIES FOLDER "documentation")
 102     endif()
 103   endif()
 104
 105   add_custom_target(html_docs
 106     COMMAND ${SPHINX_BUILD} -b html -c ${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/.. ./_html
 107     COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/mymath.sty ${CMAKE_CURRENT_BINARY_DIR}
 108     DEPENDS ${OPENCV_DOC_DEPS}
 109     WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
 110     COMMENT "Generating Online Documentation"
 111     )
 112
 113   if(ENABLE_SOLUTION_FOLDERS)
 114     set_target_properties(html_docs PROPERTIES FOLDER "documentation")
 115   endif()
 116
 117   foreach(f ${DOC_LIST})
 118     install(FILES "${f}" DESTINATION "${OPENCV_DOC_INSTALL_PATH}" COMPONENT main)
 119   endforeach()
 120
 121   foreach(f ${OPTIONAL_DOC_LIST})
 122     install(FILES "${f}" DESTINATION "${OPENCV_DOC_INSTALL_PATH}" OPTIONAL)
 123   endforeach()
 124
 125 endif()