configure.in

   1 AC_PREREQ([2.67])
   2 AC_INIT([cryptsetup],[1.4.4-git])
   3
   4 dnl library version from <major>.<minor>.<release>[-<suffix>]
   5 LIBCRYPTSETUP_VERSION=$(echo $PACKAGE_VERSION | cut -f1 -d-)
   6 LIBCRYPTSETUP_VERSION_INFO=6:0:2
   7
   8 AC_CONFIG_SRCDIR(src/cryptsetup.c)
   9 AC_CONFIG_MACRO_DIR([m4])
  10
  11 AC_CONFIG_HEADERS([config.h:config.h.in])
  12 AM_INIT_AUTOMAKE(dist-bzip2)
  13
  14 if test "x$prefix" = "xNONE"; then
  15         sysconfdir=/etc
  16 fi
  17 AC_PREFIX_DEFAULT(/usr)
  18
  19 AC_CANONICAL_HOST
  20 AC_USE_SYSTEM_EXTENSIONS
  21 AC_PROG_CC
  22 AM_PROG_CC_C_O
  23 AC_PROG_CPP
  24 AC_PROG_INSTALL
  25 AC_PROG_MAKE_SET
  26 AC_ENABLE_STATIC(no)
  27 LT_INIT
  28
  29 AC_HEADER_DIRENT
  30 AC_HEADER_STDC
  31 AC_CHECK_HEADERS(fcntl.h malloc.h inttypes.h sys/ioctl.h sys/mman.h \
  32         ctype.h unistd.h locale.h)
  33
  34 AC_CHECK_HEADERS(uuid/uuid.h,,[AC_MSG_ERROR([You need the uuid library.])])
  35 AC_CHECK_HEADER(libdevmapper.h,,[AC_MSG_ERROR([You need the device-mapper library.])])
  36
  37 saved_LIBS=$LIBS
  38 AC_CHECK_LIB(uuid, uuid_clear, ,[AC_MSG_ERROR([You need the uuid library.])])
  39 AC_SUBST(UUID_LIBS, $LIBS)
  40 LIBS=$saved_LIBS
  41
  42 AC_CHECK_FUNCS([posix_memalign])
  43
  44 AC_C_CONST
  45 AC_C_BIGENDIAN
  46 AC_TYPE_OFF_T
  47 AC_SYS_LARGEFILE
  48
  49 AC_PROG_GCC_TRADITIONAL
  50
  51 dnl ==========================================================================
  52
  53 AM_GNU_GETTEXT([external],[need-ngettext])
  54 AM_GNU_GETTEXT_VERSION([0.15])
  55
  56 dnl ==========================================================================
  57
  58 saved_LIBS=$LIBS
  59 AC_CHECK_LIB(popt, poptConfigFileToString,,
  60         [AC_MSG_ERROR([You need popt 1.7 or newer to compile.])])
  61 AC_SUBST(POPT_LIBS, $LIBS)
  62 LIBS=$saved_LIBS
  63
  64 dnl ==========================================================================
  65 dnl FIPS extensions
  66 AC_ARG_ENABLE([fips], AS_HELP_STRING([--enable-fips],[enable FIPS mode restrictions]),
  67 [with_fips=$enableval],
  68 [with_fips=no])
  69
  70 if test "x$with_fips" = "xyes"; then
  71         AC_DEFINE(ENABLE_FIPS, 1, [Enable FIPS mode restrictions])
  72
  73         if test "x$enable_static" = "xyes" -o "x$enable_static_cryptsetup" = "xyes" ; then
  74                 AC_MSG_ERROR([Static build is not compatible with FIPS.])
  75         fi
  76
  77         saved_LIBS=$LIBS
  78         AC_CHECK_LIB(fipscheck, FIPSCHECK_verify, ,[AC_MSG_ERROR([You need the fipscheck library.])])
  79         AC_SUBST(FIPSCHECK_LIBS, $LIBS)
  80         LIBS=$saved_LIBS
  81
  82 fi
  83
  84 AC_DEFUN([NO_FIPS], [
  85         if test "x$with_fips" = "xyes"; then
  86                 AC_MSG_ERROR([This option is not compatible with FIPS.])
  87         fi
  88 ])
  89
  90 dnl ==========================================================================
  91 dnl Crypto backend functions
  92
  93 AC_DEFUN([CONFIGURE_GCRYPT], [
  94         if test "x$with_fips" = "xyes"; then
  95                 GCRYPT_REQ_VERSION=1.4.5
  96         else
  97                 GCRYPT_REQ_VERSION=1.1.42
  98         fi
  99         AM_PATH_LIBGCRYPT($GCRYPT_REQ_VERSION,,[AC_MSG_ERROR([You need the gcrypt library.])])
 100
 101         if test x$enable_static_cryptsetup = xyes; then
 102                 saved_LIBS=$LIBS
 103                 LIBS="$saved_LIBS $LIBGCRYPT_LIBS -static"
 104                 AC_CHECK_LIB(gcrypt, gcry_check_version,,
 105                         AC_MSG_ERROR([Cannot find static gcrypt library.]),
 106                         [-lgpg-error])
 107                 LIBGCRYPT_STATIC_LIBS="$LIBGCRYPT_LIBS -lgpg-error"
 108                 LIBS=$saved_LIBS
 109         fi
 110
 111         CRYPTO_CFLAGS=$LIBGCRYPT_CFLAGS
 112         CRYPTO_LIBS=$LIBGCRYPT_LIBS
 113         CRYPTO_STATIC_LIBS=$LIBGCRYPT_STATIC_LIBS
 114
 115         AC_DEFINE_UNQUOTED(GCRYPT_REQ_VERSION, ["$GCRYPT_REQ_VERSION"], [Requested gcrypt version])
 116 ])
 117
 118 AC_DEFUN([CONFIGURE_OPENSSL], [
 119         PKG_CHECK_MODULES([OPENSSL], [openssl >= 0.9.8],,
 120                 AC_MSG_ERROR([You need openssl library.]))
 121         CRYPTO_CFLAGS=$OPENSSL_CFLAGS
 122         CRYPTO_LIBS=$OPENSSL_LIBS
 123
 124         if test x$enable_static_cryptsetup = xyes; then
 125                 saved_PKG_CONFIG=$PKG_CONFIG
 126                 PKG_CONFIG="$PKG_CONFIG --static"
 127                 PKG_CHECK_MODULES([OPENSSL], [openssl])
 128                 CRYPTO_STATIC_LIBS=$OPENSSL_LIBS
 129                 PKG_CONFIG=$saved_PKG_CONFIG
 130         fi
 131         NO_FIPS([])
 132 ])
 133
 134 AC_DEFUN([CONFIGURE_NSS], [
 135         if test x$enable_static_cryptsetup = xyes; then
 136                 AC_MSG_ERROR([Static build of cryptsetup is not supported with NSS.])
 137         fi
 138
 139         AC_MSG_WARN([NSS backend does NOT provide backward compatibility (missing ripemd160 hash).])
 140
 141         PKG_CHECK_MODULES([NSS], [nss],,
 142                 AC_MSG_ERROR([You need nss library.]))
 143
 144         saved_CFLAGS=$CFLAGS
 145         CFLAGS="$CFLAGS $NSS_CFLAGS"
 146         AC_CHECK_DECLS([NSS_GetVersion], [], [], [#include <nss.h>])
 147         CFLAGS=$saved_CFLAGS
 148
 149         CRYPTO_CFLAGS=$NSS_CFLAGS
 150         CRYPTO_LIBS=$NSS_LIBS
 151         NO_FIPS([])
 152 ])
 153
 154 AC_DEFUN([CONFIGURE_KERNEL], [
 155         AC_CHECK_HEADERS(linux/if_alg.h,,
 156                 [AC_MSG_ERROR([You need Linux kernel with userspace crypto interface.])])
 157 #       AC_CHECK_DECLS([AF_ALG],,
 158 #               [AC_MSG_ERROR([You need Linux kernel with userspace crypto interface.])],
 159 #               [#include <sys/socket.h>])
 160         NO_FIPS([])
 161 ])
 162
 163 AC_DEFUN([CONFIGURE_NETTLE], [
 164         AC_CHECK_HEADERS(nettle/sha.h,,
 165                 [AC_MSG_ERROR([You need Nettle cryptographic library.])])
 166
 167         saved_LIBS=$LIBS
 168         AC_CHECK_LIB(nettle, nettle_ripemd160_init,,
 169                 [AC_MSG_ERROR([You need Nettle library version 2.4 or more recent.])])
 170         CRYPTO_LIBS=$LIBS
 171         LIBS=$saved_LIBS
 172
 173         CRYPTO_STATIC_LIBS=$CRYPTO_LIBS
 174         NO_FIPS([])
 175 ])
 176
 177 dnl ==========================================================================
 178 saved_LIBS=$LIBS
 179
 180 AC_ARG_ENABLE([static-cryptsetup],
 181         AS_HELP_STRING([--enable-static-cryptsetup],
 182         [enable build of static cryptsetup binary]))
 183 if test x$enable_static_cryptsetup = xyes; then
 184         if test x$enable_static = xno; then
 185                 AC_MSG_WARN([Requested static cryptsetup build, enabling static library.])
 186                 enable_static=yes
 187         fi
 188 fi
 189 AM_CONDITIONAL(STATIC_CRYPTSETUP, test x$enable_static_cryptsetup = xyes)
 190
 191 AC_ARG_ENABLE(selinux,
 192         AS_HELP_STRING([--disable-selinux],
 193         [disable selinux support [default=auto]]),[], [])
 194
 195 AC_ARG_ENABLE([udev],
 196         AS_HELP_STRING([--disable-udev],
 197         [disable udev support]),[], enable_udev=yes)
 198
 199 dnl Try to use pkg-config for devmapper, but fallback to old detection
 200 PKG_CHECK_MODULES([DEVMAPPER], [devmapper >= 1.02.03],, [
 201         AC_CHECK_LIB(devmapper, dm_task_set_name,,
 202                 [AC_MSG_ERROR([You need the device-mapper library.])])
 203         AC_CHECK_LIB(devmapper, dm_task_set_message,,
 204                 [AC_MSG_ERROR([The device-mapper library on your system is too old.])])
 205         DEVMAPPER_LIBS=$LIBS
 206 ])
 207 LIBS=$saved_LIBS
 208
 209 LIBS="$LIBS $DEVMAPPER_LIBS"
 210 AC_CHECK_DECLS([dm_task_secure_data], [], [], [#include <libdevmapper.h>])
 211 AC_CHECK_DECLS([dm_task_retry_remove], [], [], [#include <libdevmapper.h>])
 212 AC_CHECK_DECLS([DM_UDEV_DISABLE_DISK_RULES_FLAG], [have_cookie=yes], [have_cookie=no], [#include <libdevmapper.h>])
 213 if test "x$enable_udev" = xyes; then
 214         if test "x$have_cookie" = xno; then
 215                 AC_MSG_WARN([The device-mapper library on your system has no udev support, udev support disabled.])
 216         else
 217                 AC_DEFINE(USE_UDEV, 1, [Try to use udev synchronisation?])
 218         fi
 219 fi
 220 LIBS=$saved_LIBS
 221
 222 dnl Crypto backend configuration.
 223 AC_ARG_WITH([crypto_backend],
 224         AS_HELP_STRING([--with-crypto_backend=BACKEND], [crypto backend (gcrypt/openssl/nss/kernel/nettle) [gcrypt]]),
 225         [], with_crypto_backend=gcrypt
 226 )
 227 case $with_crypto_backend in
 228         gcrypt)  CONFIGURE_GCRYPT([]) ;;
 229         openssl) CONFIGURE_OPENSSL([]) ;;
 230         nss)     CONFIGURE_NSS([]) ;;
 231         kernel)  CONFIGURE_KERNEL([]) ;;
 232         nettle)  CONFIGURE_NETTLE([]) ;;
 233         *) AC_MSG_ERROR([Unknown crypto backend.]) ;;
 234 esac
 235 AM_CONDITIONAL(CRYPTO_BACKEND_GCRYPT,  test $with_crypto_backend = gcrypt)
 236 AM_CONDITIONAL(CRYPTO_BACKEND_OPENSSL, test $with_crypto_backend = openssl)
 237 AM_CONDITIONAL(CRYPTO_BACKEND_NSS,     test $with_crypto_backend = nss)
 238 AM_CONDITIONAL(CRYPTO_BACKEND_KERNEL,  test $with_crypto_backend = kernel)
 239 AM_CONDITIONAL(CRYPTO_BACKEND_NETTLE,  test $with_crypto_backend = nettle)
 240
 241 dnl Magic for cryptsetup.static build.
 242 if test x$enable_static_cryptsetup = xyes; then
 243         saved_PKG_CONFIG=$PKG_CONFIG
 244         PKG_CONFIG="$PKG_CONFIG --static"
 245
 246         LIBS="$saved_LIBS -static"
 247         AC_CHECK_LIB(popt, poptGetContext,,
 248                 AC_MSG_ERROR([Cannot find static popt library.]))
 249
 250         dnl Try to detect needed device-mapper static libraries, try pkg-config first.
 251         LIBS="$saved_LIBS -static"
 252         PKG_CHECK_MODULES([DEVMAPPER_STATIC], [devmapper >= 1.02.27],,[
 253                 DEVMAPPER_STATIC_LIBS=$DEVMAPPER_LIBS
 254                 if test "x$enable_selinux" != xno; then
 255                         AC_CHECK_LIB(sepol, sepol_bool_set)
 256                         AC_CHECK_LIB(selinux, is_selinux_enabled)
 257                         DEVMAPPER_STATIC_LIBS="$DEVMAPPER_STATIC_LIBS $LIBS"
 258                 fi
 259         ])
 260         LIBS="$saved_LIBS $DEVMAPPER_STATIC_LIBS"
 261         AC_CHECK_LIB(devmapper, dm_task_set_uuid,,
 262                 AC_MSG_ERROR([Cannot link with static device-mapper library.]))
 263
 264         dnl Try to detect uuid static library.
 265         LIBS="$saved_LIBS -static"
 266         AC_CHECK_LIB(uuid, uuid_generate,,
 267                 AC_MSG_ERROR([Cannot find static uuid library.]))
 268
 269         LIBS=$saved_LIBS
 270         PKG_CONFIG=$saved_PKG_CONFIG
 271 fi
 272
 273 AC_SUBST([DEVMAPPER_LIBS])
 274 AC_SUBST([DEVMAPPER_STATIC_LIBS])
 275
 276 AC_SUBST([CRYPTO_CFLAGS])
 277 AC_SUBST([CRYPTO_LIBS])
 278 AC_SUBST([CRYPTO_STATIC_LIBS])
 279
 280 AC_SUBST([LIBCRYPTSETUP_VERSION])
 281 AC_SUBST([LIBCRYPTSETUP_VERSION_INFO])
 282
 283 dnl ==========================================================================
 284 AC_ARG_ENABLE([dev-random], AS_HELP_STRING([--enable-dev-random],
 285 [use blocking /dev/random by default for key generator (otherwise use /dev/urandom)]),
 286 [default_rng=/dev/random], [default_rng=/dev/urandom])
 287 AC_DEFINE_UNQUOTED(DEFAULT_RNG, ["$default_rng"], [default RNG type for key generator])
 288
 289 dnl ==========================================================================
 290 AC_DEFUN([CS_DEFINE],
 291         [AC_DEFINE_UNQUOTED(DEFAULT_[]m4_translit([$1], [-a-z], [_A-Z]), [$2], [$3])
 292 ])
 293
 294 AC_DEFUN([CS_STR_WITH], [AC_ARG_WITH([$1],
 295         [AS_HELP_STRING(--with-[$1], [default $2 [$3]])],
 296         [CS_DEFINE([$1], ["$withval"], [$2])],
 297         [CS_DEFINE([$1], ["$3"], [$2])]
 298 )])
 299
 300 AC_DEFUN([CS_NUM_WITH], [AC_ARG_WITH([$1],
 301         [AS_HELP_STRING(--with-[$1], [default $2 [$3]])],
 302         [CS_DEFINE([$1], [$withval], [$2])],
 303         [CS_DEFINE([$1], [$3], [$2])]
 304 )])
 305
 306 dnl ==========================================================================
 307 dnl Python bindings
 308 AC_ARG_ENABLE([python], AS_HELP_STRING([--enable-python],[enable Python bindings]),
 309 [with_python=$enableval],
 310 [with_python=no])
 311
 312 if test "x$with_python" = "xyes"; then
 313         AM_PATH_PYTHON([2.4])
 314
 315         if ! test -x "$PYTHON-config" ; then
 316             AC_MSG_ERROR([Cannot find python development packages to build bindings])
 317         fi
 318
 319         PYTHON_INCLUDES=$($PYTHON-config --includes)
 320         AC_SUBST(PYTHON_INCLUDES)
 321 fi
 322 AM_CONDITIONAL([PYTHON_CRYPTSETUP], [test "x$with_python" = "xyes"])
 323
 324 dnl ==========================================================================
 325 CS_STR_WITH([plain-hash],   [password hashing function for plain mode], [ripemd160])
 326 CS_STR_WITH([plain-cipher], [cipher for plain mode], [aes])
 327 CS_STR_WITH([plain-mode],   [cipher mode for plain mode], [cbc-essiv:sha256])
 328 CS_NUM_WITH([plain-keybits],[key length in bits for plain mode], [256])
 329
 330 CS_STR_WITH([luks1-hash],   [hash function for LUKS1 header], [sha1])
 331 CS_STR_WITH([luks1-cipher], [cipher for LUKS1], [aes])
 332 CS_STR_WITH([luks1-mode],   [cipher mode for LUKS1], [cbc-essiv:sha256])
 333 CS_NUM_WITH([luks1-keybits],[key length in bits for LUKS1], [256])
 334
 335 CS_STR_WITH([loopaes-cipher], [cipher for loop-AES mode], [aes])
 336 CS_NUM_WITH([loopaes-keybits],[key length in bits for loop-AES mode], [256])
 337
 338 CS_NUM_WITH([keyfile-size-maxkb],[maximum keyfile size (in kilobytes)], [8192])
 339 CS_NUM_WITH([passphrase-size-max],[maximum keyfile size (in kilobytes)], [512])
 340
 341 dnl ==========================================================================
 342
 343 AC_CONFIG_FILES([ Makefile
 344 lib/Makefile
 345 lib/libcryptsetup.pc
 346 lib/crypto_backend/Makefile
 347 lib/luks1/Makefile
 348 lib/loopaes/Makefile
 349 src/Makefile
 350 po/Makefile.in
 351 man/Makefile
 352 tests/Makefile
 353 python/Makefile
 354 ])
 355 AC_OUTPUT