cpu/arm920t/start.S

   1 /*
   2  *  armboot - Startup Code for ARM920 CPU-core
   3  *
   4  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
   5  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
   6  *  Copyright (c) 2002  Gary Jennejohn <gj@denx.de>
   7  *
   8  * See file CREDITS for list of people who contributed to this
   9  * project.
  10  *
  11  * This program is free software; you can redistribute it and/or
  12  * modify it under the terms of the GNU General Public License as
  13  * published by the Free Software Foundation; either version 2 of
  14  * the License, or (at your option) any later version.
  15  *
  16  * This program is distributed in the hope that it will be useful,
  17  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  18  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19  * GNU General Public License for more details.
  20  *
  21  * You should have received a copy of the GNU General Public License
  22  * along with this program; if not, write to the Free Software
  23  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  24  * MA 02111-1307 USA
  25  */
  26
  27 #include <config.h>
  28 #include <version.h>
  29 #include <status_led.h>
  30
  31 /*
  32  *************************************************************************
  33  *
  34  * Jump vector table as in table 3.1 in [1]
  35  *
  36  *************************************************************************
  37  */
  38
  39
  40 .globl _start
  41 _start: b       start_code
  42         ldr     pc, _undefined_instruction
  43         ldr     pc, _software_interrupt
  44         ldr     pc, _prefetch_abort
  45         ldr     pc, _data_abort
  46         ldr     pc, _not_used
  47         ldr     pc, _irq
  48         ldr     pc, _fiq
  49
  50 _undefined_instruction: .word undefined_instruction
  51 _software_interrupt:    .word software_interrupt
  52 _prefetch_abort:        .word prefetch_abort
  53 _data_abort:            .word data_abort
  54 _not_used:              .word not_used
  55 _irq:                   .word irq
  56 _fiq:                   .word fiq
  57
  58         .balignl 16,0xdeadbeef
  59
  60
  61 /*
  62  *************************************************************************
  63  *
  64  * Startup Code (called from the ARM reset exception vector)
  65  *
  66  * do important init only if we don't start from memory!
  67  * relocate armboot to ram
  68  * setup stack
  69  * jump to second stage
  70  *
  71  *************************************************************************
  72  */
  73
  74 _TEXT_BASE:
  75         .word   TEXT_BASE
  76
  77 .globl _armboot_start
  78 _armboot_start:
  79         .word _start
  80
  81 /*
  82  * These are defined in the board-specific linker script.
  83  */
  84 .globl _bss_start
  85 _bss_start:
  86         .word __bss_start
  87
  88 .globl _bss_end
  89 _bss_end:
  90         .word _end
  91
  92 #ifdef CONFIG_USE_IRQ
  93 /* IRQ stack memory (calculated at run-time) */
  94 .globl IRQ_STACK_START
  95 IRQ_STACK_START:
  96         .word   0x0badc0de
  97
  98 /* IRQ stack memory (calculated at run-time) */
  99 .globl FIQ_STACK_START
 100 FIQ_STACK_START:
 101         .word 0x0badc0de
 102 #endif
 103
 104
 105 /*
 106  * the actual start code
 107  */
 108
 109 start_code:
 110         /*
 111          * set the cpu to SVC32 mode
 112          */
 113         mrs     r0,cpsr
 114         bic     r0,r0,#0x1f
 115         orr     r0,r0,#0xd3
 116         msr     cpsr,r0
 117
 118         bl coloured_LED_init
 119         bl red_LED_on
 120
 121 #if     defined(CONFIG_AT91RM9200DK) || defined(CONFIG_AT91RM9200EK)
 122         /*
 123          * relocate exception table
 124          */
 125         ldr     r0, =_start
 126         ldr     r1, =0x0
 127         mov     r2, #16
 128 copyex:
 129         subs    r2, r2, #1
 130         ldr     r3, [r0], #4
 131         str     r3, [r1], #4
 132         bne     copyex
 133 #endif
 134
 135 #if defined(CONFIG_S3C2400) || defined(CONFIG_S3C2410)
 136         /* turn off the watchdog */
 137
 138 # if defined(CONFIG_S3C2400)
 139 #  define pWTCON                0x15300000
 140 #  define INTMSK                0x14400008      /* Interupt-Controller base addresses */
 141 #  define CLKDIVN       0x14800014      /* clock divisor register */
 142 #else
 143 #  define pWTCON                0x53000000
 144 #  define INTMSK                0x4A000008      /* Interupt-Controller base addresses */
 145 #  define INTSUBMSK     0x4A00001C
 146 #  define CLKDIVN       0x4C000014      /* clock divisor register */
 147 # endif
 148
 149         ldr     r0, =pWTCON
 150         mov     r1, #0x0
 151         str     r1, [r0]
 152
 153         /*
 154          * mask all IRQs by setting all bits in the INTMR - default
 155          */
 156         mov     r1, #0xffffffff
 157         ldr     r0, =INTMSK
 158         str     r1, [r0]
 159 # if defined(CONFIG_S3C2410)
 160         ldr     r1, =0x3ff
 161         ldr     r0, =INTSUBMSK
 162         str     r1, [r0]
 163 # endif
 164
 165         /* FCLK:HCLK:PCLK = 1:2:4 */
 166         /* default FCLK is 120 MHz ! */
 167         ldr     r0, =CLKDIVN
 168         mov     r1, #3
 169         str     r1, [r0]
 170 #endif  /* CONFIG_S3C2400 || CONFIG_S3C2410 */
 171
 172         /*
 173          * we do sys-critical inits only at reboot,
 174          * not when booting from ram!
 175          */
 176 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 177         bl      cpu_init_crit
 178 #endif
 179
 180 #ifndef CONFIG_SKIP_RELOCATE_UBOOT
 181 relocate:                               /* relocate U-Boot to RAM           */
 182         adr     r0, _start              /* r0 <- current position of code   */
 183         ldr     r1, _TEXT_BASE          /* test if we run from flash or RAM */
 184         cmp     r0, r1                  /* don't reloc during debug         */
 185         beq     stack_setup
 186
 187         ldr     r2, _armboot_start
 188         ldr     r3, _bss_start
 189         sub     r2, r3, r2              /* r2 <- size of armboot            */
 190         add     r2, r0, r2              /* r2 <- source end address         */
 191
 192 copy_loop:
 193         ldmia   r0!, {r3-r10}           /* copy from source address [r0]    */
 194         stmia   r1!, {r3-r10}           /* copy to   target address [r1]    */
 195         cmp     r0, r2                  /* until source end addreee [r2]    */
 196         ble     copy_loop
 197 #endif  /* CONFIG_SKIP_RELOCATE_UBOOT */
 198
 199         /* Set up the stack                                                 */
 200 stack_setup:
 201         ldr     r0, _TEXT_BASE          /* upper 128 KiB: relocated uboot   */
 202         sub     r0, r0, #CONFIG_SYS_MALLOC_LEN  /* malloc area                      */
 203         sub     r0, r0, #CONFIG_SYS_GBL_DATA_SIZE /* bdinfo                        */
 204 #ifdef CONFIG_USE_IRQ
 205         sub     r0, r0, #(CONFIG_STACKSIZE_IRQ+CONFIG_STACKSIZE_FIQ)
 206 #endif
 207         sub     sp, r0, #12             /* leave 3 words for abort-stack    */
 208
 209 clear_bss:
 210         ldr     r0, _bss_start          /* find start of bss segment        */
 211         ldr     r1, _bss_end            /* stop here                        */
 212         mov     r2, #0x00000000         /* clear                            */
 213
 214 clbss_l:str     r2, [r0]                /* clear loop...                    */
 215         add     r0, r0, #4
 216         cmp     r0, r1
 217         ble     clbss_l
 218
 219         ldr     pc, _start_armboot
 220
 221 _start_armboot: .word start_armboot
 222
 223
 224 /*
 225  *************************************************************************
 226  *
 227  * CPU_init_critical registers
 228  *
 229  * setup important registers
 230  * setup memory timing
 231  *
 232  *************************************************************************
 233  */
 234
 235
 236 #ifndef CONFIG_SKIP_LOWLEVEL_INIT
 237 cpu_init_crit:
 238         /*
 239          * flush v4 I/D caches
 240          */
 241         mov     r0, #0
 242         mcr     p15, 0, r0, c7, c7, 0   /* flush v3/v4 cache */
 243         mcr     p15, 0, r0, c8, c7, 0   /* flush v4 TLB */
 244
 245         /*
 246          * disable MMU stuff and caches
 247          */
 248         mrc     p15, 0, r0, c1, c0, 0
 249         bic     r0, r0, #0x00002300     @ clear bits 13, 9:8 (--V- --RS)
 250         bic     r0, r0, #0x00000087     @ clear bits 7, 2:0 (B--- -CAM)
 251         orr     r0, r0, #0x00000002     @ set bit 2 (A) Align
 252         orr     r0, r0, #0x00001000     @ set bit 12 (I) I-Cache
 253         mcr     p15, 0, r0, c1, c0, 0
 254
 255         /*
 256          * before relocating, we have to setup RAM timing
 257          * because memory timing is board-dependend, you will
 258          * find a lowlevel_init.S in your board directory.
 259          */
 260         mov     ip, lr
 261 #if     defined(CONFIG_AT91RM9200EK)
 262
 263 #else
 264         bl      lowlevel_init
 265 #endif
 266         mov     lr, ip
 267         mov     pc, lr
 268 #endif /* CONFIG_SKIP_LOWLEVEL_INIT */
 269
 270 /*
 271  *************************************************************************
 272  *
 273  * Interrupt handling
 274  *
 275  *************************************************************************
 276  */
 277
 278 @
 279 @ IRQ stack frame.
 280 @
 281 #define S_FRAME_SIZE    72
 282
 283 #define S_OLD_R0        68
 284 #define S_PSR           64
 285 #define S_PC            60
 286 #define S_LR            56
 287 #define S_SP            52
 288
 289 #define S_IP            48
 290 #define S_FP            44
 291 #define S_R10           40
 292 #define S_R9            36
 293 #define S_R8            32
 294 #define S_R7            28
 295 #define S_R6            24
 296 #define S_R5            20
 297 #define S_R4            16
 298 #define S_R3            12
 299 #define S_R2            8
 300 #define S_R1            4
 301 #define S_R0            0
 302
 303 #define MODE_SVC 0x13
 304 #define I_BIT    0x80
 305
 306 /*
 307  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 308  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 309  */
 310
 311         .macro  bad_save_user_regs
 312         sub     sp, sp, #S_FRAME_SIZE
 313         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 314         ldr     r2, _armboot_start
 315         sub     r2, r2, #(CONFIG_STACKSIZE)
 316         sub     r2, r2, #(CONFIG_SYS_MALLOC_LEN)
 317         sub     r2, r2, #(CONFIG_SYS_GBL_DATA_SIZE+8)  @ set base 2 words into abort stack
 318         ldmia   r2, {r2 - r3}                   @ get pc, cpsr
 319         add     r0, sp, #S_FRAME_SIZE           @ restore sp_SVC
 320
 321         add     r5, sp, #S_SP
 322         mov     r1, lr
 323         stmia   r5, {r0 - r3}                   @ save sp_SVC, lr_SVC, pc, cpsr
 324         mov     r0, sp
 325         .endm
 326
 327         .macro  irq_save_user_regs
 328         sub     sp, sp, #S_FRAME_SIZE
 329         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 330         add     r7, sp, #S_PC
 331         stmdb   r7, {sp, lr}^                   @ Calling SP, LR
 332         str     lr, [r7, #0]                    @ Save calling PC
 333         mrs     r6, spsr
 334         str     r6, [r7, #4]                    @ Save CPSR
 335         str     r0, [r7, #8]                    @ Save OLD_R0
 336         mov     r0, sp
 337         .endm
 338
 339         .macro  irq_restore_user_regs
 340         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 341         mov     r0, r0
 342         ldr     lr, [sp, #S_PC]                 @ Get PC
 343         add     sp, sp, #S_FRAME_SIZE
 344         subs    pc, lr, #4                      @ return & move spsr_svc into cpsr
 345         .endm
 346
 347         .macro get_bad_stack
 348         ldr     r13, _armboot_start             @ setup our mode stack
 349         sub     r13, r13, #(CONFIG_STACKSIZE)
 350         sub     r13, r13, #(CONFIG_SYS_MALLOC_LEN)
 351         sub     r13, r13, #(CONFIG_SYS_GBL_DATA_SIZE+8) @ reserved a couple spots in abort stack
 352
 353         str     lr, [r13]                       @ save caller lr / spsr
 354         mrs     lr, spsr
 355         str     lr, [r13, #4]
 356
 357         mov     r13, #MODE_SVC                  @ prepare SVC-Mode
 358         @ msr   spsr_c, r13
 359         msr     spsr, r13
 360         mov     lr, pc
 361         movs    pc, lr
 362         .endm
 363
 364         .macro get_irq_stack                    @ setup IRQ stack
 365         ldr     sp, IRQ_STACK_START
 366         .endm
 367
 368         .macro get_fiq_stack                    @ setup FIQ stack
 369         ldr     sp, FIQ_STACK_START
 370         .endm
 371
 372 /*
 373  * exception handlers
 374  */
 375         .align  5
 376 undefined_instruction:
 377         get_bad_stack
 378         bad_save_user_regs
 379         bl      do_undefined_instruction
 380
 381         .align  5
 382 software_interrupt:
 383         get_bad_stack
 384         bad_save_user_regs
 385         bl      do_software_interrupt
 386
 387         .align  5
 388 prefetch_abort:
 389         get_bad_stack
 390         bad_save_user_regs
 391         bl      do_prefetch_abort
 392
 393         .align  5
 394 data_abort:
 395         get_bad_stack
 396         bad_save_user_regs
 397         bl      do_data_abort
 398
 399         .align  5
 400 not_used:
 401         get_bad_stack
 402         bad_save_user_regs
 403         bl      do_not_used
 404
 405 #ifdef CONFIG_USE_IRQ
 406
 407         .align  5
 408 irq:
 409         get_irq_stack
 410         irq_save_user_regs
 411         bl      do_irq
 412         irq_restore_user_regs
 413
 414         .align  5
 415 fiq:
 416         get_fiq_stack
 417         /* someone ought to write a more effiction fiq_save_user_regs */
 418         irq_save_user_regs
 419         bl      do_fiq
 420         irq_restore_user_regs
 421
 422 #else
 423
 424         .align  5
 425 irq:
 426         get_bad_stack
 427         bad_save_user_regs
 428         bl      do_irq
 429
 430         .align  5
 431 fiq:
 432         get_bad_stack
 433         bad_save_user_regs
 434         bl      do_fiq
 435
 436 #endif