dleyna-connector-dbus/configure.ac

   1 AC_PREREQ([2.66])
   2
   3 AC_INIT([dleyna-connector-dbus],
   4         [0.0.1],
   5         [https://github.com/01org/dleyna-connector-dbus/issues/new],
   6         ,
   7         [https://01.org/dleyna/])
   8
   9 AC_CONFIG_HEADERS([config.h])
  10 AC_CONFIG_AUX_DIR([build-aux])
  11 AC_CONFIG_MACRO_DIR([m4])
  12 AC_CONFIG_SRCDIR([src/connector-dbus.c])
  13
  14 AC_PREFIX_DEFAULT(/usr/local)
  15
  16 AM_INIT_AUTOMAKE([subdir-objects])
  17
  18 AM_MAINTAINER_MODE
  19 AM_SILENT_RULES([yes])
  20
  21 DLEYNA_CONNECTOR_DBUS_COMPILER_FLAGS
  22
  23 # Checks for languages.
  24 AC_LANG_C
  25
  26 # Checks for programs.
  27 AC_PROG_CC
  28 AM_PROG_CC_C_O
  29 AC_PROG_MKDIR_P
  30
  31 # Initialize libtool
  32 # Disable generation of static libraries
  33 LT_PREREQ([2.2.6])
  34 LT_INIT([dlopen disable-static])
  35 LT_LANG([C])
  36
  37 # Checks for libraries.
  38 PKG_PROG_PKG_CONFIG(0.16)
  39 PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.28])
  40 PKG_CHECK_MODULES([GIO], [gio-2.0 >= 2.28])
  41 PKG_CHECK_MODULES([DBUS], [dbus-1])
  42
  43 # Checks for header files.
  44 AC_CHECK_HEADERS([stdlib.h string.h syslog.h])
  45
  46 # Checks for typedefs, structures, and compiler characteristics.
  47 AC_TYPE_UINT8_T
  48 AC_HEADER_STDBOOL
  49 AC_TYPE_SIZE_T
  50
  51 # Checks for library functions.
  52 AC_FUNC_MALLOC
  53 AC_FUNC_REALLOC
  54 AC_CHECK_FUNCS([memset strchr strrchr strstr])
  55
  56 # Define Log Level values
  57 LOG_LEVEL_0=0x00
  58 LOG_LEVEL_1=0x01
  59 LOG_LEVEL_2=0x02
  60 LOG_LEVEL_3=0x04
  61 LOG_LEVEL_4=0x08
  62 LOG_LEVEL_5=0x10
  63 LOG_LEVEL_6=0x20
  64 LOG_LEVEL_7=0x13
  65 LOG_LEVEL_8=0x3F
  66
  67 AC_DEFINE_UNQUOTED([DLEYNA_LOG_LEVEL_DISABLED], [${LOG_LEVEL_0}], [Log level flag for disabled messages])
  68 AC_DEFINE_UNQUOTED([DLEYNA_LOG_LEVEL_ERROR],    [${LOG_LEVEL_1}], [Log level flag for errors])
  69 AC_DEFINE_UNQUOTED([DLEYNA_LOG_LEVEL_CRITICAL], [${LOG_LEVEL_2}], [Log level flag for critical messages])
  70 AC_DEFINE_UNQUOTED([DLEYNA_LOG_LEVEL_WARNING],  [${LOG_LEVEL_3}], [Log level flag for warnings])
  71 AC_DEFINE_UNQUOTED([DLEYNA_LOG_LEVEL_MESSAGE],  [${LOG_LEVEL_4}], [Log level flag for messages])
  72 AC_DEFINE_UNQUOTED([DLEYNA_LOG_LEVEL_INFO],     [${LOG_LEVEL_5}], [Log level flag for informational messages])
  73 AC_DEFINE_UNQUOTED([DLEYNA_LOG_LEVEL_DEBUG],    [${LOG_LEVEL_6}], [Log level flag for debug messages])
  74 AC_DEFINE_UNQUOTED([DLEYNA_LOG_LEVEL_DEFAULT],  [${LOG_LEVEL_7}], [Log level flag to display default level messages])
  75 AC_DEFINE_UNQUOTED([DLEYNA_LOG_LEVEL_ALL],      [${LOG_LEVEL_8}], [Log level flag for all messages])
  76
  77 AC_ARG_ENABLE(master-build,,
  78                 [],
  79                 [master_build=no])
  80
  81 AS_IF([test "x$master_build" = "xno"],
  82       [PKG_CHECK_MODULES([DLEYNA_CORE], [dleyna-core-1.0 >= 0.0.1])],
  83       [DLEYNA_CORE_CFLAGS="-I../dleyna-core";
  84        DLEYNA_CORE_LIBS="-L../dleyna-core/.libs -ldleyna-core-1.0"
  85       ])
  86
  87 AC_ARG_ENABLE(debug,
  88                 AS_HELP_STRING(
  89                         [--enable-debug],
  90                         [enable compiling with debugging information]),
  91                 [],
  92                 [enable_debug=no])
  93
  94 AS_CASE("${enable_debug}",
  95         [yes], [CFLAGS="$CFLAGS -g";
  96                 AC_DEFINE_UNQUOTED([DLEYNA_DEBUG_ENABLED],[1], [Compiling with debugging information enabled])
  97                ],
  98         [no], [],
  99         [AC_MSG_ERROR([bad value ${enable_debug} for --enable-debug])])
 100
 101
 102 AC_ARG_ENABLE(werror,
 103                 AS_HELP_STRING(
 104                         [--enable-werror],
 105                         [warnings are treated as errors]),
 106                 [],
 107                 [enable_werror=no])
 108
 109 AS_CASE("${enable_werror}",
 110         [yes], [CFLAGS="$CFLAGS -Werror"],
 111         [no], [],
 112         [AC_MSG_ERROR([bad value ${enable_werror} for --enable-werror])])
 113
 114
 115 AC_ARG_ENABLE(optimization,
 116                 AS_HELP_STRING(
 117                         [--disable-optimization],
 118                         [disable code optimization through compiler]),
 119                 [],
 120                 [enable_optimization=yes])
 121
 122 AS_CASE("${enable_optimization}",
 123         [yes], [disable_optimization=no],
 124         [no], [CFLAGS="$CFLAGS -O0"; disable_optimization=yes],
 125         [AC_MSG_ERROR([bad value ${enable_optimization} for --enable-werror])])
 126
 127 AC_ARG_WITH(log-level,
 128                 AS_HELP_STRING(
 129                         [--with-log-level],
 130                         [enable logging information (0,1..6,7,8)\
 131                          0=disabled \
 132                          7=default (=1,2,5) \
 133                          8=all (=1,2,3,4,5,6) \
 134                          1,..,6=a comma separated list of log level\
 135                         ]),
 136                 [],
 137                 [with_log_level=7])
 138
 139 DLEYNA_LOG_LEVEL_CHECK([${with_log_level}])
 140
 141 AC_CONFIG_FILES([Makefile])
 142
 143 AC_OUTPUT
 144
 145 AS_ECHO(["-------------------------------------------------
 146
 147 ${PACKAGE_NAME} Version ${PACKAGE_VERSION}
 148
 149 Prefix    : '${prefix}'
 150 Compiler  : '${CC}'
 151 CFLAGS    : '${CFLAGS}'
 152
 153 -Package features:
 154         - enable-werror       : ${enable_werror}
 155         - enable-debug        : ${enable_debug}
 156         - disable-optimization: ${disable_optimization}
 157         - with-log-level      : ${with_log_level}
 158
 159 --------------------------------------------------"])