demos/declarative/flickr/flickr.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2011 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: Nokia Corporation (qt-info@nokia.com)
   6 **
   7 ** This file is part of the QtDeclarative module of the Qt Toolkit.
   8 **
   9 ** $QT_BEGIN_LICENSE:LGPL$
  10 ** No Commercial Usage
  11 ** This file contains pre-release code and may not be distributed.
  12 ** You may use this file in accordance with the terms and conditions
  13 ** contained in the Technology Preview License Agreement accompanying
  14 ** this package.
  15 **
  16 ** GNU Lesser General Public License Usage
  17 ** Alternatively, this file may be used under the terms of the GNU Lesser
  18 ** General Public License version 2.1 as published by the Free Software
  19 ** Foundation and appearing in the file LICENSE.LGPL included in the
  20 ** packaging of this file.  Please review the following information to
  21 ** ensure the GNU Lesser General Public License version 2.1 requirements
  22 ** will be met: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
  23 **
  24 ** In addition, as a special exception, Nokia gives you certain additional
  25 ** rights.  These rights are described in the Nokia Qt LGPL Exception
  26 ** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
  27 **
  28 ** If you have questions regarding the use of this file, please contact
  29 ** Nokia at qt-info@nokia.com.
  30 **
  31 **
  32 **
  33 **
  34 **
  35 **
  36 **
  37 **
  38 ** $QT_END_LICENSE$
  39 **
  40 ****************************************************************************/
  41
  42 import QtQuick 1.0
  43 import "common" as Common
  44 import "mobile" as Mobile
  45
  46 Item {
  47     id: screen; width: 320; height: 480
  48     property bool inListView : false
  49
  50     Rectangle {
  51         id: background
  52         anchors.fill: parent; color: "#343434";
  53
  54         Image { source: "mobile/images/stripes.png"; fillMode: Image.Tile; anchors.fill: parent; opacity: 0.3 }
  55
  56         Common.RssModel { id: rssModel }
  57
  58         Item {
  59             id: views
  60             width: parent.width
  61             anchors.top: titleBar.bottom; anchors.bottom: toolBar.top
  62
  63             GridView {
  64                 id: photoGridView; model: rssModel; delegate: Mobile.GridDelegate {}
  65                 cacheBuffer: 1000
  66                 cellWidth: (parent.width-2)/4; cellHeight: cellWidth; width: parent.width; height: parent.height
  67             }
  68
  69             ListView {
  70                 id: photoListView; model: rssModel; delegate: Mobile.ListDelegate { }
  71                 width: parent.width; height: parent.height; x: -(parent.width * 1.5); cacheBuffer: 100;
  72             }
  73
  74             states: State {
  75                 name: "ListView"; when: screen.inListView == true
  76                 PropertyChanges { target: photoListView; x: 0 }
  77                 PropertyChanges { target: photoGridView; x: -(parent.width * 1.5) }
  78             }
  79
  80             transitions: Transition {
  81                 NumberAnimation { properties: "x"; duration: 500; easing.type: Easing.InOutQuad }
  82             }
  83
  84             Mobile.ImageDetails { id: imageDetails; width: parent.width; anchors.left: views.right; height: parent.height }
  85
  86             Item { id: foreground; anchors.fill: parent }
  87         }
  88
  89         Mobile.TitleBar { id: titleBar; width: parent.width; height: 40; opacity: 0.9 }
  90
  91         Mobile.ToolBar {
  92             id: toolBar
  93             height: 40; anchors.bottom: parent.bottom; width: parent.width; opacity: 0.9
  94             button1Label: "Update"; button2Label: "View mode"
  95             onButton1Clicked: rssModel.reload()
  96             onButton2Clicked: if (screen.inListView == true) screen.inListView = false; else screen.inListView = true
  97         }
  98
  99         Connections {
 100             target: imageDetails
 101             onClosed: {
 102                 if (background.state == "DetailedView") {
 103                     background.state = '';
 104                     imageDetails.photoUrl = "";
 105                 }
 106             }
 107         }
 108
 109         states: State {
 110             name: "DetailedView"
 111             PropertyChanges { target: views; x: -parent.width }
 112             PropertyChanges { target: toolBar; button1Label: "View..." }
 113             PropertyChanges {
 114                 target: toolBar
 115                 onButton1Clicked: if (imageDetails.state=='') imageDetails.state='Back'; else imageDetails.state=''
 116             }
 117             PropertyChanges { target: toolBar; button2Label: "Back" }
 118             PropertyChanges { target: toolBar; onButton2Clicked: imageDetails.closed() }
 119         }
 120
 121         transitions: Transition {
 122             NumberAnimation { properties: "x"; duration: 500; easing.type: Easing.InOutQuad }
 123         }
 124     }
 125 }