cpu/arm720t/start.S

   1 /*
   2  *  armboot - Startup Code for ARM720 CPU-core
   3  *
   4  *  Copyright (c) 2001  Marius Gröger <mag@sysgo.de>
   5  *  Copyright (c) 2002  Alex Züpke <azu@sysgo.de>
   6  *
   7  * See file CREDITS for list of people who contributed to this
   8  * project.
   9  *
  10  * This program is free software; you can redistribute it and/or
  11  * modify it under the terms of the GNU General Public License as
  12  * published by the Free Software Foundation; either version 2 of
  13  * the License, or (at your option) any later version.
  14  *
  15  * This program is distributed in the hope that it will be useful,
  16  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  17  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18  * GNU General Public License for more details.
  19  *
  20  * You should have received a copy of the GNU General Public License
  21  * along with this program; if not, write to the Free Software
  22  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  23  * MA 02111-1307 USA
  24  */
  25
  26
  27 #include <config.h>
  28 #include <version.h>
  29
  30
  31 /*
  32  *************************************************************************
  33  *
  34  * Jump vector table as in table 3.1 in [1]
  35  *
  36  *************************************************************************
  37  */
  38
  39
  40 .globl _start
  41 _start: b       reset
  42         ldr     pc, _undefined_instruction
  43         ldr     pc, _software_interrupt
  44         ldr     pc, _prefetch_abort
  45         ldr     pc, _data_abort
  46         ldr     pc, _not_used
  47         ldr     pc, _irq
  48         ldr     pc, _fiq
  49
  50 _undefined_instruction: .word undefined_instruction
  51 _software_interrupt:    .word software_interrupt
  52 _prefetch_abort:        .word prefetch_abort
  53 _data_abort:            .word data_abort
  54 _not_used:              .word not_used
  55 _irq:                   .word irq
  56 _fiq:                   .word fiq
  57
  58         .balignl 16,0xdeadbeef
  59
  60
  61 /*
  62  *************************************************************************
  63  *
  64  * Startup Code (reset vector)
  65  *
  66  * do important init only if we don't start from memory!
  67  * relocate armboot to ram
  68  * setup stack
  69  * jump to second stage
  70  *
  71  *************************************************************************
  72  */
  73
  74 /*
  75  * CFG_MEM_END is in the board dependent config-file (configs/config_BOARD.h)
  76  */
  77 _TEXT_BASE:
  78         .word   TEXT_BASE
  79
  80 .globl _armboot_start
  81 _armboot_start:
  82         .word _start
  83
  84 /*
  85  * Note: _armboot_end_data and _armboot_end are defined
  86  * by the (board-dependent) linker script.
  87  * _armboot_end_data is the first usable FLASH address after armboot
  88  */
  89 .globl _armboot_end_data
  90 _armboot_end_data:
  91         .word armboot_end_data
  92 .globl _armboot_end
  93 _armboot_end:
  94         .word armboot_end
  95
  96 /*
  97  * _armboot_real_end is the first usable RAM address behind armboot
  98  * and the various stacks
  99  */
 100 .globl _armboot_real_end
 101 _armboot_real_end:
 102         .word 0x0badc0de
 103
 104 #ifdef CONFIG_USE_IRQ
 105 /* IRQ stack memory (calculated at run-time) */
 106 .globl IRQ_STACK_START
 107 IRQ_STACK_START:
 108         .word   0x0badc0de
 109
 110 /* IRQ stack memory (calculated at run-time) */
 111 .globl FIQ_STACK_START
 112 FIQ_STACK_START:
 113         .word 0x0badc0de
 114 #endif
 115
 116
 117 /*
 118  * the actual reset code
 119  */
 120
 121 reset:
 122         /*
 123          * set the cpu to SVC32 mode
 124          */
 125         mrs     r0,cpsr
 126         bic     r0,r0,#0x1f
 127         orr     r0,r0,#0x13
 128         msr     cpsr,r0
 129
 130         /*
 131          * we do sys-critical inits only at reboot,
 132          * not when booting from ram!
 133          */
 134 #ifdef CONFIG_INIT_CRITICAL
 135         bl      cpu_init_crit
 136 #endif
 137
 138 relocate:
 139         /*
 140          * relocate armboot to RAM
 141          */
 142         adr     r0, _start              /* r0 <- current position of code */
 143         ldr     r2, _armboot_start
 144         ldr     r3, _armboot_end
 145         sub     r2, r3, r2              /* r2 <- size of armboot */
 146         ldr     r1, _TEXT_BASE          /* r1 <- destination address */
 147         add     r2, r0, r2              /* r2 <- source end address */
 148
 149         /*
 150          * r0 = source address
 151          * r1 = target address
 152          * r2 = source end address
 153          */
 154 copy_loop:
 155         ldmia   r0!, {r3-r10}
 156         stmia   r1!, {r3-r10}
 157         cmp     r0, r2
 158         ble     copy_loop
 159
 160         /* set up the stack */
 161         ldr     r0, _armboot_end
 162         add     r0, r0, #CONFIG_STACKSIZE
 163         sub     sp, r0, #12             /* leave 3 words for abort-stack */
 164
 165         ldr     pc, _start_armboot
 166
 167 _start_armboot: .word start_armboot
 168
 169
 170 /*
 171  *************************************************************************
 172  *
 173  * CPU_init_critical registers
 174  *
 175  * setup important registers
 176  * setup memory timing
 177  *
 178  *************************************************************************
 179  */
 180
 181
 182 /* Interupt-Controller base addresses */
 183 INTMR1:         .word   0x80000280 @ 32 bit size
 184 INTMR2:         .word   0x80001280 @ 16 bit size
 185 INTMR3:         .word   0x80002280 @  8 bit size
 186
 187 /* SYSCONs */
 188 SYSCON1:        .word   0x80000100
 189 SYSCON2:        .word   0x80001100
 190 SYSCON3:        .word   0x80002200
 191
 192 #define CLKCTL         0x6  /* mask */
 193 #define CLKCTL_18      0x0  /* 18.432 MHz */
 194 #define CLKCTL_36      0x2  /* 36.864 MHz */
 195 #define CLKCTL_49      0x4  /* 49.152 MHz */
 196 #define CLKCTL_73      0x6  /* 73.728 MHz */
 197
 198 cpu_init_crit:
 199         /*
 200          * mask all IRQs by clearing all bits in the INTMRs
 201          */
 202         mov     r1, #0x00
 203         ldr     r0, INTMR1
 204         str     r1, [r0]
 205         ldr     r0, INTMR2
 206         str     r1, [r0]
 207         ldr     r0, INTMR3
 208         str     r1, [r0]
 209
 210         /*
 211          * flush v4 I/D caches
 212          */
 213         mov     r0, #0
 214         mcr     p15, 0, r0, c7, c7, 0   /* flush v3/v4 cache */
 215         mcr     p15, 0, r0, c8, c7, 0   /* flush v4 TLB */
 216
 217         /*
 218          * disable MMU stuff and caches
 219          */
 220         mrc     p15,0,r0,c1,c0
 221         bic     r0, r0, #0x00002300     @ clear bits 13, 9:8 (--V- --RS)
 222         bic     r0, r0, #0x0000008f     @ clear bits 7, 3:0 (B--- WCAM)
 223         orr     r0, r0, #0x00000002     @ set bit 2 (A) Align
 224         mcr     p15,0,r0,c1,c0
 225
 226 #ifdef CONFIG_ARM7_REVD
 227         /* set clock speed */
 228         /* !!! we run @ 36 MHz due to a hardware flaw in Rev. D processors */
 229         /* !!! not doing DRAM refresh properly! */
 230         ldr     r0, SYSCON3
 231         ldr     r1, [r0]
 232         bic     r1, r1, #CLKCTL
 233         orr     r1, r1, #CLKCTL_36
 234         str     r1, [r0]
 235 #endif
 236
 237         /*
 238          * before relocating, we have to setup RAM timing
 239          * because memory timing is board-dependend, you will
 240          * find a memsetup.S in your board directory.
 241          */
 242         mov     ip, lr
 243         bl      memsetup
 244         mov     lr, ip
 245
 246         mov     pc, lr
 247
 248
 249 /*
 250  *************************************************************************
 251  *
 252  * Interrupt handling
 253  *
 254  *************************************************************************
 255  */
 256
 257 @
 258 @ IRQ stack frame.
 259 @
 260 #define S_FRAME_SIZE    72
 261
 262 #define S_OLD_R0        68
 263 #define S_PSR           64
 264 #define S_PC            60
 265 #define S_LR            56
 266 #define S_SP            52
 267
 268 #define S_IP            48
 269 #define S_FP            44
 270 #define S_R10           40
 271 #define S_R9            36
 272 #define S_R8            32
 273 #define S_R7            28
 274 #define S_R6            24
 275 #define S_R5            20
 276 #define S_R4            16
 277 #define S_R3            12
 278 #define S_R2            8
 279 #define S_R1            4
 280 #define S_R0            0
 281
 282 #define MODE_SVC 0x13
 283 #define I_BIT    0x80
 284
 285 /*
 286  * use bad_save_user_regs for abort/prefetch/undef/swi ...
 287  * use irq_save_user_regs / irq_restore_user_regs for IRQ/FIQ handling
 288  */
 289
 290         .macro  bad_save_user_regs
 291         sub     sp, sp, #S_FRAME_SIZE
 292         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 293         add     r8, sp, #S_PC
 294
 295         ldr     r2, _armboot_end
 296         add     r2, r2, #CONFIG_STACKSIZE
 297         sub     r2, r2, #8
 298         ldmia   r2, {r2 - r4}                   @ get pc, cpsr, old_r0
 299         add     r0, sp, #S_FRAME_SIZE           @ restore sp_SVC
 300
 301         add     r5, sp, #S_SP
 302         mov     r1, lr
 303         stmia   r5, {r0 - r4}                   @ save sp_SVC, lr_SVC, pc, cpsr, old_r
 304         mov     r0, sp
 305         .endm
 306
 307         .macro  irq_save_user_regs
 308         sub     sp, sp, #S_FRAME_SIZE
 309         stmia   sp, {r0 - r12}                  @ Calling r0-r12
 310         add     r8, sp, #S_PC
 311         stmdb   r8, {sp, lr}^                   @ Calling SP, LR
 312         str     lr, [r8, #0]                    @ Save calling PC
 313         mrs     r6, spsr
 314         str     r6, [r8, #4]                    @ Save CPSR
 315         str     r0, [r8, #8]                    @ Save OLD_R0
 316         mov     r0, sp
 317         .endm
 318
 319         .macro  irq_restore_user_regs
 320         ldmia   sp, {r0 - lr}^                  @ Calling r0 - lr
 321         mov     r0, r0
 322         ldr     lr, [sp, #S_PC]                 @ Get PC
 323         add     sp, sp, #S_FRAME_SIZE
 324         subs    pc, lr, #4                      @ return & move spsr_svc into cpsr
 325         .endm
 326
 327         .macro get_bad_stack
 328         ldr     r13, _armboot_end               @ setup our mode stack
 329         add     r13, r13, #CONFIG_STACKSIZE     @ resides at top of normal stack
 330         sub     r13, r13, #8
 331
 332         str     lr, [r13]                       @ save caller lr / spsr
 333         mrs     lr, spsr
 334         str     lr, [r13, #4]
 335
 336         mov     r13, #MODE_SVC                  @ prepare SVC-Mode
 337         msr     spsr_c, r13
 338         mov     lr, pc
 339         movs    pc, lr
 340         .endm
 341
 342         .macro get_irq_stack                    @ setup IRQ stack
 343         ldr     sp, IRQ_STACK_START
 344         .endm
 345
 346         .macro get_fiq_stack                    @ setup FIQ stack
 347         ldr     sp, FIQ_STACK_START
 348         .endm
 349
 350 /*
 351  * exception handlers
 352  */
 353         .align  5
 354 undefined_instruction:
 355         get_bad_stack
 356         bad_save_user_regs
 357         bl      do_undefined_instruction
 358
 359         .align  5
 360 software_interrupt:
 361         get_bad_stack
 362         bad_save_user_regs
 363         bl      do_software_interrupt
 364
 365         .align  5
 366 prefetch_abort:
 367         get_bad_stack
 368         bad_save_user_regs
 369         bl      do_prefetch_abort
 370
 371         .align  5
 372 data_abort:
 373         get_bad_stack
 374         bad_save_user_regs
 375         bl      do_data_abort
 376
 377         .align  5
 378 not_used:
 379         get_bad_stack
 380         bad_save_user_regs
 381         bl      do_not_used
 382
 383 #ifdef CONFIG_USE_IRQ
 384
 385         .align  5
 386 irq:
 387         get_irq_stack
 388         irq_save_user_regs
 389         bl      do_irq
 390         irq_restore_user_regs
 391
 392         .align  5
 393 fiq:
 394         get_fiq_stack
 395         /* someone ought to write a more effiction fiq_save_user_regs */
 396         irq_save_user_regs
 397         bl      do_fiq
 398         irq_restore_user_regs
 399
 400 #else
 401
 402         .align  5
 403 irq:
 404         get_bad_stack
 405         bad_save_user_regs
 406         bl      do_irq
 407
 408         .align  5
 409 fiq:
 410         get_bad_stack
 411         bad_save_user_regs
 412         bl      do_fiq
 413
 414 #endif
 415
 416         .align  5
 417 .globl reset_cpu
 418 reset_cpu:
 419         mov     ip, #0
 420         mcr     p15, 0, ip, c7, c7, 0           @ invalidate cache
 421         mcr     p15, 0, ip, c8, c7, 0           @ flush TLB (v4)
 422         mrc     p15, 0, ip, c1, c0, 0           @ get ctrl register
 423         bic     ip, ip, #0x000f                 @ ............wcam
 424         bic     ip, ip, #0x2100                 @ ..v....s........
 425         mcr     p15, 0, ip, c1, c0, 0           @ ctrl register
 426         mov     pc, r0