cpu/mpc85xx/release.S

   1 /*
   2  * Copyright 2008-2009 Freescale Semiconductor, Inc.
   3  * Kumar Gala <kumar.gala@freescale.com>
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 #include <config.h>
  25 #include <mpc85xx.h>
  26 #include <version.h>
  27
  28 #define _LINUX_CONFIG_H 1       /* avoid reading Linux autoconf.h file  */
  29
  30 #include <ppc_asm.tmpl>
  31 #include <ppc_defs.h>
  32
  33 #include <asm/cache.h>
  34 #include <asm/mmu.h>
  35
  36 /* To boot secondary cpus, we need a place for them to start up.
  37  * Normally, they start at 0xfffffffc, but that's usually the
  38  * firmware, and we don't want to have to run the firmware again.
  39  * Instead, the primary cpu will set the BPTR to point here to
  40  * this page.  We then set up the core, and head to
  41  * start_secondary.  Note that this means that the code below
  42  * must never exceed 1023 instructions (the branch at the end
  43  * would then be the 1024th).
  44  */
  45         .globl  __secondary_start_page
  46         .align  12
  47 __secondary_start_page:
  48 /* First do some preliminary setup */
  49         lis     r3, HID0_EMCP@h         /* enable machine check */
  50 #ifndef CONFIG_E500MC
  51         ori     r3,r3,HID0_TBEN@l       /* enable Timebase */
  52 #endif
  53 #ifdef CONFIG_PHYS_64BIT
  54         ori     r3,r3,HID0_ENMAS7@l     /* enable MAS7 updates */
  55 #endif
  56         mtspr   SPRN_HID0,r3
  57
  58 #ifndef CONFIG_E500MC
  59         li      r3,(HID1_ASTME|HID1_ABE)@l      /* Addr streaming & broadcast */
  60         mtspr   SPRN_HID1,r3
  61 #endif
  62
  63         /* Enable branch prediction */
  64         li      r3,0x201
  65         mtspr   SPRN_BUCSR,r3
  66
  67         /* Ensure TB is 0 */
  68         li      r3,0
  69         mttbl   r3
  70         mttbu   r3
  71
  72         /* Enable/invalidate the I-Cache */
  73         mfspr   r0,SPRN_L1CSR1
  74         ori     r0,r0,(L1CSR1_ICFI|L1CSR1_ICE)
  75         mtspr   SPRN_L1CSR1,r0
  76         isync
  77
  78         /* Enable/invalidate the D-Cache */
  79         mfspr   r0,SPRN_L1CSR0
  80         ori     r0,r0,(L1CSR0_DCFI|L1CSR0_DCE)
  81         msync
  82         isync
  83         mtspr   SPRN_L1CSR0,r0
  84         isync
  85
  86 #define toreset(x) (x - __secondary_start_page + 0xfffff000)
  87
  88         /* get our PIR to figure out our table entry */
  89         lis     r3,toreset(__spin_table)@h
  90         ori     r3,r3,toreset(__spin_table)@l
  91
  92         /* r10 has the base address for the entry */
  93         mfspr   r0,SPRN_PIR
  94 #ifdef CONFIG_E500MC
  95         rlwinm  r4,r0,27,27,31
  96 #else
  97         mr      r4,r0
  98 #endif
  99         slwi    r8,r4,5
 100         add     r10,r3,r8
 101
 102 #ifdef CONFIG_BACKSIDE_L2_CACHE
 103         /* Enable/invalidate the L2 cache */
 104         msync
 105         lis     r2,(L2CSR0_L2FI|L2CSR0_L2LFC)@h
 106         ori     r2,r2,(L2CSR0_L2FI|L2CSR0_L2LFC)@l
 107         mtspr   SPRN_L2CSR0,r2
 108 1:
 109         mfspr   r3,SPRN_L2CSR0
 110         and.    r1,r3,r2
 111         bne     1b
 112
 113         lis     r3,CONFIG_SYS_INIT_L2CSR0@h
 114         ori     r3,r3,CONFIG_SYS_INIT_L2CSR0@l
 115         mtspr   SPRN_L2CSR0,r3
 116         isync
 117 2:
 118         mfspr   r3,SPRN_L2CSR0
 119         andis.  r1,r3,L2CSR0_L2E@h
 120         beq     2b
 121 #endif
 122
 123 #define EPAPR_MAGIC             (0x45504150)
 124 #define ENTRY_ADDR_UPPER        0
 125 #define ENTRY_ADDR_LOWER        4
 126 #define ENTRY_R3_UPPER          8
 127 #define ENTRY_R3_LOWER          12
 128 #define ENTRY_RESV              16
 129 #define ENTRY_PIR               20
 130 #define ENTRY_R6_UPPER          24
 131 #define ENTRY_R6_LOWER          28
 132 #define ENTRY_SIZE              32
 133
 134         /* setup the entry */
 135         li      r3,0
 136         li      r8,1
 137         stw     r0,ENTRY_PIR(r10)
 138         stw     r3,ENTRY_ADDR_UPPER(r10)
 139         stw     r8,ENTRY_ADDR_LOWER(r10)
 140         stw     r3,ENTRY_R3_UPPER(r10)
 141         stw     r4,ENTRY_R3_LOWER(r10)
 142         stw     r3,ENTRY_R6_UPPER(r10)
 143         stw     r3,ENTRY_R6_LOWER(r10)
 144
 145         /* load r13 with the address of the 'bootpg' in SDRAM */
 146         lis     r13,toreset(__bootpg_addr)@h
 147         ori     r13,r13,toreset(__bootpg_addr)@l
 148         lwz     r13,0(r13)
 149
 150         /* setup mapping for AS = 1, and jump there */
 151         lis     r11,(MAS0_TLBSEL(1)|MAS0_ESEL(1))@h
 152         mtspr   SPRN_MAS0,r11
 153         lis     r11,(MAS1_VALID|MAS1_IPROT)@h
 154         ori     r11,r11,(MAS1_TS|MAS1_TSIZE(BOOKE_PAGESZ_4K))@l
 155         mtspr   SPRN_MAS1,r11
 156         oris    r11,r13,(MAS2_I)@h
 157         ori     r11,r13,(MAS2_I)@l
 158         mtspr   SPRN_MAS2,r11
 159         oris    r11,r13,(MAS3_SX|MAS3_SW|MAS3_SR)@h
 160         ori     r11,r13,(MAS3_SX|MAS3_SW|MAS3_SR)@l
 161         mtspr   SPRN_MAS3,r11
 162         tlbwe
 163
 164         bl      1f
 165 1:      mflr    r11
 166         /*
 167          * OR in 0xfff to create a mask of the bootpg SDRAM address.  We use
 168          * this mask to fixup the cpu spin table and the address that we want
 169          * to jump to, eg change them from 0xfffffxxx to 0x7ffffxxx if the
 170          * bootpg is at 0x7ffff000 in SDRAM.
 171          */
 172         ori     r13,r13,0xfff
 173         and     r11, r11, r13
 174         and     r10, r10, r13
 175
 176         addi    r11,r11,(2f-1b)
 177         mfmsr   r13
 178         ori     r12,r13,MSR_IS|MSR_DS@l
 179
 180         mtspr   SPRN_SRR0,r11
 181         mtspr   SPRN_SRR1,r12
 182         rfi
 183
 184         /* spin waiting for addr */
 185 2:
 186         lwz     r4,ENTRY_ADDR_LOWER(r10)
 187         andi.   r11,r4,1
 188         bne     2b
 189         isync
 190
 191         /* setup IVORs to match fixed offsets */
 192 #include "fixed_ivor.S"
 193
 194         /* get the upper bits of the addr */
 195         lwz     r11,ENTRY_ADDR_UPPER(r10)
 196
 197         /* setup branch addr */
 198         mtspr   SPRN_SRR0,r4
 199
 200         /* mark the entry as released */
 201         li      r8,3
 202         stw     r8,ENTRY_ADDR_LOWER(r10)
 203
 204         /* mask by ~64M to setup our tlb we will jump to */
 205         rlwinm  r12,r4,0,0,5
 206
 207         /* setup r3, r4, r5, r6, r7, r8, r9 */
 208         lwz     r3,ENTRY_R3_LOWER(r10)
 209         li      r4,0
 210         li      r5,0
 211         lwz     r6,ENTRY_R6_LOWER(r10)
 212         lis     r7,(64*1024*1024)@h
 213         li      r8,0
 214         li      r9,0
 215
 216         /* load up the pir */
 217         lwz     r0,ENTRY_PIR(r10)
 218         mtspr   SPRN_PIR,r0
 219         mfspr   r0,SPRN_PIR
 220         stw     r0,ENTRY_PIR(r10)
 221
 222         mtspr   IVPR,r12
 223 /*
 224  * Coming here, we know the cpu has one TLB mapping in TLB1[0]
 225  * which maps 0xfffff000-0xffffffff one-to-one.  We set up a
 226  * second mapping that maps addr 1:1 for 64M, and then we jump to
 227  * addr
 228  */
 229         lis     r10,(MAS0_TLBSEL(1)|MAS0_ESEL(0))@h
 230         mtspr   SPRN_MAS0,r10
 231         lis     r10,(MAS1_VALID|MAS1_IPROT)@h
 232         ori     r10,r10,(MAS1_TSIZE(BOOKE_PAGESZ_64M))@l
 233         mtspr   SPRN_MAS1,r10
 234         /* WIMGE = 0b00000 for now */
 235         mtspr   SPRN_MAS2,r12
 236         ori     r12,r12,(MAS3_SX|MAS3_SW|MAS3_SR)
 237         mtspr   SPRN_MAS3,r12
 238 #ifdef CONFIG_ENABLE_36BIT_PHYS
 239         mtspr   SPRN_MAS7,r11
 240 #endif
 241         tlbwe
 242
 243 /* Now we have another mapping for this page, so we jump to that
 244  * mapping
 245  */
 246         mtspr   SPRN_SRR1,r13
 247         rfi
 248
 249         /*
 250          * Allocate some space for the SDRAM address of the bootpg.
 251          * This variable has to be in the boot page so that it can
 252          * be accessed by secondary cores when they come out of reset.
 253          */
 254         .globl __bootpg_addr
 255 __bootpg_addr:
 256         .long   0
 257
 258         .align L1_CACHE_SHIFT
 259         .globl __spin_table
 260 __spin_table:
 261         .space CONFIG_MAX_CPUS*ENTRY_SIZE
 262
 263         /* Fill in the empty space.  The actual reset vector is
 264          * the last word of the page */
 265 __secondary_start_code_end:
 266         .space 4092 - (__secondary_start_code_end - __secondary_start_page)
 267 __secondary_reset_vector:
 268         b       __secondary_start_page