configurecompiler.cmake

   1 #----------------------------------------
   2 # Detect and set platform variable names
   3 #     - for non-windows build platform & architecture is detected using inbuilt CMAKE variables and cross target component configure
   4 #     - for windows we use the passed in parameter to CMAKE to determine build arch
   5 #----------------------------------------
   6 if(CMAKE_SYSTEM_NAME STREQUAL Linux)
   7     set(CLR_CMAKE_PLATFORM_UNIX 1)
   8     if(CLR_CROSS_COMPONENTS_BUILD)
   9         # CMAKE_HOST_SYSTEM_PROCESSOR returns the value of `uname -p` on host.
  10         if(CMAKE_HOST_SYSTEM_PROCESSOR STREQUAL x86_64 OR CMAKE_HOST_SYSTEM_PROCESSOR STREQUAL amd64)
  11             if(CLR_CMAKE_TARGET_ARCH STREQUAL "arm")
  12                 if($ENV{CROSSCOMPILE} STREQUAL "1")
  13                     set(CLR_CMAKE_PLATFORM_UNIX_X86 1)
  14                 else()
  15                     set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
  16                 endif()
  17             else()
  18                 set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
  19             endif()
  20         elseif(CMAKE_HOST_SYSTEM_PROCESSOR STREQUAL i686)
  21             set(CLR_CMAKE_PLATFORM_UNIX_X86 1)
  22         else()
  23             clr_unknown_arch()
  24         endif()
  25     else()
  26         # CMAKE_SYSTEM_PROCESSOR returns the value of `uname -p` on target.
  27         # For the AMD/Intel 64bit architecture two different strings are common.
  28         # Linux and Darwin identify it as "x86_64" while FreeBSD and netbsd uses the
  29         # "amd64" string. Accept either of the two here.
  30         if(CMAKE_SYSTEM_PROCESSOR STREQUAL x86_64 OR CMAKE_SYSTEM_PROCESSOR STREQUAL amd64)
  31             set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
  32         elseif(CMAKE_SYSTEM_PROCESSOR STREQUAL armv7l)
  33             set(CLR_CMAKE_PLATFORM_UNIX_ARM 1)
  34         elseif(CMAKE_SYSTEM_PROCESSOR STREQUAL arm)
  35             set(CLR_CMAKE_PLATFORM_UNIX_ARM 1)
  36         elseif(CMAKE_SYSTEM_PROCESSOR STREQUAL aarch64)
  37             set(CLR_CMAKE_PLATFORM_UNIX_ARM64 1)
  38         elseif(CMAKE_SYSTEM_PROCESSOR STREQUAL i686)
  39             set(CLR_CMAKE_PLATFORM_UNIX_X86 1)
  40         else()
  41             clr_unknown_arch()
  42         endif()
  43     endif()
  44     set(CLR_CMAKE_PLATFORM_LINUX 1)
  45
  46     # Detect Linux ID
  47     if(DEFINED CLR_CMAKE_LINUX_ID)
  48         if(CLR_CMAKE_LINUX_ID STREQUAL ubuntu)
  49             set(CLR_CMAKE_TARGET_UBUNTU_LINUX 1)
  50         elseif(CLR_CMAKE_LINUX_ID STREQUAL tizen)
  51             set(CLR_CMAKE_TARGET_TIZEN_LINUX 1)
  52         elseif(CLR_CMAKE_LINUX_ID STREQUAL alpine)
  53             set(CLR_CMAKE_PLATFORM_ALPINE_LINUX 1)
  54         endif()
  55         if(CLR_CMAKE_LINUX_ID STREQUAL ubuntu)
  56             set(CLR_CMAKE_PLATFORM_UBUNTU_LINUX 1)
  57         endif()
  58     endif(DEFINED CLR_CMAKE_LINUX_ID)
  59 endif(CMAKE_SYSTEM_NAME STREQUAL Linux)
  60
  61 if(CMAKE_SYSTEM_NAME STREQUAL Darwin)
  62   set(CLR_CMAKE_PLATFORM_UNIX 1)
  63   set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
  64   set(CLR_CMAKE_PLATFORM_DARWIN 1)
  65   if(CMAKE_VERSION VERSION_LESS "3.4.0")
  66     set(CMAKE_ASM_COMPILE_OBJECT "${CMAKE_C_COMPILER} <FLAGS> <DEFINES> -o <OBJECT> -c <SOURCE>")
  67   else()
  68     set(CMAKE_ASM_COMPILE_OBJECT "${CMAKE_C_COMPILER} <FLAGS> <DEFINES> <INCLUDES> -o <OBJECT> -c <SOURCE>")
  69   endif(CMAKE_VERSION VERSION_LESS "3.4.0")
  70 endif(CMAKE_SYSTEM_NAME STREQUAL Darwin)
  71
  72 if(CMAKE_SYSTEM_NAME STREQUAL FreeBSD)
  73   set(CLR_CMAKE_PLATFORM_UNIX 1)
  74   set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
  75   set(CLR_CMAKE_PLATFORM_FREEBSD 1)
  76 endif(CMAKE_SYSTEM_NAME STREQUAL FreeBSD)
  77
  78 if(CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
  79   set(CLR_CMAKE_PLATFORM_UNIX 1)
  80   set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
  81   set(CLR_CMAKE_PLATFORM_OPENBSD 1)
  82 endif(CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
  83
  84 if(CMAKE_SYSTEM_NAME STREQUAL NetBSD)
  85   set(CLR_CMAKE_PLATFORM_UNIX 1)
  86   set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
  87   set(CLR_CMAKE_PLATFORM_NETBSD 1)
  88 endif(CMAKE_SYSTEM_NAME STREQUAL NetBSD)
  89
  90 if(CMAKE_SYSTEM_NAME STREQUAL SunOS)
  91   set(CLR_CMAKE_PLATFORM_UNIX 1)
  92   EXECUTE_PROCESS(
  93     COMMAND isainfo -n
  94     OUTPUT_VARIABLE SUNOS_NATIVE_INSTRUCTION_SET
  95     )
  96   if(SUNOS_NATIVE_INSTRUCTION_SET MATCHES "amd64")
  97     set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
  98     set(CMAKE_SYSTEM_PROCESSOR "amd64")
  99   else()
 100     clr_unknown_arch()
 101   endif()
 102   set(CLR_CMAKE_PLATFORM_SUNOS 1)
 103 endif(CMAKE_SYSTEM_NAME STREQUAL SunOS)
 104
 105 #--------------------------------------------
 106 # This repo builds two set of binaries
 107 # 1. binaries which execute on target arch machine
 108 #        - for such binaries host architecture & target architecture are same
 109 #        - eg. coreclr.dll
 110 # 2. binaries which execute on host machine but target another architecture
 111 #        - host architecture is different from target architecture
 112 #        - eg. crossgen.exe - runs on x64 machine and generates nis targeting arm64
 113 #        - for complete list of such binaries refer to file crosscomponents.cmake
 114 #-------------------------------------------------------------
 115 # Set HOST architecture variables
 116 if(CLR_CMAKE_PLATFORM_UNIX_ARM)
 117     set(CLR_CMAKE_PLATFORM_ARCH_ARM 1)
 118     set(CLR_CMAKE_HOST_ARCH "arm")
 119 elseif(CLR_CMAKE_PLATFORM_UNIX_ARM64)
 120     set(CLR_CMAKE_PLATFORM_ARCH_ARM64 1)
 121     set(CLR_CMAKE_HOST_ARCH "arm64")
 122 elseif(CLR_CMAKE_PLATFORM_UNIX_AMD64)
 123     set(CLR_CMAKE_PLATFORM_ARCH_AMD64 1)
 124     set(CLR_CMAKE_HOST_ARCH "x64")
 125 elseif(CLR_CMAKE_PLATFORM_UNIX_X86)
 126     set(CLR_CMAKE_PLATFORM_ARCH_I386 1)
 127     set(CLR_CMAKE_HOST_ARCH "x86")
 128 elseif(WIN32)
 129     # CLR_CMAKE_HOST_ARCH is passed in as param to cmake
 130     if (CLR_CMAKE_HOST_ARCH STREQUAL x64)
 131         set(CLR_CMAKE_PLATFORM_ARCH_AMD64 1)
 132     elseif(CLR_CMAKE_HOST_ARCH STREQUAL x86)
 133         set(CLR_CMAKE_PLATFORM_ARCH_I386 1)
 134     elseif(CLR_CMAKE_HOST_ARCH STREQUAL arm)
 135         set(CLR_CMAKE_PLATFORM_ARCH_ARM 1)
 136     elseif(CLR_CMAKE_HOST_ARCH STREQUAL arm64)
 137         set(CLR_CMAKE_PLATFORM_ARCH_ARM64 1)
 138     else()
 139         clr_unknown_arch()
 140     endif()
 141 endif()
 142
 143 # Set TARGET architecture variables
 144 # Target arch will be a cmake param (optional) for both windows as well as non-windows build
 145 # if target arch is not specified then host & target are same
 146 if(NOT DEFINED CLR_CMAKE_TARGET_ARCH OR CLR_CMAKE_TARGET_ARCH STREQUAL "" )
 147   set(CLR_CMAKE_TARGET_ARCH ${CLR_CMAKE_HOST_ARCH})
 148 endif()
 149
 150 # Set target architecture variables
 151 if (CLR_CMAKE_TARGET_ARCH STREQUAL x64)
 152     set(CLR_CMAKE_TARGET_ARCH_AMD64 1)
 153   elseif(CLR_CMAKE_TARGET_ARCH STREQUAL x86)
 154     set(CLR_CMAKE_TARGET_ARCH_I386 1)
 155   elseif(CLR_CMAKE_TARGET_ARCH STREQUAL arm64)
 156     set(CLR_CMAKE_TARGET_ARCH_ARM64 1)
 157   elseif(CLR_CMAKE_TARGET_ARCH STREQUAL arm)
 158     set(CLR_CMAKE_TARGET_ARCH_ARM 1)
 159   else()
 160     clr_unknown_arch()
 161 endif()
 162
 163 # check if host & target arch combination are valid
 164 if(NOT(CLR_CMAKE_TARGET_ARCH STREQUAL CLR_CMAKE_HOST_ARCH))
 165     if(NOT((CLR_CMAKE_PLATFORM_ARCH_AMD64 AND CLR_CMAKE_TARGET_ARCH_ARM64) OR (CLR_CMAKE_PLATFORM_ARCH_I386 AND CLR_CMAKE_TARGET_ARCH_ARM) OR (CLR_CMAKE_PLATFORM_ARCH_AMD64 AND CLR_CMAKE_TARGET_ARCH_ARM)))
 166         message(FATAL_ERROR "Invalid host and target arch combination")
 167     endif()
 168 endif()
 169
 170 #-----------------------------------------------------
 171 # Initialize Cmake compiler flags and other variables
 172 #-----------------------------------------------------
 173
 174 if (CMAKE_CONFIGURATION_TYPES) # multi-configuration generator?
 175     set(CMAKE_CONFIGURATION_TYPES "Debug;Checked;Release;RelWithDebInfo" CACHE STRING "" FORCE)
 176 endif (CMAKE_CONFIGURATION_TYPES)
 177
 178 set(CMAKE_C_FLAGS_CHECKED ${CLR_C_FLAGS_CHECKED_INIT} CACHE STRING "Flags used by the compiler during checked builds.")
 179 set(CMAKE_CXX_FLAGS_CHECKED ${CLR_CXX_FLAGS_CHECKED_INIT} CACHE STRING "Flags used by the compiler during checked builds.")
 180 set(CMAKE_EXE_LINKER_FLAGS_CHECKED "")
 181 set(CMAKE_SHARED_LINKER_FLAGS_CHECKED "")
 182
 183 set(CMAKE_CXX_STANDARD_LIBRARIES "") # do not link against standard win32 libs i.e. kernel32, uuid, user32, etc.
 184
 185 if (WIN32)
 186   # For multi-configuration toolset (as Visual Studio)
 187   # set the different configuration defines.
 188   foreach (Config DEBUG CHECKED RELEASE RELWITHDEBINFO)
 189     foreach (Definition IN LISTS CLR_DEFINES_${Config}_INIT)
 190       set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS $<$<CONFIG:${Config}>:${Definition}>)
 191     endforeach (Definition)
 192   endforeach (Config)
 193
 194   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /GUARD:CF")
 195   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /GUARD:CF")
 196
 197   # Linker flags
 198   #
 199   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /MANIFEST:NO") #Do not create Side-by-Side Assembly Manifest
 200
 201   if (CLR_CMAKE_PLATFORM_ARCH_ARM)
 202     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /SUBSYSTEM:WINDOWS,6.02") #windows subsystem - arm minimum is 6.02
 203   elseif(CLR_CMAKE_PLATFORM_ARCH_ARM64)
 204     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /SUBSYSTEM:WINDOWS,6.03") #windows subsystem - arm64 minimum is 6.03
 205   else ()
 206     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /SUBSYSTEM:WINDOWS,6.01") #windows subsystem
 207   endif ()
 208
 209   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /LARGEADDRESSAWARE") # can handle addresses larger than 2 gigabytes
 210   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /NXCOMPAT") #Compatible with Data Execution Prevention
 211   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /DYNAMICBASE") #Use address space layout randomization
 212   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /PDBCOMPRESS") #shrink pdb size
 213   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /DEBUG")
 214   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /IGNORE:4197,4013,4254,4070,4221")
 215
 216   set(CMAKE_STATIC_LINKER_FLAGS "${CMAKE_STATIC_LINKER_FLAGS} /IGNORE:4221")
 217
 218   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /DEBUG /PDBCOMPRESS")
 219   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /STACK:1572864")
 220
 221   # Temporarily disable incremental link due to incremental linking CFG bug crashing crossgen.
 222   # See https://github.com/dotnet/coreclr/issues/12592
 223   # This has been fixed in VS 2017 Update 5 but we're keeping this around until everyone is off
 224   # the versions that have the bug. The bug manifests itself as a bad crash.
 225   set(NO_INCREMENTAL_LINKER_FLAGS "/INCREMENTAL:NO")
 226
 227   # Debug build specific flags
 228   set(CMAKE_SHARED_LINKER_FLAGS_DEBUG "/NOVCFEATURE ${NO_INCREMENTAL_LINKER_FLAGS}")
 229   set(CMAKE_EXE_LINKER_FLAGS_DEBUG "${NO_INCREMENTAL_LINKER_FLAGS}")
 230
 231   # Checked build specific flags
 232   set(CMAKE_SHARED_LINKER_FLAGS_CHECKED "${CMAKE_SHARED_LINKER_FLAGS_CHECKED} /OPT:REF /OPT:NOICF /NOVCFEATURE ${NO_INCREMENTAL_LINKER_FLAGS}")
 233   set(CMAKE_STATIC_LINKER_FLAGS_CHECKED "${CMAKE_STATIC_LINKER_FLAGS_CHECKED}")
 234   set(CMAKE_EXE_LINKER_FLAGS_CHECKED "${CMAKE_EXE_LINKER_FLAGS_CHECKED} /OPT:REF /OPT:NOICF ${NO_INCREMENTAL_LINKER_FLAGS}")
 235
 236   # Release build specific flags
 237   set(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_SHARED_LINKER_FLAGS_RELEASE} /LTCG /OPT:REF /OPT:ICF ${NO_INCREMENTAL_LINKER_FLAGS}")
 238   set(CMAKE_STATIC_LINKER_FLAGS_RELEASE "${CMAKE_STATIC_LINKER_FLAGS_RELEASE} /LTCG")
 239   set(CMAKE_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE} /LTCG /OPT:REF /OPT:ICF ${NO_INCREMENTAL_LINKER_FLAGS}")
 240
 241   # ReleaseWithDebugInfo build specific flags
 242   set(CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO} /LTCG /OPT:REF /OPT:ICF ${NO_INCREMENTAL_LINKER_FLAGS}")
 243   set(CMAKE_STATIC_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_STATIC_LINKER_FLAGS_RELWITHDEBINFO} /LTCG")
 244   set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO} /LTCG /OPT:REF /OPT:ICF ${NO_INCREMENTAL_LINKER_FLAGS}")
 245
 246   # Force uCRT to be dynamically linked for Release build
 247   set(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_SHARED_LINKER_FLAGS_RELEASE} /NODEFAULTLIB:libucrt.lib /DEFAULTLIB:ucrt.lib")
 248   set(CMAKE_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE} /NODEFAULTLIB:libucrt.lib /DEFAULTLIB:ucrt.lib")
 249   set(CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO} /NODEFAULTLIB:libucrt.lib /DEFAULTLIB:ucrt.lib")
 250   set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO} /NODEFAULTLIB:libucrt.lib /DEFAULTLIB:ucrt.lib")
 251
 252 elseif (CLR_CMAKE_PLATFORM_UNIX)
 253   # Set the values to display when interactively configuring CMAKE_BUILD_TYPE
 254   set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "DEBUG;CHECKED;RELEASE;RELWITHDEBINFO")
 255
 256   # Use uppercase CMAKE_BUILD_TYPE for the string comparisons below
 257   string(TOUPPER ${CMAKE_BUILD_TYPE} UPPERCASE_CMAKE_BUILD_TYPE)
 258
 259   # For single-configuration toolset
 260   # set the different configuration defines.
 261   if (UPPERCASE_CMAKE_BUILD_TYPE STREQUAL DEBUG)
 262     # First DEBUG
 263     set_property(DIRECTORY  PROPERTY COMPILE_DEFINITIONS ${CLR_DEFINES_DEBUG_INIT})
 264   elseif (UPPERCASE_CMAKE_BUILD_TYPE STREQUAL CHECKED)
 265     # Then CHECKED
 266     set_property(DIRECTORY PROPERTY COMPILE_DEFINITIONS ${CLR_DEFINES_CHECKED_INIT})
 267   elseif (UPPERCASE_CMAKE_BUILD_TYPE STREQUAL RELEASE)
 268     # Then RELEASE
 269     set_property(DIRECTORY PROPERTY COMPILE_DEFINITIONS ${CLR_DEFINES_RELEASE_INIT})
 270   elseif (UPPERCASE_CMAKE_BUILD_TYPE STREQUAL RELWITHDEBINFO)
 271     # And then RELWITHDEBINFO
 272     set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS ${CLR_DEFINES_RELWITHDEBINFO_INIT})
 273   else ()
 274     message(FATAL_ERROR "Unknown build type! Set CMAKE_BUILD_TYPE to DEBUG, CHECKED, RELEASE, or RELWITHDEBINFO!")
 275   endif ()
 276
 277   # set the CLANG sanitizer flags for debug build
 278   if(UPPERCASE_CMAKE_BUILD_TYPE STREQUAL DEBUG OR UPPERCASE_CMAKE_BUILD_TYPE STREQUAL CHECKED)
 279     # obtain settings from running enablesanitizers.sh
 280     string(FIND "$ENV{DEBUG_SANITIZERS}" "asan" __ASAN_POS)
 281     string(FIND "$ENV{DEBUG_SANITIZERS}" "ubsan" __UBSAN_POS)
 282     if ((${__ASAN_POS} GREATER -1) OR (${__UBSAN_POS} GREATER -1))
 283       set(CLR_SANITIZE_CXX_FLAGS "${CLR_SANITIZE_CXX_FLAGS} -fsanitize-blacklist=${CMAKE_CURRENT_SOURCE_DIR}/sanitizerblacklist.txt -fsanitize=")
 284       set(CLR_SANITIZE_LINK_FLAGS "${CLR_SANITIZE_LINK_FLAGS} -fsanitize=")
 285       if (${__ASAN_POS} GREATER -1)
 286         set(CLR_SANITIZE_CXX_FLAGS "${CLR_SANITIZE_CXX_FLAGS}address,")
 287         set(CLR_SANITIZE_LINK_FLAGS "${CLR_SANITIZE_LINK_FLAGS}address,")
 288         add_definitions(-DHAS_ASAN)
 289         message("Address Sanitizer (asan) enabled")
 290       endif ()
 291       if (${__UBSAN_POS} GREATER -1)
 292         # all sanitizier flags are enabled except alignment (due to heavy use of __unaligned modifier)
 293         set(CLR_SANITIZE_CXX_FLAGS "${CLR_SANITIZE_CXX_FLAGS}bool,bounds,enum,float-cast-overflow,float-divide-by-zero,function,integer,nonnull-attribute,null,object-size,return,returns-nonnull-attribute,shift,unreachable,vla-bound,vptr")
 294         set(CLR_SANITIZE_LINK_FLAGS "${CLR_SANITIZE_LINK_FLAGS}undefined")
 295         message("Undefined Behavior Sanitizer (ubsan) enabled")
 296       endif ()
 297
 298       # -fdata-sections -ffunction-sections: each function has own section instead of one per .o file (needed for --gc-sections)
 299       # -fPIC: enable Position Independent Code normally just for shared libraries but required when linking with address sanitizer
 300       # -O1: optimization level used instead of -O0 to avoid compile error "invalid operand for inline asm constraint"
 301       set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} ${CLR_SANITIZE_CXX_FLAGS} -fdata-sections -ffunction-sections -fPIC -O1")
 302       set(CMAKE_CXX_FLAGS_CHECKED "${CMAKE_CXX_FLAGS_CHECKED} ${CLR_SANITIZE_CXX_FLAGS} -fdata-sections -ffunction-sections -fPIC -O1")
 303
 304       set(CMAKE_EXE_LINKER_FLAGS_DEBUG "${CMAKE_EXE_LINKER_FLAGS_DEBUG} ${CLR_SANITIZE_LINK_FLAGS}")
 305       set(CMAKE_EXE_LINKER_FLAGS_CHECKED "${CMAKE_EXE_LINKER_FLAGS_CHECKED} ${CLR_SANITIZE_LINK_FLAGS}")
 306
 307       # -Wl and --gc-sections: drop unused sections\functions (similar to Windows /Gy function-level-linking)
 308       set(CMAKE_SHARED_LINKER_FLAGS_DEBUG "${CMAKE_SHARED_LINKER_FLAGS_DEBUG} ${CLR_SANITIZE_LINK_FLAGS} -Wl,--gc-sections")
 309       set(CMAKE_SHARED_LINKER_FLAGS_CHECKED "${CMAKE_SHARED_LINKER_FLAGS_CHECKED} ${CLR_SANITIZE_LINK_FLAGS} -Wl,--gc-sections")
 310     endif ()
 311   endif(UPPERCASE_CMAKE_BUILD_TYPE STREQUAL DEBUG OR UPPERCASE_CMAKE_BUILD_TYPE STREQUAL CHECKED)
 312 endif(WIN32)
 313
 314 # CLR_ADDITIONAL_LINKER_FLAGS - used for passing additional arguments to linker
 315 # CLR_ADDITIONAL_COMPILER_OPTIONS - used for passing additional arguments to compiler
 316 #
 317 # For example:
 318 #       ./build-native.sh cmakeargs "-DCLR_ADDITIONAL_COMPILER_OPTIONS=<...>" cmakeargs "-DCLR_ADDITIONAL_LINKER_FLAGS=<...>"
 319 #
 320 if(CLR_CMAKE_PLATFORM_UNIX)
 321     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} ${CLR_ADDITIONAL_LINKER_FLAGS}")
 322     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${CLR_ADDITIONAL_LINKER_FLAGS}" )
 323     add_compile_options(${CLR_ADDITIONAL_COMPILER_OPTIONS})
 324 endif(CLR_CMAKE_PLATFORM_UNIX)
 325
 326 if(CLR_CMAKE_PLATFORM_LINUX)
 327   set(CMAKE_ASM_FLAGS "${CMAKE_ASM_FLAGS} -Wa,--noexecstack")
 328   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--build-id=sha1")
 329   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--build-id=sha1")
 330 endif(CLR_CMAKE_PLATFORM_LINUX)
 331
 332 #------------------------------------
 333 # Definitions (for platform)
 334 #-----------------------------------
 335 if (CLR_CMAKE_PLATFORM_ARCH_AMD64)
 336   add_definitions(-D_AMD64_)
 337   add_definitions(-D_WIN64)
 338   add_definitions(-DAMD64)
 339   add_definitions(-DBIT64=1)
 340 elseif (CLR_CMAKE_PLATFORM_ARCH_I386)
 341   add_definitions(-D_X86_)
 342 elseif (CLR_CMAKE_PLATFORM_ARCH_ARM)
 343   add_definitions(-D_ARM_)
 344   add_definitions(-DARM)
 345 elseif (CLR_CMAKE_PLATFORM_ARCH_ARM64)
 346   add_definitions(-D_ARM64_)
 347   add_definitions(-DARM64)
 348   add_definitions(-D_WIN64)
 349   add_definitions(-DBIT64=1)
 350 else ()
 351   clr_unknown_arch()
 352 endif ()
 353
 354 if (CLR_CMAKE_PLATFORM_UNIX)
 355   if(CLR_CMAKE_PLATFORM_LINUX)
 356     if(CLR_CMAKE_PLATFORM_UNIX_AMD64)
 357       message("Detected Linux x86_64")
 358       add_definitions(-DLINUX64)
 359     elseif(CLR_CMAKE_PLATFORM_UNIX_ARM)
 360       message("Detected Linux ARM")
 361       add_definitions(-DLINUX32)
 362     elseif(CLR_CMAKE_PLATFORM_UNIX_ARM64)
 363       message("Detected Linux ARM64")
 364       add_definitions(-DLINUX64)
 365     elseif(CLR_CMAKE_PLATFORM_UNIX_X86)
 366       message("Detected Linux i686")
 367       add_definitions(-DLINUX32)
 368     else()
 369       clr_unknown_arch()
 370     endif()
 371   endif(CLR_CMAKE_PLATFORM_LINUX)
 372 endif(CLR_CMAKE_PLATFORM_UNIX)
 373
 374 if (CLR_CMAKE_PLATFORM_UNIX)
 375   add_definitions(-DPLATFORM_UNIX=1)
 376
 377   if(CLR_CMAKE_PLATFORM_DARWIN)
 378     message("Detected OSX x86_64")
 379   endif(CLR_CMAKE_PLATFORM_DARWIN)
 380
 381   if(CLR_CMAKE_PLATFORM_FREEBSD)
 382     message("Detected FreeBSD amd64")
 383   endif(CLR_CMAKE_PLATFORM_FREEBSD)
 384
 385   if(CLR_CMAKE_PLATFORM_NETBSD)
 386     message("Detected NetBSD amd64")
 387   endif(CLR_CMAKE_PLATFORM_NETBSD)
 388 endif(CLR_CMAKE_PLATFORM_UNIX)
 389
 390 if (WIN32)
 391   # Define the CRT lib references that link into Desktop imports
 392   set(STATIC_MT_CRT_LIB  "libcmt$<$<OR:$<CONFIG:Debug>,$<CONFIG:Checked>>:d>.lib")
 393   set(STATIC_MT_VCRT_LIB  "libvcruntime$<$<OR:$<CONFIG:Debug>,$<CONFIG:Checked>>:d>.lib")
 394   set(STATIC_MT_CPP_LIB  "libcpmt$<$<OR:$<CONFIG:Debug>,$<CONFIG:Checked>>:d>.lib")
 395 endif(WIN32)
 396
 397 # Architecture specific files folder name
 398 if (CLR_CMAKE_TARGET_ARCH_AMD64)
 399     set(ARCH_SOURCES_DIR amd64)
 400 elseif (CLR_CMAKE_TARGET_ARCH_ARM64)
 401     set(ARCH_SOURCES_DIR arm64)
 402 elseif (CLR_CMAKE_TARGET_ARCH_ARM)
 403     set(ARCH_SOURCES_DIR arm)
 404 elseif (CLR_CMAKE_TARGET_ARCH_I386)
 405     set(ARCH_SOURCES_DIR i386)
 406 else ()
 407     clr_unknown_arch()
 408 endif ()
 409
 410 #--------------------------------------
 411 # Compile Options
 412 #--------------------------------------
 413 if (CLR_CMAKE_PLATFORM_UNIX)
 414   # Disable frame pointer optimizations so profilers can get better call stacks
 415   add_compile_options(-fno-omit-frame-pointer)
 416
 417   # The -fms-extensions enable the stuff like __if_exists, __declspec(uuid()), etc.
 418   add_compile_options(-fms-extensions )
 419   #-fms-compatibility      Enable full Microsoft Visual C++ compatibility
 420   #-fms-extensions         Accept some non-standard constructs supported by the Microsoft compiler
 421
 422   # Make signed arithmetic overflow of addition, subtraction, and multiplication wrap around
 423   # using twos-complement representation (this is normally undefined according to the C++ spec).
 424   add_compile_options(-fwrapv)
 425
 426   if(CLR_CMAKE_PLATFORM_DARWIN)
 427     # We cannot enable "stack-protector-strong" on OS X due to a bug in clang compiler (current version 7.0.2)
 428     add_compile_options(-fstack-protector)
 429   else()
 430     add_compile_options(-fstack-protector-strong)
 431   endif(CLR_CMAKE_PLATFORM_DARWIN)
 432
 433   add_definitions(-DDISABLE_CONTRACTS)
 434   # The -ferror-limit is helpful during the porting, it makes sure the compiler doesn't stop
 435   # after hitting just about 20 errors.
 436   add_compile_options(-ferror-limit=4096)
 437
 438   if (CLR_CMAKE_WARNINGS_ARE_ERRORS)
 439     # All warnings that are not explicitly disabled are reported as errors
 440     add_compile_options(-Werror)
 441   endif(CLR_CMAKE_WARNINGS_ARE_ERRORS)
 442
 443   # Disabled warnings
 444   add_compile_options(-Wno-unused-private-field)
 445   add_compile_options(-Wno-unused-variable)
 446   # Explicit constructor calls are not supported by clang (this->ClassName::ClassName())
 447   add_compile_options(-Wno-microsoft)
 448   # This warning is caused by comparing 'this' to NULL
 449   add_compile_options(-Wno-tautological-compare)
 450   # There are constants of type BOOL used in a condition. But BOOL is defined as int
 451   # and so the compiler thinks that there is a mistake.
 452   add_compile_options(-Wno-constant-logical-operand)
 453   # We use pshpack1/2/4/8.h and poppack.h headers to set and restore packing. However
 454   # clang 6.0 complains when the packing change lifetime is not contained within
 455   # a header file.
 456   add_compile_options(-Wno-pragma-pack)
 457
 458   add_compile_options(-Wno-unknown-warning-option)
 459
 460   #These seem to indicate real issues
 461   add_compile_options(-Wno-invalid-offsetof)
 462   # The following warning indicates that an attribute __attribute__((__ms_struct__)) was applied
 463   # to a struct or a class that has virtual members or a base class. In that case, clang
 464   # may not generate the same object layout as MSVC.
 465   add_compile_options(-Wno-incompatible-ms-struct)
 466
 467   # Some architectures (e.g., ARM) assume char type is unsigned while CoreCLR assumes char is signed
 468   # as x64 does. It has been causing issues in ARM (https://github.com/dotnet/coreclr/issues/4746)
 469   add_compile_options(-fsigned-char)
 470 endif(CLR_CMAKE_PLATFORM_UNIX)
 471
 472 if(CLR_CMAKE_PLATFORM_UNIX_ARM)
 473    # Because we don't use CMAKE_C_COMPILER/CMAKE_CXX_COMPILER to use clang
 474    # we have to set the triple by adding a compiler argument
 475    add_compile_options(-mthumb)
 476    add_compile_options(-mfpu=vfpv3)
 477    add_compile_options(-march=armv7-a)
 478    if(ARM_SOFTFP)
 479      add_definitions(-DARM_SOFTFP)
 480      add_compile_options(-mfloat-abi=softfp)
 481    endif(ARM_SOFTFP)
 482 endif(CLR_CMAKE_PLATFORM_UNIX_ARM)
 483
 484 if (WIN32)
 485   # Compile options for targeting windows
 486
 487   # The following options are set by the razzle build
 488   add_compile_options(/TP) # compile all files as C++
 489   add_compile_options(/d2Zi+) # make optimized builds debugging easier
 490   add_compile_options(/nologo) # Suppress Startup Banner
 491   add_compile_options(/W3) # set warning level to 3
 492   add_compile_options(/WX) # treat warnings as errors
 493   add_compile_options(/Oi) # enable intrinsics
 494   add_compile_options(/Oy-) # disable suppressing of the creation of frame pointers on the call stack for quicker function calls
 495   add_compile_options(/U_MT) # undefine the predefined _MT macro
 496   add_compile_options(/GF) # enable read-only string pooling
 497   add_compile_options(/Gm-) # disable minimal rebuild
 498   add_compile_options(/EHa) # enable C++ EH (w/ SEH exceptions)
 499   add_compile_options(/Zp8) # pack structs on 8-byte boundary
 500   add_compile_options(/Gy) # separate functions for linker
 501   add_compile_options(/Zc:wchar_t-) # C++ language conformance: wchar_t is NOT the native type, but a typedef
 502   add_compile_options(/Zc:forScope) # C++ language conformance: enforce Standard C++ for scoping rules
 503   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /GR-") # disable C++ RTTI
 504   add_compile_options(/FC) # use full pathnames in diagnostics
 505   add_compile_options(/MP) # Build with Multiple Processes (number of processes equal to the number of processors)
 506   add_compile_options(/GS) # Buffer Security Check
 507   add_compile_options(/Zm200) # Specify Precompiled Header Memory Allocation Limit of 150MB
 508   add_compile_options(/wd4960 /wd4961 /wd4603 /wd4627 /wd4838 /wd4456 /wd4457 /wd4458 /wd4459 /wd4091 /we4640)
 509   add_compile_options(/Zi) # enable debugging information
 510   add_compile_options(/ZH:SHA_256) # use SHA256 for generating hashes of compiler processed source files.
 511   add_compile_options(/source-charset:utf-8) # Force MSVC to compile source as UTF-8.
 512
 513   if (CLR_CMAKE_PLATFORM_ARCH_I386)
 514     add_compile_options(/Gz)
 515   endif (CLR_CMAKE_PLATFORM_ARCH_I386)
 516
 517   add_compile_options($<$<OR:$<CONFIG:Release>,$<CONFIG:Relwithdebinfo>>:/GL>)
 518   add_compile_options($<$<OR:$<OR:$<CONFIG:Release>,$<CONFIG:Relwithdebinfo>>,$<CONFIG:Checked>>:/O1>)
 519
 520   if (CLR_CMAKE_PLATFORM_ARCH_AMD64)
 521   # The generator expression in the following command means that the /homeparams option is added only for debug builds
 522   add_compile_options($<$<CONFIG:Debug>:/homeparams>) # Force parameters passed in registers to be written to the stack
 523   endif (CLR_CMAKE_PLATFORM_ARCH_AMD64)
 524
 525   # enable control-flow-guard support for native components for non-Arm64 builds
 526   # Added using variables instead of add_compile_options to let individual projects override it
 527   set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /guard:cf")
 528   set(CMAKE_C_FLAGS "${CMAKE_CXX_FLAGS} /guard:cf")
 529
 530   # Statically linked CRT (libcmt[d].lib, libvcruntime[d].lib and libucrt[d].lib) by default. This is done to avoid
 531   # linking in VCRUNTIME140.DLL for a simplified xcopy experience by reducing the dependency on VC REDIST.
 532   #
 533   # For Release builds, we shall dynamically link into uCRT [ucrtbase.dll] (which is pushed down as a Windows Update on downlevel OS) but
 534   # wont do the same for debug/checked builds since ucrtbased.dll is not redistributable and Debug/Checked builds are not
 535   # production-time scenarios.
 536   add_compile_options($<$<OR:$<CONFIG:Release>,$<CONFIG:Relwithdebinfo>>:/MT>)
 537   add_compile_options($<$<OR:$<CONFIG:Debug>,$<CONFIG:Checked>>:/MTd>)
 538
 539   set(CMAKE_ASM_MASM_FLAGS "${CMAKE_ASM_MASM_FLAGS} /ZH:SHA_256")
 540
 541 endif (WIN32)
 542
 543 if(CLR_CMAKE_ENABLE_CODE_COVERAGE)
 544
 545   if(CLR_CMAKE_PLATFORM_UNIX)
 546     string(TOUPPER ${CMAKE_BUILD_TYPE} UPPERCASE_CMAKE_BUILD_TYPE)
 547     if(NOT UPPERCASE_CMAKE_BUILD_TYPE STREQUAL DEBUG)
 548       message( WARNING "Code coverage results with an optimised (non-Debug) build may be misleading" )
 549     endif(NOT UPPERCASE_CMAKE_BUILD_TYPE STREQUAL DEBUG)
 550
 551     add_compile_options(-fprofile-arcs)
 552     add_compile_options(-ftest-coverage)
 553     set(CLANG_COVERAGE_LINK_FLAGS  "--coverage")
 554     set(CMAKE_SHARED_LINKER_FLAGS  "${CMAKE_SHARED_LINKER_FLAGS} ${CLANG_COVERAGE_LINK_FLAGS}")
 555     set(CMAKE_EXE_LINKER_FLAGS     "${CMAKE_EXE_LINKER_FLAGS} ${CLANG_COVERAGE_LINK_FLAGS}")
 556   else()
 557     message(FATAL_ERROR "Code coverage builds not supported on current platform")
 558   endif(CLR_CMAKE_PLATFORM_UNIX)
 559
 560 endif(CLR_CMAKE_ENABLE_CODE_COVERAGE)