cpu/arm720t/start.S

   1 /*
   2  *  armboot - Startup Code for ARM720 CPU-core
   3  *
   4  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
   5  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
   6  *
   7  * See file CREDITS for list of people who contributed to this
   8  * project.
   9  *
  10  * This program is free software; you can redistribute it and/or
  11  * modify it under the terms of the GNU General Public License as
  12  * published by the Free Software Foundation; either version 2 of
  13  * the License, or (at your option) any later version.
  14  *
  15  * This program is distributed in the hope that it will be useful,
  16  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18  * GNU General Public License for more details.
  19  *
  20  * You should have received a copy of the GNU General Public License
  21  * along with this program; if not, write to the Free Software
  22  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  23  * MA 02111-1307 USA
  24  */
  25
  26
  27 #include <config.h>
  28 #include <version.h>
  29 #include <asm/hardware.h>
  30
  31 /*
  32  *************************************************************************
  33  *
  34  * Jump vector table as in table 3.1 in [1]
  35  *
  36  *************************************************************************
  37  */
  38
  39
  40 .globl _start
  41 _start: b       reset
  42         ldr     pc, _undefined_instruction
  43         ldr     pc, _software_interrupt
  44         ldr     pc, _prefetch_abort
  45         ldr     pc, _data_abort
  46         ldr     pc, _not_used
  47         ldr     pc, _irq
  48         ldr     pc, _fiq
  49
  50 _undefined_instruction: .word undefined_instruction
  51 _software_interrupt:    .word software_interrupt
  52 _prefetch_abort:        .word prefetch_abort
  53 _data_abort:            .word data_abort
  54 _not_used:              .word not_used
  55 _irq:                   .word irq
  56 _fiq:                   .word fiq
  57
  58         .balignl 16,0xdeadbeef
  59
  60
  61 /*
  62  *************************************************************************
  63  *
  64  * Startup Code (reset vector)
  65  *
  66  * do important init only if we don't start from RAM!
  67  * relocate armboot to ram
  68  * setup stack
  69  * jump to second stage
  70  *
  71  *************************************************************************
  72  */
  73
  74 _TEXT_BASE:
  75         .word   TEXT_BASE
  76
  77 .globl _armboot_start
  78 _armboot_start:
  79         .word _start
  80
  81 /*
  82  * These are defined in the board-specific linker script.
  83  */
  84 .globl _bss_start
  85 _bss_start:
  86         .word __bss_start
  87
  88 .globl _bss_end
  89 _bss_end:
  90         .word _end
  91
  92 #ifdef CONFIG_USE_IRQ
  93 /* IRQ stack memory (calculated at run-time) */
  94 .globl IRQ_STACK_START
  95 IRQ_STACK_START:
  96         .word   0x0badc0de
  97
  98 /* IRQ stack memory (calculated at run-time) */
  99 .globl FIQ_STACK_START
 100 FIQ_STACK_START:
 101         .word 0x0badc0de
 102 #endif
 103
 104
 105 /*
 106  * the actual reset code
 107  */
 108
 109 reset:
 110         /*
 111          * set the cpu to SVC32 mode
 112          */
 113         mrs     r0,cpsr
 114         bic     r0,r0,#0x1f
 115         orr     r0,r0,#0x13
 116         msr     cpsr,r0
 117
 118         /*
 119          * we do sys-critical inits only at reboot,
 120          * not when booting from ram!
 121          */
 122 #ifdef CONFIG_INIT_CRITICAL
 123         bl      cpu_init_crit
 124 #endif
 125
 126 relocate:                               /* relocate U-Boot to RAM           */
 127         adr     r0, _start              /* r0 <- current position of code   */
 128         ldr     r1, _TEXT_BASE          /* test if we run from flash or RAM */
 129         cmp     r0, r1                  /* don't reloc during debug         */
 130         beq     stack_setup
 131
 132 #if TEXT_BASE
 133         ldr     r2, =0x0                /* Relocate the exception vectors   */
 134         cmp     r1, r2                  /* and associated data to address   */
 135         ldmneia r0!, {r3-r10}           /* 0x0. Do nothing if TEXT_BASE is  */
 136         stmneia r2!, {r3-r10}           /* 0x0. Copy the first 15 words.    */
 137         ldmneia r0, {r3-r9}
 138         stmneia r2, {r3-r9}
 139         adrne   r0, _start              /* restore r0                       */
 140 #endif
 141
 142         ldr     r2, _armboot_start
 143         ldr     r3, _bss_start
 144         sub     r2, r3, r2              /* r2 <- size of armboot            */
 145         add     r2, r0, r2              /* r2 <- source end address         */
 146
 147 copy_loop:
 148         ldmia   r0!, {r3-r10}           /* copy from source address [r0]    */
 149         stmia   r1!, {r3-r10}           /* copy to   target address [r1]    */
 150         cmp     r0, r2                  /* until source end addreee [r2]    */
 151         ble     copy_loop
 152
 153         /* Set up the stack                                                 */
 154 stack_setup:
 155         ldr     r0, _TEXT_BASE          /* upper 128 KiB: relocated uboot   */
 156         sub     r0, r0, #CFG_MALLOC_LEN /* malloc area                      */
 157         sub     r0, r0, #CFG_GBL_DATA_SIZE /* bdinfo                        */
 158 #ifdef CONFIG_USE_IRQ
 159         sub     r0, r0, #(CONFIG_STACKSIZE_IRQ+CONFIG_STACKSIZE_FIQ)
 160 #endif
 161         sub     sp, r0, #12             /* leave 3 words for abort-stack    */
 162
 163 clear_bss:
 164         ldr     r0, _bss_start          /* find start of bss segment        */
 165         ldr     r1, _bss_end            /* stop here                        */
 166         mov     r2, #0x00000000         /* clear                            */
 167
 168 clbss_l:str     r2, [r0]                /* clear loop...                    */
 169         add     r0, r0, #4
 170         cmp     r0, r1
 171         bne     clbss_l
 172
 173         ldr     pc, _start_armboot
 174
 175 _start_armboot: .word start_armboot
 176
 177 /*
 178  *************************************************************************
 179  *
 180  * CPU_init_critical registers
 181  *
 182  * setup important registers
 183  * setup memory timing
 184  *
 185  *************************************************************************
 186  */
 187
 188 #if defined(CONFIG_IMPA7) || defined(CONFIG_EP7312)
 189
 190 /* Interupt-Controller base addresses */
 191 INTMR1:         .word   0x80000280 @ 32 bit size
 192 INTMR2:         .word   0x80001280 @ 16 bit size
 193 INTMR3:         .word   0x80002280 @  8 bit size
 194
 195 /* SYSCONs */
 196 SYSCON1:        .word   0x80000100
 197 SYSCON2:        .word   0x80001100
 198 SYSCON3:        .word   0x80002200
 199
 200 #define CLKCTL         0x6  /* mask */
 201 #define CLKCTL_18      0x0  /* 18.432 MHz */
 202 #define CLKCTL_36      0x2  /* 36.864 MHz */
 203 #define CLKCTL_49      0x4  /* 49.152 MHz */
 204 #define CLKCTL_73      0x6  /* 73.728 MHz */
 205
 206 #endif
 207
 208 cpu_init_crit:
 209 #if defined(CONFIG_IMPA7) || defined(CONFIG_EP7312)
 210
 211         /*
 212          * mask all IRQs by clearing all bits in the INTMRs
 213          */
 214         mov     r1, #0x00
 215         ldr     r0, INTMR1
 216         str     r1, [r0]
 217         ldr     r0, INTMR2
 218         str     r1, [r0]
 219         ldr     r0, INTMR3
 220         str     r1, [r0]
 221
 222         /*
 223          * flush v4 I/D caches
 224          */
 225         mov     r0, #0
 226         mcr     p15, 0, r0, c7, c7, 0   /* flush v3/v4 cache */
 227         mcr     p15, 0, r0, c8, c7, 0   /* flush v4 TLB */
 228
 229         /*
 230          * disable MMU stuff and caches
 231          */
 232         mrc     p15,0,r0,c1,c0
 233         bic     r0, r0, #0x00002300     @ clear bits 13, 9:8 (--V- --RS)
 234         bic     r0, r0, #0x0000008f     @ clear bits 7, 3:0 (B--- WCAM)
 235         orr     r0, r0, #0x00000002     @ set bit 2 (A) Align
 236         mcr     p15,0,r0,c1,c0
 237 #elif defined(CONFIG_NETARM)
 238         /*
 239          * prior to software reset : need to set pin PORTC4 to be *HRESET
 240          */
 241         ldr     r0, =NETARM_GEN_MODULE_BASE
 242         ldr     r1, =(NETARM_GEN_PORT_MODE(0x10) | \
 243                         NETARM_GEN_PORT_DIR(0x10))
 244         str     r1, [r0, #+NETARM_GEN_PORTC]
 245         /*
 246          * software reset : see HW Ref. Guide 8.2.4 : Software Service register
 247          *                  for an explanation of this process
 248          */
 249         ldr     r0, =NETARM_GEN_MODULE_BASE
 250         ldr     r1, =NETARM_GEN_SW_SVC_RESETA
 251         str     r1, [r0, #+NETARM_GEN_SOFTWARE_SERVICE]
 252         ldr     r1, =NETARM_GEN_SW_SVC_RESETB
 253         str     r1, [r0, #+NETARM_GEN_SOFTWARE_SERVICE]
 254         ldr     r1, =NETARM_GEN_SW_SVC_RESETA
 255         str     r1, [r0, #+NETARM_GEN_SOFTWARE_SERVICE]
 256         ldr     r1, =NETARM_GEN_SW_SVC_RESETB
 257         str     r1, [r0, #+NETARM_GEN_SOFTWARE_SERVICE]
 258         /*
 259          * setup PLL and System Config
 260          */
 261         ldr     r0, =NETARM_GEN_MODULE_BASE
 262
 263         ldr     r1, =(  NETARM_GEN_SYS_CFG_LENDIAN | \
 264                         NETARM_GEN_SYS_CFG_BUSFULL | \
 265                         NETARM_GEN_SYS_CFG_USER_EN | \
 266                         NETARM_GEN_SYS_CFG_ALIGN_ABORT | \
 267                         NETARM_GEN_SYS_CFG_BUSARB_INT | \
 268                         NETARM_GEN_SYS_CFG_BUSMON_EN )
 269
 270         str     r1, [r0, #+NETARM_GEN_SYSTEM_CONTROL]
 271
 272         ldr     r1, =(  NETARM_GEN_PLL_CTL_PLLCNT(NETARM_PLL_COUNT_VAL) | \
 273                         NETARM_GEN_PLL_CTL_POLTST_DEF | \
 274                         NETARM_GEN_PLL_CTL_INDIV(1) | \
 275                         NETARM_GEN_PLL_CTL_ICP_DEF | \
 276                         NETARM_GEN_PLL_CTL_OUTDIV(2) )
 277         str     r1, [r0, #+NETARM_GEN_PLL_CONTROL]
 278         /*
 279          * mask all IRQs by clearing all bits in the INTMRs
 280          */
 281         mov     r1, #0
 282         ldr     r0, =NETARM_GEN_MODULE_BASE
 283         str     r1, [r0, #+NETARM_GEN_INTR_ENABLE]
 284
 285 #elif defined(CONFIG_S3C4510B)
 286
 287         /*
 288          * Mask off all IRQ sources
 289          */
 290         ldr     r1, =REG_INTMASK
 291         ldr     r0, =0x3FFFFF
 292         str     r0, [r1]
 293
 294         /*
 295          * Disable Cache
 296          */
 297         ldr r0, =REG_SYSCFG
 298         ldr r1, =0x83ffffa0     /* cache-disabled  */
 299         str r1, [r0]
 300
 301 #else
 302 #error No cpu_init_crit() defined for current CPU type
 303 #endif
 304
 305 #ifdef CONFIG_ARM7_REVD
 306         /* set clock speed */
 307         /* !!! we run @ 36 MHz due to a hardware flaw in Rev. D processors */
 308         /* !!! not doing DRAM refresh properly! */
 309         ldr     r0, SYSCON3
 310         ldr     r1, [r0]
 311         bic     r1, r1, #CLKCTL
 312         orr     r1, r1, #CLKCTL_36
 313         str     r1, [r0]
 314 #endif
 315
 316         /*
 317          * before relocating, we have to setup RAM timing
 318          * because memory timing is board-dependent, you will
 319          * find a memsetup.S in your board directory.
 320          */
 321         mov     ip, lr
 322         bl      memsetup
 323         mov     lr, ip
 324
 325         mov     pc, lr
 326
 327
 328 /*
 329  *************************************************************************
 330  *
 331  * Interrupt handling
 332  *
 333  *************************************************************************
 334  */
 335
 336 @
 337 @ IRQ stack frame.
 338 @
 339 #define S_FRAME_SIZE    72
 340
 341 #define S_OLD_R0        68
 342 #define S_PSR           64
 343 #define S_PC            60
 344 #define S_LR            56
 345 #define S_SP            52
 346
 347 #define S_IP            48
 348 #define S_FP            44
 349 #define S_R10           40
 350 #define S_R9            36
 351 #define S_R8            32
 352 #define S_R7            28
 353 #define S_R6            24
 354 #define S_R5            20
 355 #define S_R4            16
 356 #define S_R3            12
 357 #define S_R2            8
 358 #define S_R1            4
 359 #define S_R0            0
 360
 361 #define MODE_SVC 0x13
 362 #define I_BIT    0x80
 363
 364 /*
 365  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 366  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 367  */
 368
 369         .macro  bad_save_user_regs
 370         sub     sp, sp, #S_FRAME_SIZE
 371         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 372         add     r8, sp, #S_PC
 373
 374         ldr     r2, _armboot_start
 375         sub     r2, r2, #(CONFIG_STACKSIZE+CFG_MALLOC_LEN)
 376         sub     r2, r2, #(CFG_GBL_DATA_SIZE+8)  @ set base 2 words into abort stack
 377         ldmia   r2, {r2 - r4}                   @ get pc, cpsr, old_r0
 378         add     r0, sp, #S_FRAME_SIZE           @ restore sp_SVC
 379
 380         add     r5, sp, #S_SP
 381         mov     r1, lr
 382         stmia   r5, {r0 - r4}                   @ save sp_SVC, lr_SVC, pc, cpsr, old_r
 383         mov     r0, sp
 384         .endm
 385
 386         .macro  irq_save_user_regs
 387         sub     sp, sp, #S_FRAME_SIZE
 388         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 389         add     r8, sp, #S_PC
 390         stmdb   r8, {sp, lr}^                   @ Calling SP, LR
 391         str     lr, [r8, #0]                    @ Save calling PC
 392         mrs     r6, spsr
 393         str     r6, [r8, #4]                    @ Save CPSR
 394         str     r0, [r8, #8]                    @ Save OLD_R0
 395         mov     r0, sp
 396         .endm
 397
 398         .macro  irq_restore_user_regs
 399         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 400         mov     r0, r0
 401         ldr     lr, [sp, #S_PC]                 @ Get PC
 402         add     sp, sp, #S_FRAME_SIZE
 403         subs    pc, lr, #4                      @ return & move spsr_svc into cpsr
 404         .endm
 405
 406         .macro get_bad_stack
 407         ldr     r13, _armboot_start             @ setup our mode stack
 408         sub     r13, r13, #(CONFIG_STACKSIZE+CFG_MALLOC_LEN)
 409         sub     r13, r13, #(CFG_GBL_DATA_SIZE+8) @ reserved a couple spots in abort stack
 410
 411         str     lr, [r13]                       @ save caller lr / spsr
 412         mrs     lr, spsr
 413         str     lr, [r13, #4]
 414
 415         mov     r13, #MODE_SVC                  @ prepare SVC-Mode
 416         msr     spsr_c, r13
 417         mov     lr, pc
 418         movs    pc, lr
 419         .endm
 420
 421         .macro get_irq_stack                    @ setup IRQ stack
 422         ldr     sp, IRQ_STACK_START
 423         .endm
 424
 425         .macro get_fiq_stack                    @ setup FIQ stack
 426         ldr     sp, FIQ_STACK_START
 427         .endm
 428
 429 /*
 430  * exception handlers
 431  */
 432         .align  5
 433 undefined_instruction:
 434         get_bad_stack
 435         bad_save_user_regs
 436         bl      do_undefined_instruction
 437
 438         .align  5
 439 software_interrupt:
 440         get_bad_stack
 441         bad_save_user_regs
 442         bl      do_software_interrupt
 443
 444         .align  5
 445 prefetch_abort:
 446         get_bad_stack
 447         bad_save_user_regs
 448         bl      do_prefetch_abort
 449
 450         .align  5
 451 data_abort:
 452         get_bad_stack
 453         bad_save_user_regs
 454         bl      do_data_abort
 455
 456         .align  5
 457 not_used:
 458         get_bad_stack
 459         bad_save_user_regs
 460         bl      do_not_used
 461
 462 #ifdef CONFIG_USE_IRQ
 463
 464         .align  5
 465 irq:
 466         get_irq_stack
 467         irq_save_user_regs
 468         bl      do_irq
 469         irq_restore_user_regs
 470
 471         .align  5
 472 fiq:
 473         get_fiq_stack
 474         /* someone ought to write a more effiction fiq_save_user_regs */
 475         irq_save_user_regs
 476         bl      do_fiq
 477         irq_restore_user_regs
 478
 479 #else
 480
 481         .align  5
 482 irq:
 483         get_bad_stack
 484         bad_save_user_regs
 485         bl      do_irq
 486
 487         .align  5
 488 fiq:
 489         get_bad_stack
 490         bad_save_user_regs
 491         bl      do_fiq
 492
 493 #endif
 494
 495 #if defined(CONFIG_IMPA7) || defined(CONFIG_EP7312)
 496         .align  5
 497 .globl reset_cpu
 498 reset_cpu:
 499         mov     ip, #0
 500         mcr     p15, 0, ip, c7, c7, 0           @ invalidate cache
 501         mcr     p15, 0, ip, c8, c7, 0           @ flush TLB (v4)
 502         mrc     p15, 0, ip, c1, c0, 0           @ get ctrl register
 503         bic     ip, ip, #0x000f                 @ ............wcam
 504         bic     ip, ip, #0x2100                 @ ..v....s........
 505         mcr     p15, 0, ip, c1, c0, 0           @ ctrl register
 506         mov     pc, r0
 507 #elif defined(CONFIG_NETARM)
 508         .align  5
 509 .globl reset_cpu
 510 reset_cpu:
 511         ldr     r1, =NETARM_MEM_MODULE_BASE
 512         ldr     r0, [r1, #+NETARM_MEM_CS0_BASE_ADDR]
 513         ldr     r1, =0xFFFFF000
 514         and     r0, r1, r0
 515         ldr     r1, =(relocate-TEXT_BASE)
 516         add     r0, r1, r0
 517         ldr     r4, =NETARM_GEN_MODULE_BASE
 518         ldr     r1, =NETARM_GEN_SW_SVC_RESETA
 519         str     r1, [r4, #+NETARM_GEN_SOFTWARE_SERVICE]
 520         ldr     r1, =NETARM_GEN_SW_SVC_RESETB
 521         str     r1, [r4, #+NETARM_GEN_SOFTWARE_SERVICE]
 522         ldr     r1, =NETARM_GEN_SW_SVC_RESETA
 523         str     r1, [r4, #+NETARM_GEN_SOFTWARE_SERVICE]
 524         ldr     r1, =NETARM_GEN_SW_SVC_RESETB
 525         str     r1, [r4, #+NETARM_GEN_SOFTWARE_SERVICE]
 526         mov     pc, r0
 527 #elif defined(CONFIG_S3C4510B)
 528 /* Nothing done here as reseting the CPU is board specific, depending
 529  * on external peripherals such as watchdog timers, etc. */
 530 #else
 531 #error No reset_cpu() defined for current CPU type
 532 #endif