demos/declarative/plasmapatrol/content/BlasterHardpoint.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2011 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: Nokia Corporation (qt-info@nokia.com)
   6 **
   7 ** This file is part of the QtDeclarative module of the Qt Toolkit.
   8 **
   9 ** $QT_BEGIN_LICENSE:LGPL$
  10 ** No Commercial Usage
  11 ** This file contains pre-release code and may not be distributed.
  12 ** You may use this file in accordance with the terms and conditions
  13 ** contained in the Technology Preview License Agreement accompanying
  14 ** this package.
  15 **
  16 ** GNU Lesser General Public License Usage
  17 ** Alternatively, this file may be used under the terms of the GNU Lesser
  18 ** General Public License version 2.1 as published by the Free Software
  19 ** Foundation and appearing in the file LICENSE.LGPL included in the
  20 ** packaging of this file.  Please review the following information to
  21 ** ensure the GNU Lesser General Public License version 2.1 requirements
  22 ** will be met: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
  23 **
  24 ** In addition, as a special exception, Nokia gives you certain additional
  25 ** rights.  These rights are described in the Nokia Qt LGPL Exception
  26 ** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
  27 **
  28 ** If you have questions regarding the use of this file, please contact
  29 ** Nokia at qt-info@nokia.com.
  30 **
  31 **
  32 **
  33 **
  34 **
  35 **
  36 **
  37 **
  38 ** $QT_END_LICENSE$
  39 **
  40 ****************************************************************************/
  41 import QtQuick 2.0
  42 import QtQuick.Particles 2.0
  43
  44 Item {
  45     id: container
  46     property variant target: {"y": -90, "x":12}
  47     property Item targetObj: container
  48     property Item hardpoint: container
  49     property ParticleSystem system
  50     property int blasts: 16
  51     property int bonusBlasts: 12
  52     property bool show: true
  53
  54     width: 24
  55     height: 24
  56     Emitter{
  57         id: visualization
  58         particle: "blaster"
  59         system: container.system
  60         emitting: show
  61         anchors.fill: parent
  62         shape: EllipseShape{}
  63         speed: TargetedDirection{ targetX: width/2; targetY: width/2; magnitude: -1; proportionalMagnitude: true}
  64         particleDuration: 1000
  65         particlesPerSecond: 64
  66
  67         particleSize: 24
  68         particleSizeVariation: 24
  69         particleEndSize: 0
  70     }
  71
  72     property int blastsLeft: 0
  73     function fireAt(targetArg, container){
  74         target = container.mapFromItem(targetArg, targetArg.width/2, targetArg.height/2);
  75         targetObj = targetArg;
  76         hardpoint = container;
  77         blastsLeft = blasts;
  78         rofTimer.repeat = true;
  79         rofTimer.start();
  80     }
  81     Timer{
  82         id: rofTimer
  83         interval: 30;//Has to be greater than 1 frame or they stack up
  84         running: false
  85         repeat: false
  86         onTriggered:{
  87             if(targetObj.hp <= 0)
  88                 return;
  89             //TODO: calculate hit and damage at target, which must be a Ship
  90             var hit;
  91             if(blastsLeft >= bonusBlasts)
  92                 hit = Math.random() > targetObj.dodge;
  93             else
  94                 hit = false; //purely aesthetic shots, because the damage isn't that fine grained
  95             if(hit == true){
  96                 switch(targetObj.shipType){
  97                 case 1: hardpoint.damageDealt += 4; break;
  98                 case 2: hardpoint.damageDealt += 5; break;
  99                 case 3: hardpoint.damageDealt += 1; break;
 100                 default: hardpoint.damageDealt += 100;
 101                 }
 102             }
 103             blastVector.targetX = target.x;
 104             blastVector.targetY = target.y;
 105             if(!hit){//TODO: Actual targetVariation
 106                 blastVector.targetX += (128 * Math.random() - 64);
 107                 blastVector.targetY += (128 * Math.random() - 64);
 108             }
 109             emitter.burst(1);
 110             blastsLeft--;
 111             if(!blastsLeft)
 112                 rofTimer.repeat = false;
 113         }
 114     }
 115     Emitter{
 116         id: emitter
 117         particle: "blaster"
 118         emitting: false
 119         system: container.system
 120         anchors.centerIn: parent
 121
 122         particleDuration: 1000
 123         particlesPerSecond: 16
 124         maxParticles: blasts
 125         particleSize: 24
 126         particleEndSize:16
 127         particleSizeVariation: 8
 128         speed: TargetedDirection{
 129             id: blastVector
 130             targetX: target.x; targetY: target.y; magnitude: 1.1; proportionalMagnitude: true
 131         }
 132     }
 133 }