cpu/arm920t/start.S

   1 /*
   2  *  armboot - Startup Code for ARM920 CPU-core
   3  *
   4  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
   5  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
   6  *  Copyright (c) 2002  Gary Jennejohn <gj@denx.de>
   7  *
   8  * See file CREDITS for list of people who contributed to this
   9  * project.
  10  *
  11  * This program is free software; you can redistribute it and/or
  12  * modify it under the terms of the GNU General Public License as
  13  * published by the Free Software Foundation; either version 2 of
  14  * the License, or (at your option) any later version.
  15  *
  16  * This program is distributed in the hope that it will be useful,
  17  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  18  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19  * GNU General Public License for more details.
  20  *
  21  * You should have received a copy of the GNU General Public License
  22  * along with this program; if not, write to the Free Software
  23  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  24  * MA 02111-1307 USA
  25  */
  26
  27
  28 #include <config.h>
  29 #include <version.h>
  30
  31
  32 /*
  33  *************************************************************************
  34  *
  35  * Jump vector table as in table 3.1 in [1]
  36  *
  37  *************************************************************************
  38  */
  39
  40
  41 .globl _start
  42 _start: b       reset
  43         ldr     pc, _undefined_instruction
  44         ldr     pc, _software_interrupt
  45         ldr     pc, _prefetch_abort
  46         ldr     pc, _data_abort
  47         ldr     pc, _not_used
  48         ldr     pc, _irq
  49         ldr     pc, _fiq
  50
  51 _undefined_instruction: .word undefined_instruction
  52 _software_interrupt:    .word software_interrupt
  53 _prefetch_abort:        .word prefetch_abort
  54 _data_abort:            .word data_abort
  55 _not_used:              .word not_used
  56 _irq:                   .word irq
  57 _fiq:                   .word fiq
  58
  59         .balignl 16,0xdeadbeef
  60
  61
  62 /*
  63  *************************************************************************
  64  *
  65  * Startup Code (reset vector)
  66  *
  67  * do important init only if we don't start from memory!
  68  * relocate armboot to ram
  69  * setup stack
  70  * jump to second stage
  71  *
  72  *************************************************************************
  73  */
  74
  75 _TEXT_BASE:
  76         .word   TEXT_BASE
  77
  78 .globl _armboot_start
  79 _armboot_start:
  80         .word _start
  81
  82 /*
  83  * These are defined in the board-specific linker script.
  84  */
  85 .globl _bss_start
  86 _bss_start:
  87         .word __bss_start
  88
  89 .globl _bss_end
  90 _bss_end:
  91         .word _end
  92
  93 #ifdef CONFIG_USE_IRQ
  94 /* IRQ stack memory (calculated at run-time) */
  95 .globl IRQ_STACK_START
  96 IRQ_STACK_START:
  97         .word   0x0badc0de
  98
  99 /* IRQ stack memory (calculated at run-time) */
 100 .globl FIQ_STACK_START
 101 FIQ_STACK_START:
 102         .word 0x0badc0de
 103 #endif
 104
 105
 106 /*
 107  * the actual reset code
 108  */
 109
 110 reset:
 111         /*
 112          * set the cpu to SVC32 mode
 113          */
 114         mrs     r0,cpsr
 115         bic     r0,r0,#0x1f
 116         orr     r0,r0,#0xd3
 117         msr     cpsr,r0
 118
 119 /* turn off the watchdog */
 120 #if defined(CONFIG_S3C2400)
 121 #define pWTCON          0x15300000
 122 /* Interupt-Controller base addresses */
 123 #define INTMSK          0x14400008
 124 /* clock divisor register */
 125 #define CLKDIVN         0x14800014
 126 #elif defined(CONFIG_S3C2410)
 127 #define pWTCON          0x53000000
 128 /* Interupt-Controller base addresses */
 129 #define INTMSK          0x4A000008
 130 #define INTSUBMSK       0x4A00001C
 131 /* clock divisor register */
 132 #define CLKDIVN         0x4C000014
 133 #endif
 134
 135         ldr     r0, =pWTCON
 136         mov     r1, #0x0
 137         str     r1, [r0]
 138
 139         /*
 140          * mask all IRQs by setting all bits in the INTMR - default
 141          */
 142         mov     r1, #0xffffffff
 143         ldr     r0, =INTMSK
 144         str     r1, [r0]
 145 #if defined(CONFIG_S3C2410)
 146         ldr     r1, =0x3ff
 147         ldr     r0, =INTSUBMSK
 148         str     r1, [r0]
 149 #endif
 150
 151         /* FCLK:HCLK:PCLK = 1:2:4 */
 152         /* default FCLK is 120 MHz ! */
 153         ldr     r0, =CLKDIVN
 154         mov     r1, #3
 155         str     r1, [r0]
 156
 157         /*
 158          * we do sys-critical inits only at reboot,
 159          * not when booting from ram!
 160          */
 161 #ifdef CONFIG_INIT_CRITICAL
 162         bl      cpu_init_crit
 163 #endif
 164
 165 relocate:                               /* relocate U-Boot to RAM           */
 166         adr     r0, _start              /* r0 <- current position of code   */
 167         ldr     r1, _TEXT_BASE          /* test if we run from flash or RAM */
 168         cmp     r0, r1                  /* don't reloc during debug         */
 169         beq     stack_setup
 170
 171         ldr     r2, _armboot_start
 172         ldr     r3, _bss_start
 173         sub     r2, r3, r2              /* r2 <- size of armboot            */
 174         add     r2, r0, r2              /* r2 <- source end address         */
 175
 176 copy_loop:
 177         ldmia   r0!, {r3-r10}           /* copy from source address [r0]    */
 178         stmia   r1!, {r3-r10}           /* copy to   target address [r1]    */
 179         cmp     r0, r2                  /* until source end addreee [r2]    */
 180         ble     copy_loop
 181
 182         /* Set up the stack                                                 */
 183 stack_setup:
 184         ldr     r0, _TEXT_BASE          /* upper 128 KiB: relocated uboot   */
 185         sub     r0, r0, #CFG_MALLOC_LEN /* malloc area                      */
 186         sub     r0, r0, #CFG_GBL_DATA_SIZE /* bdinfo                        */
 187 #ifdef CONFIG_USE_IRQ
 188         sub     r0, r0, #(CONFIG_STACKSIZE_IRQ+CONFIG_STACKSIZE_FIQ)
 189 #endif
 190         sub     sp, r0, #12             /* leave 3 words for abort-stack    */
 191
 192 clear_bss:
 193         ldr     r0, _bss_start          /* find start of bss segment        */
 194         add     r0, r0, #4              /* start at first byte of bss       */
 195         ldr     r1, _bss_end            /* stop here                        */
 196         mov     r2, #0x00000000         /* clear                            */
 197
 198 clbss_l:str     r2, [r0]                /* clear loop...                    */
 199         add     r0, r0, #4
 200         cmp     r0, r1
 201         bne     clbss_l
 202
 203 #if 0
 204         /* try doing this stuff after the relocation */
 205         ldr     r0, =pWTCON
 206         mov     r1, #0x0
 207         str     r1, [r0]
 208
 209         /*
 210          * mask all IRQs by setting all bits in the INTMR - default
 211          */
 212         mov     r1, #0xffffffff
 213         ldr     r0, =INTMR
 214         str     r1, [r0]
 215
 216         /* FCLK:HCLK:PCLK = 1:2:4 */
 217         /* default FCLK is 120 MHz ! */
 218         ldr     r0, =CLKDIVN
 219         mov     r1, #3
 220         str     r1, [r0]
 221         /* END stuff after relocation */
 222 #endif
 223
 224         ldr     pc, _start_armboot
 225
 226 _start_armboot: .word start_armboot
 227
 228
 229 /*
 230  *************************************************************************
 231  *
 232  * CPU_init_critical registers
 233  *
 234  * setup important registers
 235  * setup memory timing
 236  *
 237  *************************************************************************
 238  */
 239
 240
 241 cpu_init_crit:
 242         /*
 243          * flush v4 I/D caches
 244          */
 245         mov     r0, #0
 246         mcr     p15, 0, r0, c7, c7, 0   /* flush v3/v4 cache */
 247         mcr     p15, 0, r0, c8, c7, 0   /* flush v4 TLB */
 248
 249         /*
 250          * disable MMU stuff and caches
 251          */
 252         mrc     p15, 0, r0, c1, c0, 0
 253         bic     r0, r0, #0x00002300     @ clear bits 13, 9:8 (--V- --RS)
 254         bic     r0, r0, #0x00000087     @ clear bits 7, 2:0 (B--- -CAM)
 255         orr     r0, r0, #0x00000002     @ set bit 2 (A) Align
 256         orr     r0, r0, #0x00001000     @ set bit 12 (I) I-Cache
 257         mcr     p15, 0, r0, c1, c0, 0
 258
 259
 260         /*
 261          * before relocating, we have to setup RAM timing
 262          * because memory timing is board-dependend, you will
 263          * find a memsetup.S in your board directory.
 264          */
 265         mov     ip, lr
 266         bl      memsetup
 267         mov     lr, ip
 268
 269         mov     pc, lr
 270
 271
 272 /*
 273  *************************************************************************
 274  *
 275  * Interrupt handling
 276  *
 277  *************************************************************************
 278  */
 279
 280 @
 281 @ IRQ stack frame.
 282 @
 283 #define S_FRAME_SIZE    72
 284
 285 #define S_OLD_R0        68
 286 #define S_PSR           64
 287 #define S_PC            60
 288 #define S_LR            56
 289 #define S_SP            52
 290
 291 #define S_IP            48
 292 #define S_FP            44
 293 #define S_R10           40
 294 #define S_R9            36
 295 #define S_R8            32
 296 #define S_R7            28
 297 #define S_R6            24
 298 #define S_R5            20
 299 #define S_R4            16
 300 #define S_R3            12
 301 #define S_R2            8
 302 #define S_R1            4
 303 #define S_R0            0
 304
 305 #define MODE_SVC 0x13
 306 #define I_BIT    0x80
 307
 308 /*
 309  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 310  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 311  */
 312
 313         .macro  bad_save_user_regs
 314         sub     sp, sp, #S_FRAME_SIZE
 315         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 316         ldr     r2, _armboot_start
 317         sub     r2, r2, #(CONFIG_STACKSIZE+CFG_MALLOC_LEN)
 318         sub     r2, r2, #(CFG_GBL_DATA_SIZE+8)  @ set base 2 words into abort stack
 319         ldmia   r2, {r2 - r3}                   @ get pc, cpsr
 320         add     r0, sp, #S_FRAME_SIZE           @ restore sp_SVC
 321
 322         add     r5, sp, #S_SP
 323         mov     r1, lr
 324         stmia   r5, {r0 - r3}                   @ save sp_SVC, lr_SVC, pc, cpsr
 325         mov     r0, sp
 326         .endm
 327
 328         .macro  irq_save_user_regs
 329         sub     sp, sp, #S_FRAME_SIZE
 330         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 331         add     r8, sp, #S_PC
 332         stmdb   r8, {sp, lr}^                   @ Calling SP, LR
 333         str     lr, [r8, #0]                    @ Save calling PC
 334         mrs     r6, spsr
 335         str     r6, [r8, #4]                    @ Save CPSR
 336         str     r0, [r8, #8]                    @ Save OLD_R0
 337         mov     r0, sp
 338         .endm
 339
 340         .macro  irq_restore_user_regs
 341         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 342         mov     r0, r0
 343         ldr     lr, [sp, #S_PC]                 @ Get PC
 344         add     sp, sp, #S_FRAME_SIZE
 345         subs    pc, lr, #4                      @ return & move spsr_svc into cpsr
 346         .endm
 347
 348         .macro get_bad_stack
 349         ldr     r13, _armboot_start             @ setup our mode stack
 350         sub     r13, r13, #(CONFIG_STACKSIZE+CFG_MALLOC_LEN)
 351         sub     r13, r13, #(CFG_GBL_DATA_SIZE+8) @ reserved a couple spots in abort stack
 352
 353         str     lr, [r13]                       @ save caller lr / spsr
 354         mrs     lr, spsr
 355         str     lr, [r13, #4]
 356
 357         mov     r13, #MODE_SVC                  @ prepare SVC-Mode
 358         @ msr   spsr_c, r13
 359         msr     spsr, r13
 360         mov     lr, pc
 361         movs    pc, lr
 362         .endm
 363
 364         .macro get_irq_stack                    @ setup IRQ stack
 365         ldr     sp, IRQ_STACK_START
 366         .endm
 367
 368         .macro get_fiq_stack                    @ setup FIQ stack
 369         ldr     sp, FIQ_STACK_START
 370         .endm
 371
 372 /*
 373  * exception handlers
 374  */
 375         .align  5
 376 undefined_instruction:
 377         get_bad_stack
 378         bad_save_user_regs
 379         bl      do_undefined_instruction
 380
 381         .align  5
 382 software_interrupt:
 383         get_bad_stack
 384         bad_save_user_regs
 385         bl      do_software_interrupt
 386
 387         .align  5
 388 prefetch_abort:
 389         get_bad_stack
 390         bad_save_user_regs
 391         bl      do_prefetch_abort
 392
 393         .align  5
 394 data_abort:
 395         get_bad_stack
 396         bad_save_user_regs
 397         bl      do_data_abort
 398
 399         .align  5
 400 not_used:
 401         get_bad_stack
 402         bad_save_user_regs
 403         bl      do_not_used
 404
 405 #ifdef CONFIG_USE_IRQ
 406
 407         .align  5
 408 irq:
 409         get_irq_stack
 410         irq_save_user_regs
 411         bl      do_irq
 412         irq_restore_user_regs
 413
 414         .align  5
 415 fiq:
 416         get_fiq_stack
 417         /* someone ought to write a more effiction fiq_save_user_regs */
 418         irq_save_user_regs
 419         bl      do_fiq
 420         irq_restore_user_regs
 421
 422 #else
 423
 424         .align  5
 425 irq:
 426         get_bad_stack
 427         bad_save_user_regs
 428         bl      do_irq
 429
 430         .align  5
 431 fiq:
 432         get_bad_stack
 433         bad_save_user_regs
 434         bl      do_fiq
 435
 436 #endif
 437
 438         .align  5
 439 .globl reset_cpu
 440 reset_cpu:
 441 #ifdef CONFIG_S3C2400
 442         bl      disable_interrupts
 443 # ifdef CONFIG_TRAB
 444         bl      disable_vfd
 445 # endif
 446         ldr     r1, _rWTCON
 447         ldr     r2, _rWTCNT
 448         /* Disable watchdog */
 449         mov     r3, #0x0000
 450         str     r3, [r1]
 451         /* Initialize watchdog timer count register */
 452         mov     r3, #0x0001
 453         str     r3, [r2]
 454         /* Enable watchdog timer; assert reset at timer timeout */
 455         mov     r3, #0x0021
 456         str     r3, [r1]
 457 _loop_forever:
 458         b       _loop_forever
 459 _rWTCON:
 460         .word   0x15300000
 461 _rWTCNT:
 462         .word   0x15300008
 463 #else /* ! CONFIG_S3C2400 */
 464         mov     ip, #0
 465         mcr     p15, 0, ip, c7, c7, 0           @ invalidate cache
 466         mcr     p15, 0, ip, c8, c7, 0           @ flush TLB (v4)
 467         mrc     p15, 0, ip, c1, c0, 0           @ get ctrl register
 468         bic     ip, ip, #0x000f                 @ ............wcam
 469         bic     ip, ip, #0x2100                 @ ..v....s........
 470         mcr     p15, 0, ip, c1, c0, 0           @ ctrl register
 471         mov     pc, r0
 472 #endif /* CONFIG_S3C2400 */