configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 # require autoconf 2.54
   3 AC_PREREQ(2.54)
   4
   5 dnl ***********************************
   6 dnl *** include special GLib macros ***
   7 dnl ***********************************
   8
   9 m4_define(glib_configure_in)
  10 m4_include(acglib.m4)dnl
  11 m4_include(glib/libcharset/codeset.m4)dnl
  12 m4_include(glib/libcharset/glibc21.m4)dnl
  13 m4_include(m4macros/glib-gettext.m4)dnl
  14
  15 #
  16 # The following version number definitions apply to GLib, GModule, GObject
  17 # and GThread as a whole, so if changes occoured in any of them, they are all
  18 # treated with the same interface and binary age.
  19 #
  20 # Making releases:
  21 #   glib_micro_version += 1;
  22 #   glib_interface_age += 1;
  23 #   glib_binary_age += 1;
  24 # if any functions have been added, set glib_interface_age to 0.
  25 # if backwards compatibility has been broken,
  26 # set glib_binary_age _and_ glib_interface_age to 0.
  27 #
  28 m4_define([glib_major_version], [2])
  29 m4_define([glib_minor_version], [9])
  30 m4_define([glib_micro_version], [5])
  31 m4_define([glib_interface_age], [3])
  32 m4_define([glib_binary_age],
  33           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  34 m4_define([glib_version],
  35           [glib_major_version.glib_minor_version.glib_micro_version])
  36
  37 # libtool version related macros
  38 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  39 m4_define([glib_lt_current],
  40           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  41 m4_define([glib_lt_revision], [glib_interface_age])
  42 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  43 m4_define([glib_lt_current_minus_age],
  44           [m4_eval(glib_lt_current - glib_lt_age)])
  45
  46 # if the minor version number is odd, then we want debugging.  Otherwise
  47 # we only want minimal debugging support.
  48 m4_define([glib_debug_default],
  49           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  50
  51
  52 AC_INIT(glib, [glib_version],
  53         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  54
  55 AC_CONFIG_SRCDIR([glib/glib.h])
  56
  57 # Save this value here, since automake will set cflags later
  58 cflags_set=${CFLAGS+set}
  59
  60 AM_INIT_AUTOMAKE([no-define])
  61
  62 # Specify a configuration file
  63 AM_CONFIG_HEADER([config.h])
  64
  65
  66 GLIB_MAJOR_VERSION=glib_major_version
  67 GLIB_MINOR_VERSION=glib_minor_version
  68 GLIB_MICRO_VERSION=glib_micro_version
  69 GLIB_INTERFACE_AGE=glib_interface_age
  70 GLIB_BINARY_AGE=glib_binary_age
  71 GLIB_VERSION=glib_version
  72
  73 AC_SUBST(GLIB_MAJOR_VERSION)
  74 AC_SUBST(GLIB_MINOR_VERSION)
  75 AC_SUBST(GLIB_MICRO_VERSION)
  76 AC_SUBST(GLIB_VERSION)
  77 AC_SUBST(GLIB_INTERFACE_AGE)
  78 AC_SUBST(GLIB_BINARY_AGE)
  79
  80 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  81           [Define to the GLIB major version])
  82 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  83           [Define to the GLIB minor version])
  84 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  85           [Define to the GLIB micro version])
  86 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  87           [Define to the GLIB interface age])
  88 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  89           [Define to the GLIB binary age])
  90
  91 # libtool versioning
  92 LT_RELEASE=glib_lt_release
  93 LT_CURRENT=glib_lt_current
  94 LT_REVISION=glib_lt_revision
  95 LT_AGE=glib_lt_age
  96 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
  97 AC_SUBST(LT_RELEASE)
  98 AC_SUBST(LT_CURRENT)
  99 AC_SUBST(LT_REVISION)
 100 AC_SUBST(LT_AGE)
 101 AC_SUBST(LT_CURRENT_MINUS_AGE)
 102
 103 dnl Initialize maintainer mode
 104 AM_MAINTAINER_MODE
 105
 106 AC_CANONICAL_HOST
 107
 108 AC_MSG_CHECKING([for the BeOS])
 109 case $host in
 110   *-*-beos*)
 111     glib_native_beos="yes"
 112     ;;
 113   *)
 114     glib_native_beos="no"
 115     ;;
 116 esac
 117 AC_MSG_RESULT([$glib_native_beos])
 118
 119 dnl
 120
 121 AC_MSG_CHECKING([for Win32])
 122 case "$host" in
 123   *-*-mingw*)
 124     glib_native_win32=yes
 125     GLIB_DEF=glib.def
 126     GMODULE_DEF=gmodule.def
 127     GOBJECT_DEF=gobject.def
 128     GTHREAD_DEF=gthread.def
 129     TESTGMODULE_EXP=testgmodule.exp
 130     glib_pid_type='void *'
 131     ;;
 132   *)
 133     glib_native_win32=no
 134     GLIB_DEF=
 135     GMODULE_DEF=
 136     GOBJECT_DEF=
 137     GTHREAD_DEF=
 138     TESTGMODULE_EXP=
 139     glib_pid_type=int
 140     ;;
 141 esac
 142 case $host in
 143   *-*-linux*)
 144     glib_os_linux=yes
 145     ;;
 146 esac
 147
 148
 149 AC_MSG_RESULT([$glib_native_win32])
 150 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 151 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 152 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 153 AC_SUBST(GLIB_DEF)
 154 AC_SUBST(GMODULE_DEF)
 155 AC_SUBST(GOBJECT_DEF)
 156 AC_SUBST(GTHREAD_DEF)
 157 AC_SUBST(TESTGMODULE_EXP)
 158
 159 if test "$glib_native_win32" = "yes"; then
 160   AC_CHECK_TOOL(WINDRES, windres, no)
 161   if test "$WINDRES" = no; then
 162     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 163   fi
 164   AC_CHECK_TOOL(NM, nm, no)
 165   if test "$NM" = no; then
 166     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 167   fi
 168   AC_CHECK_TOOL(RANLIB, ranlib, :)
 169   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 170 fi
 171 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 172
 173 if test "$glib_native_win32" != yes; then
 174     # libtool option to control which symbols are exported
 175     # right now, symbols starting with _ are not exported
 176     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 177 else
 178     # We currently use .def files on Windows
 179     LIBTOOL_EXPORT_OPTIONS=
 180 fi
 181 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 182
 183 dnl declare --enable-* args and collect ac_help strings
 184 AC_ARG_ENABLE(debug,
 185               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 186                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 187               enable_debug=glib_debug_default)
 188
 189 AC_ARG_ENABLE(gc_friendly,
 190               [AC_HELP_STRING([--enable-gc-friendly],
 191                               [turn on garbage collector friendliness [default=no]])],,
 192               [enable_gc_friendly=no])
 193 AC_ARG_ENABLE(mem_pools,
 194               [AC_HELP_STRING([--disable-mem-pools],
 195                               [disable all glib memory pools])],,
 196               [disable_mem_pools=no])
 197 AC_ARG_ENABLE(threads,
 198               [AC_HELP_STRING([--enable-threads],
 199                               [turn on basic thread support [default=yes]
 200 ([=no] will override --with-threads)])],,
 201               [enable_threads=yes])
 202 AC_ARG_ENABLE(rebuilds,
 203               [AC_HELP_STRING([--disable-rebuilds],
 204                               [disable all source autogeneration rules])],,
 205               [enable_rebuilds=yes])
 206 AC_ARG_ENABLE(visibility,
 207               [AC_HELP_STRING([--disable-visibility],
 208                               [don't use ELF visibility attributes])],,
 209               [enable_visibility=yes])
 210
 211 if test "x$enable_threads" != "xyes"; then
 212   enable_threads=no
 213 fi
 214
 215 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, ["${enable_debug}"],
 216         [Whether glib was compiled with debugging enabled])
 217
 218 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 219 if test "x$enable_gc_friendly" = "xyes"; then
 220   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 221   AC_MSG_RESULT([yes])
 222 else
 223   AC_MSG_RESULT([no])
 224 fi
 225
 226 AC_MSG_CHECKING([whether to disable memory pools])
 227 if test "x$disable_mem_pools" = "xno"; then
 228   AC_MSG_RESULT([no])
 229 else
 230   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 231   AC_SUBST(DISABLE_MEM_POOLS)
 232   AC_MSG_RESULT([yes])
 233 fi
 234
 235 if test "$glib_native_win32" = "yes"; then
 236   if test x$enable_static = xyes -o x$enable_static = x; then
 237     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 238     enable_static=no
 239   fi
 240   if test x$enable_shared = xno; then
 241     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 242   fi
 243   enable_shared=yes
 244 fi
 245
 246 dnl Checks for programs.
 247 AC_PROG_CC
 248
 249 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 250 AC_CHECK_PROGS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 251 AC_LANG_SAVE
 252 AC_LANG_CPLUSPLUS
 253 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 254 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 255 AC_LANG_RESTORE
 256
 257 AM_PROG_CC_STDC
 258 AC_PROG_INSTALL
 259
 260 AC_SYS_LARGEFILE
 261
 262 #
 263 # Find pkg-config
 264 #
 265 AC_PATH_PROG(PKG_CONFIG, [pkg-config], [no])
 266 if test x$PKG_CONFIG = xno ; then
 267   AC_MSG_ERROR([*** pkg-config not found. See http://www.freedesktop.org/software/pkgconfig/])
 268 fi
 269
 270 if $PKG_CONFIG --atleast-pkgconfig-version 0.14 ; then
 271   :
 272 else
 273   AC_MSG_ERROR([*** pkg-config too old; version 0.14 or better required.])
 274 fi
 275
 276 if test "x$enable_debug" = "xyes"; then
 277   if test x$cflags_set != xset ; then
 278       case " $CFLAGS " in
 279       *[[\ \    ]]-g[[\ \       ]]*) ;;
 280       *) CFLAGS="$CFLAGS -g" ;;
 281       esac
 282   fi
 283
 284   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 285 else
 286   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 287
 288   if test "x$enable_debug" = "xno"; then
 289     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 290   fi
 291 fi
 292
 293 if test "x$enable_visibility" = "xno"; then
 294   GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DDISABLE_VISIBILITY"
 295 fi
 296
 297 # Ensure MSVC-compatible struct packing convention is used when
 298 # compiling for Win32 with gcc.
 299 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 300 # gcc2 uses "-fnative-struct".
 301 if test x"$glib_native_win32" = xyes; then
 302   if test x"$GCC" = xyes; then
 303     msnative_struct=''
 304     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 305     if test -z "$ac_cv_prog_CC"; then
 306       our_gcc="$CC"
 307     else
 308       our_gcc="$ac_cv_prog_CC"
 309     fi
 310     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 311       2.)
 312         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 313           msnative_struct='-fnative-struct'
 314         fi
 315         ;;
 316       *)
 317         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 318           msnative_struct='-mms-bitfields'
 319         fi
 320         ;;
 321     esac
 322     if test x"$msnative_struct" = x ; then
 323       AC_MSG_RESULT([no way])
 324       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 325     else
 326       CFLAGS="$CFLAGS $msnative_struct"
 327       AC_MSG_RESULT([${msnative_struct}])
 328     fi
 329   fi
 330 fi
 331
 332 AC_EXEEXT
 333
 334 # define a MAINT-like variable REBUILD which is set if Perl
 335 # and awk are found, so autogenerated sources can be rebuilt
 336 AC_PROG_AWK
 337 AC_CHECK_PROGS(PERL, [perl5 perl])
 338 # We would like indent, but don't require it.
 339 AC_CHECK_PROG(INDENT, indent, indent)
 340 REBUILD=\#
 341 if test "x$enable_rebuilds" = "xyes" && \
 342      test -n "$PERL" && \
 343      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 344      test -n "$AWK" ; then
 345   REBUILD=
 346 fi
 347 AC_SUBST(REBUILD)
 348
 349 # Need full path to Perl for glib-mkenums
 350 #
 351 if test "x$PERL" != x ; then
 352   AC_PATH_PROG(PERL_PATH, [$PERL])
 353 else
 354   PERL_PATH="/usr/bin/env perl"
 355 fi
 356 AC_SUBST(PERL_PATH)
 357
 358 dnl ***********************
 359 dnl *** Tests for iconv ***
 360 dnl ***********************
 361 dnl
 362 dnl We do this before the gettext checks, to avoid distortion
 363
 364 AC_ARG_WITH(libiconv,
 365             [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 366                             [use the libiconv library])],,
 367             [with_libiconv=maybe])
 368
 369 found_iconv=no
 370 case $with_libiconv in
 371   maybe)
 372     # Check in the C library first
 373     AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 374     # Check if we have GNU libiconv
 375     if test $found_iconv = "no"; then
 376       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 377     fi
 378     # Check if we have a iconv in -liconv, possibly from vendor
 379     if test $found_iconv = "no"; then
 380       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 381     fi
 382     ;;
 383   no)
 384     AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 385     ;;
 386   gnu|yes)
 387     AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 388     ;;
 389   native)
 390     AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 391     ;;
 392 esac
 393
 394 if test "x$found_iconv" = "xno" ; then
 395    AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 396 fi
 397
 398 jm_GLIBC21
 399 AC_ARG_ENABLE(iconv-cache,
 400               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 401                               [cache iconv descriptors [default=auto]])],,
 402               [enable_iconv_cache=auto])
 403
 404 AC_MSG_CHECKING([Whether to cache iconv descriptors])
 405 case $enable_iconv_cache in
 406   auto)
 407     if test $ac_cv_gnu_library_2_1 = yes; then
 408       enable_iconv_cache=no
 409     else
 410       enable_iconv_cache=yes
 411     fi
 412   ;;
 413   yes|no)
 414   ;;
 415   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 416   ;;
 417 esac
 418
 419 if test $enable_iconv_cache = yes; then
 420    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 421 fi
 422
 423 AC_MSG_RESULT($enable_iconv_cache)
 424
 425
 426 dnl
 427 dnl gettext support
 428 dnl
 429
 430 ALL_LINGUAS="am ar az be bg bn bs ca cs cy da de el en_CA en_GB eo es et eu fa fi fr ga gl gu he hi hr hu id is it ja ko ku lt lv mk ml mn ms nb ne nl nn no or pa pl pt pt_BR ro ru rw sk sl sq sr sr@Latn sr@ije sv ta te th tl tr tt uk vi wa xh yi zh_CN zh_HK zh_TW"
 431 GLIB_GNU_GETTEXT
 432
 433 if test "$gt_cv_have_gettext" != "yes" ; then
 434   AC_MSG_ERROR([
 435 *** You must have either have gettext support in your C library, or use the
 436 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 437 ])
 438 fi
 439
 440 LIBS="$INTLLIBS $LIBS"
 441
 442 GETTEXT_PACKAGE=glib20
 443 AC_SUBST(GETTEXT_PACKAGE)
 444 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 445   [Define the gettext package to be used])
 446
 447 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 448
 449 dnl
 450 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 451 dnl
 452
 453 if test x$with_libiconv != xno ; then
 454   case " $INTLLIBS " in
 455   *[[\ \        ]]-liconv[[\ \  ]]*) ;;
 456   *) ICONV_LIBS="-liconv" ;;
 457   esac
 458 fi
 459 AC_SUBST(ICONV_LIBS)
 460
 461 case $with_libiconv in
 462   gnu)
 463     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 464     ;;
 465   native)
 466     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 467     ;;
 468 esac
 469
 470 dnl Initialize libtool
 471 AM_DISABLE_STATIC
 472 AC_LIBTOOL_WIN32_DLL
 473 AM_PROG_LIBTOOL
 474
 475 if test "x$GCC" = "xyes"; then
 476   case " $CFLAGS " in
 477   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 478   *) CFLAGS="$CFLAGS -Wall" ;;
 479   esac
 480 fi
 481
 482 dnl
 483 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 484 dnl
 485 if test $cross_compiling != yes ; then
 486     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 487     glib_save_LIBS=$LIBS
 488     LIBS="$LIBS -lm"
 489     AC_TRY_RUN([#include <math.h>
 490                  int main (void) { return (log(1) != log(1.)); }],
 491          AC_MSG_RESULT(none needed),
 492          glib_save_CFLAGS=$CFLAGS
 493          CFLAGS="$CFLAGS -std1"
 494          AC_TRY_RUN([#include <math.h>
 495                      int main (void) { return (log(1) != log(1.)); }],
 496              AC_MSG_RESULT(-std1),
 497              AC_MSG_RESULT()
 498              CFLAGS=$glib_save_CFLAGS
 499              AC_MSG_WARN(
 500                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 501          )
 502     )
 503     LIBS=$glib_save_LIBS
 504 fi
 505
 506 dnl NeXTStep cc seems to need this
 507 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 508 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 509   AC_MSG_RESULT(none needed),
 510   glib_save_CFLAGS=$CFLAGS
 511   CFLAGS="$CFLAGS -posix"
 512   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 513     AC_MSG_RESULT(-posix),
 514     AC_MSG_RESULT()
 515     CFLAGS=$glib_save_CFLAGS
 516     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 517
 518 # Checks for header files.
 519 AC_HEADER_STDC
 520
 521 # Checks for library functions.
 522 AC_FUNC_VPRINTF
 523 AC_FUNC_MMAP
 524 AC_FUNC_ALLOCA
 525 AC_CHECK_FUNCS(posix_memalign)
 526 AC_CHECK_FUNCS(memalign)
 527 AC_CHECK_FUNCS(valloc)
 528
 529 AC_CHECK_FUNCS(atexit on_exit)
 530
 531 AC_CHECK_SIZEOF(char)
 532 AC_CHECK_SIZEOF(short)
 533 AC_CHECK_SIZEOF(long)
 534 AC_CHECK_SIZEOF(int)
 535 AC_CHECK_SIZEOF(void *)
 536 AC_CHECK_SIZEOF(long long)
 537 AC_CHECK_SIZEOF(__int64)
 538
 539 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 540   :
 541 else
 542   AC_MSG_ERROR([
 543 *** GLib requires a 64 bit type. You might want to consider
 544 *** using the GNU C compiler.
 545 ])
 546 fi
 547
 548 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 549         # long long is a 64 bit integer.
 550         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 551         AC_CACHE_VAL(glib_cv_long_long_format,[
 552                 for format in ll q I64; do
 553                   AC_TRY_RUN([#include <stdio.h>
 554                         int main()
 555                         {
 556                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 557                           char buffer[1000];
 558                           sprintf (buffer, "%${format}u", a);
 559                           sscanf (buffer, "%${format}u", &b);
 560                           exit (b!=a);
 561                         }
 562                         ],
 563                         [glib_cv_long_long_format=${format}
 564                         break],
 565                         [],[:])
 566                 done])
 567         if test -n "$glib_cv_long_long_format"; then
 568           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 569           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 570           if test x"$glib_cv_long_long_format" = xI64; then
 571             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 572           fi
 573         else
 574           AC_MSG_RESULT(none)
 575         fi
 576 elif test x$ac_cv_sizeof___int64 = x8; then
 577         # __int64 is a 64 bit integer.
 578         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 579         # We know this is MSVCRT.DLL, and what the formats are
 580         glib_cv_long_long_format=I64
 581         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 582         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 583         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 584 fi
 585
 586 dnl long doubles were not used, and a portability problem
 587 dnl AC_C_LONG_DOUBLE
 588 AC_C_CONST
 589
 590 dnl ok, here we try to check whether the systems prototypes for
 591 dnl malloc and friends actually match the prototypes provided
 592 dnl by gmem.h (keep in sync). i currently only know how to check
 593 dnl this reliably with gcc (-Werror), improvements for other
 594 dnl compilers are apprechiated.
 595 SANE_MALLOC_PROTOS=no
 596 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 597 glib_save_CFLAGS=$CFLAGS
 598 if test "x$GCC" = "xyes"; then
 599   CFLAGS="$CFLAGS -Werror"
 600   AC_TRY_COMPILE([#include <stdlib.h>], [
 601     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 602     void* (*my_malloc_p)  (size_t)         = malloc;
 603     void  (*my_free_p)    (void*)          = free;
 604     void* (*my_realloc_p) (void*, size_t)  = realloc;
 605     my_calloc_p = 0;
 606     my_malloc_p = 0;
 607     my_free_p = 0;
 608     my_realloc_p = 0;
 609   ],
 610     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 611       [Define if you have correct malloc prototypes])
 612     SANE_MALLOC_PROTOS=yes)
 613 fi
 614 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 615 CFLAGS=$glib_save_CFLAGS
 616
 617 dnl
 618 dnl check in which direction the stack grows
 619 dnl
 620 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 621         AC_TRY_RUN([
 622         volatile int *a = 0, *b = 0;
 623         void foo (void);
 624         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 625         void foo (void) { volatile int x = 5; b = &x; }
 626         ],
 627         glib_cv_stack_grows=no
 628         ,
 629         glib_cv_stack_grows=yes
 630         ,)
 631 ])
 632
 633 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 634 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 635 dnl actually supported.
 636 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 637         AC_COMPILE_IFELSE([
 638         __inline int foo () { return 0; }
 639         int main () { return foo (); }
 640         ],
 641         glib_cv_has__inline=yes
 642         ,
 643         glib_cv_has__inline=no
 644         ,)
 645 ])
 646 case x$glib_cv_has__inline in
 647 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 648 esac
 649 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 650         AC_COMPILE_IFELSE([
 651         __inline__ int foo () { return 0; }
 652         int main () { return foo (); }
 653         ],
 654         glib_cv_has__inline__=yes
 655         ,
 656         glib_cv_has__inline__=no
 657         ,)
 658 ])
 659 case x$glib_cv_has__inline__ in
 660 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 661 esac
 662 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 663         AC_COMPILE_IFELSE([
 664         #undef inline
 665         inline int foo () { return 0; }
 666         int main () { return foo (); }
 667         ],
 668         glib_cv_hasinline=yes
 669         ,
 670         glib_cv_hasinline=no
 671         ,)
 672 ])
 673 case x$glib_cv_hasinline in
 674 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 675 esac
 676
 677 # if we can use inline functions in headers
 678 AC_MSG_CHECKING(if inline functions in headers work)
 679 AC_LINK_IFELSE([
 680 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 681 #  undef inline
 682 #  define inline __inline__
 683 #elif !defined (G_HAVE_INLINE)
 684 #  undef inline
 685 #  if defined (G_HAVE___INLINE__)
 686 #    define inline __inline__
 687 #  elif defined (G_HAVE___INLINE)
 688 #    define inline __inline
 689 #  endif
 690 #endif
 691
 692 int glib_test_func2 (int);
 693
 694 static inline int
 695 glib_test_func1 (void) {
 696   return glib_test_func2 (1);
 697 }
 698
 699 int
 700 main (void) {
 701   int i = 1;
 702 }],[g_can_inline=yes],[g_can_inline=no])
 703 AC_MSG_RESULT($g_can_inline)
 704
 705 dnl *** check for working do while(0) macros ***
 706 AC_CACHE_CHECK([for working do while(0) macros], g_support_dowhile_macros, [
 707         AC_TRY_COMPILE([],[
 708         #define STMT_START do
 709         #define STMT_END while(0)
 710         #define STMT_TEST STMT_START { i = 0; } STMT_END
 711         int main(void) { int i = 1; STMT_TEST; return i; }],
 712         [g_support_dowhile_macros=yes],
 713         [g_support_dowhile_macros=no],
 714         [g_support_dowhile_macros=yes])
 715 ])
 716 if test x$g_support_dowhile_macros = xyes; then
 717   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 718 fi
 719
 720 # check for flavours of varargs macros
 721 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 722 AC_TRY_COMPILE([],[
 723 int a(int p1, int p2, int p3);
 724 #define call_a(...) a(1,__VA_ARGS__)
 725 call_a(2,3);
 726 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 727 AC_MSG_RESULT($g_have_iso_c_varargs)
 728
 729 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 730 if test "$CXX" = ""; then
 731 dnl No C++ compiler
 732   g_have_iso_cxx_varargs=no
 733 else
 734   AC_LANG_CPLUSPLUS
 735   AC_TRY_COMPILE([],[
 736 int a(int p1, int p2, int p3);
 737 #define call_a(...) a(1,__VA_ARGS__)
 738 call_a(2,3);
 739 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 740   AC_LANG_C
 741 fi
 742 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 743
 744 AC_MSG_CHECKING(for GNUC varargs macros)
 745 AC_TRY_COMPILE([],[
 746 int a(int p1, int p2, int p3);
 747 #define call_a(params...) a(1,params)
 748 call_a(2,3);
 749 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 750 AC_MSG_RESULT($g_have_gnuc_varargs)
 751
 752 # check for GNUC visibility support
 753 AC_MSG_CHECKING(for GNUC visibility attribute)
 754 GLIB_CHECK_COMPILE_WARNINGS([
 755 void
 756 __attribute__ ((visibility ("hidden")))
 757      f_hidden (void)
 758 {
 759 }
 760 void
 761 __attribute__ ((visibility ("internal")))
 762      f_internal (void)
 763 {
 764 }
 765 void
 766 __attribute__ ((visibility ("protected")))
 767      f_protected (void)
 768 {
 769 }
 770 void
 771 __attribute__ ((visibility ("default")))
 772      f_default (void)
 773 {
 774 }
 775 int main (int argc, char **argv)
 776 {
 777         f_hidden();
 778         f_internal();
 779         f_protected();
 780         f_default();
 781         return 0;
 782 }
 783 ],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 784 AC_MSG_RESULT($g_have_gnuc_visibility)
 785 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 786
 787 # check for bytesex stuff
 788 AC_C_BIGENDIAN
 789
 790 # check for header files
 791 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h sys/param.h sys/poll.h])
 792 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 793 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h sched.h malloc.h])
 794
 795 # Checks for libcharset
 796 jm_LANGINFO_CODESET
 797 jm_GLIBC21
 798 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 799 AC_CHECK_FUNCS(setlocale)
 800
 801 # check additional type sizes
 802 AC_CHECK_SIZEOF(size_t)
 803
 804 dnl Try to figure out whether gsize, gssize should be long or int
 805 AC_MSG_CHECKING([for the appropriate definition for size_t])
 806
 807 case $ac_cv_sizeof_size_t in
 808   $ac_cv_sizeof_short)
 809       glib_size_type=short
 810       ;;
 811   $ac_cv_sizeof_int)
 812       glib_size_type=int
 813       ;;
 814   $ac_cv_sizeof_long)
 815       glib_size_type=long
 816       ;;
 817   *)  AC_MSG_ERROR([No type matching size_t in size])
 818       ;;
 819 esac
 820
 821 dnl If int/long are the same size, we see which one produces
 822 dnl warnings when used in the location as size_t. (This matters
 823 dnl on AIX with xlc)
 824 dnl
 825 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 826    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 827   GLIB_CHECK_COMPILE_WARNINGS([
 828 #if defined(_AIX) && !defined(__GNUC__)
 829 #pragma options langlvl=stdc89
 830 #endif
 831 #include <stddef.h>
 832 int main ()
 833 {
 834   size_t s = 1;
 835   unsigned int *size_int = &s;
 836   return (int)*size_int;
 837 }
 838     ],glib_size_type=int,
 839       [GLIB_CHECK_COMPILE_WARNINGS([
 840 #if defined(_AIX) && !defined(__GNUC__)
 841 #pragma options langlvl=stdc89
 842 #endif
 843 #include <stddef.h>
 844 int main ()
 845 {
 846    size_t s = 1;
 847    unsigned long *size_long = &s;
 848    return (int)*size_long;
 849 }
 850         ],glib_size_type=long)])
 851 fi
 852
 853 AC_MSG_RESULT(unsigned $glib_size_type)
 854
 855 # Check for some functions
 856 AC_CHECK_FUNCS(lstat strerror strsignal memmove mkstemp vsnprintf stpcpy strcasecmp strncasecmp poll getcwd nanosleep vasprintf setenv unsetenv getc_unlocked readlink symlink)
 857
 858 AC_CHECK_HEADERS(crt_externs.h)
 859 AC_CHECK_FUNCS(_NSGetEnviron)
 860
 861 AC_FUNC_VSNPRINTF_C99
 862 AC_FUNC_PRINTF_UNIX98
 863
 864 #
 865 # Check whether to use an included printf
 866 #
 867
 868 AC_ARG_ENABLE(included-printf,
 869               [AC_HELP_STRING([--enable-included-printf],
 870                               [use included printf [default=auto]])],
 871               enable_included_printf="$enableval")
 872
 873 need_included_printf=no
 874 if test "x$enable_included_printf" = "xyes" ; then
 875   need_included_printf=yes
 876 fi
 877 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
 878   need_included_printf=yes
 879 fi
 880 if test "$ac_cv_func_printf_unix98" != "yes" ; then
 881   need_included_printf=yes
 882 fi
 883 if test "x$ac_cv_sizeof_long_long" = "x8" &&
 884    test -z "$glib_cv_long_long_format" ; then
 885   need_included_printf=yes
 886 fi
 887
 888 if test "x$enable_included_printf" = "xno" &&
 889    test "x$need_included_printf" = "xyes" ; then
 890   AC_MSG_ERROR([
 891 *** Your C library's printf doesn't appear to have the features that
 892 *** GLib needs, but you specified --enable-included-printf=no.])
 893 fi
 894
 895 enable_included_printf=$need_included_printf
 896
 897 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
 898 if test "$enable_included_printf" != "yes" ; then
 899   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
 900 else
 901   if test -z "$glib_cv_long_long_format" ; then
 902     glib_cv_long_long_format="ll"
 903   fi
 904   AC_DEFINE(HAVE_VASPRINTF,1)
 905 fi
 906
 907 # Checks needed for gnulib vasnprintf
 908 bh_C_SIGNED
 909 jm_AC_TYPE_LONG_LONG
 910 gt_TYPE_LONGDOUBLE
 911 gt_TYPE_WCHAR_T
 912 gt_TYPE_WINT_T
 913 AC_TYPE_SIZE_T
 914 AC_CHECK_TYPES(ptrdiff_t)
 915 jm_AC_TYPE_INTMAX_T
 916 AC_CHECK_FUNCS(snprintf)
 917 AC_FUNC_SNPRINTF_C99
 918
 919 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
 920 # The check is borrowed from the PERL Configure script.
 921 if test "$ac_cv_func_memmove" != "yes"; then
 922   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
 923     glib_cv_working_bcopy,[AC_TRY_RUN([
 924       int main() {
 925         char buf[128], abc[128], *b;
 926         int len, off, align;
 927         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
 928         for (align = 7; align >= 0; align--) {
 929           for (len = 36; len; len--) {
 930             b = buf+align; bcopy(abc, b, len);
 931             for (off = 1; off <= len; off++) {
 932               bcopy(b, b+off, len); bcopy(b+off, b, len);
 933                 if (bcmp(b, abc, len)) return(1);
 934             }
 935           }
 936         }
 937         return(0);
 938       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
 939
 940   GLIB_ASSERT_SET(glib_cv_working_bcopy)
 941   if test "$glib_cv_working_bcopy" = "yes"; then
 942     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
 943   fi
 944 fi
 945
 946 # Check for sys_errlist
 947 AC_MSG_CHECKING(for sys_errlist)
 948 AC_TRY_LINK(, [
 949 extern char *sys_errlist[];
 950 extern int sys_nerr;
 951 sys_errlist[sys_nerr-1][0] = 0;
 952 ], glib_ok=yes, glib_ok=no)
 953 AC_MSG_RESULT($glib_ok)
 954 if test "$glib_ok" = "no"; then
 955     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
 956 fi
 957
 958 # Check for sys_siglist
 959 AC_MSG_CHECKING(for sys_siglist)
 960 AC_TRY_LINK(, [
 961 extern char *sys_siglist[];
 962 exit (sys_siglist[0]);
 963 ], glib_ok=yes, glib_ok=no)
 964 AC_MSG_RESULT($glib_ok)
 965 if test "$glib_ok" = "no"; then
 966     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
 967 fi
 968
 969 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
 970 AC_MSG_CHECKING(for sys_siglist declaration)
 971 AC_TRY_COMPILE([#include <signal.h>], [
 972 strlen (sys_siglist[0]);
 973 ], glib_ok=yes, glib_ok=no)
 974 AC_MSG_RESULT($glib_ok)
 975 if test "$glib_ok" = "no"; then
 976     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
 977 fi
 978
 979 # Check if <sys/select.h> needs to be included for fd_set
 980 AC_MSG_CHECKING([for fd_set])
 981 AC_TRY_COMPILE([#include <sys/types.h>],
 982         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 983 if test "$gtk_ok" = "yes"; then
 984     AC_MSG_RESULT([yes, found in sys/types.h])
 985 else
 986     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
 987     if test "$gtk_ok" = "yes"; then
 988         # *** FIXME: give it a different name
 989         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
 990         AC_MSG_RESULT([yes, found in sys/select.h])
 991     else
 992         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
 993         AC_MSG_RESULT(no)
 994     fi
 995 fi
 996
 997 dnl *** check for sane realloc() ***
 998 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
 999         AC_TRY_RUN([#include <stdlib.h>
1000         int main() {
1001           return realloc (0, sizeof (int)) == 0;
1002         }],
1003         [glib_cv_sane_realloc=yes],
1004         [glib_cv_sane_realloc=no],
1005         [glib_cv_sane_realloc=yes])
1006 ])
1007 if test x$glib_cv_sane_realloc = xyes; then
1008   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1009 fi
1010
1011 dnl Check for nl_langinfo and CODESET
1012
1013 AC_MSG_CHECKING([for nl_langinfo (CODESET)])
1014 AC_TRY_COMPILE([#include <langinfo.h>],
1015         [char *codeset = nl_langinfo (CODESET);],
1016    AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1017    have_codeset=yes,
1018    have_codeset=no)
1019 AC_MSG_RESULT($have_codeset)
1020
1021
1022 dnl ****************************************
1023 dnl *** posix_memalign                   ***
1024 dnl ****************************************
1025 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1026 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1027     glib_cv_compliant_posix_memalign=0
1028     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1029         AC_TRY_RUN([
1030                 #define _XOPEN_SOURCE 600
1031                 #include <stdlib.h>
1032                 #include <malloc.h>
1033                 static void test_memalign (size_t boundary, size_t size) {
1034                     void *mem = 0;
1035                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1036                         exit (1);
1037                 }
1038                 int main() {
1039                     test_memalign (  128,   128 - 2 * sizeof (void*));
1040                     test_memalign (  256,   256 - 2 * sizeof (void*));
1041                     test_memalign (  512,   512 - 2 * sizeof (void*));
1042                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1043                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1044                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1045                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1046                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1047                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1048                     exit (0); /* success */
1049                 }
1050                 ],
1051             [glib_cv_compliant_posix_memalign=1], [], [:])
1052       :
1053     fi
1054     ])
1055 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1056     AC_MSG_RESULT(yes)
1057     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1058 else
1059     AC_MSG_RESULT(no)
1060 fi
1061
1062
1063 dnl ****************************************
1064 dnl *** strlcpy/strlcat                  ***
1065 dnl ****************************************
1066 # Check for strlcpy
1067 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1068 AC_TRY_RUN([#include <stdlib.h>
1069 #include <string.h>
1070 int main() {
1071   char p[10];
1072   (void) strlcpy (p, "hi", 10);
1073   if (strlcat (p, "bye", 0) != 3)
1074     return 1;
1075   return 0;
1076 }], glib_cv_have_strlcpy=yes,
1077     glib_cv_have_strlcpy=no,
1078     glib_cv_have_strlcpy=no)])
1079 if test "$glib_cv_have_strlcpy" = "yes"; then
1080     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1081 fi
1082
1083
1084 dnl **********************
1085 dnl *** va_copy checks ***
1086 dnl **********************
1087 dnl we currently check for all three va_copy possibilities, so we get
1088 dnl all results in config.log for bug reports.
1089 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1090         AC_LINK_IFELSE([#include <stdarg.h>
1091         void f (int i, ...) {
1092         va_list args1, args2;
1093         va_start (args1, i);
1094         va_copy (args2, args1);
1095         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1096           exit (1);
1097         va_end (args1); va_end (args2);
1098         }
1099         int main() {
1100           f (0, 42);
1101           return 0;
1102         }],
1103         [glib_cv_va_copy=yes],
1104         [glib_cv_va_copy=no])
1105 ])
1106 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1107         AC_LINK_IFELSE([#include <stdarg.h>
1108         void f (int i, ...) {
1109         va_list args1, args2;
1110         va_start (args1, i);
1111         __va_copy (args2, args1);
1112         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1113           exit (1);
1114         va_end (args1); va_end (args2);
1115         }
1116         int main() {
1117           f (0, 42);
1118           return 0;
1119         }],
1120         [glib_cv___va_copy=yes],
1121         [glib_cv___va_copy=no])
1122 ])
1123
1124 if test "x$glib_cv_va_copy" = "xyes"; then
1125   g_va_copy_func=va_copy
1126 else if test "x$glib_cv___va_copy" = "xyes"; then
1127   g_va_copy_func=__va_copy
1128 fi
1129 fi
1130
1131 if test -n "$g_va_copy_func"; then
1132   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1133 fi
1134
1135 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1136         AC_TRY_RUN([#include <stdarg.h>
1137         void f (int i, ...) {
1138         va_list args1, args2;
1139         va_start (args1, i);
1140         args2 = args1;
1141         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1142           exit (1);
1143         va_end (args1); va_end (args2);
1144         }
1145         int main() {
1146           f (0, 42);
1147           return 0;
1148         }],
1149         [glib_cv_va_val_copy=yes],
1150         [glib_cv_va_val_copy=no],
1151         [glib_cv_va_val_copy=yes])
1152 ])
1153
1154 if test "x$glib_cv_va_val_copy" = "xno"; then
1155   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1156 fi
1157
1158 dnl ***********************
1159 dnl *** g_module checks ***
1160 dnl ***********************
1161 G_MODULE_LIBS=
1162 G_MODULE_LIBS_EXTRA=
1163 G_MODULE_PLUGIN_LIBS=
1164 if test x"$glib_native_win32" = xyes; then
1165   dnl No use for this on Win32
1166   G_MODULE_LDFLAGS=
1167 else
1168   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1169 fi
1170 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1171 G_MODULE_NEED_USCORE=0
1172 G_MODULE_BROKEN_RTLD_GLOBAL=0
1173 G_MODULE_HAVE_DLERROR=0
1174 dnl *** force native WIN32 shared lib loader
1175 if test -z "$G_MODULE_IMPL"; then
1176   case "$host" in
1177   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1178   esac
1179 fi
1180 dnl *** force native AIX library loader
1181 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1182 if test -z "$G_MODULE_IMPL"; then
1183   case "$host" in
1184   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1185   esac
1186 fi
1187 dnl *** dlopen() and dlsym() in system libraries
1188 if test -z "$G_MODULE_IMPL"; then
1189         AC_CHECK_FUNC(dlopen,
1190                       [AC_CHECK_FUNC(dlsym,
1191                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1192                       [])
1193 fi
1194 dnl *** load_image (BeOS)
1195 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1196   AC_CHECK_LIB(root, load_image,
1197       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1198       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1199       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1200       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1201       [])
1202 fi
1203 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1204 if test -z "$G_MODULE_IMPL"; then
1205         AC_CHECK_FUNC(NSLinkModule,
1206                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1207                        G_MODULE_NEED_USCORE=1],
1208                       [])
1209 fi
1210 dnl *** dlopen() and dlsym() in libdl
1211 if test -z "$G_MODULE_IMPL"; then
1212         AC_CHECK_LIB(dl, dlopen,
1213                      [AC_CHECK_LIB(dl, dlsym,
1214                                    [G_MODULE_LIBS=-ldl
1215                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1216                      [])
1217 fi
1218 dnl *** shl_load() in libdld (HP-UX)
1219 if test -z "$G_MODULE_IMPL"; then
1220         AC_CHECK_LIB(dld, shl_load,
1221                 [G_MODULE_LIBS=-ldld
1222                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1223                 [])
1224 fi
1225 dnl *** additional checks for G_MODULE_IMPL_DL
1226 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1227         LIBS_orig="$LIBS"
1228         LDFLAGS_orig="$LDFLAGS"
1229         LIBS="$G_MODULE_LIBS $LIBS"
1230         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1231 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1232         echo "void glib_plugin_test(void) { }" > plugin.c
1233         ${SHELL} ./libtool --mode=compile ${CC} -shared \
1234                 -export-dynamic -o plugin.o plugin.c 2>&1 >/dev/null
1235         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1236                 glib_cv_rtldglobal_broken,[
1237                 AC_TRY_RUN([
1238 #include <dlfcn.h>
1239 #ifndef RTLD_GLOBAL
1240 #  define RTLD_GLOBAL 0
1241 #endif
1242 #ifndef RTLD_LAZY
1243 #  define RTLD_LAZY 0
1244 #endif
1245 int glib_plugin_test;
1246 int main () {
1247     void *handle, *global, *local;
1248     global = &glib_plugin_test;
1249     handle = dlopen ("./.libs/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1250     if (!handle) return 0;
1251     local = dlsym (handle, "glib_plugin_test");
1252     return global == local;
1253 }                       ],
1254                         [glib_cv_rtldglobal_broken=no],
1255                         [glib_cv_rtldglobal_broken=yes],
1256                         [glib_cv_rtldglobal_broken=no])
1257                 rm -f plugin.c plugin.o plugin.lo .libs/plugin.o
1258                 rmdir .libs 2>/dev/null
1259         ])
1260         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1261                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1262         else
1263                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1264         fi
1265 dnl *** check whether we need preceeding underscores
1266         AC_CACHE_CHECK([for preceeding underscore in symbols],
1267                 glib_cv_uscore,[
1268                 AC_TRY_RUN([#include <dlfcn.h>
1269                 int glib_underscore_test (void) { return 42; }
1270                 int main() {
1271                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1272                   handle = dlopen ((void*)0, 0);
1273                   if (handle) {
1274                     f1 = dlsym (handle, "glib_underscore_test");
1275                     f2 = dlsym (handle, "_glib_underscore_test");
1276                   } return (!f2 || f1);
1277                 }],
1278                         [glib_cv_uscore=yes],
1279                         [glib_cv_uscore=no],
1280                         [])
1281                 rm -f plugin.c plugin.$ac_objext plugin.lo
1282         ])
1283         GLIB_ASSERT_SET(glib_cv_uscore)
1284         if test "x$glib_cv_uscore" = "xyes"; then
1285                 G_MODULE_NEED_USCORE=1
1286         else
1287                 G_MODULE_NEED_USCORE=0
1288         fi
1289
1290         LDFLAGS="$LDFLAGS_orig"
1291 dnl *** check for having dlerror()
1292         AC_CHECK_FUNC(dlerror,
1293                 [G_MODULE_HAVE_DLERROR=1],
1294                 [G_MODULE_HAVE_DLERROR=0])
1295         LIBS="$LIBS_orig"
1296 fi
1297 dnl *** done, have we got an implementation?
1298 if test -z "$G_MODULE_IMPL"; then
1299         G_MODULE_IMPL=0
1300         G_MODULE_SUPPORTED=false
1301 else
1302         G_MODULE_SUPPORTED=true
1303 fi
1304
1305 AC_MSG_CHECKING(for the suffix of shared libraries)
1306 case "$host_os" in
1307   hpux9* | hpux10* | hpux11*)  # taken from ltconfig
1308     case "$host_cpu" in
1309       hppa*)
1310         glib_gmodule_suffix='sl'
1311         ;;
1312       ia64*)
1313         glib_gmodule_suffix='so'
1314         ;;
1315     esac
1316     ;;
1317   cygwin* | mingw*)
1318     glib_gmodule_suffix='dll'
1319     ;;
1320   aix*)
1321     glib_gmodule_suffix='a'
1322     ;;
1323   *)
1324     glib_gmodule_suffix='so'
1325     ;;
1326 esac
1327 AC_MSG_RESULT(.$glib_gmodule_suffix)
1328
1329 AC_SUBST(G_MODULE_SUPPORTED)
1330 AC_SUBST(G_MODULE_IMPL)
1331 AC_SUBST(G_MODULE_LIBS)
1332 AC_SUBST(G_MODULE_LIBS_EXTRA)
1333 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1334 AC_SUBST(G_MODULE_LDFLAGS)
1335 AC_SUBST(G_MODULE_HAVE_DLERROR)
1336 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1337 AC_SUBST(G_MODULE_NEED_USCORE)
1338 AC_SUBST(GLIB_DEBUG_FLAGS)
1339
1340 dnl **********************
1341 dnl *** g_spawn checks ***
1342 dnl **********************
1343
1344 AC_MSG_CHECKING(for gspawn implementation)
1345 case "$host" in
1346   *-*-mingw*)
1347     GSPAWN=gspawn-win32.lo
1348     ;;
1349   *)
1350     GSPAWN=gspawn.lo
1351     ;;
1352 esac
1353 AC_MSG_RESULT($GSPAWN)
1354 AC_SUBST(GSPAWN)
1355
1356 dnl *************************
1357 dnl *** GIOChannel checks ***
1358 dnl *************************
1359
1360 AC_MSG_CHECKING(for GIOChannel implementation)
1361 case "$host" in
1362   *-*-mingw*)
1363     GIO=giowin32.lo
1364     ;;
1365   *)
1366     GIO=giounix.lo
1367     ;;
1368 esac
1369 AC_MSG_RESULT($GIO)
1370 AC_SUBST(GIO)
1371
1372 dnl ****************************************
1373 dnl *** platform dependent source checks ***
1374 dnl ****************************************
1375
1376 AC_MSG_CHECKING(for platform-dependent source)
1377 case "$host" in
1378   *-*-cygwin*|*-*-mingw*)
1379     PLATFORMDEP=gwin32.lo
1380     ;;
1381   *)
1382     PLATFORMDEP=
1383     ;;
1384 esac
1385 AC_MSG_RESULT($PLATFORMDEP)
1386 AC_SUBST(PLATFORMDEP)
1387
1388 AC_MSG_CHECKING([whether to compile timeloop])
1389 case "$host" in
1390   *-*-cygwin*|*-*-mingw*)
1391     enable_timeloop=no
1392     ;;
1393   *)
1394     enable_timeloop=yes
1395     ;;
1396 esac
1397 AC_MSG_RESULT($enable_timeloop)
1398 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1399
1400 AC_MSG_CHECKING([if building for some Win32 platform])
1401 case "$host" in
1402   *-*-mingw*|*-*-cygwin*)
1403     platform_win32=yes
1404     ;;
1405   *)
1406     platform_win32=no
1407     ;;
1408 esac
1409 AC_MSG_RESULT($platform_win32)
1410 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1411
1412 dnl ***********************
1413 dnl *** g_thread checks ***
1414 dnl ***********************
1415
1416 AC_ARG_WITH(threads,
1417            [AC_HELP_STRING([--with-threads=@<:@none/posix/dce/win32@:>@],
1418                            [specify a thread implementation to use])],
1419            [if test "x$with_threads" = x; then
1420                 want_threads=yes
1421             else
1422                 want_threads=$with_threads
1423             fi],
1424            [want_threads=yes])
1425 if test "x$enable_threads" = "xno"; then
1426         want_threads=no
1427 fi
1428
1429 dnl error and warning message
1430 dnl *************************
1431
1432 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1433                 computer. GLib will not have a default thread implementation."
1434
1435 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1436                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1437                 compilation now, but then your programs might not work.
1438                 Please provide information on how it is done on your system."
1439
1440 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1441                 "
1442
1443 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1444                 provide information on your thread implementation.
1445                 You can also run 'configure --disable-threads'
1446                 to compile without thread support."
1447
1448 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1449                 functions will not be MT-safe during their first call because
1450                 there is no working 'getpwuid_r' on your system."
1451
1452 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1453                 because there is no 'localtime_r' on your system."
1454
1455 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1456                 crude surrogate will be used. If you happen to know a
1457                 yield function for your system, please inform the GLib
1458                 developers."
1459
1460 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1461                 threads on your system. Thus threads can only have the default
1462                 priority. If you happen to know these main/max
1463                 priorities, please inform the GLib developers."
1464
1465 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1466                 linking threaded applications. As GLib cannot do that
1467                 automatically, you will get an linkg error everytime you are
1468                 not using the right compiler. In that case you have to relink
1469                 with the right compiler. Ususally just '_r' is appended
1470                 to the compiler name."
1471
1472 dnl determination of thread implementation
1473 dnl ***************************************
1474
1475 # have_threads=no   means no thread support
1476 # have_threads=none means no default thread implementation
1477
1478 have_threads=no
1479 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1480                                 || test "x$want_threads" = xdce; then
1481         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1482         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1483         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1484         glib_save_CPPFLAGS="$CPPFLAGS"
1485         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1486         if test "x$have_threads" = xno; then
1487                 AC_TRY_COMPILE([#include <pthread.h>],
1488                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1489                         have_threads=posix)
1490         fi
1491         if test "x$have_threads" = xno; then
1492                 AC_TRY_COMPILE([#include <pthread.h>],
1493                         [pthread_mutex_t m;
1494                          pthread_mutex_init (&m, pthread_mutexattr_default);],
1495                         have_threads=dce)
1496         fi
1497         # Tru64Unix requires -pthread to find pthread.h. See #103020
1498         CPPFLAGS="$CPPFLAGS -pthread"
1499         if test "x$have_threads" = xno; then
1500         AC_TRY_COMPILE([#include <pthread.h>],
1501                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1502                        have_threads=posix)
1503         fi
1504         CPPFLAGS="$glib_save_CPPFLAGS"
1505 fi
1506 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1507         case $host in
1508                 *-*-mingw*)
1509                 have_threads=win32
1510                 ;;
1511         esac
1512 fi
1513 if test "x$want_threads" = xnone; then
1514         have_threads=none
1515 fi
1516
1517 AC_MSG_CHECKING(for thread implementation)
1518
1519 if test "x$have_threads" = xno && test "x$want_threads" != xno; then
1520         AC_MSG_RESULT(none available)
1521         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
1522 else
1523         AC_MSG_RESULT($have_threads)
1524 fi
1525
1526
1527 dnl determination of G_THREAD_CFLAGS
1528 dnl ********************************
1529
1530 G_THREAD_LIBS=
1531 G_THREAD_LIBS_EXTRA=
1532 G_THREAD_CFLAGS=
1533
1534 dnl
1535 dnl Test program for basic POSIX threads functionality
1536 dnl
1537 m4_define([glib_thread_test],[
1538 #include <pthread.h>
1539 int check_me = 0;
1540 void* func(void* data) {check_me = 42; return &check_me;}
1541 int main()
1542  { pthread_t t;
1543    void *ret;
1544    pthread_create (&t, $1, func, 0);
1545    pthread_join (t, &ret);
1546    exit (check_me != 42 || ret != &check_me);
1547 }])
1548
1549 dnl
1550 dnl Test program for sched_get_priority_min()
1551 dnl
1552 m4_define([glib_sched_priority_test],[
1553 #include <sched.h>
1554 #include <errno.h>
1555 int main() {
1556     errno = 0;
1557     return sched_get_priority_min(SCHED_OTHER)==-1
1558            && errno != 0;
1559 }])
1560
1561 if test x"$have_threads" != xno; then
1562
1563   if test x"$have_threads" = xposix; then
1564     # First we test for posix, whether -pthread or -pthreads do the trick as
1565     # both CPPFLAG and LIBS.
1566     # One of them does for most gcc versions and some other platforms/compilers
1567     # too and could be considered as the canonical way to go.
1568     case $host in
1569       *-*-cygwin*)
1570          # skip cygwin -pthread or -pthreads test
1571          ;;
1572       *)
1573         for flag in pthread pthreads mt; do
1574           glib_save_CFLAGS="$CFLAGS"
1575           CFLAGS="$CFLAGS -$flag"
1576           AC_TRY_RUN(glib_thread_test(0),
1577                      glib_flag_works=yes,
1578                      glib_flag_works=no,
1579                      [AC_LINK_IFELSE(glib_thread_test(0),
1580                                      glib_flag_works=yes,
1581                                      glib_flag_works=no)])
1582           CFLAGS="$glib_save_CFLAGS"
1583           if test $glib_flag_works = yes ; then
1584              G_THREAD_CFLAGS=-$flag
1585              G_THREAD_LIBS=-$flag
1586           fi
1587         done
1588          ;;
1589     esac
1590   fi
1591
1592   if test x"$G_THREAD_CFLAGS" = x; then
1593
1594     # The canonical -pthread[s] does not work. Try something different.
1595
1596     case $host in
1597         *-aix*)
1598                 if test x"$GCC" = xyes; then
1599                         # GCC 3.0 and above needs -pthread.
1600                         # Should be coverd by the case above.
1601                         # GCC 2.x and below needs -mthreads
1602                         G_THREAD_CFLAGS="-mthreads"
1603                         G_THREAD_LIBS=$G_THREAD_CFLAGS
1604                 else
1605                         # We are probably using the aix compiler. Normaly a
1606                         # program would have to be compiled with the _r variant
1607                         # of the corresponding compiler, but we as GLib cannot
1608                         # do that: but the good news is that for compiling the
1609                         # only difference is the added -D_THREAD_SAFE compile
1610                         # option. This is according to the "C for AIX User's
1611                         # Guide".
1612                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
1613                 fi
1614                 ;;
1615         *-dg-dgux*)  # DG/UX
1616                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
1617                 ;;
1618         *-osf*)
1619                 # So we are using dce threads. posix threads are already
1620                 # catched above.
1621                 G_THREAD_CFLAGS="-threads"
1622                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1623                 ;;
1624         *-sysv5uw7*) # UnixWare 7
1625                 # We are not using gcc with -pthread. Catched above.
1626                 G_THREAD_CFLAGS="-Kthread"
1627                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1628                 ;;
1629         *-mingw*)
1630                 # No flag needed when using MSVCRT.DLL
1631                 G_THREAD_CFLAGS=""
1632                 ;;
1633         *)
1634                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
1635                 ;;
1636     esac
1637
1638   fi
1639
1640     # if we are not finding the localtime_r function, then we probably are
1641     # not using the proper multithread flag
1642
1643     glib_save_CPPFLAGS="$CPPFLAGS"
1644     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1645
1646     # First we test, whether localtime_r is declared in time.h
1647     # directly. Then we test whether a macro localtime_r exists, in
1648     # which case localtime_r in the test program is replaced and thus
1649     # if we still find localtime_r in the output, it is not defined as
1650     # a macro.
1651
1652     AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
1653       [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
1654                                                            localtime_r(a,b)],
1655                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
1656
1657     CPPFLAGS="$glib_save_CPPFLAGS"
1658
1659     AC_MSG_CHECKING(thread related cflags)
1660     AC_MSG_RESULT($G_THREAD_CFLAGS)
1661     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1662 fi
1663
1664 dnl determination of G_THREAD_LIBS
1665 dnl ******************************
1666
1667 mutex_has_default=no
1668 case $have_threads in
1669         posix|dce)
1670           glib_save_CPPFLAGS="$CPPFLAGS"
1671           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1672           if test x"$G_THREAD_LIBS" = x; then
1673             case $host in
1674               *-aix*)
1675                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
1676                 # probably using the aix compiler.
1677                 AC_MSG_WARN($AIX_COMPILE_INFO)
1678                 ;;
1679               *)
1680                 G_THREAD_LIBS=error
1681                 glib_save_LIBS="$LIBS"
1682                 for thread_lib in "" pthread pthread32 pthreads thread dce; do
1683                         if test x"$thread_lib" = x; then
1684                                 add_thread_lib=""
1685                                 IN=""
1686                         else
1687                                 add_thread_lib="-l$thread_lib"
1688                                 IN=" in -l$thread_lib"
1689                         fi
1690                         if test x"$have_threads" = xposix; then
1691                                 defattr=0
1692                         else
1693                                 defattr=pthread_attr_default
1694                         fi
1695
1696                         LIBS="$add_thread_lib $glib_save_LIBS"
1697
1698                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
1699                         AC_TRY_RUN(glib_thread_test($defattr),
1700                                    glib_result=yes,
1701                                    glib_result=no,
1702                                    [AC_LINK_IFELSE(glib_thread_test($defattr),
1703                                                    glib_result=yes,
1704                                                    glib_result=no)])
1705                         AC_MSG_RESULT($glib_result)
1706
1707                         if test "$glib_result" = "yes" ; then
1708                           G_THREAD_LIBS="$add_thread_lib"
1709                           break
1710                         fi
1711                 done
1712                 if test "x$G_THREAD_LIBS" = xerror; then
1713                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1714                 fi
1715                 LIBS="$glib_save_LIBS"
1716                 ;;
1717             esac
1718           fi
1719
1720           glib_save_LIBS="$LIBS"
1721           for thread_lib in "" rt rte; do
1722             if test x"$thread_lib" = x; then
1723               add_thread_lib=""
1724               IN=""
1725             else
1726               add_thread_lib="-l$thread_lib"
1727               IN=" in -l$thread_lib"
1728             fi
1729             LIBS="$add_thread_lib $glib_save_LIBS"
1730
1731             AC_MSG_CHECKING(for sched_get_priority_min$IN)
1732             AC_TRY_RUN(glib_sched_priority_test,
1733                        glib_result=yes,
1734                        glib_result=no,
1735                        [AC_LINK_IFELSE(glib_sched_priority_test,
1736                                        glib_result=yes,
1737                                        glib_result=no)])
1738             AC_MSG_RESULT($glib_result)
1739
1740             if test "$glib_result" = "yes" ; then
1741                G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
1742                posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
1743                posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
1744                break
1745             fi
1746           done
1747           LIBS="$glib_save_LIBS"
1748           mutex_has_default=yes
1749           mutex_default_type='pthread_mutex_t'
1750           mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
1751           mutex_header_file='pthread.h'
1752           if test "x$have_threads" = "xposix"; then
1753             g_threads_impl="POSIX"
1754           else
1755             g_threads_impl="DCE"
1756             have_threads="posix"
1757           fi
1758           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
1759           CPPFLAGS="$glib_save_CPPFLAGS"
1760           ;;
1761         win32)
1762            g_threads_impl="WIN32"
1763            ;;
1764         none|no)
1765            g_threads_impl="NONE"
1766            ;;
1767         *)
1768            g_threads_impl="NONE"
1769            G_THREAD_LIBS=error
1770            ;;
1771 esac
1772
1773 if test "x$G_THREAD_LIBS" = xerror; then
1774         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1775 fi
1776
1777 case $host in
1778   *-*-beos*)
1779     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
1780     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1781     ;;
1782   *)
1783     ;;
1784 esac
1785
1786 AC_MSG_CHECKING(thread related libraries)
1787 AC_MSG_RESULT($G_THREAD_LIBS)
1788
1789 dnl check for mt safe function variants and some posix functions
1790 dnl ************************************************************
1791
1792 if test x"$have_threads" != xno; then
1793         glib_save_LIBS="$LIBS"
1794         # we are not doing the following for now, as this might require glib
1795         # to always be linked with the thread libs on some platforms.
1796         # LIBS="$LIBS $G_THREAD_LIBS"
1797         AC_CHECK_FUNCS(localtime_r)
1798         if test "$ac_cv_header_pwd_h" = "yes"; then
1799                 AC_CACHE_CHECK([for posix getpwuid_r],
1800                         ac_cv_func_posix_getpwuid_r,
1801                         [AC_TRY_RUN([
1802 #include <errno.h>
1803 #include <pwd.h>
1804 int main () {
1805     char buffer[10000];
1806     struct passwd pwd, *pwptr = &pwd;
1807     int error;
1808     errno = 0;
1809     error = getpwuid_r (0, &pwd, buffer,
1810                         sizeof (buffer), &pwptr);
1811    return (error < 0 && errno == ENOSYS)
1812            || error == ENOSYS;
1813 }                               ],
1814                                 [ac_cv_func_posix_getpwuid_r=yes],
1815                                 [ac_cv_func_posix_getpwuid_r=no])])
1816                 GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
1817                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
1818                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
1819                                 [Have POSIX function getpwuid_r])
1820                 else
1821                         AC_CACHE_CHECK([for nonposix getpwuid_r],
1822                                 ac_cv_func_nonposix_getpwuid_r,
1823                                 [AC_TRY_LINK([#include <pwd.h>],
1824                                         [char buffer[10000];
1825                                         struct passwd pwd;
1826                                         getpwuid_r (0, &pwd, buffer,
1827                                                         sizeof (buffer));],
1828                                         [ac_cv_func_nonposix_getpwuid_r=yes],
1829                                         [ac_cv_func_nonposix_getpwuid_r=no])])
1830                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
1831                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
1832                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
1833                                         [Have non-POSIX function getpwuid_r])
1834                         fi
1835                 fi
1836         fi
1837         LIBS="$G_THREAD_LIBS $LIBS"
1838         if test x"$have_threads" = xposix; then
1839                 glib_save_CPPFLAGS="$CPPFLAGS"
1840                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1841                 dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
1842                 GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
1843                 # This is not AC_CHECK_FUNC to also work with function
1844                 # name mangling in header files.
1845                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
1846                 AC_TRY_LINK([#include <pthread.h>],
1847                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
1848                         [AC_MSG_RESULT(yes)
1849                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
1850                                   [Have function pthread_attr_setstacksize])],
1851                         [AC_MSG_RESULT(no)])
1852                 AC_MSG_CHECKING(for minimal/maximal thread priority)
1853                 if test x"$posix_priority_min" = x; then
1854                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
1855                                 PX_PRIO_MIN],,[
1856                                 posix_priority_min=PX_PRIO_MIN
1857                                 posix_priority_max=PX_PRIO_MAX])
1858                 fi
1859                 if test x"$posix_priority_min" = x; then
1860                         # AIX
1861                         AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
1862                                 PTHREAD_PRIO_MIN],,[
1863                                 posix_priority_min=PTHREAD_PRIO_MIN
1864                                 posix_priority_max=PTHREAD_PRIO_MAX])
1865                 fi
1866                 if test x"$posix_priority_min" = x; then
1867                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
1868                                 PRI_OTHER_MIN],,[
1869                                 posix_priority_min=PRI_OTHER_MIN
1870                                 posix_priority_max=PRI_OTHER_MAX])
1871                 fi
1872                 if test x"$posix_priority_min" = x; then
1873                         AC_MSG_RESULT(none found)
1874                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
1875                         posix_priority_min=-1
1876                         posix_priority_max=-1
1877                 else
1878                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
1879                         AC_MSG_CHECKING(for pthread_setschedparam)
1880                         AC_TRY_LINK([#include <pthread.h>],
1881                           [pthread_t t; pthread_setschedparam(t, 0, NULL)],
1882                           [AC_MSG_RESULT(yes)
1883                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
1884                            AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
1885                           [AC_MSG_RESULT(no)
1886                            AC_MSG_WARN($POSIX_NO_PRIORITIES)])
1887                 fi
1888                 posix_yield_func=none
1889                 AC_MSG_CHECKING(for posix yield function)
1890                 for yield_func in sched_yield pthread_yield_np pthread_yield \
1891                                                         thr_yield; do
1892                         AC_TRY_LINK([#include <pthread.h>],
1893                                 [$yield_func()],
1894                                 [posix_yield_func="$yield_func"
1895                                 break])
1896                 done
1897                 if test x"$posix_yield_func" = xnone; then
1898                         AC_MSG_RESULT(none found)
1899                         AC_MSG_WARN($POSIX_NO_YIELD)
1900                         posix_yield_func="g_usleep(1000)"
1901                 else
1902                         AC_MSG_RESULT($posix_yield_func)
1903                         posix_yield_func="$posix_yield_func()"
1904                 fi
1905                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
1906                 CPPFLAGS="$glib_save_CPPFLAGS"
1907
1908         elif test x"$have_threads" = xwin32; then
1909                 # It's a pointer to a private struct
1910                 GLIB_SIZEOF(,struct _GThreadData *, system_thread)
1911         fi
1912
1913         LIBS="$glib_save_LIBS"
1914
1915         # now spit out all the warnings.
1916         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
1917            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
1918                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
1919         fi
1920         if test "$ac_cv_func_localtime_r" != "yes"; then
1921                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
1922         fi
1923 fi
1924
1925 if test x"$glib_cv_sizeof_system_thread" = x; then
1926    # use a pointer as a fallback.
1927    GLIB_SIZEOF(,void *, system_thread)
1928 fi
1929
1930 #
1931 # Hack to deal with:
1932 #
1933 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
1934 #     building shared libraries with linux.
1935 #
1936 case $host in
1937   *-*-linux*)
1938     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
1939     ;;
1940   *)
1941     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
1942     ;;
1943 esac
1944
1945 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
1946                    [Source file containing theread implementation])
1947 AC_SUBST(G_THREAD_CFLAGS)
1948 AC_SUBST(G_THREAD_LIBS)
1949 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
1950 AC_SUBST(G_THREAD_LIBS_EXTRA)
1951
1952 dnl **********************************************
1953 dnl *** GDefaultMutex setup and initialization ***
1954 dnl **********************************************
1955 dnl
1956 dnl if mutex_has_default = yes, we also got
1957 dnl mutex_default_type, mutex_default_init and mutex_header_file
1958 if test $mutex_has_default = yes ; then
1959         glib_save_CPPFLAGS="$CPPFLAGS"
1960         glib_save_LIBS="$LIBS"
1961         LIBS="$G_THREAD_LIBS $LIBS"
1962         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1963         GLIB_SIZEOF([#include <$mutex_header_file>],
1964                     $mutex_default_type,
1965                     gmutex)
1966         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
1967                            $mutex_default_type,
1968                            gmutex,
1969                            $glib_cv_sizeof_gmutex,
1970                            $mutex_default_init)
1971         if test x"$glib_cv_byte_contents_gmutex" = xno; then
1972                 mutex_has_default=no
1973         fi
1974         CPPFLAGS="$glib_save_CPPFLAGS"
1975         LIBS="$glib_save_LIBS"
1976 fi
1977
1978 dnl ********************************
1979 dnl *** g_atomic_* tests for gcc ***
1980 dnl ********************************
1981
1982 AC_MSG_CHECKING([whether to use assembler code for atomic operations])
1983
1984 if test x"$GCC" = xyes; then
1985   case $host_cpu in
1986     i386)
1987       AC_MSG_RESULT([none])
1988       glib_memory_barrier_needed=no
1989       ;;
1990     i?86)
1991       AC_MSG_RESULT([i486])
1992       AC_DEFINE_UNQUOTED(G_ATOMIC_I486, 1,
1993                          [i486 atomic implementation])
1994       glib_memory_barrier_needed=no
1995       ;;
1996     sparc*)
1997       SPARCV9_WARNING="Try to rerun configure with CFLAGS='-mcpu=v9',
1998                 when you are using a sparc with v9 instruction set (most
1999                 sparcs nowadays). This will make the code for atomic
2000                 operations much faster. The resulting code will not run
2001                 on very old sparcs though."
2002
2003       AC_LINK_IFELSE([[
2004         main ()
2005         {
2006           int tmp1, tmp2, tmp3;
2007           __asm__ __volatile__("casx [%2], %0, %1"
2008                                : "=&r" (tmp1), "=&r" (tmp2) : "r" (&tmp3));
2009         }]],
2010         AC_MSG_RESULT([sparcv9])
2011         AC_DEFINE_UNQUOTED(G_ATOMIC_SPARCV9, 1,
2012                            [sparcv9 atomic implementation]),
2013         AC_MSG_RESULT([no])
2014         AC_MSG_WARN([[$SPARCV9_WARNING]]))
2015       glib_memory_barrier_needed=yes
2016       ;;
2017     alpha*)
2018       AC_MSG_RESULT([alpha])
2019       AC_DEFINE_UNQUOTED(G_ATOMIC_ALPHA, 1,
2020                          [alpha atomic implementation])
2021       glib_memory_barrier_needed=yes
2022       ;;
2023     x86_64)
2024       AC_MSG_RESULT([x86_64])
2025       AC_DEFINE_UNQUOTED(G_ATOMIC_X86_64, 1,
2026                          [x86_64 atomic implementation])
2027       glib_memory_barrier_needed=no
2028      ;;
2029     powerpc*)
2030       AC_MSG_RESULT([powerpc])
2031       AC_DEFINE_UNQUOTED(G_ATOMIC_POWERPC, 1,
2032                          [powerpc atomic implementation])
2033       glib_memory_barrier_needed=yes
2034       ;;
2035     ia64)
2036       AC_MSG_RESULT([ia64])
2037       AC_DEFINE_UNQUOTED(G_ATOMIC_IA64, 1,
2038                          [ia64 atomic implementation])
2039       glib_memory_barrier_needed=yes
2040       ;;
2041     s390|s390x)
2042       AC_MSG_RESULT([s390])
2043       AC_DEFINE_UNQUOTED(G_ATOMIC_S390, 1,
2044                          [s390 atomic implementation])
2045       glib_memory_barrier_needed=no
2046       ;;
2047     *)
2048       AC_MSG_RESULT([none])
2049       glib_memory_barrier_needed=yes
2050       ;;
2051   esac
2052 fi
2053
2054 dnl ****************************************
2055 dnl *** GLib POLL* compatibility defines ***
2056 dnl ****************************************
2057
2058 glib_poll_includes=["
2059 #include <sys/types.h>
2060 #include <sys/poll.h>
2061 "]
2062
2063 if test $ac_cv_header_sys_types_h = yes &&
2064    test $ac_cv_header_sys_poll_h = yes ; then
2065   glib_failed=false
2066   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2067   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2068   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2069   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2070   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2071   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2072   if $glib_failed ; then
2073     AC_MSG_ERROR([Could not determine values for POLL* constants])
2074   fi
2075 else
2076   glib_cv_value_POLLIN=1
2077   glib_cv_value_POLLOUT=4
2078   glib_cv_value_POLLPRI=2
2079   glib_cv_value_POLLERR=8
2080   glib_cv_value_POLLHUP=16
2081   glib_cv_value_POLLNVAL=32
2082 fi
2083
2084 dnl **********************
2085 dnl *** Win32 API libs ***
2086 dnl **********************
2087
2088 case $host in
2089   *-*-cygwin*)
2090         G_LIBS_EXTRA="-luser32 -lkernel32"
2091     ;;
2092   *-*-mingw*)
2093         G_LIBS_EXTRA="-lws2_32 -lole32"
2094     ;;
2095   *)
2096         G_LIBS_EXTRA=""
2097     ;;
2098 esac
2099 AC_SUBST(G_LIBS_EXTRA)
2100
2101 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2102 dnl since we need it for g_iconv()
2103
2104 AC_MSG_CHECKING([for EILSEQ])
2105 AC_TRY_COMPILE([
2106 #include <errno.h>
2107 ],
2108 [
2109 int error = EILSEQ;
2110 ], have_eilseq=yes, have_eilseq=no);
2111 AC_MSG_RESULT($have_eilseq)
2112
2113 dnl ******************************************************************
2114 dnl *** Look for glib-genmarshal in PATH if we are cross-compiling ***
2115 dnl ******************************************************************
2116
2117 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2118
2119 if test $cross_compiling = yes; then
2120   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2121   if test x$GLIB_GENMARSHAL = xno; then
2122     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2123   fi
2124 fi
2125
2126 dnl **************************
2127 dnl *** Checks for gtk-doc ***
2128 dnl **************************
2129
2130 GTK_DOC_CHECK([1.4])
2131
2132 AC_ARG_ENABLE(man,
2133               [AC_HELP_STRING([--enable-man],
2134                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2135               enable_man=no)
2136
2137 if test "${enable_man}" != no; then
2138 dnl
2139 dnl Check for xsltproc
2140 dnl
2141 AC_PATH_PROG([XSLTPROC], [xsltproc])
2142   if test -z "$XSLTPROC"; then
2143     enable_man=no
2144   fi
2145
2146   dnl check for DocBook DTD and stylesheets in the local catalog.
2147   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2148      [DocBook XML DTD V4.1.2],,enable_man=no)
2149   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2150      [DocBook XSL Stylesheets],,enable_man=no)
2151 fi
2152
2153 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2154
2155 dnl ******************************
2156 dnl *** output the whole stuff ***
2157 dnl ******************************
2158
2159 dnl this section will only be run if config.status is invoked with no
2160 dnl arguments, or with "glibconfig.h" as an argument.
2161 AC_CONFIG_COMMANDS([glibconfig.h],
2162 [
2163         outfile=glibconfig.h-tmp
2164         cat > $outfile <<\_______EOF
2165 /* glibconfig.h
2166  *
2167  * This is a generated file.  Please modify 'configure.in'
2168  */
2169
2170 #ifndef __G_LIBCONFIG_H__
2171 #define __G_LIBCONFIG_H__
2172
2173 #include <glib/gmacros.h>
2174
2175 _______EOF
2176
2177         if test x$glib_limits_h = xyes; then
2178           echo '#include <limits.h>' >> $outfile
2179         fi
2180         if test x$glib_float_h = xyes; then
2181           echo '#include <float.h>' >> $outfile
2182         fi
2183         if test x$glib_values_h = xyes; then
2184           echo '#include <values.h>' >> $outfile
2185         fi
2186         if test "$glib_header_alloca_h" = "yes"; then
2187           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2188         fi
2189         if test x$glib_sys_poll_h = xyes; then
2190           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2191         fi
2192
2193         cat >> $outfile <<_______EOF
2194
2195 G_BEGIN_DECLS
2196
2197 #define G_MINFLOAT      $glib_mf
2198 #define G_MAXFLOAT      $glib_Mf
2199 #define G_MINDOUBLE     $glib_md
2200 #define G_MAXDOUBLE     $glib_Md
2201 #define G_MINSHORT      $glib_ms
2202 #define G_MAXSHORT      $glib_Ms
2203 #define G_MAXUSHORT     $glib_Mus
2204 #define G_MININT        $glib_mi
2205 #define G_MAXINT        $glib_Mi
2206 #define G_MAXUINT       $glib_Mui
2207 #define G_MINLONG       $glib_ml
2208 #define G_MAXLONG       $glib_Ml
2209 #define G_MAXULONG      $glib_Mul
2210
2211 _______EOF
2212
2213
2214         ### this should always be true in a modern C/C++ compiler
2215         cat >>$outfile <<_______EOF
2216 typedef signed char gint8;
2217 typedef unsigned char guint8;
2218 _______EOF
2219
2220
2221         if test -n "$gint16"; then
2222           cat >>$outfile <<_______EOF
2223 typedef signed $gint16 gint16;
2224 typedef unsigned $gint16 guint16;
2225 #define G_GINT16_MODIFIER $gint16_modifier
2226 #define G_GINT16_FORMAT $gint16_format
2227 #define G_GUINT16_FORMAT $guint16_format
2228 _______EOF
2229         fi
2230
2231
2232         if test -n "$gint32"; then
2233           cat >>$outfile <<_______EOF
2234 typedef signed $gint32 gint32;
2235 typedef unsigned $gint32 guint32;
2236 #define G_GINT32_MODIFIER $gint32_modifier
2237 #define G_GINT32_FORMAT $gint32_format
2238 #define G_GUINT32_FORMAT $guint32_format
2239 _______EOF
2240         fi
2241
2242         cat >>$outfile <<_______EOF
2243 #define G_HAVE_GINT64 1          /* deprecated, always true */
2244
2245 ${glib_extension}typedef signed $gint64 gint64;
2246 ${glib_extension}typedef unsigned $gint64 guint64;
2247
2248 #define G_GINT64_CONSTANT(val)  $gint64_constant
2249 #define G_GUINT64_CONSTANT(val) $guint64_constant
2250 _______EOF
2251
2252         if test x$gint64_format != x ; then
2253           cat >>$outfile <<_______EOF
2254 #define G_GINT64_MODIFIER $gint64_modifier
2255 #define G_GINT64_FORMAT $gint64_format
2256 #define G_GUINT64_FORMAT $guint64_format
2257 _______EOF
2258         else
2259           cat >>$outfile <<_______EOF
2260 #undef G_GINT64_MODIFIER
2261 #undef G_GINT64_FORMAT
2262 #undef G_GUINT64_FORMAT
2263 _______EOF
2264         fi
2265
2266         cat >>$outfile <<_______EOF
2267
2268 #define GLIB_SIZEOF_VOID_P $glib_void_p
2269 #define GLIB_SIZEOF_LONG   $glib_long
2270 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2271
2272 _______EOF
2273
2274         cat >>$outfile <<_______EOF
2275 typedef signed $glib_size_type_define gssize;
2276 typedef unsigned $glib_size_type_define gsize;
2277 #define G_GSIZE_MODIFIER $gsize_modifier
2278 #define G_GSSIZE_FORMAT $gssize_format
2279 #define G_GSIZE_FORMAT $gsize_format
2280
2281 #define G_MAXSIZE       G_MAXU$glib_msize_type
2282 _______EOF
2283
2284         if test -z "$glib_unknown_void_p"; then
2285           cat >>$outfile <<_______EOF
2286
2287 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2288 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2289
2290 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2291 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2292 _______EOF
2293         else
2294           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2295         fi
2296
2297
2298
2299         cat >>$outfile <<_______EOF
2300 $glib_atexit
2301 $glib_memmove
2302 $glib_defines
2303 $glib_os
2304
2305 $glib_vacopy
2306
2307 #ifdef  __cplusplus
2308 #define G_HAVE_INLINE   1
2309 #else   /* !__cplusplus */
2310 $glib_inline
2311 #endif  /* !__cplusplus */
2312
2313 #ifdef  __cplusplus
2314 #define G_CAN_INLINE    1
2315 _______EOF
2316
2317         if test x$g_can_inline = xyes ; then
2318                 cat >>$outfile <<_______EOF
2319 #else   /* !__cplusplus */
2320 #define G_CAN_INLINE    1
2321 _______EOF
2322         fi
2323
2324         cat >>$outfile <<_______EOF
2325 #endif
2326
2327 _______EOF
2328
2329         if test x$g_have_iso_c_varargs = xyes ; then
2330                 cat >>$outfile <<_______EOF
2331 #ifndef __cplusplus
2332 # define G_HAVE_ISO_VARARGS 1
2333 #endif
2334 _______EOF
2335         fi
2336         if test x$g_have_iso_cxx_varargs = xyes ; then
2337                 cat >>$outfile <<_______EOF
2338 #ifdef __cplusplus
2339 # define G_HAVE_ISO_VARARGS 1
2340 #endif
2341 _______EOF
2342         fi
2343         if test x$g_have_gnuc_varargs = xyes ; then
2344                 cat >>$outfile <<_______EOF
2345
2346 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2347  * is passed ISO vararg support is turned off, and there is no work
2348  * around to turn it on, so we unconditionally turn it off.
2349  */
2350 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2351 #  undef G_HAVE_ISO_VARARGS
2352 #endif
2353
2354 #define G_HAVE_GNUC_VARARGS 1
2355 _______EOF
2356         fi
2357
2358         case x$g_stack_grows in
2359         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2360         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2361         esac
2362
2363
2364         echo >>$outfile
2365         if test x$g_have_eilseq = xno; then
2366                 cat >>$outfile <<_______EOF
2367 #ifndef EILSEQ
2368 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
2369  * The correspondence between this and the corresponding definition
2370  * in libiconv is essential.
2371  */
2372 #  define EILSEQ ENOENT
2373 #endif
2374 _______EOF
2375
2376         fi
2377
2378         if test x$g_have_gnuc_visibility = xyes ; then
2379                 cat >>$outfile <<_______EOF
2380 #define G_HAVE_GNUC_VISIBILITY 1
2381 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2382 _______EOF
2383         else
2384                 cat >>$outfile <<_______EOF
2385 #define G_GNUC_INTERNAL
2386 _______EOF
2387         fi
2388
2389
2390         echo >>$outfile
2391         if test x$g_mutex_has_default = xyes; then
2392                 cat >>$outfile <<_______EOF
2393 $g_enable_threads_def G_THREADS_ENABLED
2394 #define G_THREADS_IMPL_$g_threads_impl_def
2395 typedef struct _GStaticMutex GStaticMutex;
2396 struct _GStaticMutex
2397 {
2398   struct _GMutex *runtime_mutex;
2399   union {
2400     char   pad[[$g_mutex_sizeof]];
2401     double dummy_double;
2402     void  *dummy_pointer;
2403     long   dummy_long;
2404   } static_mutex;
2405 };
2406 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
2407 #define g_static_mutex_get_mutex(mutex) \\
2408   (g_thread_use_default_impl ? ((GMutex*) ((mutex)->static_mutex.pad)) : \\
2409    g_static_mutex_get_mutex_impl_shortcut (&((mutex)->runtime_mutex)))
2410 _______EOF
2411         else
2412                 cat >>$outfile <<_______EOF
2413 $g_enable_threads_def G_THREADS_ENABLED
2414 #define G_THREADS_IMPL_$g_threads_impl_def
2415 typedef struct _GMutex* GStaticMutex;
2416 #define G_STATIC_MUTEX_INIT NULL
2417 #define g_static_mutex_get_mutex(mutex) \\
2418   (g_static_mutex_get_mutex_impl_shortcut (mutex))
2419 _______EOF
2420         fi
2421
2422         cat >>$outfile <<_______EOF
2423 /* This represents a system thread as used by the implementation. An
2424  * alien implementaion, as loaded by g_thread_init can only count on
2425  * "sizeof (gpointer)" bytes to store their info. We however need more
2426  * for some of our native implementations. */
2427 typedef union _GSystemThread GSystemThread;
2428 union _GSystemThread
2429 {
2430   char   data[[$g_system_thread_sizeof]];
2431   double dummy_double;
2432   void  *dummy_pointer;
2433   long   dummy_long;
2434 };
2435 _______EOF
2436         if test x"$g_memory_barrier_needed" != xno; then
2437           echo >>$outfile
2438           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
2439         fi
2440
2441         echo >>$outfile
2442         g_bit_sizes="16 32 64"
2443         for bits in $g_bit_sizes; do
2444           cat >>$outfile <<_______EOF
2445 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
2446 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
2447 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
2448 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
2449 _______EOF
2450         done
2451
2452         cat >>$outfile <<_______EOF
2453 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
2454 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
2455 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
2456 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
2457 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
2458 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
2459 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
2460 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
2461 #define G_BYTE_ORDER $g_byte_order
2462
2463 #define GLIB_SYSDEF_POLLIN =$g_pollin
2464 #define GLIB_SYSDEF_POLLOUT =$g_pollout
2465 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
2466 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
2467 #define GLIB_SYSDEF_POLLERR =$g_pollerr
2468 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
2469
2470 #define G_MODULE_SUFFIX "$g_module_suffix"
2471
2472 typedef $g_pid_type GPid;
2473
2474 G_END_DECLS
2475
2476 #endif /* GLIBCONFIG_H */
2477 _______EOF
2478
2479
2480         if cmp -s $outfile glibconfig.h; then
2481           AC_MSG_NOTICE([glibconfig.h is unchanged])
2482           rm -f $outfile
2483         else
2484           mv $outfile glibconfig.h
2485         fi
2486 ],[
2487
2488 # Note that if two cases are the same, case goes with the first one.
2489 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
2490 # on variable expansion in case labels.  Look at the generated config.status
2491 # for a hint.
2492
2493 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
2494   glib_header_alloca_h="$ac_cv_working_alloca_h"
2495 else
2496   glib_header_alloca_h="$ac_cv_header_alloca_h"
2497 fi
2498
2499 case xyes in
2500 x$ac_cv_header_float_h)
2501   glib_float_h=yes
2502   glib_mf=FLT_MIN glib_Mf=FLT_MAX
2503   glib_md=DBL_MIN glib_Md=DBL_MAX
2504   ;;
2505 x$ac_cv_header_values_h)
2506   glib_values_h=yes
2507   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
2508   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
2509   ;;
2510 esac
2511
2512 case xyes in
2513 x$ac_cv_header_limits_h)
2514   glib_limits_h=yes
2515   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
2516   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
2517   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
2518   ;;
2519 x$ac_cv_header_values_h)
2520   glib_values_h=yes
2521   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
2522   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
2523   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
2524   ;;
2525 esac
2526
2527 if test x$ac_cv_header_sys_poll_h = xyes ; then
2528   glib_sys_poll_h=yes
2529 fi
2530
2531 case 2 in
2532 $ac_cv_sizeof_short)
2533   gint16=short
2534   gint16_modifier='"h"'
2535   gint16_format='"hi"'
2536   guint16_format='"hu"'
2537   ;;
2538 $ac_cv_sizeof_int)
2539   gint16=int
2540   gint16_modifier='""'
2541   gint16_format='"i"'
2542   guint16_format='"u"'
2543   ;;
2544 esac
2545 case 4 in
2546 $ac_cv_sizeof_short)
2547   gint32=short
2548   gint32_modifier='"h"'
2549   gint32_format='"hi"'
2550   guint32_format='"hu"'
2551   ;;
2552 $ac_cv_sizeof_int)
2553   gint32=int
2554   gint32_modifier='""'
2555   gint32_format='"i"'
2556   guint32_format='"u"'
2557   ;;
2558 $ac_cv_sizeof_long)
2559   gint32=long
2560   gint32_modifier='"l"'
2561   gint32_format='"li"'
2562   guint32_format='"lu"'
2563   ;;
2564 esac
2565 case 8 in
2566 $ac_cv_sizeof_int)
2567   gint64=int
2568   gint64_modifier='""'
2569   gint64_format='"i"'
2570   guint64_format='"u"'
2571   glib_extension=
2572   gint64_constant='(val)'
2573   guint64_constant='(val)'
2574   ;;
2575 $ac_cv_sizeof_long)
2576   gint64=long
2577   gint64_modifier='"l"'
2578   gint64_format='"li"'
2579   guint64_format='"lu"'
2580   glib_extension=
2581   gint64_constant='(val##L)'
2582   guint64_constant='(val##UL)'
2583   ;;
2584 $ac_cv_sizeof_long_long)
2585   gint64='long long'
2586   if test -n "$glib_cv_long_long_format"; then
2587     gint64_modifier='"'$glib_cv_long_long_format'"'
2588     gint64_format='"'$glib_cv_long_long_format'i"'
2589     guint64_format='"'$glib_cv_long_long_format'u"'
2590   fi
2591   glib_extension='G_GNUC_EXTENSION '
2592   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
2593   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
2594   ;;
2595 $ac_cv_sizeof___int64)
2596   gint64='__int64'
2597   if test -n "$glib_cv_long_long_format"; then
2598     gint64_modifier='"'$glib_cv_long_long_format'"'
2599     gint64_format='"'$glib_cv_long_long_format'i"'
2600     guint64_format='"'$glib_cv_long_long_format'u"'
2601   fi
2602   glib_extension=
2603   gint64_constant='(val##i64)'
2604   guint64_constant='(val##ui64)'
2605   ;;
2606 esac
2607 glib_size_t=$ac_cv_sizeof_size_t
2608 glib_size_type_define=$glib_size_type
2609 glib_void_p=$ac_cv_sizeof_long
2610 glib_long=$ac_cv_sizeof_void_p
2611
2612 case $glib_size_type in
2613 short)
2614   gsize_modifier='"h"'
2615   gsize_format='"hu"'
2616   gssize_format='"hi"'
2617   glib_msize_type='SHRT'
2618   ;;
2619 int)
2620   gsize_modifier='""'
2621   gsize_format='"u"'
2622   gssize_format='"i"'
2623   glib_msize_type='INT'
2624   ;;
2625 long)
2626   gsize_modifier='"l"'
2627   gsize_format='"lu"'
2628   gssize_format='"li"'
2629   glib_msize_type='LONG'
2630   ;;
2631 esac
2632
2633 gintbits=`expr $ac_cv_sizeof_int \* 8`
2634 glongbits=`expr $ac_cv_sizeof_long \* 8`
2635
2636
2637 case $ac_cv_sizeof_void_p in
2638 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
2639 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
2640 *)                      glib_unknown_void_p=yes ;;
2641 esac
2642
2643
2644 case xyes in
2645 x$ac_cv_func_atexit)
2646   glib_atexit="
2647 #ifdef NeXT /* @#%@! NeXTStep */
2648 # define g_ATEXIT(proc) (!atexit (proc))
2649 #else
2650 # define g_ATEXIT(proc) (atexit (proc))
2651 #endif"
2652   ;;
2653 x$ac_cv_func_on_exit)
2654   glib_atexit="
2655 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
2656   ;;
2657 esac
2658
2659 case xyes in
2660 x$ac_cv_func_memmove)
2661   glib_memmove='
2662 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
2663   ;;
2664 x$glib_cv_working_bcopy)
2665   glib_memmove="
2666 /* memmove isn't available, but bcopy can copy overlapping memory regions */
2667 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
2668   ;;
2669 *)
2670   glib_memmove="
2671 /* memmove isn't found and bcopy can't copy overlapping memory regions,
2672  * so we have to roll our own copy routine. */
2673 void g_memmove (void* dest, const void * src, unsigned long len);"
2674   ;;
2675 esac
2676
2677 glib_defines="
2678 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
2679 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
2680 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
2681 "
2682
2683 case xyes in
2684 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
2685 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
2686 *)                      glib_vacopy=''
2687 esac
2688
2689 if test x$glib_cv_va_val_copy = xno; then
2690   glib_vacopy="\$glib_vacopy
2691 #define G_VA_COPY_AS_ARRAY 1"
2692 fi
2693
2694 if test x$glib_cv_hasinline = xyes; then
2695     glib_inline='#define G_HAVE_INLINE 1'
2696 fi
2697 if test x$glib_cv_has__inline = xyes; then
2698     glib_inline="\$glib_inline
2699 #define G_HAVE___INLINE 1"
2700 fi
2701 if test x$glib_cv_has__inline__ = xyes; then
2702     glib_inline="\$glib_inline
2703 #define G_HAVE___INLINE__ 1"
2704 fi
2705
2706 g_have_gnuc_varargs=$g_have_gnuc_varargs
2707 g_have_iso_c_varargs=$g_have_iso_c_varargs
2708 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
2709
2710 g_can_inline=$g_can_inline
2711 g_have_gnuc_visibility=$g_have_gnuc_visibility
2712
2713 case xyes in
2714 x$ac_cv_c_bigendian)
2715   g_byte_order=G_BIG_ENDIAN
2716   g_bs_native=BE
2717   g_bs_alien=LE
2718   ;;
2719 *)
2720   g_byte_order=G_LITTLE_ENDIAN
2721   g_bs_native=LE
2722   g_bs_alien=BE
2723   ;;
2724 esac
2725
2726 g_pollin=$glib_cv_value_POLLIN
2727 g_pollout=$glib_cv_value_POLLOUT
2728 g_pollpri=$glib_cv_value_POLLPRI
2729 g_pollhup=$glib_cv_value_POLLHUP
2730 g_pollerr=$glib_cv_value_POLLERR
2731 g_pollnval=$glib_cv_value_POLLNVAL
2732
2733 g_stack_grows=$glib_cv_stack_grows
2734
2735 g_have_eilseq=$have_eilseq
2736
2737 case x$have_threads in
2738 xno)    g_enable_threads_def="#undef";;
2739 *)      g_enable_threads_def="#define";;
2740 esac
2741
2742 g_threads_impl_def=$g_threads_impl
2743
2744 g_mutex_has_default="$mutex_has_default"
2745 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
2746 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
2747 g_mutex_contents="$glib_cv_byte_contents_gmutex"
2748
2749 g_memory_barrier_needed="$glib_memory_barrier_needed"
2750
2751 g_module_suffix="$glib_gmodule_suffix"
2752
2753 g_pid_type="$glib_pid_type"
2754 case $host in
2755   *-*-beos*)
2756     glib_os="#define G_OS_BEOS"
2757     ;;
2758   *-*-cygwin*)
2759     glib_os="#define G_OS_UNIX
2760 #define G_PLATFORM_WIN32
2761 #define G_WITH_CYGWIN"
2762     ;;
2763   *-*-mingw*)
2764     glib_os="#define G_OS_WIN32
2765 #define G_PLATFORM_WIN32"
2766     ;;
2767   *)
2768     glib_os="#define G_OS_UNIX"
2769     ;;
2770 esac
2771 ])
2772
2773 AC_CONFIG_FILES([
2774 glib-2.0.pc
2775 glib-2.0-uninstalled.pc
2776 gmodule-2.0.pc
2777 gmodule-export-2.0.pc
2778 gmodule-no-export-2.0.pc
2779 gmodule-2.0-uninstalled.pc
2780 gmodule-no-export-2.0-uninstalled.pc
2781 gthread-2.0.pc
2782 gthread-2.0-uninstalled.pc
2783 gobject-2.0.pc
2784 gobject-2.0-uninstalled.pc
2785 glib-zip
2786 glib-gettextize
2787 Makefile
2788 build/Makefile
2789 build/win32/Makefile
2790 build/win32/dirent/Makefile
2791 glib/Makefile
2792 glib/libcharset/Makefile
2793 glib/gnulib/Makefile
2794 gmodule/Makefile
2795 gmodule/gmoduleconf.h
2796 gobject/Makefile
2797 gobject/glib-mkenums
2798 gthread/Makefile
2799 po/Makefile.in
2800 docs/Makefile
2801 docs/reference/Makefile
2802 docs/reference/glib/Makefile
2803 docs/reference/glib/version.xml
2804 docs/reference/gobject/Makefile
2805 docs/reference/gobject/version.xml
2806 tests/Makefile
2807 tests/gobject/Makefile
2808 tests/refcount/Makefile
2809 m4macros/Makefile
2810 ])
2811
2812 AC_CONFIG_COMMANDS([chmod-scripts],
2813 [chmod 0755 glib-zip
2814 chmod 0755 glib-gettextize
2815 chmod 0755 gobject/glib-mkenums])
2816
2817 # we want to invoke this macro solely so that the config.status script
2818 # and automake generated makefiles know about these generated files.
2819 # They are only needed to distcheck the package
2820 if false; then
2821   AC_CONFIG_FILES([
2822     INSTALL
2823     README
2824     config.h.win32
2825     glibconfig.h.win32
2826     glib/makefile.msc
2827     glib/glib.rc
2828     gmodule/makefile.msc
2829     gmodule/gmodule.rc
2830     gobject/makefile.msc
2831     gobject/gobject.rc
2832     gthread/makefile.msc
2833     gthread/gthread.rc
2834     tests/makefile.msc
2835   ])
2836 fi
2837
2838 AC_OUTPUT