demos/declarative/samegame/SamegameCore/BoomBlock.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2011 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: Nokia Corporation (qt-info@nokia.com)
   6 **
   7 ** This file is part of the QtDeclarative module of the Qt Toolkit.
   8 **
   9 ** $QT_BEGIN_LICENSE:LGPL$
  10 ** No Commercial Usage
  11 ** This file contains pre-release code and may not be distributed.
  12 ** You may use this file in accordance with the terms and conditions
  13 ** contained in the Technology Preview License Agreement accompanying
  14 ** this package.
  15 **
  16 ** GNU Lesser General Public License Usage
  17 ** Alternatively, this file may be used under the terms of the GNU Lesser
  18 ** General Public License version 2.1 as published by the Free Software
  19 ** Foundation and appearing in the file LICENSE.LGPL included in the
  20 ** packaging of this file.  Please review the following information to
  21 ** ensure the GNU Lesser General Public License version 2.1 requirements
  22 ** will be met: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
  23 **
  24 ** In addition, as a special exception, Nokia gives you certain additional
  25 ** rights.  These rights are described in the Nokia Qt LGPL Exception
  26 ** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
  27 **
  28 ** If you have questions regarding the use of this file, please contact
  29 ** Nokia at qt-info@nokia.com.
  30 **
  31 **
  32 **
  33 **
  34 **
  35 **
  36 **
  37 **
  38 ** $QT_END_LICENSE$
  39 **
  40 ****************************************************************************/
  41
  42 import QtQuick 1.1
  43 import Qt.labs.particles 1.0
  44
  45 Item {
  46     id: block
  47     property bool dying: false
  48     property bool spawned: false
  49     property int type: 0
  50
  51     Behavior on x {
  52         enabled: spawned;
  53         SpringAnimation{ spring: 2; damping: 0.2 }
  54     }
  55     Behavior on y {
  56         SpringAnimation{ spring: 2; damping: 0.2 }
  57     }
  58
  59     Image {
  60         id: img
  61         source: {
  62             if(type == 0){
  63                 "pics/redStone.png";
  64             } else if(type == 1) {
  65                 "pics/blueStone.png";
  66             } else {
  67                 "pics/greenStone.png";
  68             }
  69         }
  70         opacity: 0
  71         Behavior on opacity { NumberAnimation { duration: 200 } }
  72         anchors.fill: parent
  73     }
  74
  75     Particles {
  76         id: particles
  77
  78         width: 1; height: 1
  79         anchors.centerIn: parent
  80
  81         emissionRate: 0
  82         lifeSpan: 700; lifeSpanDeviation: 600
  83         angle: 0; angleDeviation: 360;
  84         velocity: 100; velocityDeviation: 30
  85         source: {
  86             if(type == 0){
  87                 "pics/redStar.png";
  88             } else if (type == 1) {
  89                 "pics/blueStar.png";
  90             } else {
  91                 "pics/greenStar.png";
  92             }
  93         }
  94     }
  95
  96     states: [
  97         State {
  98             name: "AliveState"; when: spawned == true && dying == false
  99             PropertyChanges { target: img; opacity: 1 }
 100         },
 101
 102         State {
 103             name: "DeathState"; when: dying == true
 104             StateChangeScript { script: particles.burst(50); }
 105             PropertyChanges { target: img; opacity: 0 }
 106             StateChangeScript { script: block.destroy(1000); }
 107         }
 108     ]
 109 }