configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 # require autoconf 2.54
   3 AC_PREREQ(2.54)
   4
   5 dnl ***********************************
   6 dnl *** include special GLib macros ***
   7 dnl ***********************************
   8
   9 m4_define(glib_configure_in)
  10 m4_include(acglib.m4)dnl
  11 m4_include(glib/libcharset/codeset.m4)dnl
  12 m4_include(glib/libcharset/glibc21.m4)dnl
  13 m4_include(m4macros/glib-gettext.m4)dnl
  14
  15 #
  16 # The following version number definitions apply to GLib, GModule, GObject
  17 # and GThread as a whole, so if changes occoured in any of them, they are all
  18 # treated with the same interface and binary age.
  19 #
  20 # Making releases:
  21 #   glib_micro_version += 1;
  22 #   glib_interface_age += 1;
  23 #   glib_binary_age += 1;
  24 # if any functions have been added, set glib_interface_age to 0.
  25 # if backwards compatibility has been broken,
  26 # set glib_binary_age _and_ glib_interface_age to 0.
  27 #
  28 m4_define([glib_major_version], [2])
  29 m4_define([glib_minor_version], [3])
  30 m4_define([glib_micro_version], [2])
  31 m4_define([glib_interface_age], [0])
  32 m4_define([glib_binary_age],
  33           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  34 m4_define([glib_version],
  35           [glib_major_version.glib_minor_version.glib_micro_version])
  36
  37 # libtool version related macros
  38 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  39 m4_define([glib_lt_current],
  40           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  41 m4_define([glib_lt_revision], [glib_interface_age])
  42 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  43 m4_define([glib_lt_current_minus_age],
  44           [m4_eval(glib_lt_current - glib_lt_age)])
  45
  46 # if the minor version number is odd, then we want debugging.  Otherwise
  47 # we only want minimal debugging support.
  48 m4_define([glib_debug_default],
  49           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  50
  51
  52 AC_INIT(glib, [glib_version],
  53         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  54
  55 AC_CONFIG_SRCDIR([glib/glib.h])
  56
  57 # Save this value here, since automake will set cflags later
  58 cflags_set=${CFLAGS+set}
  59
  60 AM_INIT_AUTOMAKE([no-define])
  61
  62 # Specify a configuration file
  63 AM_CONFIG_HEADER([config.h])
  64
  65
  66 GLIB_MAJOR_VERSION=glib_major_version
  67 GLIB_MINOR_VERSION=glib_minor_version
  68 GLIB_MICRO_VERSION=glib_micro_version
  69 GLIB_INTERFACE_AGE=glib_interface_age
  70 GLIB_BINARY_AGE=glib_binary_age
  71 GLIB_VERSION=glib_version
  72
  73 AC_SUBST(GLIB_MAJOR_VERSION)
  74 AC_SUBST(GLIB_MINOR_VERSION)
  75 AC_SUBST(GLIB_MICRO_VERSION)
  76 AC_SUBST(GLIB_VERSION)
  77 AC_SUBST(GLIB_INTERFACE_AGE)
  78 AC_SUBST(GLIB_BINARY_AGE)
  79
  80 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  81           [Define to the GLIB major version])
  82 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  83           [Define to the GLIB minor version])
  84 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  85           [Define to the GLIB micro version])
  86 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  87           [Define to the GLIB interface age])
  88 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  89           [Define to the GLIB binary age])
  90
  91 # libtool versioning
  92 LT_RELEASE=glib_lt_release
  93 LT_CURRENT=glib_lt_current
  94 LT_REVISION=glib_lt_revision
  95 LT_AGE=glib_lt_age
  96 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
  97 AC_SUBST(LT_RELEASE)
  98 AC_SUBST(LT_CURRENT)
  99 AC_SUBST(LT_REVISION)
 100 AC_SUBST(LT_AGE)
 101 AC_SUBST(LT_CURRENT_MINUS_AGE)
 102
 103 dnl Initialize maintainer mode
 104 AM_MAINTAINER_MODE
 105
 106 AC_CANONICAL_HOST
 107
 108 AC_MSG_CHECKING([for the BeOS])
 109 case $host in
 110   *-*-beos*)
 111     glib_native_beos="yes"
 112     ;;
 113   *)
 114     glib_native_beos="no"
 115     ;;
 116 esac
 117 AC_MSG_RESULT([$glib_native_beos])
 118
 119 dnl
 120
 121 AC_MSG_CHECKING([for Win32])
 122 case "$host" in
 123   *-*-mingw*)
 124     glib_native_win32=yes
 125     G_LIB_WIN32_RESOURCE=glib-win32res.lo
 126     G_MODULE_WIN32_RESOURCE=gmodule-win32res.lo
 127     G_OBJECT_WIN32_RESOURCE=gobject-win32res.lo
 128     G_THREAD_WIN32_RESOURCE=gthread-win32res.lo
 129     GLIB_DEF=glib.def
 130     GMODULE_DEF=gmodule.def
 131     GOBJECT_DEF=gobject.def
 132     GTHREAD_DEF=gthread.def
 133     TESTGMODULE_EXP=testgmodule.exp
 134     glib_pid_type=HANDLE
 135     ;;
 136   *)
 137     glib_native_win32=no
 138     G_LIB_WIN32_RESOURCE=
 139     G_MODULE_WIN32_RESOURCE=
 140     G_OBJECT_WIN32_RESOURCE=
 141     G_THREAD_WIN32_RESOURCE=
 142     GLIB_DEF=
 143     GMODULE_DEF=
 144     GOBJECT_DEF=
 145     GTHREAD_DEF=
 146     TESTGMODULE_EXP=
 147     glib_pid_type=int
 148     ;;
 149 esac
 150 AC_MSG_RESULT([$glib_native_win32])
 151 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 152 AC_SUBST(G_LIB_WIN32_RESOURCE)
 153 AC_SUBST(G_MODULE_WIN32_RESOURCE)
 154 AC_SUBST(G_OBJECT_WIN32_RESOURCE)
 155 AC_SUBST(G_THREAD_WIN32_RESOURCE)
 156 AC_SUBST(GLIB_DEF)
 157 AC_SUBST(GMODULE_DEF)
 158 AC_SUBST(GOBJECT_DEF)
 159 AC_SUBST(GTHREAD_DEF)
 160 AC_SUBST(TESTGMODULE_EXP)
 161
 162 if test "$glib_native_win32" = "yes"; then
 163   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 164 fi
 165 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 166
 167 dnl declare --enable-* args and collect ac_help strings
 168 AC_ARG_ENABLE(debug,
 169               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 170                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 171               enable_debug=glib_debug_default)
 172
 173 AC_ARG_ENABLE(gc_friendly,
 174               [AC_HELP_STRING([--enable-gc-friendly],
 175                               [turn on garbage collector friendliness [default=no]])],,
 176               [enable_gc_friendly=no])
 177 AC_ARG_ENABLE(mem_pools,
 178               [AC_HELP_STRING([--disable-mem-pools],
 179                               [disable all glib memory pools])],,
 180               [disable_mem_pools=no])
 181 AC_ARG_ENABLE(ansi,
 182               [AC_HELP_STRING([--enable-ansi],
 183                               [turn on strict ansi [default=no]])],,
 184               [enable_ansi=no])
 185 AC_ARG_ENABLE(threads,
 186               [AC_HELP_STRING([--enable-threads],
 187                               [turn on basic thread support [default=yes]
 188 ([=no] will override --with-threads)])],,
 189               [enable_threads=yes])
 190 AC_ARG_ENABLE(rebuilds,
 191               [AC_HELP_STRING([--disable-rebuilds],
 192                               [disable all source autogeneration rules])],,
 193               [enable_rebuilds=yes])
 194
 195 if test "x$enable_threads" != "xyes"; then
 196   enable_threads=no
 197 fi
 198
 199 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, ["${enable_debug}"],
 200         [Whether glib was compiled with debugging enabled])
 201
 202 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 203 if test "x$enable_gc_friendly" = "xyes"; then
 204   AC_DEFINE(ENABLE_GC_FRIENDLY, 1, [Whether to enable GC friendliness])
 205   AC_SUBST(ENABLE_GC_FRIENDLY)
 206   AC_MSG_RESULT([yes])
 207 else
 208   AC_MSG_RESULT([no])
 209 fi
 210
 211 AC_MSG_CHECKING([whether to disable memory pools])
 212 if test "x$disable_mem_pools" = "xno"; then
 213   AC_MSG_RESULT([no])
 214 else
 215   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 216   AC_SUBST(DISABLE_MEM_POOLS)
 217   AC_MSG_RESULT([yes])
 218 fi
 219
 220 if test "$glib_native_win32" = "yes"; then
 221   if test x$enable_static = xyes -o x$enable_static = x; then
 222     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 223     enable_static=no
 224   fi
 225   if test x$enable_shared = xno; then
 226     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 227   fi
 228   enable_shared=yes
 229 fi
 230
 231 dnl Checks for programs.
 232 AC_PROG_CC
 233
 234 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 235 AC_CHECK_PROGS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 236 AC_LANG_SAVE
 237 AC_LANG_CPLUSPLUS
 238 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 239 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 240 AC_LANG_RESTORE
 241
 242 AM_PROG_CC_STDC
 243 AC_PROG_INSTALL
 244
 245 AC_SYS_LARGEFILE
 246
 247 #
 248 # Find pkg-config
 249 #
 250 AC_PATH_PROG(PKG_CONFIG, [pkg-config], [no])
 251 if test x$PKG_CONFIG = xno ; then
 252   AC_MSG_ERROR([*** pkg-config not found. See http://www.freedesktop.org/software/pkgconfig/])
 253 fi
 254
 255 if $PKG_CONFIG --atleast-pkgconfig-version 0.14 ; then
 256   :
 257 else
 258   AC_MSG_ERROR([*** pkg-config too old; version 0.14 or better required.])
 259 fi
 260
 261 if test "x$enable_debug" = "xyes"; then
 262   if test x$cflags_set != xset ; then
 263       case " $CFLAGS " in
 264       *[[\ \    ]]-g[[\ \       ]]*) ;;
 265       *) CFLAGS="$CFLAGS -g" ;;
 266       esac
 267   fi
 268
 269   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 270 else
 271   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 272
 273   if test "x$enable_debug" = "xno"; then
 274     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 275   fi
 276 fi
 277
 278 # Ensure MSVC-compatible struct packing convention is used when
 279 # compiling for Win32 with gcc.
 280 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 281 # gcc2 uses "-fnative-struct".
 282 if test x"$glib_native_win32" = xyes; then
 283   if test x"$GCC" = xyes; then
 284     msnative_struct=''
 285     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 286     if test -z "$ac_cv_prog_CC"; then
 287       our_gcc="$CC"
 288     else
 289       our_gcc="$ac_cv_prog_CC"
 290     fi
 291     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 292       2.)
 293         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 294           msnative_struct='-fnative-struct'
 295         fi
 296         ;;
 297       *)
 298         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 299           msnative_struct='-mms-bitfields'
 300         fi
 301         ;;
 302     esac
 303     if test x"$msnative_struct" = x ; then
 304       AC_MSG_RESULT([no way])
 305       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 306     else
 307       CFLAGS="$CFLAGS $msnative_struct"
 308       AC_MSG_RESULT([${msnative_struct}])
 309     fi
 310   fi
 311 fi
 312
 313 AC_CYGWIN
 314 AC_EXEEXT
 315
 316 # define a MAINT-like variable REBUILD which is set if Perl
 317 # and awk are found, so autogenerated sources can be rebuilt
 318 AC_PROG_AWK
 319 AC_CHECK_PROGS(PERL, [perl5 perl])
 320 # We would like indent, but don't require it.
 321 AC_CHECK_PROG(INDENT, indent, indent)
 322 REBUILD=\#
 323 if test "x$enable_rebuilds" = "xyes" && \
 324      test -n "$PERL" && \
 325      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 326      test -n "$AWK" ; then
 327   REBUILD=
 328 fi
 329 AC_SUBST(REBUILD)
 330
 331 # Need full path to Perl for glib-mkenums
 332 #
 333 if test "x$PERL" != x ; then
 334   AC_PATH_PROG(PERL_PATH, [$PERL])
 335 else
 336   PERL_PATH="/usr/bin/env perl"
 337 fi
 338 AC_SUBST(PERL_PATH)
 339
 340 dnl ***********************
 341 dnl *** Tests for iconv ***
 342 dnl ***********************
 343 dnl
 344 dnl We do this before the gettext checks, to avoid distortion
 345
 346 AC_ARG_WITH(libiconv,
 347             [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 348                             [use the libiconv library])],,
 349             [with_libiconv=maybe])
 350
 351 found_iconv=no
 352 case $with_libiconv in
 353   maybe)
 354     # Check in the C library first
 355     AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 356     # Check if we have GNU libiconv
 357     if test $found_iconv = "no"; then
 358       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 359     fi
 360     # Check if we have a iconv in -liconv, possibly from vendor
 361     if test $found_iconv = "no"; then
 362       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 363     fi
 364     ;;
 365   no)
 366     AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 367     ;;
 368   gnu|yes)
 369     AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 370     ;;
 371   native)
 372     AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 373     ;;
 374 esac
 375
 376 if test "x$found_iconv" = "xno" ; then
 377    AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 378 fi
 379
 380 dnl
 381 dnl gettext support
 382 dnl
 383
 384 ALL_LINGUAS="am ar az be bg bn ca cs cy da de el eo es et eu fa fi fr gl he hi hr id is it ja ko lt lv mk mn ms nl nn no pl pt pt_BR ro ru sk sl sq sr sr@Latn sv ta tr uk vi yi zh_CN zh_TW"
 385 GLIB_GNU_GETTEXT
 386
 387 if test "$gt_cv_have_gettext" != "yes" ; then
 388   AC_MSG_ERROR([
 389 *** You must have either have gettext support in your C library, or use the
 390 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 391 ])
 392 fi
 393
 394 LIBS="$INTLLIBS $LIBS"
 395
 396 GETTEXT_PACKAGE=glib20
 397 AC_SUBST(GETTEXT_PACKAGE)
 398 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 399   [Define the gettext package to be used])
 400
 401 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 402
 403 dnl
 404 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 405 dnl
 406
 407 if test x$with_libiconv != xno ; then
 408   case " $INTLLIBS " in
 409   *[[\ \        ]]-liconv[[\ \  ]]*) ;;
 410   *) ICONV_LIBS="-liconv" ;;
 411   esac
 412 fi
 413 AC_SUBST(ICONV_LIBS)
 414
 415 case $with_libiconv in
 416   gnu)
 417     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 418     ;;
 419   native)
 420     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 421     ;;
 422 esac
 423
 424 dnl Initialize libtool
 425 AM_DISABLE_STATIC
 426 AM_PROG_LIBTOOL
 427
 428 if test "x$GCC" = "xyes"; then
 429   case " $CFLAGS " in
 430   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 431   *) CFLAGS="$CFLAGS -Wall" ;;
 432   esac
 433
 434   if test "x$enable_ansi" = "xyes"; then
 435     case " $CFLAGS " in
 436     *[[\ \      ]]-ansi[[\ \    ]]*) ;;
 437     *) CFLAGS="$CFLAGS -ansi" ;;
 438     esac
 439
 440     case " $CFLAGS " in
 441     *[[\ \      ]]-pedantic[[\ \        ]]*) ;;
 442     *) CFLAGS="$CFLAGS -pedantic" ;;
 443     esac
 444   fi
 445 fi
 446
 447 dnl
 448 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 449 dnl
 450 if test $cross_compiling != yes ; then
 451     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 452     glib_save_LIBS=$LIBS
 453     LIBS="$LIBS -lm"
 454     AC_TRY_RUN([#include <math.h>
 455                  int main (void) { return (log(1) != log(1.)); }],
 456          AC_MSG_RESULT(none needed),
 457          glib_save_CFLAGS=$CFLAGS
 458          CFLAGS="$CFLAGS -std1"
 459          AC_TRY_RUN([#include <math.h>
 460                      int main (void) { return (log(1) != log(1.)); }],
 461              AC_MSG_RESULT(-std1),
 462              AC_MSG_RESULT()
 463              CFLAGS=$glib_save_CFLAGS
 464              AC_MSG_WARN(
 465                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 466          )
 467     )
 468     LIBS=$glib_save_LIBS
 469 fi
 470
 471 dnl NeXTStep cc seems to need this
 472 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 473 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 474   AC_MSG_RESULT(none needed),
 475   glib_save_CFLAGS=$CFLAGS
 476   CFLAGS="$CFLAGS -posix"
 477   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 478     AC_MSG_RESULT(-posix),
 479     AC_MSG_RESULT()
 480     CFLAGS=$glib_save_CFLAGS
 481     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 482
 483 # Checks for header files.
 484 AC_HEADER_STDC
 485
 486 # Checks for library functions.
 487 AC_FUNC_VPRINTF
 488
 489 AC_FUNC_ALLOCA
 490
 491 AC_CHECK_FUNCS(atexit on_exit)
 492
 493 AC_CHECK_SIZEOF(char)
 494 AC_CHECK_SIZEOF(short)
 495 AC_CHECK_SIZEOF(long)
 496 AC_CHECK_SIZEOF(int)
 497 AC_CHECK_SIZEOF(void *)
 498 AC_CHECK_SIZEOF(long long)
 499 AC_CHECK_SIZEOF(__int64)
 500
 501 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 502   :
 503 else
 504   AC_MSG_ERROR([
 505 *** GLib requires a 64 bit type. You might want to consider
 506 *** using the GNU C compiler.
 507 ])
 508 fi
 509
 510 if test x$ac_cv_sizeof_long_long = x8; then
 511         # long long is a 64 bit integer.
 512         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 513         AC_CACHE_VAL(glib_cv_long_long_format,[
 514                 for format in ll q I64; do
 515                   AC_TRY_RUN([#include <stdio.h>
 516                         int main()
 517                         {
 518                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 519                           char buffer[1000];
 520                           sprintf (buffer, "%${format}u", a);
 521                           sscanf (buffer, "%${format}u", &b);
 522                           exit (b!=a);
 523                         }
 524                         ],
 525                         [glib_cv_long_long_format=${format}
 526                         break],
 527                         [],[:])
 528                 done])
 529         if test -n "$glib_cv_long_long_format"; then
 530           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 531           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 532         else
 533           AC_MSG_RESULT(none)
 534         fi
 535 elif test x$ac_cv_sizeof___int64 = x8; then
 536         # __int64 is a 64 bit integer.
 537         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 538         # We know this is MSVC, and what the formats are
 539         glib_cv_long_long_format=I64
 540         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 541         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 542         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing __int64 with format I64])
 543 fi
 544
 545 dnl long doubles were not used, and a portability problem
 546 dnl AC_C_LONG_DOUBLE
 547 AC_C_CONST
 548
 549 dnl ok, here we try to check whether the systems prototypes for
 550 dnl malloc and friends actually match the prototypes provided
 551 dnl by gmem.h (keep in sync). i currently only know how to check
 552 dnl this reliably with gcc (-Werror), improvements for other
 553 dnl compilers are apprechiated.
 554 SANE_MALLOC_PROTOS=no
 555 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 556 glib_save_CFLAGS=$CFLAGS
 557 if test "x$GCC" = "xyes"; then
 558   CFLAGS="$CFLAGS -Werror"
 559   AC_TRY_COMPILE([#include <stdlib.h>], [
 560     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 561     void* (*my_malloc_p)  (size_t)         = malloc;
 562     void  (*my_free_p)    (void*)          = free;
 563     void* (*my_realloc_p) (void*, size_t)  = realloc;
 564     my_calloc_p = 0;
 565     my_malloc_p = 0;
 566     my_free_p = 0;
 567     my_realloc_p = 0;
 568   ],
 569     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 570       [Define if you have correct malloc prototypes])
 571     SANE_MALLOC_PROTOS=yes)
 572 fi
 573 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 574 CFLAGS=$glib_save_CFLAGS
 575
 576 dnl
 577 dnl check in which direction the stack grows
 578 dnl
 579 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 580         AC_TRY_RUN([
 581         volatile int *a = 0, *b = 0;
 582         void foo (void);
 583         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 584         void foo (void) { volatile int x = 5; b = &x; }
 585         ],
 586         glib_cv_stack_grows=no
 587         ,
 588         glib_cv_stack_grows=yes
 589         ,)
 590 ])
 591
 592 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 593 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 594 dnl actually supported.
 595 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 596         AC_COMPILE_IFELSE([
 597         __inline int foo () { return 0; }
 598         int main () { return foo (); }
 599         ],
 600         glib_cv_has__inline=yes
 601         ,
 602         glib_cv_has__inline=no
 603         ,)
 604 ])
 605 case x$glib_cv_has__inline in
 606 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 607 esac
 608 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 609         AC_COMPILE_IFELSE([
 610         __inline__ int foo () { return 0; }
 611         int main () { return foo (); }
 612         ],
 613         glib_cv_has__inline__=yes
 614         ,
 615         glib_cv_has__inline__=no
 616         ,)
 617 ])
 618 case x$glib_cv_has__inline__ in
 619 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 620 esac
 621 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 622         AC_COMPILE_IFELSE([
 623         #undef inline
 624         inline int foo () { return 0; }
 625         int main () { return foo (); }
 626         ],
 627         glib_cv_hasinline=yes
 628         ,
 629         glib_cv_hasinline=no
 630         ,)
 631 ])
 632 case x$glib_cv_hasinline in
 633 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 634 esac
 635
 636 # check for flavours of varargs macros
 637 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 638 AC_TRY_COMPILE([],[
 639 int a(int p1, int p2, int p3);
 640 #define call_a(...) a(1,__VA_ARGS__)
 641 call_a(2,3);
 642 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 643 AC_MSG_RESULT($g_have_iso_c_varargs)
 644
 645 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 646 if test "$CXX" = ""; then
 647 dnl No C++ compiler
 648   g_have_iso_cxx_varargs=no
 649 else
 650   AC_LANG_CPLUSPLUS
 651   AC_TRY_COMPILE([],[
 652 int a(int p1, int p2, int p3);
 653 #define call_a(...) a(1,__VA_ARGS__)
 654 call_a(2,3);
 655 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 656   AC_LANG_C
 657 fi
 658 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 659
 660 AC_MSG_CHECKING(for GNUC varargs macros)
 661 AC_TRY_COMPILE([],[
 662 int a(int p1, int p2, int p3);
 663 #define call_a(params...) a(1,params)
 664 call_a(2,3);
 665 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 666 AC_MSG_RESULT($g_have_gnuc_varargs)
 667
 668 # check for bytesex stuff
 669 AC_C_BIGENDIAN
 670
 671 # check for header files
 672 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h sys/param.h sys/poll.h sys/select.h sys/types.h])
 673 AC_CHECK_HEADERS([sys/time.h sys/times.h unistd.h values.h stdint.h sched.h])
 674
 675 # Checks for libcharset
 676 jm_LANGINFO_CODESET
 677 jm_GLIBC21
 678 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 679 AC_CHECK_FUNCS(setlocale)
 680
 681 # check additional type sizes
 682 AC_CHECK_SIZEOF(size_t)
 683
 684 dnl Try to figure out whether gsize, gssize should be long or int
 685 AC_MSG_CHECKING([for the appropriate definition for size_t])
 686
 687 case $ac_cv_sizeof_size_t in
 688   $ac_cv_sizeof_short)
 689       glib_size_type=short
 690       ;;
 691   $ac_cv_sizeof_int)
 692       glib_size_type=int
 693       ;;
 694   $ac_cv_sizeof_long)
 695       glib_size_type=long
 696       ;;
 697   *)  AC_MSG_ERROR([No type matching size_t in size])
 698       ;;
 699 esac
 700
 701 dnl If int/long are the same size, we see which one produces
 702 dnl warnings when used in the location as size_t. (This matters
 703 dnl on AIX with xlc)
 704 dnl
 705 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 706    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 707   GLIB_CHECK_COMPILE_WARNINGS([
 708 #include <stddef.h>
 709 int main ()
 710 {
 711   size_t s = 1;
 712   unsigned int *size_int = &s;
 713   return (int)*size_int;
 714 }
 715     ],glib_size_type=int,
 716       [GLIB_CHECK_COMPILE_WARNINGS([
 717 #include <stddef.h>
 718 int main ()
 719 {
 720    size_t s = 1;
 721    unsigned long *size_long = &s;
 722    return (int)*size_long;
 723 }
 724         ],glib_size_type=long)])
 725 fi
 726
 727 AC_MSG_RESULT(unsigned $glib_size_type)
 728
 729 # Check for some functions
 730 AC_CHECK_FUNCS(lstat strerror strsignal memmove mkstemp vsnprintf stpcpy strcasecmp strncasecmp poll getcwd nanosleep vasprintf setenv unsetenv getc_unlocked readlink symlink)
 731
 732 AC_FUNC_VSNPRINTF_C99
 733 AC_FUNC_PRINTF_UNIX98
 734
 735 #
 736 # Check whether to use an included printf
 737 #
 738
 739 AC_ARG_ENABLE(included-printf,
 740               [AC_HELP_STRING([--enable-included-printf],
 741                               [use included printf [default=auto]])],
 742               enable_included_printf="$enableval")
 743
 744 need_included_printf=no
 745 if test "x$enable_included_printf" = "xyes" ; then
 746   need_included_printf=yes
 747 fi
 748 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
 749   need_included_printf=yes
 750 fi
 751 if test "$ac_cv_func_printf_unix98" != "yes" ; then
 752   need_included_printf=yes
 753 fi
 754 if test "x$ac_cv_sizeof_long_long" = "x8" &&
 755    test -z "$glib_cv_long_long_format" ; then
 756   need_included_printf=yes
 757 fi
 758
 759 if test "x$enable_included_printf" = "xno" &&
 760    test "x$need_included_printf" = "xyes" ; then
 761   AC_MSG_ERROR([
 762 *** Your C library's printf doesn't appear to have the features that
 763 *** GLib needs, but you specified --enable-included-printf=no.])
 764 fi
 765
 766 enable_included_printf=$need_included_printf
 767
 768 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
 769 if test "$enable_included_printf" != "yes" ; then
 770   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
 771 else
 772   if test -z "$glib_cv_long_long_format" ; then
 773     glib_cv_long_long_format="ll"
 774   fi
 775   AC_DEFINE(HAVE_VASPRINTF,1)
 776 fi
 777
 778 # Checks needed for gnulib vasnprintf
 779 bh_C_SIGNED
 780 jm_AC_TYPE_LONG_LONG
 781 gt_TYPE_LONGDOUBLE
 782 gt_TYPE_WCHAR_T
 783 gt_TYPE_WINT_T
 784 AC_TYPE_SIZE_T
 785 AC_CHECK_TYPES(ptrdiff_t)
 786 jm_AC_TYPE_INTMAX_T
 787 AC_CHECK_FUNCS(snprintf)
 788 AC_FUNC_SNPRINTF_C99
 789
 790 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
 791 # The check is borrowed from the PERL Configure script.
 792 if test "$ac_cv_func_memmove" != "yes"; then
 793   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
 794     glib_cv_working_bcopy,[AC_TRY_RUN([
 795       int main() {
 796         char buf[128], abc[128], *b;
 797         int len, off, align;
 798         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
 799         for (align = 7; align >= 0; align--) {
 800           for (len = 36; len; len--) {
 801             b = buf+align; bcopy(abc, b, len);
 802             for (off = 1; off <= len; off++) {
 803               bcopy(b, b+off, len); bcopy(b+off, b, len);
 804                 if (bcmp(b, abc, len)) return(1);
 805             }
 806           }
 807         }
 808         return(0);
 809       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
 810
 811   GLIB_ASSERT_SET(glib_cv_working_bcopy)
 812   if test "$glib_cv_working_bcopy" = "yes"; then
 813     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
 814   fi
 815 fi
 816
 817 # Check for sys_errlist
 818 AC_MSG_CHECKING(for sys_errlist)
 819 AC_TRY_LINK(, [
 820 extern char *sys_errlist[];
 821 extern int sys_nerr;
 822 sys_errlist[sys_nerr-1][0] = 0;
 823 ], glib_ok=yes, glib_ok=no)
 824 AC_MSG_RESULT($glib_ok)
 825 if test "$glib_ok" = "no"; then
 826     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
 827 fi
 828
 829 # Check for sys_siglist
 830 AC_MSG_CHECKING(for sys_siglist)
 831 AC_TRY_LINK(, [
 832 extern char *sys_siglist[];
 833 exit (sys_siglist[0]);
 834 ], glib_ok=yes, glib_ok=no)
 835 AC_MSG_RESULT($glib_ok)
 836 if test "$glib_ok" = "no"; then
 837     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
 838 fi
 839
 840 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
 841 AC_MSG_CHECKING(for sys_siglist declaration)
 842 AC_TRY_COMPILE([#include <signal.h>], [
 843 strlen (sys_siglist[0]);
 844 ], glib_ok=yes, glib_ok=no)
 845 AC_MSG_RESULT($glib_ok)
 846 if test "$glib_ok" = "no"; then
 847     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
 848 fi
 849
 850 # Check if <sys/select.h> needs to be included for fd_set
 851 AC_MSG_CHECKING([for fd_set])
 852 AC_TRY_COMPILE([#include <sys/types.h>],
 853         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 854 if test "$gtk_ok" = "yes"; then
 855     AC_MSG_RESULT([yes, found in sys/types.h])
 856 else
 857     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
 858     if test "$gtk_ok" = "yes"; then
 859         # *** FIXME: give it a different name
 860         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
 861         AC_MSG_RESULT([yes, found in sys/select.h])
 862     else
 863         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
 864         AC_MSG_RESULT(no)
 865     fi
 866 fi
 867
 868 dnl *** check for sane realloc() ***
 869 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
 870         AC_TRY_RUN([#include <stdlib.h>
 871         int main() {
 872           return realloc (0, sizeof (int)) == 0;
 873         }],
 874         [glib_cv_sane_realloc=yes],
 875         [glib_cv_sane_realloc=no],
 876         [glib_cv_sane_realloc=yes])
 877 ])
 878 if test x$glib_cv_sane_realloc = xyes; then
 879   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
 880 fi
 881
 882 dnl Check for nl_langinfo and CODESET
 883
 884 AC_MSG_CHECKING([for nl_langinfo (CODESET)])
 885 AC_TRY_COMPILE([#include <langinfo.h>],
 886         [char *codeset = nl_langinfo (CODESET);],
 887    AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
 888    have_codeset=yes,
 889    have_codeset=no)
 890 AC_MSG_RESULT($have_codeset)
 891
 892
 893 dnl ****************************************
 894 dnl *** strlcpy/strlcat                  ***
 895 dnl ****************************************
 896 # Check for strlcpy
 897 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
 898 AC_TRY_RUN([#include <stdlib.h>
 899 #include <string.h>
 900 int main() {
 901   char p[10];
 902   (void) strlcpy (p, "hi", 10);
 903   if (strlcat (p, "bye", 0) != 3)
 904     return 1;
 905   return 0;
 906 }], glib_cv_have_strlcpy=yes,
 907     glib_cv_have_strlcpy=no,
 908     glib_cv_have_strlcpy=no)])
 909 if test "$glib_cv_have_strlcpy" = "yes"; then
 910     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
 911 fi
 912
 913
 914 dnl **********************
 915 dnl *** va_copy checks ***
 916 dnl **********************
 917 dnl we currently check for all three va_copy possibilities, so we get
 918 dnl all results in config.log for bug reports.
 919 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
 920         AC_LINK_IFELSE([#include <stdarg.h>
 921         void f (int i, ...) {
 922         va_list args1, args2;
 923         va_start (args1, i);
 924         va_copy (args2, args1);
 925         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 926           exit (1);
 927         va_end (args1); va_end (args2);
 928         }
 929         int main() {
 930           f (0, 42);
 931           return 0;
 932         }],
 933         [glib_cv_va_copy=yes],
 934         [glib_cv_va_copy=no])
 935 ])
 936 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
 937         AC_LINK_IFELSE([#include <stdarg.h>
 938         void f (int i, ...) {
 939         va_list args1, args2;
 940         va_start (args1, i);
 941         __va_copy (args2, args1);
 942         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 943           exit (1);
 944         va_end (args1); va_end (args2);
 945         }
 946         int main() {
 947           f (0, 42);
 948           return 0;
 949         }],
 950         [glib_cv___va_copy=yes],
 951         [glib_cv___va_copy=no])
 952 ])
 953
 954 if test "x$glib_cv_va_copy" = "xyes"; then
 955   g_va_copy_func=va_copy
 956 else if test "x$glib_cv___va_copy" = "xyes"; then
 957   g_va_copy_func=__va_copy
 958 fi
 959 fi
 960
 961 if test -n "$g_va_copy_func"; then
 962   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
 963 fi
 964
 965 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
 966         AC_TRY_RUN([#include <stdarg.h>
 967         void f (int i, ...) {
 968         va_list args1, args2;
 969         va_start (args1, i);
 970         args2 = args1;
 971         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 972           exit (1);
 973         va_end (args1); va_end (args2);
 974         }
 975         int main() {
 976           f (0, 42);
 977           return 0;
 978         }],
 979         [glib_cv_va_val_copy=yes],
 980         [glib_cv_va_val_copy=no],
 981         [glib_cv_va_val_copy=yes])
 982 ])
 983
 984 if test "x$glib_cv_va_val_copy" = "xno"; then
 985   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 986 fi
 987
 988 dnl ***********************
 989 dnl *** g_module checks ***
 990 dnl ***********************
 991 G_MODULE_LIBS=
 992 G_MODULE_LIBS_EXTRA=
 993 G_MODULE_PLUGIN_LIBS=
 994 if test x"$glib_native_win32" = xyes; then
 995   dnl No use for this on Win32
 996   G_MODULE_LDFLAGS=
 997 else
 998   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
 999 fi
1000 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1001 G_MODULE_NEED_USCORE=0
1002 G_MODULE_BROKEN_RTLD_GLOBAL=0
1003 G_MODULE_HAVE_DLERROR=0
1004 dnl *** force native WIN32 shared lib loader
1005 if test -z "$G_MODULE_IMPL"; then
1006   case "$host" in
1007   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1008   esac
1009 fi
1010 dnl *** dlopen() and dlsym() in system libraries
1011 if test -z "$G_MODULE_IMPL"; then
1012         AC_CHECK_FUNC(dlopen,
1013                       [AC_CHECK_FUNC(dlsym,
1014                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1015                       [])
1016 fi
1017 dnl *** load_image (BeOS)
1018 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1019   AC_CHECK_LIB(root, load_image,
1020       [G_MODULE_LIBS="-lbe -lroot -lglib"
1021       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1022       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1023       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1024       [])
1025 fi
1026 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1027 if test -z "$G_MODULE_IMPL"; then
1028         AC_CHECK_FUNC(NSLinkModule,
1029                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1030                        G_MODULE_NEED_USCORE=1],
1031                       [])
1032 fi
1033 dnl *** dlopen() and dlsym() in libdl
1034 if test -z "$G_MODULE_IMPL"; then
1035         AC_CHECK_LIB(dl, dlopen,
1036                      [AC_CHECK_LIB(dl, dlsym,
1037                                    [G_MODULE_LIBS=-ldl
1038                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1039                      [])
1040 fi
1041 dnl *** shl_load() in libdld (HP-UX)
1042 if test -z "$G_MODULE_IMPL"; then
1043         AC_CHECK_LIB(dld, shl_load,
1044                 [G_MODULE_LIBS=-ldld
1045                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1046                 [])
1047 fi
1048 dnl *** additional checks for G_MODULE_IMPL_DL
1049 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1050         LIBS_orig="$LIBS"
1051         LDFLAGS_orig="$LDFLAGS"
1052         LIBS="$G_MODULE_LIBS $LIBS"
1053         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1054 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1055         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1056                 glib_cv_rtldglobal_broken,[
1057                 AC_TRY_RUN([
1058 #include <dlfcn.h>
1059 #ifndef RTLD_GLOBAL
1060 #  define RTLD_GLOBAL 0
1061 #endif
1062 #ifndef RTLD_LAZY
1063 #  define RTLD_LAZY 0
1064 #endif
1065 int pthread_create;
1066 int main () {
1067     void *handle, *global, *local;
1068     global = &pthread_create;
1069     handle = dlopen ("libpthread.so", RTLD_GLOBAL | RTLD_LAZY);
1070     if (!handle) return 0;
1071     local = dlsym (handle, "pthread_create");
1072     return global == local;
1073 }                       ],
1074                         [glib_cv_rtldglobal_broken=no],
1075                         [glib_cv_rtldglobal_broken=yes],
1076                         [glib_cv_rtldglobal_broken=no])
1077                 rm -f plugin.c plugin.o plugin.lo
1078         ])
1079         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1080                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1081         else
1082                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1083         fi
1084 dnl *** check whether we need preceeding underscores
1085         AC_CACHE_CHECK([for preceeding underscore in symbols],
1086                 glib_cv_uscore,[
1087                 AC_TRY_RUN([#include <dlfcn.h>
1088                 int glib_underscore_test (void) { return 42; }
1089                 int main() {
1090                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1091                   handle = dlopen ((void*)0, 0);
1092                   if (handle) {
1093                     f1 = dlsym (handle, "glib_underscore_test");
1094                     f2 = dlsym (handle, "_glib_underscore_test");
1095                   } return (!f2 || f1);
1096                 }],
1097                         [glib_cv_uscore=yes],
1098                         [glib_cv_uscore=no],
1099                         [])
1100                 rm -f plugin.c plugin.$ac_objext plugin.lo
1101         ])
1102         GLIB_ASSERT_SET(glib_cv_uscore)
1103         if test "x$glib_cv_uscore" = "xyes"; then
1104                 G_MODULE_NEED_USCORE=1
1105         else
1106                 G_MODULE_NEED_USCORE=0
1107         fi
1108
1109         LDFLAGS="$LDFLAGS_orig"
1110 dnl *** check for having dlerror()
1111         AC_CHECK_FUNC(dlerror,
1112                 [G_MODULE_HAVE_DLERROR=1],
1113                 [G_MODULE_HAVE_DLERROR=0])
1114         LIBS="$LIBS_orig"
1115 fi
1116 dnl *** done, have we got an implementation?
1117 if test -z "$G_MODULE_IMPL"; then
1118         G_MODULE_IMPL=0
1119         G_MODULE_SUPPORTED=false
1120 else
1121         G_MODULE_SUPPORTED=true
1122 fi
1123
1124 AC_MSG_CHECKING(for the suffix of shared libraries)
1125 case "$host_os" in
1126   hpux9* | hpux10* | hpux11*)  # taken from ltconfig
1127     glib_gmodule_suffix='sl'
1128     ;;
1129   cygwin* | mingw*)
1130     glib_gmodule_suffix='dll'
1131     ;;
1132   *)
1133     glib_gmodule_suffix='so'
1134     ;;
1135 esac
1136 AC_MSG_RESULT(.$glib_gmodule_suffix)
1137
1138 AC_SUBST(G_MODULE_SUPPORTED)
1139 AC_SUBST(G_MODULE_IMPL)
1140 AC_SUBST(G_MODULE_LIBS)
1141 AC_SUBST(G_MODULE_LIBS_EXTRA)
1142 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1143 AC_SUBST(G_MODULE_LDFLAGS)
1144 AC_SUBST(G_MODULE_HAVE_DLERROR)
1145 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1146 AC_SUBST(G_MODULE_NEED_USCORE)
1147 AC_SUBST(GLIB_DEBUG_FLAGS)
1148
1149 dnl **********************
1150 dnl *** g_spawn checks ***
1151 dnl **********************
1152
1153 AC_MSG_CHECKING(for gspawn implementation)
1154 case "$host" in
1155   *-*-mingw*)
1156     GSPAWN=gspawn-win32.lo
1157     ;;
1158   *)
1159     GSPAWN=gspawn.lo
1160     ;;
1161 esac
1162 AC_MSG_RESULT($GSPAWN)
1163 AC_SUBST(GSPAWN)
1164
1165 dnl *************************
1166 dnl *** GIOChannel checks ***
1167 dnl *************************
1168
1169 AC_MSG_CHECKING(for GIOChannel implementation)
1170 case "$host" in
1171   *-*-mingw*)
1172     GIO=giowin32.lo
1173     ;;
1174   *)
1175     GIO=giounix.lo
1176     ;;
1177 esac
1178 AC_MSG_RESULT($GIO)
1179 AC_SUBST(GIO)
1180
1181 dnl check for cpu to enable double checked locking when possible
1182 dnl ************************************************************
1183
1184 if test x"$have_threads" != xno; then
1185         AC_MSG_CHECKING(whether double checked locking is safe)
1186         # According to glibc/linuxthreads the following platforms do
1187         # not have the notion of a read or write memory barrier and
1188         # therefore the double checked locking should be safe. Have a
1189         # look at pthread_once in glibc/linuxthreads/mutex.c to see,
1190         # what this means.
1191         case $host_cpu in
1192                 arm|hppa|i386|i686|ia64|m68k|sh|cris|x86_64)
1193                         g_use_double_checked_locking=yes
1194                 ;;
1195                 *)
1196                         g_use_double_checked_locking=no
1197                 ;;
1198         esac
1199         AC_MSG_RESULT($g_use_double_checked_locking)
1200 fi
1201
1202 dnl ****************************************
1203 dnl *** platform dependent source checks ***
1204 dnl ****************************************
1205
1206 AC_MSG_CHECKING(for platform-dependent source)
1207 case "$host" in
1208   *-*-cygwin*|*-*-mingw*)
1209     PLATFORMDEP=gwin32.lo
1210     ;;
1211   *)
1212     PLATFORMDEP=
1213     ;;
1214 esac
1215 AC_MSG_RESULT($PLATFORMDEP)
1216 AC_SUBST(PLATFORMDEP)
1217
1218 AC_MSG_CHECKING([whether to compile timeloop])
1219 case "$host" in
1220   *-*-cygwin*|*-*-mingw*)
1221     enable_timeloop=no
1222     ;;
1223   *)
1224     enable_timeloop=yes
1225     ;;
1226 esac
1227 AC_MSG_RESULT($enable_timeloop)
1228 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1229
1230 AC_MSG_CHECKING([if building for some Win32 platform])
1231 case "$host" in
1232   *-*-mingw*|*-*-cygwin*)
1233     platform_win32=yes
1234     ;;
1235   *)
1236     platform_win32=no
1237     ;;
1238 esac
1239 AC_MSG_RESULT($platform_win32)
1240 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1241
1242 dnl ***********************
1243 dnl *** g_thread checks ***
1244 dnl ***********************
1245
1246 AC_ARG_WITH(threads,
1247            [AC_HELP_STRING([--with-threads=@<:@none/posix/dce/solaris/win32@:>@],
1248                            [specify a thread implementation to use])],
1249            [if test "x$with_threads" = x; then
1250                 want_threads=yes
1251             else
1252                 want_threads=$with_threads
1253             fi],
1254            [want_threads=yes])
1255 if test "x$enable_threads" = "xno"; then
1256         want_threads=no
1257 fi
1258
1259 dnl error and warning message
1260 dnl *************************
1261
1262 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1263                 computer. GLib will not have a default thread implementation."
1264
1265 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1266                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1267                 compilation now, but then your programs might not work.
1268                 Please provide information on how it is done on your system."
1269
1270 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1271                 "
1272
1273 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1274                 provide information on your thread implementation.
1275                 You can also run 'configure --disable-threads'
1276                 to compile without thread support."
1277
1278 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1279                 functions will not be MT-safe during their first call because
1280                 there is no working 'getpwuid_r' on your system."
1281
1282 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1283                 because there is no 'localtime_r' on your system."
1284
1285 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1286                 crude surrogate will be used. If you happen to know a
1287                 yield function for your system, please inform the GLib
1288                 developers."
1289
1290 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1291                 threads on your system. Thus threads can only have the default
1292                 priority. If you happen to know these main/max
1293                 priorities, please inform the GLib developers."
1294
1295 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1296                 linking threaded applications. As GLib cannot do that
1297                 automatically, you will get an linkg error everytime you are
1298                 not using the right compiler. In that case you have to relink
1299                 with the right compiler. Ususally just '_r' is appended
1300                 to the compiler name."
1301
1302 dnl determination of thread implementation
1303 dnl ***************************************
1304
1305 # have_threads=no   means no thread support
1306 # have_threads=none means no default thread implementation
1307
1308 have_threads=no
1309 if test "x$want_threads" = xyes || test "x$want_threads" = xsolaris; then
1310         case $host in
1311                 *-*-solaris*)
1312                 AC_CHECK_LIB(thread, cond_init, have_threads=solaris)
1313                 ;;
1314         esac
1315 fi
1316 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1317                                 || test "x$want_threads" = xdce; then
1318         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1319         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1320         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1321         glib_save_CPPFLAGS="$CPPFLAGS"
1322         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1323         if test "x$have_threads" = xno; then
1324                 AC_TRY_COMPILE([#include <pthread.h>],
1325                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1326                         have_threads=posix)
1327         fi
1328         if test "x$have_threads" = xno; then
1329                 AC_TRY_COMPILE([#include <pthread.h>],
1330                         [pthread_mutex_t m;
1331                          pthread_mutex_init (&m, pthread_mutexattr_default);],
1332                         have_threads=dce)
1333         fi
1334         # Tru64Unix requires -pthread to find pthread.h. See #103020
1335         CPPFLAGS="$CPPFLAGS -pthread"
1336         if test "x$have_threads" = xno; then
1337         AC_TRY_COMPILE([#include <pthread.h>],
1338                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1339                        have_threads=posix)
1340         fi
1341         CPPFLAGS="$glib_save_CPPFLAGS"
1342 fi
1343 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1344         case $host in
1345                 *-*-mingw*)
1346                 have_threads=win32
1347                 ;;
1348         esac
1349 fi
1350 if test "x$want_threads" = xnone; then
1351         have_threads=none
1352 fi
1353
1354 AC_MSG_CHECKING(for thread implementation)
1355
1356 if test "x$have_threads" = xno && test "x$want_threads" != xno; then
1357         AC_MSG_RESULT(none available)
1358         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
1359 else
1360         AC_MSG_RESULT($have_threads)
1361 fi
1362
1363
1364 dnl determination of G_THREAD_CFLAGS
1365 dnl ********************************
1366
1367 G_THREAD_LIBS=
1368 G_THREAD_LIBS_EXTRA=
1369 G_THREAD_CFLAGS=
1370
1371 dnl
1372 dnl Test program for basic POSIX threads functionality
1373 dnl
1374 m4_define([glib_thread_test],[
1375 #include <pthread.h>
1376 int check_me = 0;
1377 void* func(void* data) {check_me = 42; return &check_me;}
1378 int main()
1379  { pthread_t t;
1380    void *ret;
1381    pthread_create (&t, $1, func, 0);
1382    pthread_join (t, &ret);
1383    exit (check_me != 42 || ret != &check_me);
1384 }])
1385
1386 dnl
1387 dnl Test program for sched_get_priority_min()
1388 dnl
1389 m4_define([glib_sched_priority_test],[
1390 #include <sched.h>
1391 #include <errno.h>
1392 int main() {
1393     errno = 0;
1394     return sched_get_priority_min(SCHED_OTHER)==-1
1395            && errno != 0;
1396 }])
1397
1398 if test x"$have_threads" != xno; then
1399
1400   if test x"$have_threads" = xposix; then
1401     # First we test for posix, whether -pthread or -pthreads do the trick as
1402     # both CPPFLAG and LIBS.
1403     # One of them does for most gcc versions and some other platforms/compilers
1404     # too and could be considered as the canonical way to go.
1405     for flag in pthread pthreads; do
1406       glib_save_CFLAGS="$CFLAGS"
1407       CFLAGS="$CFLAGS -$flag"
1408       AC_TRY_RUN(glib_thread_test(0),
1409                  glib_flag_works=yes,
1410                  glib_flag_works=no,
1411                  [AC_LINK_IFELSE(glib_thread_test(0),
1412                                  glib_flag_works=yes,
1413                                  glib_flag_works=no)])
1414       CFLAGS="$glib_save_CFLAGS"
1415       if test $glib_flag_works = yes ; then
1416          G_THREAD_CFLAGS=-$flag
1417          G_THREAD_LIBS=-$flag
1418       fi
1419     done
1420   fi
1421
1422   if test x"$G_THREAD_CFLAGS" = x; then
1423
1424     # The canonical -pthread[s] does not work. Try something different.
1425
1426     case $host in
1427         *-aix*)
1428                 if test x"$GCC" = xyes; then
1429                         # GCC 3.0 and above needs -pthread.
1430                         # Should be coverd by the case above.
1431                         # GCC 2.x and below needs -mthreads
1432                         G_THREAD_CFLAGS="-mthreads"
1433                         G_THREAD_LIBS=$G_THREAD_CFLAGS
1434                 else
1435                         # We are probably using the aix compiler. Normaly a
1436                         # program would have to be compiled with the _r variant
1437                         # of the corresponding compiler, but we as GLib cannot
1438                         # do that: but the good news is that for compiling the
1439                         # only difference is the added -D_THREAD_SAFE compile
1440                         # option. This is according to the "C for AIX User's
1441                         # Guide".
1442                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
1443                 fi
1444                 ;;
1445         *-dg-dgux*)  # DG/UX
1446                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
1447                 ;;
1448         *-osf*)
1449                 # So we are using dce threads. posix threads are already
1450                 # catched above.
1451                 G_THREAD_CFLAGS="-threads"
1452                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1453                 ;;
1454         *-solaris*)
1455                 if test x"$GCC" = xyes; then
1456                    # We are using solaris threads. posix threads are
1457                    # already catched above.
1458                         G_THREAD_CFLAGS="-threads"
1459                 else
1460                         G_THREAD_CFLAGS="-mt"
1461                 fi
1462                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1463                 ;;
1464         *-sysv5uw7*) # UnixWare 7
1465                 # We are not using gcc with -pthread. Catched above.
1466                 G_THREAD_CFLAGS="-Kthread"
1467                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1468                 ;;
1469         *-mingw*)
1470                 # No flag needed when using MSVCRT.DLL
1471                 G_THREAD_CFLAGS=""
1472                 ;;
1473         *)
1474                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
1475                 ;;
1476     esac
1477
1478   fi
1479
1480     # if we are not finding the localtime_r function, then we probably are
1481     # not using the proper multithread flag
1482
1483     glib_save_CPPFLAGS="$CPPFLAGS"
1484     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1485
1486     # First we test, whether localtime_r is declared in time.h
1487     # directly. Then we test whether a macro localtime_r exists, in
1488     # which case localtime_r in the test program is replaced and thus
1489     # if we still find localtime_r in the output, it is not defined as
1490     # a macro.
1491
1492     AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
1493       [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
1494                                                            localtime_r(a,b)],
1495                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
1496
1497     CPPFLAGS="$glib_save_CPPFLAGS"
1498
1499     AC_MSG_CHECKING(thread related cflags)
1500     AC_MSG_RESULT($G_THREAD_CFLAGS)
1501     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1502 fi
1503
1504 dnl determination of G_THREAD_LIBS
1505 dnl ******************************
1506
1507 mutex_has_default=no
1508 case $have_threads in
1509         posix|dce)
1510           glib_save_CPPFLAGS="$CPPFLAGS"
1511           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1512           if test x"$G_THREAD_LIBS" = x; then
1513             case $host in
1514               *-aix*)
1515                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
1516                 # probably using the aix compiler.
1517                 AC_MSG_WARN($AIX_COMPILE_INFO)
1518                 ;;
1519               *)
1520                 G_THREAD_LIBS=error
1521                 glib_save_LIBS="$LIBS"
1522                 for thread_lib in "" pthread pthread32 pthreads thread dce; do
1523                         if test x"$thread_lib" = x; then
1524                                 add_thread_lib=""
1525                                 IN=""
1526                         else
1527                                 add_thread_lib="-l$thread_lib"
1528                                 IN=" in -l$thread_lib"
1529                         fi
1530                         if test x"$have_threads" = xposix; then
1531                                 defattr=0
1532                         else
1533                                 defattr=pthread_attr_default
1534                         fi
1535
1536                         LIBS="$add_thread_lib $glib_save_LIBS"
1537
1538                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
1539                         AC_TRY_RUN(glib_thread_test($defattr),
1540                                    glib_result=yes,
1541                                    glib_result=no,
1542                                    [AC_LINK_IFELSE(glib_thread_test($defattr),
1543                                                    glib_result=yes,
1544                                                    glib_result=no)])
1545                         AC_MSG_RESULT($glib_result)
1546
1547                         if test "$glib_result" = "yes" ; then
1548                           G_THREAD_LIBS="$add_thread_lib"
1549                           break
1550                         fi
1551                 done
1552                 if test "x$G_THREAD_LIBS" = xerror; then
1553                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1554                 fi
1555                 LIBS="$glib_save_LIBS"
1556                 ;;
1557             esac
1558           fi
1559
1560           glib_save_LIBS="$LIBS"
1561           for thread_lib in "" rt rte; do
1562             if test x"$thread_lib" = x; then
1563               add_thread_lib=""
1564               IN=""
1565             else
1566               add_thread_lib="-l$thread_lib"
1567               IN=" in -l$thread_lib"
1568             fi
1569             LIBS="$add_thread_lib $glib_save_LIBS"
1570
1571             AC_MSG_CHECKING(for sched_get_priority_min$IN)
1572             AC_TRY_RUN(glib_sched_priority_test,
1573                        glib_result=yes,
1574                        glib_result=no,
1575                        [AC_LINK_IFELSE(glib_sched_priority_test,
1576                                        glib_result=yes,
1577                                        glib_result=no)])
1578             AC_MSG_RESULT($glib_result)
1579
1580             if test "$glib_result" = "yes" ; then
1581                G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
1582                posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
1583                posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
1584                break
1585             fi
1586           done
1587           LIBS="$glib_save_LIBS"
1588           mutex_has_default=yes
1589           mutex_default_type='pthread_mutex_t'
1590           mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
1591           mutex_header_file='pthread.h'
1592           if test "x$have_threads" = "xposix"; then
1593             g_threads_impl="POSIX"
1594           else
1595             g_threads_impl="DCE"
1596             have_threads="posix"
1597           fi
1598           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
1599           CPPFLAGS="$glib_save_CPPFLAGS"
1600           ;;
1601         solaris)
1602            mutex_has_default=yes
1603            mutex_default_type='mutex_t'
1604            mutex_default_init="DEFAULTMUTEX"
1605            mutex_header_file='thread.h'
1606            g_threads_impl="SOLARIS"
1607            ;;
1608         win32)
1609            g_threads_impl="WIN32"
1610            ;;
1611         none|no)
1612            g_threads_impl="NONE"
1613            ;;
1614         *)
1615            g_threads_impl="NONE"
1616            G_THREAD_LIBS=error
1617            ;;
1618 esac
1619
1620 if test "x$G_THREAD_LIBS" = xerror; then
1621         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1622 fi
1623
1624 case $host in
1625   *-*-beos*)
1626     G_THREAD_LIBS="-lbe -lroot -lglib "
1627     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1628     ;;
1629   *)
1630     ;;
1631 esac
1632
1633 AC_MSG_CHECKING(thread related libraries)
1634 AC_MSG_RESULT($G_THREAD_LIBS)
1635
1636 dnl check for mt safe function variants and some posix functions
1637 dnl ************************************************************
1638
1639 if test x"$have_threads" != xno; then
1640         glib_save_LIBS="$LIBS"
1641         # we are not doing the following for now, as this might require glib
1642         # to always be linked with the thread libs on some platforms.
1643         # LIBS="$LIBS $G_THREAD_LIBS"
1644         AC_CHECK_FUNCS(localtime_r)
1645         if test "$ac_cv_header_pwd_h" = "yes"; then
1646                 AC_CACHE_CHECK([for posix getpwuid_r],
1647                         ac_cv_func_posix_getpwuid_r,
1648                         [AC_TRY_RUN([
1649 #include <errno.h>
1650 #include <pwd.h>
1651 int main () {
1652     char buffer[10000];
1653     struct passwd pwd, *pwptr = &pwd;
1654     int error;
1655     errno = 0;
1656     error = getpwuid_r (0, &pwd, buffer,
1657                         sizeof (buffer), &pwptr);
1658    return (error < 0 && errno == ENOSYS)
1659            || error == ENOSYS;
1660 }                               ],
1661                                 [ac_cv_func_posix_getpwuid_r=yes],
1662                                 [ac_cv_func_posix_getpwuid_r=no])])
1663                 GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
1664                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
1665                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
1666                                 [Have POSIX function getpwuid_r])
1667                 else
1668                         AC_CACHE_CHECK([for nonposix getpwuid_r],
1669                                 ac_cv_func_nonposix_getpwuid_r,
1670                                 [AC_TRY_LINK([#include <pwd.h>],
1671                                         [char buffer[10000];
1672                                         struct passwd pwd;
1673                                         getpwuid_r (0, &pwd, buffer,
1674                                                         sizeof (buffer));],
1675                                         [ac_cv_func_nonposix_getpwuid_r=yes],
1676                                         [ac_cv_func_nonposix_getpwuid_r=no])])
1677                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
1678                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
1679                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
1680                                         [Have non-POSIX function getpwuid_r])
1681                         fi
1682                 fi
1683         fi
1684         LIBS="$G_THREAD_LIBS $LIBS"
1685         if test x"$have_threads" = xposix; then
1686                 glib_save_CPPFLAGS="$CPPFLAGS"
1687                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1688                 dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
1689                 GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
1690                 # This is not AC_CHECK_FUNC to also work with function
1691                 # name mangling in header files.
1692                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
1693                 AC_TRY_LINK([#include <pthread.h>],
1694                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
1695                         [AC_MSG_RESULT(yes)
1696                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
1697                                   [Have function pthread_attr_setstacksize])],
1698                         [AC_MSG_RESULT(no)])
1699                 AC_MSG_CHECKING(for minimal/maximal thread priority)
1700                 if test x"$posix_priority_min" = x; then
1701                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
1702                                 PX_PRIO_MIN],,[
1703                                 posix_priority_min=PX_PRIO_MIN
1704                                 posix_priority_max=PX_PRIO_MAX])
1705                 fi
1706                 if test x"$posix_priority_min" = x; then
1707                         # AIX
1708                         AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
1709                                 PTHREAD_PRIO_MIN],,[
1710                                 posix_priority_min=PTHREAD_PRIO_MIN
1711                                 posix_priority_max=PTHREAD_PRIO_MAX])
1712                 fi
1713                 if test x"$posix_priority_min" = x; then
1714                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
1715                                 PRI_OTHER_MIN],,[
1716                                 posix_priority_min=PRI_OTHER_MIN
1717                                 posix_priority_max=PRI_OTHER_MAX])
1718                 fi
1719                 if test x"$posix_priority_min" = x; then
1720                         AC_MSG_RESULT(none found)
1721                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
1722                         posix_priority_min=-1
1723                         posix_priority_max=-1
1724                 else
1725                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
1726                         AC_MSG_CHECKING(for pthread_setschedparam)
1727                         AC_TRY_LINK([#include <pthread.h>],
1728                           [pthread_t t; pthread_setschedparam(t, 0, NULL)],
1729                           [AC_MSG_RESULT(yes)
1730                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
1731                            AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
1732                           [AC_MSG_RESULT(no)
1733                            AC_MSG_WARN($POSIX_NO_PRIORITIES)])
1734                 fi
1735                 posix_yield_func=none
1736                 AC_MSG_CHECKING(for posix yield function)
1737                 for yield_func in sched_yield pthread_yield_np pthread_yield \
1738                                                         thr_yield; do
1739                         AC_TRY_LINK([#include <pthread.h>],
1740                                 [$yield_func()],
1741                                 [posix_yield_func="$yield_func"
1742                                 break])
1743                 done
1744                 if test x"$posix_yield_func" = xnone; then
1745                         AC_MSG_RESULT(none found)
1746                         AC_MSG_WARN($POSIX_NO_YIELD)
1747                         posix_yield_func="g_usleep(1000)"
1748                 else
1749                         AC_MSG_RESULT($posix_yield_func)
1750                         posix_yield_func="$posix_yield_func()"
1751                 fi
1752                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
1753                 CPPFLAGS="$glib_save_CPPFLAGS"
1754
1755                 AC_CACHE_CHECK([whether to use the PID niceness surrogate for thread priorities],
1756                                glib_cv_use_pid_surrogate,
1757                  [AC_TRY_RUN([
1758 #include <pthread.h>
1759 #include <sys/types.h>
1760 #include <unistd.h>
1761 pid_t other_pid = 0;
1762
1763 void* func(void* data) {other_pid = getpid();}
1764 main()
1765 { pthread_t t;
1766   void *ret;
1767   pthread_create (&t, 0, func, NULL);
1768   pthread_join (t, &ret);
1769   exit (getpid()==other_pid ||
1770         $posix_priority_min != $posix_priority_max);
1771 }               ],
1772                 [glib_cv_use_pid_surrogate=yes],
1773                 [glib_cv_use_pid_surrogate=no],
1774                 [])])
1775           GLIB_ASSERT_SET(glib_cv_use_pid_surrogate)
1776           if test "$glib_cv_use_pid_surrogate" = "yes" ; then
1777             AC_DEFINE(G_THREAD_USE_PID_SURROGATE, 1,
1778                       [whether to use the PID niceness surrogate for thread priorities])
1779           fi
1780
1781         elif test x"$have_threads" = xwin32; then
1782                 # It's a pointer to a private struct
1783                 GLIB_SIZEOF(,struct _GThreadData *, system_thread)
1784         elif test x"$have_threads" = xsolaris; then
1785                 GLIB_SIZEOF([#include <thread.h>], thread_t, system_thread)
1786         fi
1787
1788         LIBS="$glib_save_LIBS"
1789
1790         # now spit out all the warnings.
1791         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
1792            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
1793                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
1794         fi
1795         if test "$ac_cv_func_localtime_r" != "yes"; then
1796                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
1797         fi
1798 fi
1799
1800 if test x"$glib_cv_sizeof_system_thread" = x; then
1801    # use a pointer as a fallback.
1802    GLIB_SIZEOF(,void *, system_thread)
1803 fi
1804
1805 #
1806 # Hack to deal with:
1807 #
1808 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
1809 #     building shared libraries with linux.
1810 #  b) libtool doesn't recognize -pthread as a library dependency.
1811 #
1812 case $host in
1813   *-*-linux*)
1814     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
1815     ;;
1816   *)
1817     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-Wc,-pthread/`"
1818     ;;
1819 esac
1820
1821 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
1822                    [Source file containing theread implementation])
1823 AC_SUBST(G_THREAD_CFLAGS)
1824 AC_SUBST(G_THREAD_LIBS)
1825 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
1826 AC_SUBST(G_THREAD_LIBS_EXTRA)
1827
1828 dnl **********************************************
1829 dnl *** GDefaultMutex setup and initialization ***
1830 dnl **********************************************
1831 dnl
1832 dnl if mutex_has_default = yes, we also got
1833 dnl mutex_default_type, mutex_default_init and mutex_header_file
1834 if test $mutex_has_default = yes ; then
1835         glib_save_CPPFLAGS="$CPPFLAGS"
1836         glib_save_LIBS="$LIBS"
1837         LIBS="$G_THREAD_LIBS $LIBS"
1838         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1839         GLIB_SIZEOF([#include <$mutex_header_file>],
1840                     $mutex_default_type,
1841                     gmutex)
1842         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
1843                            $mutex_default_type,
1844                            gmutex,
1845                            $glib_cv_sizeof_gmutex,
1846                            $mutex_default_init)
1847         if test x"$glib_cv_byte_contents_gmutex" = xno; then
1848                 mutex_has_default=no
1849         fi
1850         CPPFLAGS="$glib_save_CPPFLAGS"
1851         LIBS="$glib_save_LIBS"
1852 fi
1853
1854 dnl ****************************************
1855 dnl *** GLib POLL* compatibility defines ***
1856 dnl ****************************************
1857
1858 glib_poll_includes=["
1859 #include <sys/types.h>
1860 #include <sys/poll.h>
1861 "]
1862
1863 if test $ac_cv_header_sys_types_h = yes &&
1864    test $ac_cv_header_sys_poll_h = yes ; then
1865   glib_failed=false
1866   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
1867   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
1868   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
1869   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
1870   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
1871   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
1872   if $glib_failed ; then
1873     AC_MSG_ERROR([Could not determine values for POLL* constants])
1874   fi
1875 else
1876   glib_cv_value_POLLIN=1
1877   glib_cv_value_POLLOUT=4
1878   glib_cv_value_POLLPRI=2
1879   glib_cv_value_POLLERR=8
1880   glib_cv_value_POLLHUP=16
1881   glib_cv_value_POLLNVAL=32
1882 fi
1883
1884 dnl **********************
1885 dnl *** Win32 API libs ***
1886 dnl **********************
1887
1888 case $host in
1889   *-*-cygwin*)
1890         G_LIBS_EXTRA="-luser32 -lkernel32"
1891     ;;
1892   *-*-mingw*)
1893         G_LIBS_EXTRA="-lwsock32"
1894     ;;
1895   *)
1896         G_LIBS_EXTRA=""
1897     ;;
1898 esac
1899 AC_SUBST(G_LIBS_EXTRA)
1900
1901 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
1902 dnl since we need it for g_iconv()
1903
1904 AC_MSG_CHECKING([for EILSEQ])
1905 AC_TRY_COMPILE([
1906 #include <errno.h>
1907 ],
1908 [
1909 int error = EILSEQ;
1910 ], have_eilseq=yes, have_eilseq=no);
1911 AC_MSG_RESULT($have_eilseq)
1912
1913 dnl ******************************************************************
1914 dnl *** Look for glib-genmarshal in PATH if we are cross-compiling ***
1915 dnl ******************************************************************
1916
1917 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
1918
1919 if test $cross_compiling = yes; then
1920   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
1921   if test x$GLIB_GENMARSHAL = xno; then
1922     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
1923   fi
1924 fi
1925
1926 dnl **************************
1927 dnl *** Checks for gtk-doc ***
1928 dnl **************************
1929
1930 GTK_DOC_CHECK([1.0])
1931
1932 AC_ARG_ENABLE(man,
1933               [AC_HELP_STRING([--enable-man],
1934                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
1935               enable_man=no)
1936
1937 if test "${enable_man}" != no; then
1938 dnl
1939 dnl Check for xsltproc
1940 dnl
1941 AC_PATH_PROG([XSLTPROC], [xsltproc])
1942   if test -z "$XSLTPROC"; then
1943     enable_man=no
1944   fi
1945
1946   dnl check for DocBook DTD and stylesheets in the local catalog.
1947   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1948      [DocBook XML DTD V4.1.2],,enable_man=no)
1949   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1950      [DocBook XSL Stylesheets],,enable_man=no)
1951 fi
1952
1953 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1954
1955 dnl ******************************
1956 dnl *** output the whole stuff ***
1957 dnl ******************************
1958
1959 dnl this section will only be run if config.status is invoked with no
1960 dnl arguments, or with "glibconfig.h" as an argument.
1961 AC_CONFIG_COMMANDS([glibconfig.h],
1962 [
1963         outfile=glibconfig.h-tmp
1964         cat > $outfile <<\_______EOF
1965 /* glibconfig.h
1966  *
1967  * This is a generated file.  Please modify 'configure.in'
1968  */
1969
1970 #ifndef __G_LIBCONFIG_H__
1971 #define __G_LIBCONFIG_H__
1972
1973 #include <glib/gmacros.h>
1974
1975 _______EOF
1976
1977         if test x$glib_limits_h = xyes; then
1978           echo '#include <limits.h>' >> $outfile
1979         fi
1980         if test x$glib_float_h = xyes; then
1981           echo '#include <float.h>' >> $outfile
1982         fi
1983         if test x$glib_values_h = xyes; then
1984           echo '#include <values.h>' >> $outfile
1985         fi
1986         if test "$glib_header_alloca_h" = "yes"; then
1987           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
1988         fi
1989         if test x$glib_sys_poll_h = xyes; then
1990           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
1991         fi
1992
1993         cat >> $outfile <<_______EOF
1994
1995 G_BEGIN_DECLS
1996
1997 #define G_MINFLOAT      $glib_mf
1998 #define G_MAXFLOAT      $glib_Mf
1999 #define G_MINDOUBLE     $glib_md
2000 #define G_MAXDOUBLE     $glib_Md
2001 #define G_MINSHORT      $glib_ms
2002 #define G_MAXSHORT      $glib_Ms
2003 #define G_MAXUSHORT     $glib_Mus
2004 #define G_MININT        $glib_mi
2005 #define G_MAXINT        $glib_Mi
2006 #define G_MAXUINT       $glib_Mui
2007 #define G_MINLONG       $glib_ml
2008 #define G_MAXLONG       $glib_Ml
2009 #define G_MAXULONG      $glib_Mul
2010
2011 _______EOF
2012
2013
2014         ### this should always be true in a modern C/C++ compiler
2015         cat >>$outfile <<_______EOF
2016 typedef signed char gint8;
2017 typedef unsigned char guint8;
2018 _______EOF
2019
2020
2021         if test -n "$gint16"; then
2022           cat >>$outfile <<_______EOF
2023 typedef signed $gint16 gint16;
2024 typedef unsigned $gint16 guint16;
2025 #define G_GINT16_MODIFIER $gint16_modifier
2026 #define G_GINT16_FORMAT $gint16_format
2027 #define G_GUINT16_FORMAT $guint16_format
2028 _______EOF
2029         fi
2030
2031
2032         if test -n "$gint32"; then
2033           cat >>$outfile <<_______EOF
2034 typedef signed $gint32 gint32;
2035 typedef unsigned $gint32 guint32;
2036 #define G_GINT32_MODIFIER $gint32_modifier
2037 #define G_GINT32_FORMAT $gint32_format
2038 #define G_GUINT32_FORMAT $guint32_format
2039 _______EOF
2040         fi
2041
2042         cat >>$outfile <<_______EOF
2043 #define G_HAVE_GINT64 1          /* deprecated, always true */
2044
2045 ${glib_extension}typedef signed $gint64 gint64;
2046 ${glib_extension}typedef unsigned $gint64 guint64;
2047
2048 #define G_GINT64_CONSTANT(val)  $gint64_constant
2049 _______EOF
2050
2051         if test x$gint64_format != x ; then
2052           cat >>$outfile <<_______EOF
2053 #define G_GINT64_MODIFIER $gint64_modifier
2054 #define G_GINT64_FORMAT $gint64_format
2055 #define G_GUINT64_FORMAT $guint64_format
2056 _______EOF
2057         else
2058           cat >>$outfile <<_______EOF
2059 #undef G_GINT64_MODIFIER
2060 #undef G_GINT64_FORMAT
2061 #undef G_GUINT64_FORMAT
2062 _______EOF
2063         fi
2064
2065         cat >>$outfile <<_______EOF
2066
2067 #define GLIB_SIZEOF_VOID_P $glib_void_p
2068 #define GLIB_SIZEOF_LONG   $glib_long
2069 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2070
2071 _______EOF
2072
2073         cat >>$outfile <<_______EOF
2074 typedef signed $glib_size_type_define gssize;
2075 typedef unsigned $glib_size_type_define gsize;
2076 #define G_GSIZE_MODIFIER $gsize_modifier
2077 #define G_GSSIZE_FORMAT $gssize_format
2078 #define G_GSIZE_FORMAT $gsize_format
2079
2080 #define G_MAXSIZE       G_MAXU$glib_msize_type
2081 _______EOF
2082
2083         if test -z "$glib_unknown_void_p"; then
2084           cat >>$outfile <<_______EOF
2085
2086 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2087 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2088
2089 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2090 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2091 _______EOF
2092         else
2093           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2094         fi
2095
2096
2097
2098         cat >>$outfile <<_______EOF
2099 $glib_atexit
2100 $glib_memmove
2101 $glib_defines
2102 $glib_os
2103
2104 $glib_vacopy
2105
2106 #ifdef  __cplusplus
2107 #define G_HAVE_INLINE   1
2108 #else   /* !__cplusplus */
2109 $glib_inline
2110 #endif  /* !__cplusplus */
2111
2112 _______EOF
2113
2114         if test x$g_have_iso_c_varargs = xyes ; then
2115                 cat >>$outfile <<_______EOF
2116 #ifndef __cplusplus
2117 # define G_HAVE_ISO_VARARGS 1
2118 #endif
2119 _______EOF
2120         fi
2121         if test x$g_have_iso_cxx_varargs = xyes ; then
2122                 cat >>$outfile <<_______EOF
2123 #ifdef __cplusplus
2124 # define G_HAVE_ISO_VARARGS 1
2125 #endif
2126 _______EOF
2127         fi
2128         if test x$g_have_gnuc_varargs = xyes ; then
2129                 cat >>$outfile <<_______EOF
2130
2131 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2132  * is passed ISO vararg support is turned off, and there is no work
2133  * around to turn it on, so we unconditionally turn it off.
2134  */
2135 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2136 #  undef G_HAVE_ISO_VARARGS
2137 #endif
2138
2139 #define G_HAVE_GNUC_VARARGS 1
2140 _______EOF
2141         fi
2142
2143         case x$g_stack_grows in
2144         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2145         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2146         esac
2147
2148
2149         echo >>$outfile
2150         if test x$g_have_eilseq = xno; then
2151                 cat >>$outfile <<_______EOF
2152 #ifndef EILSEQ
2153 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
2154  * The correspondence between this and the corresponding definition
2155  * in libiconv is essential.
2156  */
2157 #  define EILSEQ ENOENT
2158 #endif
2159 _______EOF
2160
2161         fi
2162
2163         echo >>$outfile
2164         if test x$g_mutex_has_default = xyes; then
2165                 cat >>$outfile <<_______EOF
2166 $g_enable_threads_def G_THREADS_ENABLED
2167 #define G_THREADS_IMPL_$g_threads_impl_def
2168 typedef struct _GStaticMutex GStaticMutex;
2169 struct _GStaticMutex
2170 {
2171   struct _GMutex *runtime_mutex;
2172   union {
2173     char   pad[[$g_mutex_sizeof]];
2174     double dummy_double;
2175     void  *dummy_pointer;
2176     long   dummy_long;
2177   } static_mutex;
2178 };
2179 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
2180 #define g_static_mutex_get_mutex(mutex) \\
2181   (g_thread_use_default_impl ? ((GMutex*) &((mutex)->static_mutex)) : \\
2182    g_static_mutex_get_mutex_impl_shortcut (&((mutex)->runtime_mutex)))
2183 _______EOF
2184         else
2185                 cat >>$outfile <<_______EOF
2186 $g_enable_threads_def G_THREADS_ENABLED
2187 #define G_THREADS_IMPL_$g_threads_impl_def
2188 typedef struct _GMutex* GStaticMutex;
2189 #define G_STATIC_MUTEX_INIT NULL
2190 #define g_static_mutex_get_mutex(mutex) \\
2191   (g_static_mutex_get_mutex_impl_shortcut (mutex))
2192 _______EOF
2193         fi
2194
2195         if test x$g_use_double_checked_locking = xyes; then
2196                 cat >>$outfile <<_______EOF
2197 /* double checked locking can be used on this platform */
2198 #define g_once(once, func, arg) \\
2199   ((once)->status == G_ONCE_STATUS_READY ? (once)->retval : \\
2200    g_once_impl (once, func, arg))
2201 #define g_static_mutex_get_mutex_impl_shortcut(mutex) \\
2202   (*(mutex) ? *(mutex) : g_static_mutex_get_mutex_impl (mutex))
2203 _______EOF
2204         else
2205                 cat >>$outfile <<_______EOF
2206 /* double checked locking is unsafe to use on this platform, do full locking */
2207 #define g_once(once, func, arg) (g_once_impl(once, func, arg))
2208 #define g_static_mutex_get_mutex_impl_shortcut(mutex) \\
2209   (g_static_mutex_get_mutex_impl (mutex))
2210 _______EOF
2211 fi
2212
2213         cat >>$outfile <<_______EOF
2214 /* This represents a system thread as used by the implementation. An
2215  * alien implementaion, as loaded by g_thread_init can only count on
2216  * "sizeof (gpointer)" bytes to store their info. We however need more
2217  * for some of our native implementations. */
2218 typedef union _GSystemThread GSystemThread;
2219 union _GSystemThread
2220 {
2221   char   data[[$g_system_thread_sizeof]];
2222   double dummy_double;
2223   void  *dummy_pointer;
2224   long   dummy_long;
2225 };
2226 _______EOF
2227
2228         echo >>$outfile
2229         g_bit_sizes="16 32 64"
2230         for bits in $g_bit_sizes; do
2231           cat >>$outfile <<_______EOF
2232 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
2233 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
2234 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
2235 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
2236 _______EOF
2237         done
2238
2239         cat >>$outfile <<_______EOF
2240 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
2241 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
2242 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
2243 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
2244 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
2245 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
2246 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
2247 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
2248 #define G_BYTE_ORDER $g_byte_order
2249
2250 #define GLIB_SYSDEF_POLLIN =$g_pollin
2251 #define GLIB_SYSDEF_POLLOUT =$g_pollout
2252 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
2253 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
2254 #define GLIB_SYSDEF_POLLERR =$g_pollerr
2255 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
2256
2257 #define G_MODULE_SUFFIX "$g_module_suffix"
2258
2259 typedef $g_pid_type GPid;
2260
2261 G_END_DECLS
2262
2263 #endif /* GLIBCONFIG_H */
2264 _______EOF
2265
2266
2267         if cmp -s $outfile glibconfig.h; then
2268           AC_MSG_NOTICE([glibconfig.h is unchanged])
2269           rm -f $outfile
2270         else
2271           mv $outfile glibconfig.h
2272         fi
2273 ],[
2274
2275 # Note that if two cases are the same, case goes with the first one.
2276 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
2277 # on variable expansion in case labels.  Look at the generated config.status
2278 # for a hint.
2279
2280 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
2281   glib_header_alloca_h="$ac_cv_working_alloca_h"
2282 else
2283   glib_header_alloca_h="$ac_cv_header_alloca_h"
2284 fi
2285
2286 case xyes in
2287 x$ac_cv_header_float_h)
2288   glib_float_h=yes
2289   glib_mf=FLT_MIN glib_Mf=FLT_MAX
2290   glib_md=DBL_MIN glib_Md=DBL_MAX
2291   ;;
2292 x$ac_cv_header_values_h)
2293   glib_values_h=yes
2294   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
2295   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
2296   ;;
2297 esac
2298
2299 case xyes in
2300 x$ac_cv_header_limits_h)
2301   glib_limits_h=yes
2302   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
2303   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
2304   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
2305   ;;
2306 x$ac_cv_header_values_h)
2307   glib_values_h=yes
2308   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
2309   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
2310   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
2311   ;;
2312 esac
2313
2314 if test x$ac_cv_header_sys_poll_h = xyes ; then
2315   glib_sys_poll_h=yes
2316 fi
2317
2318 case 2 in
2319 $ac_cv_sizeof_short)
2320   gint16=short
2321   gint16_modifier='"h"'
2322   gint16_format='"hi"'
2323   guint16_format='"hu"'
2324   ;;
2325 $ac_cv_sizeof_int)
2326   gint16=int
2327   gint16_modifier='""'
2328   gint16_format='"i"'
2329   guint16_format='"u"'
2330   ;;
2331 esac
2332 case 4 in
2333 $ac_cv_sizeof_short)
2334   gint32=short
2335   gint32_modifier='"h"'
2336   gint32_format='"hi"'
2337   guint32_format='"hu"'
2338   ;;
2339 $ac_cv_sizeof_int)
2340   gint32=int
2341   gint32_modifier='""'
2342   gint32_format='"i"'
2343   guint32_format='"u"'
2344   ;;
2345 $ac_cv_sizeof_long)
2346   gint32=long
2347   gint32_modifier='"l"'
2348   gint32_format='"li"'
2349   guint32_format='"lu"'
2350   ;;
2351 esac
2352 case 8 in
2353 $ac_cv_sizeof_int)
2354   gint64=int
2355   gint64_modifier='""'
2356   gint64_format='"i"'
2357   guint64_format='"u"'
2358   glib_extension=
2359   gint64_constant='(val)'
2360   ;;
2361 $ac_cv_sizeof_long)
2362   gint64=long
2363   gint64_modifier='"l"'
2364   gint64_format='"li"'
2365   guint64_format='"lu"'
2366   glib_extension=
2367   gint64_constant='(val##L)'
2368   ;;
2369 $ac_cv_sizeof_long_long)
2370   gint64='long long'
2371   if test -n "$glib_cv_long_long_format"; then
2372     gint64_modifier='"'$glib_cv_long_long_format'"'
2373     gint64_format='"'$glib_cv_long_long_format'i"'
2374     guint64_format='"'$glib_cv_long_long_format'u"'
2375   fi
2376   glib_extension='G_GNUC_EXTENSION '
2377   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
2378   ;;
2379 $ac_cv_sizeof___int64)
2380   gint64='__int64'
2381   if test -n "$glib_cv_long_long_format"; then
2382     gint64_modifier='"'$glib_cv_long_long_format'"'
2383     gint64_format='"'$glib_cv_long_long_format'i"'
2384     guint64_format='"'$glib_cv_long_long_format'u"'
2385   fi
2386   glib_extension=
2387   gint64_constant='(val##i64)'
2388   ;;
2389 esac
2390 glib_size_t=$ac_cv_sizeof_size_t
2391 glib_size_type_define=$glib_size_type
2392 glib_void_p=$ac_cv_sizeof_long
2393 glib_long=$ac_cv_sizeof_void_p
2394
2395 case $glib_size_type in
2396 short)
2397   gsize_modifier='"h"'
2398   gsize_format='"hu"'
2399   gssize_format='"hi"'
2400   glib_msize_type='SHRT'
2401   ;;
2402 int)
2403   gsize_modifier='""'
2404   gsize_format='"u"'
2405   gssize_format='"i"'
2406   glib_msize_type='INT'
2407   ;;
2408 long)
2409   gsize_modifier='"l"'
2410   gsize_format='"lu"'
2411   gssize_format='"li"'
2412   glib_msize_type='LONG'
2413   ;;
2414 esac
2415
2416 gintbits=`expr $ac_cv_sizeof_int \* 8`
2417 glongbits=`expr $ac_cv_sizeof_long \* 8`
2418
2419
2420 case $ac_cv_sizeof_void_p in
2421 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
2422 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
2423 *)                      glib_unknown_void_p=yes ;;
2424 esac
2425
2426
2427 case xyes in
2428 x$ac_cv_func_atexit)
2429   glib_atexit="
2430 #ifdef NeXT /* @#%@! NeXTStep */
2431 # define g_ATEXIT(proc) (!atexit (proc))
2432 #else
2433 # define g_ATEXIT(proc) (atexit (proc))
2434 #endif"
2435   ;;
2436 x$ac_cv_func_on_exit)
2437   glib_atexit="
2438 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
2439   ;;
2440 esac
2441
2442 case xyes in
2443 x$ac_cv_func_memmove)
2444   glib_memmove='
2445 #define g_memmove(d,s,n) G_STMT_START { memmove ((d), (s), (n)); } G_STMT_END'
2446   ;;
2447 x$glib_cv_working_bcopy)
2448   glib_memmove="
2449 /* memmove isn't available, but bcopy can copy overlapping memory regions */
2450 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
2451   ;;
2452 *)
2453   glib_memmove="
2454 /* memmove isn't found and bcopy can't copy overlapping memory regions,
2455  * so we have to roll our own copy routine. */
2456 void g_memmove (void* dest, const void * src, unsigned long len);"
2457   ;;
2458 esac
2459
2460 glib_defines="
2461 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
2462 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
2463 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
2464 "
2465
2466 case xyes in
2467 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
2468 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
2469 *)                      glib_vacopy=''
2470 esac
2471
2472 if test x$glib_cv_va_val_copy = xno; then
2473   glib_vacopy="\$glib_vacopy
2474 #define G_VA_COPY_AS_ARRAY 1"
2475 fi
2476
2477 if test x$glib_cv_hasinline = xyes; then
2478     glib_inline='#define G_HAVE_INLINE 1'
2479 fi
2480 if test x$glib_cv_has__inline = xyes; then
2481     glib_inline="\$glib_inline
2482 #define G_HAVE___INLINE 1"
2483 fi
2484 if test x$glib_cv_has__inline__ = xyes; then
2485     glib_inline="\$glib_inline
2486 #define G_HAVE___INLINE__ 1"
2487 fi
2488
2489 g_have_gnuc_varargs=$g_have_gnuc_varargs
2490 g_have_iso_c_varargs=$g_have_iso_c_varargs
2491 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
2492
2493 case xyes in
2494 x$ac_cv_c_bigendian)
2495   g_byte_order=G_BIG_ENDIAN
2496   g_bs_native=BE
2497   g_bs_alien=LE
2498   ;;
2499 *)
2500   g_byte_order=G_LITTLE_ENDIAN
2501   g_bs_native=LE
2502   g_bs_alien=BE
2503   ;;
2504 esac
2505
2506 g_pollin=$glib_cv_value_POLLIN
2507 g_pollout=$glib_cv_value_POLLOUT
2508 g_pollpri=$glib_cv_value_POLLPRI
2509 g_pollhup=$glib_cv_value_POLLHUP
2510 g_pollerr=$glib_cv_value_POLLERR
2511 g_pollnval=$glib_cv_value_POLLNVAL
2512
2513 g_stack_grows=$glib_cv_stack_grows
2514
2515 g_have_eilseq=$have_eilseq
2516
2517 case x$have_threads in
2518 xno)    g_enable_threads_def="#undef";;
2519 *)      g_enable_threads_def="#define";;
2520 esac
2521
2522 g_threads_impl_def=$g_threads_impl
2523 g_use_double_checked_locking=$g_use_double_checked_locking
2524
2525 g_mutex_has_default="$mutex_has_default"
2526 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
2527 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
2528 g_mutex_contents="$glib_cv_byte_contents_gmutex"
2529
2530 g_module_suffix="$glib_gmodule_suffix"
2531
2532 g_pid_type="$glib_pid_type"
2533 case $host in
2534   *-*-beos*)
2535     glib_os="#define G_OS_BEOS"
2536     ;;
2537   *-*-cygwin*)
2538     glib_os="#define G_OS_UNIX
2539 #define G_PLATFORM_WIN32
2540 #define G_WITH_CYGWIN"
2541     ;;
2542   *-*-mingw*)
2543     glib_os="#define G_OS_WIN32
2544 #define G_PLATFORM_WIN32"
2545     ;;
2546   *)
2547     glib_os="#define G_OS_UNIX"
2548     ;;
2549 esac
2550 ])
2551
2552 AC_CONFIG_FILES([
2553 glib-2.0.pc
2554 glib-2.0-uninstalled.pc
2555 gmodule-2.0.pc
2556 gmodule-2.0-uninstalled.pc
2557 gthread-2.0.pc
2558 gthread-2.0-uninstalled.pc
2559 gobject-2.0.pc
2560 gobject-2.0-uninstalled.pc
2561 glib-zip
2562 glib-gettextize
2563 Makefile
2564 build/Makefile
2565 build/win32/Makefile
2566 build/win32/dirent/Makefile
2567 glib/Makefile
2568 glib/libcharset/Makefile
2569 glib/gnulib/Makefile
2570 gmodule/Makefile
2571 gmodule/gmoduleconf.h
2572 gobject/Makefile
2573 gobject/glib-mkenums
2574 gthread/Makefile
2575 po/Makefile.in
2576 docs/Makefile
2577 docs/reference/Makefile
2578 docs/reference/glib/Makefile
2579 docs/reference/glib/version.xml
2580 docs/reference/gobject/Makefile
2581 docs/reference/gobject/version.xml
2582 tests/Makefile
2583 tests/gobject/Makefile
2584 m4macros/Makefile
2585 ])
2586
2587 AC_CONFIG_COMMANDS([chmod-scripts],
2588 [chmod 0755 glib-zip
2589 chmod 0755 glib-gettextize
2590 chmod 0755 gobject/glib-mkenums])
2591
2592 # we want to invoke this macro solely so that the config.status script
2593 # and automake generated makefiles know about these generated files.
2594 # They are only needed to distcheck the package
2595 if false; then
2596   AC_CONFIG_FILES([
2597     INSTALL
2598     README
2599     config.h.win32
2600     glibconfig.h.win32
2601     glib/makefile.mingw
2602     glib/makefile.msc
2603     glib/glib.rc
2604     gmodule/makefile.mingw
2605     gmodule/makefile.msc
2606     gmodule/gmodule.rc
2607     gobject/makefile.mingw
2608     gobject/makefile.msc
2609     gobject/gobject.rc
2610     gthread/makefile.mingw
2611     gthread/makefile.msc
2612     gthread/gthread.rc
2613     tests/makefile.mingw
2614     tests/makefile.msc
2615   ])
2616 fi
2617
2618 AC_OUTPUT