cpu/mcf5445x/start.S

   1 /*
   2  * Copyright (C) 2003   Josef Baumgartner <josef.baumgartner@telex.de>
   3  * Based on code from Bernhard Kuhn <bkuhn@metrowerks.com>
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 #include <config.h>
  25 #include <timestamp.h>
  26 #include "version.h"
  27
  28 #ifndef  CONFIG_IDENT_STRING
  29 #define  CONFIG_IDENT_STRING ""
  30 #endif
  31
  32 /* last three long word reserved for cache status */
  33 #define CACR_STATUS     (CONFIG_SYS_INIT_RAM_ADDR+CONFIG_SYS_INIT_RAM_END-12)
  34 #define ICACHE_STATUS   (CONFIG_SYS_INIT_RAM_ADDR+CONFIG_SYS_INIT_RAM_END- 8)
  35 #define DCACHE_STATUS   (CONFIG_SYS_INIT_RAM_ADDR+CONFIG_SYS_INIT_RAM_END- 4)
  36
  37 #define _START  _start
  38 #define _FAULT  _fault
  39
  40 #define SAVE_ALL                                                \
  41         move.w  #0x2700,%sr;            /* disable intrs */     \
  42         subl    #60,%sp;                /* space for 15 regs */ \
  43         moveml  %d0-%d7/%a0-%a6,%sp@;
  44
  45 #define RESTORE_ALL                                             \
  46         moveml  %sp@,%d0-%d7/%a0-%a6;                           \
  47         addl    #60,%sp;                /* space for 15 regs */ \
  48         rte;
  49
  50 #if defined(CONFIG_CF_SBF)
  51 #define ASM_DRAMINIT    (asm_dram_init - TEXT_BASE + CONFIG_SYS_INIT_RAM_ADDR)
  52 #define ASM_SBF_IMG_HDR (asm_sbf_img_hdr - TEXT_BASE + CONFIG_SYS_INIT_RAM_ADDR)
  53 #endif
  54
  55 .text
  56
  57 /*
  58  *      Vector table. This is used for initial platform startup.
  59  *      These vectors are to catch any un-intended traps.
  60  */
  61 _vectors:
  62 #if defined(CONFIG_CF_SBF)
  63
  64 INITSP: .long   0               /* Initial SP   */
  65 INITPC: .long   ASM_DRAMINIT    /* Initial PC   */
  66
  67 #else
  68
  69 INITSP:         .long   0       /* Initial SP   */
  70 INITPC:         .long   _START  /* Initial PC           */
  71
  72 #endif
  73
  74 vector02:       .long   _FAULT  /* Access Error         */
  75 vector03:       .long   _FAULT  /* Address Error        */
  76 vector04:       .long   _FAULT  /* Illegal Instruction  */
  77 vector05:       .long   _FAULT  /* Reserved             */
  78 vector06:       .long   _FAULT  /* Reserved             */
  79 vector07:       .long   _FAULT  /* Reserved             */
  80 vector08:       .long   _FAULT  /* Privilege Violation  */
  81 vector09:       .long   _FAULT  /* Trace                */
  82 vector0A:       .long   _FAULT  /* Unimplemented A-Line */
  83 vector0B:       .long   _FAULT  /* Unimplemented F-Line */
  84 vector0C:       .long   _FAULT  /* Debug Interrupt      */
  85 vector0D:       .long   _FAULT  /* Reserved             */
  86 vector0E:       .long   _FAULT  /* Format Error         */
  87 vector0F:       .long   _FAULT  /* Unitialized Int.     */
  88
  89 /* Reserved */
  90 vector10_17:
  91 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
  92
  93 vector18:       .long   _FAULT  /* Spurious Interrupt   */
  94 vector19:       .long   _FAULT  /* Autovector Level 1   */
  95 vector1A:       .long   _FAULT  /* Autovector Level 2   */
  96 vector1B:       .long   _FAULT  /* Autovector Level 3   */
  97 vector1C:       .long   _FAULT  /* Autovector Level 4   */
  98 vector1D:       .long   _FAULT  /* Autovector Level 5   */
  99 vector1E:       .long   _FAULT  /* Autovector Level 6   */
 100 vector1F:       .long   _FAULT  /* Autovector Level 7   */
 101
 102 #if !defined(CONFIG_CF_SBF)
 103
 104 /* TRAP #0 - #15 */
 105 vector20_2F:
 106 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 107 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 108
 109 /* Reserved     */
 110 vector30_3F:
 111 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 112 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 113
 114 vector64_127:
 115 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 116 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 117 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 118 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 119 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 120 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 121 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 122 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 123
 124 vector128_191:
 125 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 126 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 127 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 128 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 129 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 130 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 131 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 132 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 133
 134 vector192_255:
 135 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 136 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 137 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 138 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 139 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 140 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 141 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 142 .long   _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT, _FAULT
 143 #endif
 144
 145 #if defined(CONFIG_CF_SBF)
 146         /* Image header: chksum 4 bytes, len 4 bytes, img dest 4 bytes */
 147 asm_sbf_img_hdr:
 148         .long   0x00000000      /* checksum, not yet implemented */
 149         .long   0x00030000      /* image length */
 150         .long   TEXT_BASE       /* image to be relocated at */
 151
 152
 153
 154 asm_dram_init:
 155         move.w #0x2700,%sr              /* Mask off Interrupt */
 156
 157         move.l  #CONFIG_SYS_INIT_RAM_ADDR, %d0
 158         movec   %d0, %VBR
 159
 160         move.l  #(CONFIG_SYS_INIT_RAM_ADDR + CONFIG_SYS_INIT_RAM_CTRL), %d0
 161         movec   %d0, %RAMBAR1
 162
 163         /* initialize general use internal ram */
 164         move.l #0, %d0
 165         move.l #(CACR_STATUS), %a1      /* CACR */
 166         move.l #(ICACHE_STATUS), %a2    /* icache */
 167         move.l #(DCACHE_STATUS), %a3    /* dcache */
 168         move.l %d0, (%a1)
 169         move.l %d0, (%a2)
 170         move.l %d0, (%a3)
 171
 172         /* invalidate and disable cache */
 173         move.l  #0x01004100, %d0        /* Invalidate cache cmd */
 174         movec   %d0, %CACR              /* Invalidate cache */
 175         move.l  #0, %d0
 176         movec   %d0, %ACR0
 177         movec   %d0, %ACR1
 178         movec   %d0, %ACR2
 179         movec   %d0, %ACR3
 180
 181         move.l  #(CONFIG_SYS_INIT_RAM_ADDR + CONFIG_SYS_INIT_SP_OFFSET), %sp
 182         clr.l %sp@-
 183
 184         /* Must disable global address */
 185         move.l  #0xFC008000, %a1
 186         move.l  #(CONFIG_SYS_CS0_BASE), (%a1)
 187         move.l  #0xFC008008, %a1
 188         move.l  #(CONFIG_SYS_CS0_CTRL), (%a1)
 189         move.l  #0xFC008004, %a1
 190         move.l  #(CONFIG_SYS_CS0_MASK), (%a1)
 191
 192         /* Dram Initialization a1, a2, and d0 */
 193         /* mscr sdram */
 194         move.l  #0xFC0A4074, %a1
 195         move.b  #(CONFIG_SYS_SDRAM_DRV_STRENGTH), (%a1)
 196         nop
 197
 198         /* SDRAM Chip 0 and 1 */
 199         move.l  #0xFC0B8110, %a1
 200         move.l  #0xFC0B8114, %a2
 201
 202         /* calculate the size */
 203         move.l  #0x13, %d1
 204         move.l  #(CONFIG_SYS_SDRAM_SIZE), %d2
 205 #ifdef CONFIG_SYS_SDRAM_BASE1
 206         lsr.l   #1, %d2
 207 #endif
 208
 209 dramsz_loop:
 210         lsr.l   #1, %d2
 211         add.l   #1, %d1
 212         cmp.l   #1, %d2
 213         bne     dramsz_loop
 214
 215         /* SDRAM Chip 0 and 1 */
 216         move.l  #(CONFIG_SYS_SDRAM_BASE), (%a1)
 217         or.l    %d1, (%a1)
 218 #ifdef CONFIG_SYS_SDRAM_BASE1
 219         move.l  #(CONFIG_SYS_SDRAM_BASE1), (%a2)
 220         or.l    %d1, (%a2)
 221 #endif
 222         nop
 223
 224         /* dram cfg1 and cfg2 */
 225         move.l  #0xFC0B8008, %a1
 226         move.l  #(CONFIG_SYS_SDRAM_CFG1), (%a1)
 227         nop
 228         move.l  #0xFC0B800C, %a2
 229         move.l  #(CONFIG_SYS_SDRAM_CFG2), (%a2)
 230         nop
 231
 232         move.l  #0xFC0B8000, %a1        /* Mode */
 233         move.l  #0xFC0B8004, %a2        /* Ctrl */
 234
 235         /* Issue PALL */
 236         move.l  #(CONFIG_SYS_SDRAM_CTRL + 2), (%a2)
 237         nop
 238
 239 #ifdef CONFIG_M54455EVB
 240         /* Issue LEMR */
 241         move.l  #(CONFIG_SYS_SDRAM_EMOD + 0x408), (%a1)
 242         nop
 243         move.l  #(CONFIG_SYS_SDRAM_MODE + 0x300), (%a1)
 244         nop
 245 #endif
 246
 247         move.l  #1000, %d1
 248         jsr     asm_delay
 249
 250         /* Issue PALL */
 251         move.l  #(CONFIG_SYS_SDRAM_CTRL + 2), (%a2)
 252         nop
 253
 254         /* Perform two refresh cycles */
 255         move.l  #(CONFIG_SYS_SDRAM_CTRL + 4), %d0
 256         nop
 257         move.l  %d0, (%a2)
 258         move.l  %d0, (%a2)
 259         nop
 260
 261 #ifdef CONFIG_M54455EVB
 262         move.l  #(CONFIG_SYS_SDRAM_MODE + 0x200), (%a1)
 263         nop
 264 #elif defined(CONFIG_M54451EVB)
 265         /* Issue LEMR */
 266         move.l  #(CONFIG_SYS_SDRAM_MODE), (%a1)
 267         nop
 268         move.l  #(CONFIG_SYS_SDRAM_EMOD), (%a1)
 269 #endif
 270
 271         move.l  #500, %d1
 272         jsr     asm_delay
 273
 274         move.l  #(CONFIG_SYS_SDRAM_CTRL), %d1
 275         and.l   #0x7FFFFFFF, %d1
 276 #ifdef CONFIG_M54455EVB
 277         or.l    #0x10000C00, %d1
 278 #elif defined(CONFIG_M54451EVB)
 279         or.l    #0x10000C00, %d1
 280 #endif
 281         move.l  %d1, (%a2)
 282         nop
 283
 284         move.l  #2000, %d1
 285         jsr     asm_delay
 286
 287         /*
 288          * DSPI Initialization
 289          * a0 - general, sram - 0x80008000 - 32, see M54455EVB.h
 290          * a1 - dspi status
 291          * a2 - dtfr
 292          * a3 - drfr
 293          * a4 - Dst addr
 294          */
 295         /* Enable pins for DSPI mode - chip-selects are enabled later */
 296 asm_dspi_init:
 297         move.l  #0xFC0A4063, %a0
 298         move.b  #0x7F, (%a0)
 299
 300         /* Configure DSPI module */
 301         move.l  #0xFC05C000, %a0
 302         move.l  #0x80FF0C00, (%a0)      /* Master, clear TX/RX FIFO */
 303
 304         move.l  #0xFC05C00C, %a0
 305         move.l  #0x3E000011, (%a0)
 306
 307         move.l  #0xFC05C034, %a2        /* dtfr */
 308         move.l  #0xFC05C03B, %a3        /* drfr */
 309
 310         move.l  #(ASM_SBF_IMG_HDR + 4), %a1
 311         move.l  (%a1)+, %d5
 312         move.l  (%a1), %a4
 313
 314         move.l  #(CONFIG_SYS_INIT_RAM_ADDR + CONFIG_SYS_SBFHDR_DATA_OFFSET), %a0
 315         move.l  #(CONFIG_SYS_SBFHDR_SIZE), %d4
 316
 317         move.l  #0xFC05C02C, %a1        /* dspi status */
 318
 319         /* Issue commands and address */
 320         move.l  #0x8002000B, %d2        /* Fast Read Cmd */
 321         jsr     asm_dspi_wr_status
 322         jsr     asm_dspi_rd_status
 323
 324         move.l  #0x80020000, %d2        /* Address byte 2 */
 325         jsr     asm_dspi_wr_status
 326         jsr     asm_dspi_rd_status
 327
 328         move.l  #0x80020000, %d2        /* Address byte 1 */
 329         jsr     asm_dspi_wr_status
 330         jsr     asm_dspi_rd_status
 331
 332         move.l  #0x80020000, %d2        /* Address byte 0 */
 333         jsr     asm_dspi_wr_status
 334         jsr     asm_dspi_rd_status
 335
 336         move.l  #0x80020000, %d2        /* Dummy Wr and Rd */
 337         jsr     asm_dspi_wr_status
 338         jsr     asm_dspi_rd_status
 339
 340         /* Transfer serial boot header to sram */
 341 asm_dspi_rd_loop1:
 342         move.l  #0x80020000, %d2
 343         jsr     asm_dspi_wr_status
 344         jsr     asm_dspi_rd_status
 345
 346         move.b  %d1, (%a0)              /* read, copy to dst */
 347
 348         add.l   #1, %a0                 /* inc dst by 1 */
 349         sub.l   #1, %d4                 /* dec cnt by 1 */
 350         bne     asm_dspi_rd_loop1
 351
 352         /* Transfer u-boot from serial flash to memory */
 353 asm_dspi_rd_loop2:
 354         move.l  #0x80020000, %d2
 355         jsr     asm_dspi_wr_status
 356         jsr     asm_dspi_rd_status
 357
 358         move.b  %d1, (%a4)              /* read, copy to dst */
 359
 360         add.l   #1, %a4                 /* inc dst by 1 */
 361         sub.l   #1, %d5                 /* dec cnt by 1 */
 362         bne     asm_dspi_rd_loop2
 363
 364         move.l  #0x00020000, %d2        /* Terminate */
 365         jsr     asm_dspi_wr_status
 366         jsr     asm_dspi_rd_status
 367
 368         /* jump to memory and execute */
 369         move.l  #(TEXT_BASE + 0x400), %a0
 370         jmp     (%a0)
 371
 372 asm_dspi_wr_status:
 373         move.l  (%a1), %d0              /* status */
 374         and.l   #0x0000F000, %d0
 375         cmp.l   #0x00003000, %d0
 376         bgt     asm_dspi_wr_status
 377
 378         move.l  %d2, (%a2)
 379         rts
 380
 381 asm_dspi_rd_status:
 382         move.l  (%a1), %d0              /* status */
 383         and.l   #0x000000F0, %d0
 384         lsr.l   #4, %d0
 385         cmp.l   #0, %d0
 386         beq     asm_dspi_rd_status
 387
 388         move.b  (%a3), %d1
 389         rts
 390
 391 asm_delay:
 392         nop
 393         subq.l  #1, %d1
 394         bne     asm_delay
 395         rts
 396 #endif                  /* CONFIG_CF_SBF */
 397
 398         .text
 399         . = 0x400
 400         .globl  _start
 401 _start:
 402 #if !defined(CONFIG_CF_SBF)
 403         nop
 404         nop
 405         move.w #0x2700,%sr              /* Mask off Interrupt */
 406
 407         /* Set vector base register at the beginning of the Flash */
 408         move.l  #CONFIG_SYS_FLASH_BASE, %d0
 409         movec   %d0, %VBR
 410
 411         move.l  #(CONFIG_SYS_INIT_RAM_ADDR + CONFIG_SYS_INIT_RAM_CTRL), %d0
 412         movec   %d0, %RAMBAR1
 413
 414         /* initialize general use internal ram */
 415         move.l #0, %d0
 416         move.l #(CACR_STATUS), %a1      /* CACR */
 417         move.l #(ICACHE_STATUS), %a2    /* icache */
 418         move.l #(DCACHE_STATUS), %a3    /* dcache */
 419         move.l %d0, (%a1)
 420         move.l %d0, (%a2)
 421         move.l %d0, (%a3)
 422
 423         /* invalidate and disable cache */
 424         move.l  #0x01004100, %d0        /* Invalidate cache cmd */
 425         movec   %d0, %CACR              /* Invalidate cache */
 426         move.l  #0, %d0
 427         movec   %d0, %ACR0
 428         movec   %d0, %ACR1
 429         movec   %d0, %ACR2
 430         movec   %d0, %ACR3
 431
 432         /* set stackpointer to end of internal ram to get some stackspace for
 433            the first c-code */
 434         move.l  #(CONFIG_SYS_INIT_RAM_ADDR + CONFIG_SYS_INIT_SP_OFFSET), %sp
 435         clr.l %sp@-
 436 #endif
 437
 438         move.l #__got_start, %a5        /* put relocation table address to a5 */
 439
 440         bsr cpu_init_f                  /* run low-level CPU init code (from flash) */
 441         bsr board_init_f                /* run low-level board init code (from flash) */
 442
 443         /* board_init_f() does not return */
 444
 445 /*------------------------------------------------------------------------------*/
 446
 447 /*
 448  * void relocate_code (addr_sp, gd, addr_moni)
 449  *
 450  * This "function" does not return, instead it continues in RAM
 451  * after relocating the monitor code.
 452  *
 453  * r3 = dest
 454  * r4 = src
 455  * r5 = length in bytes
 456  * r6 = cachelinesize
 457  */
 458         .globl  relocate_code
 459 relocate_code:
 460         link.w %a6,#0
 461         move.l 8(%a6), %sp              /* set new stack pointer */
 462
 463         move.l 12(%a6), %d0             /* Save copy of Global Data pointer */
 464         move.l 16(%a6), %a0             /* Save copy of Destination Address */
 465
 466         move.l #CONFIG_SYS_MONITOR_BASE, %a1
 467         move.l #__init_end, %a2
 468         move.l %a0, %a3
 469
 470         /* copy the code to RAM */
 471 1:
 472         move.l (%a1)+, (%a3)+
 473         cmp.l  %a1,%a2
 474         bgt.s    1b
 475
 476 /*
 477  * We are done. Do not return, instead branch to second part of board
 478  * initialization, now running from RAM.
 479  */
 480         move.l  %a0, %a1
 481         add.l   #(in_ram - CONFIG_SYS_MONITOR_BASE), %a1
 482         jmp     (%a1)
 483
 484 in_ram:
 485
 486 clear_bss:
 487         /*
 488          * Now clear BSS segment
 489          */
 490         move.l  %a0, %a1
 491         add.l   #(_sbss - CONFIG_SYS_MONITOR_BASE),%a1
 492         move.l  %a0, %d1
 493         add.l   #(_ebss - CONFIG_SYS_MONITOR_BASE),%d1
 494 6:
 495         clr.l   (%a1)+
 496         cmp.l   %a1,%d1
 497         bgt.s   6b
 498
 499         /*
 500          * fix got table in RAM
 501          */
 502         move.l  %a0, %a1
 503         add.l   #(__got_start - CONFIG_SYS_MONITOR_BASE),%a1
 504         move.l  %a1,%a5                 /* * fix got pointer register a5 */
 505
 506         move.l  %a0, %a2
 507         add.l   #(__got_end - CONFIG_SYS_MONITOR_BASE),%a2
 508
 509 7:
 510         move.l  (%a1),%d1
 511         sub.l   #_start,%d1
 512         add.l   %a0,%d1
 513         move.l  %d1,(%a1)+
 514         cmp.l   %a2, %a1
 515         bne     7b
 516
 517         /* calculate relative jump to board_init_r in ram */
 518         move.l %a0, %a1
 519         add.l #(board_init_r - CONFIG_SYS_MONITOR_BASE), %a1
 520
 521         /* set parameters for board_init_r */
 522         move.l %a0,-(%sp)               /* dest_addr */
 523         move.l %d0,-(%sp)               /* gd */
 524         jsr     (%a1)
 525
 526 /*------------------------------------------------------------------------------*/
 527 /* exception code */
 528         .globl _fault
 529 _fault:
 530         bra _fault
 531         .globl  _exc_handler
 532
 533 _exc_handler:
 534         SAVE_ALL
 535         movel   %sp,%sp@-
 536         bsr exc_handler
 537         addql   #4,%sp
 538         RESTORE_ALL
 539
 540         .globl  _int_handler
 541 _int_handler:
 542         SAVE_ALL
 543         movel   %sp,%sp@-
 544         bsr int_handler
 545         addql   #4,%sp
 546         RESTORE_ALL
 547
 548 /*------------------------------------------------------------------------------*/
 549 /* cache functions */
 550         .globl  icache_enable
 551 icache_enable:
 552         move.l #(CACR_STATUS), %a1      /* read CACR Status */
 553         move.l  (%a1), %d1
 554
 555         move.l  #0x00040100, %d0        /* Invalidate icache */
 556         movec   %d0, %CACR
 557
 558         move.l  #(CONFIG_SYS_SDRAM_BASE + 0xC000), %d0  /* Setup icache */
 559         movec   %d0, %ACR2
 560
 561         move.l  #0x04088020, %d0        /* Enable bcache and icache */
 562         movec   %d0, %CACR
 563
 564         move.l #(ICACHE_STATUS), %a1
 565         moveq   #1, %d0
 566         move.l  %d0, (%a1)
 567         rts
 568
 569         .globl  icache_disable
 570 icache_disable:
 571         move.l #(CACR_STATUS), %a1      /* read CACR Status */
 572         move.l  (%a1), %d0
 573
 574         move.l  #0xFFF77BFF, %d0
 575         or.l    #0x00040100, %d0        /* Setup cache mask */
 576         movec   %d0, %CACR              /* Invalidate icache */
 577         clr.l   %d0
 578         movec   %d0, %ACR2
 579         movec   %d0, %ACR3
 580
 581         move.l #(ICACHE_STATUS), %a1
 582         moveq   #0, %d0
 583         move.l  %d0, (%a1)
 584         rts
 585
 586         .globl  icache_status
 587 icache_status:
 588         move.l #(ICACHE_STATUS), %a1
 589         move.l  (%a1), %d0
 590         rts
 591
 592         .globl  icache_invalid
 593 icache_invalid:
 594         move.l #(CACR_STATUS), %a1      /* read CACR Status */
 595         move.l  (%a1), %d0
 596
 597         move.l  #0x00040100, %d0        /* Invalidate icache */
 598         movec   %d0, %CACR              /* Enable and invalidate cache */
 599         rts
 600
 601         .globl  dcache_enable
 602 dcache_enable:
 603         move.l #(CACR_STATUS), %a1      /* read CACR Status */
 604         move.l  (%a1), %d1
 605
 606         move.l  #0x01040100, %d0
 607         movec   %d0, %CACR              /* Invalidate dcache */
 608
 609         move.l  #0x80088020, %d0        /* Enable bcache and icache */
 610         movec   %d0, %CACR
 611
 612         move.l #(DCACHE_STATUS), %a1
 613         moveq   #1, %d0
 614         move.l  %d0, (%a1)
 615         rts
 616
 617         .globl  dcache_disable
 618 dcache_disable:
 619         move.l #(CACR_STATUS), %a1      /* read CACR Status */
 620         move.l  (%a1), %d0
 621
 622         and.l   #0x7FFFFFFF, %d0
 623         or.l    #0x01000000, %d0        /* Setup cache mask */
 624         movec   %d0, %CACR              /* Disable dcache */
 625         clr.l   %d0
 626         movec   %d0, %ACR0
 627         movec   %d0, %ACR1
 628
 629         move.l #(DCACHE_STATUS), %a1
 630         moveq   #0, %d0
 631         move.l  %d0, (%a1)
 632         rts
 633
 634         .globl  dcache_invalid
 635 dcache_invalid:
 636         move.l #(CACR_STATUS), %a1      /* read CACR Status */
 637         move.l  (%a1), %d0
 638
 639         move.l  #0x81088020, %d0        /* Setup cache mask */
 640         movec   %d0, %CACR              /* Enable and invalidate cache */
 641         rts
 642
 643         .globl  dcache_status
 644 dcache_status:
 645         move.l #(DCACHE_STATUS), %a1
 646         move.l  (%a1), %d0
 647         rts
 648
 649 /*------------------------------------------------------------------------------*/
 650
 651         .globl  version_string
 652 version_string:
 653         .ascii U_BOOT_VERSION
 654         .ascii " (", U_BOOT_DATE, " - ", U_BOOT_TIME, ")"
 655         .ascii CONFIG_IDENT_STRING, "\0"
 656         .align 4