demos/declarative/snake/content/Link.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2011 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: Nokia Corporation (qt-info@nokia.com)
   6 **
   7 ** This file is part of the QtDeclarative module of the Qt Toolkit.
   8 **
   9 ** $QT_BEGIN_LICENSE:LGPL$
  10 ** No Commercial Usage
  11 ** This file contains pre-release code and may not be distributed.
  12 ** You may use this file in accordance with the terms and conditions
  13 ** contained in the Technology Preview License Agreement accompanying
  14 ** this package.
  15 **
  16 ** GNU Lesser General Public License Usage
  17 ** Alternatively, this file may be used under the terms of the GNU Lesser
  18 ** General Public License version 2.1 as published by the Free Software
  19 ** Foundation and appearing in the file LICENSE.LGPL included in the
  20 ** packaging of this file.  Please review the following information to
  21 ** ensure the GNU Lesser General Public License version 2.1 requirements
  22 ** will be met: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
  23 **
  24 ** In addition, as a special exception, Nokia gives you certain additional
  25 ** rights.  These rights are described in the Nokia Qt LGPL Exception
  26 ** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
  27 **
  28 ** If you have questions regarding the use of this file, please contact
  29 ** Nokia at qt-info@nokia.com.
  30 **
  31 **
  32 **
  33 **
  34 **
  35 **
  36 **
  37 **
  38 ** $QT_END_LICENSE$
  39 **
  40 ****************************************************************************/
  41
  42 import QtQuick 1.0
  43 import Qt.labs.particles 1.0
  44
  45 Item { id:link
  46     property bool dying: false
  47     property bool spawned: false
  48     property int type: 0
  49     property int row: 0
  50     property int column: 0
  51     property int rotation;
  52
  53     width: 40;
  54     height: 40
  55
  56     x: margin - 3 + gridSize * column
  57     y: margin - 3 + gridSize * row
  58     Behavior on x { NumberAnimation { duration: spawned ? heartbeatInterval : 0} }
  59     Behavior on y { NumberAnimation { duration: spawned ? heartbeatInterval : 0 } }
  60
  61
  62     Item {
  63         id: img
  64         anchors.fill: parent
  65         Image {
  66             source: {
  67                 if(type == 1) {
  68                     "pics/blueStone.png";
  69                 } else if (type == 2) {
  70                     "pics/head.png";
  71                 } else {
  72                     "pics/redStone.png";
  73                 }
  74             }
  75
  76             transform: Rotation {
  77                 id: actualImageRotation
  78                 origin.x: width/2; origin.y: height/2;
  79                 angle: rotation * 90
  80                 Behavior on angle {
  81                     RotationAnimation{
  82                         direction: RotationAnimation.Shortest
  83                         duration: spawned ? 200 : 0
  84                     }
  85                 }
  86             }
  87         }
  88
  89         Image {
  90             source: "pics/stoneShadow.png"
  91         }
  92
  93         opacity: 0
  94     }
  95
  96
  97     Particles { id: particles
  98         width:1; height:1; anchors.centerIn: parent;
  99         emissionRate: 0;
 100         lifeSpan: 700; lifeSpanDeviation: 600;
 101         angle: 0; angleDeviation: 360;
 102         velocity: 100; velocityDeviation:30;
 103         source: {
 104             if(type == 1){
 105                 "pics/blueStar.png";
 106             } else {
 107                 "pics/redStar.png";
 108             }
 109         }
 110     }
 111
 112     states: [
 113         State{ name: "AliveState"; when: spawned == true && dying == false
 114             PropertyChanges { target: img; opacity: 1 }
 115         },
 116         State{ name: "DeathState"; when: dying == true
 117             StateChangeScript { script: particles.burst(50); }
 118             PropertyChanges { target: img; opacity: 0 }
 119         }
 120     ]
 121
 122     transitions: [
 123         Transition {
 124             NumberAnimation { target: img; property: "opacity"; duration: 200 }
 125         }
 126     ]
 127
 128 }