demos/declarative/flickr/mobile/GridDelegate.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2011 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: Nokia Corporation (qt-info@nokia.com)
   6 **
   7 ** This file is part of the QtDeclarative module of the Qt Toolkit.
   8 **
   9 ** $QT_BEGIN_LICENSE:LGPL$
  10 ** No Commercial Usage
  11 ** This file contains pre-release code and may not be distributed.
  12 ** You may use this file in accordance with the terms and conditions
  13 ** contained in the Technology Preview License Agreement accompanying
  14 ** this package.
  15 **
  16 ** GNU Lesser General Public License Usage
  17 ** Alternatively, this file may be used under the terms of the GNU Lesser
  18 ** General Public License version 2.1 as published by the Free Software
  19 ** Foundation and appearing in the file LICENSE.LGPL included in the
  20 ** packaging of this file.  Please review the following information to
  21 ** ensure the GNU Lesser General Public License version 2.1 requirements
  22 ** will be met: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
  23 **
  24 ** In addition, as a special exception, Nokia gives you certain additional
  25 ** rights.  These rights are described in the Nokia Qt LGPL Exception
  26 ** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
  27 **
  28 ** If you have questions regarding the use of this file, please contact
  29 ** Nokia at qt-info@nokia.com.
  30 **
  31 **
  32 **
  33 **
  34 **
  35 **
  36 **
  37 **
  38 ** $QT_END_LICENSE$
  39 **
  40 ****************************************************************************/
  41
  42 import QtQuick 1.0
  43
  44 Item {
  45     id: wrapper; width: GridView.view.cellWidth; height: GridView.view.cellHeight
  46
  47     function photoClicked() {
  48         imageDetails.photoTitle = title;
  49         imageDetails.photoTags = tags;
  50         imageDetails.photoWidth = photoWidth;
  51         imageDetails.photoHeight = photoHeight;
  52         imageDetails.photoType = photoType;
  53         imageDetails.photoAuthor = photoAuthor;
  54         imageDetails.photoDate = photoDate;
  55         imageDetails.photoUrl = url;
  56         imageDetails.rating = 0;
  57         scaleMe.state = "Details";
  58     }
  59
  60     Item {
  61         anchors.centerIn: parent
  62         scale: 0.0
  63         Behavior on scale { NumberAnimation { easing.type: Easing.InOutQuad} }
  64         id: scaleMe
  65
  66         Item {
  67             width: 77; height: 77; anchors.centerIn: parent
  68             Rectangle {
  69                 id: whiteRect; width: 77; height: 77; color: "#dddddd"; smooth: true
  70                 Image { id: thumb; source: imagePath; x: 1; y: 1; smooth: true }
  71                 Image { source: "images/gloss.png" }
  72             }
  73         }
  74
  75         Connections {
  76             target: toolBar
  77             onButton2Clicked: if (scaleMe.state == 'Details' ) scaleMe.state = 'Show'
  78         }
  79
  80         states: [
  81             State {
  82                 name: "Show"; when: thumb.status == Image.Ready
  83                 PropertyChanges { target: scaleMe; scale: 1 }
  84             },
  85             State {
  86                 name: "Details"
  87                 PropertyChanges { target: scaleMe; scale: 1 }
  88                 ParentChange { target: whiteRect; x: 10; y: 20; parent: imageDetails.frontContainer }
  89                 PropertyChanges { target: background; state: "DetailedView" }
  90             }
  91         ]
  92         transitions: [
  93             Transition {
  94                 from: "Show"; to: "Details"
  95                 ParentAnimation {
  96                     via: foreground
  97                     NumberAnimation { properties: "x,y"; duration: 500; easing.type: Easing.InOutQuad }
  98                 }
  99             },
 100             Transition {
 101                 from: "Details"; to: "Show"
 102                 ParentAnimation {
 103                     via: foreground
 104                     NumberAnimation { properties: "x,y"; duration: 500; easing.type: Easing.InOutQuad }
 105                 }
 106             }
 107         ]
 108     }
 109     MouseArea { anchors.fill: wrapper; onClicked: photoClicked() }
 110 }
 111