configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.53)dnl              dnl Minimum Autoconf version required.
   3 AC_INIT([GNU C Library], [(see version.h)], [http://sourceware.org/bugzilla/], [glibc])
   4 AC_CONFIG_SRCDIR([include/features.h])
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_AUX_DIR([scripts])
   7
   8 dnl This is here so we can set $subdirs directly based on configure fragments.
   9 AC_CONFIG_SUBDIRS()
  10
  11 AC_CANONICAL_HOST
  12
  13 AC_PROG_CC
  14 if test $host != $build; then
  15   AC_CHECK_PROGS(BUILD_CC, gcc cc)
  16 fi
  17 AC_SUBST(cross_compiling)
  18 AC_PROG_CPP
  19 # We need the C++ compiler only for testing.
  20 AC_PROG_CXX
  21
  22 if test "`cd $srcdir; /bin/pwd`" = "`/bin/pwd`"; then
  23   AC_MSG_ERROR([you must configure in a separate build directory])
  24 fi
  25
  26 # This will get text that should go into config.make.
  27 config_vars=
  28
  29 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  30 AC_ARG_WITH([gd],
  31             AC_HELP_STRING([--with-gd=DIR],
  32                            [find libgd include dir and library with prefix DIR]),
  33             [dnl
  34 case "$with_gd" in
  35 yes|''|no) ;;
  36 *) libgd_include="-I$withval/include"
  37    libgd_ldflags="-L$withval/lib" ;;
  38 esac
  39 ])
  40 AC_ARG_WITH([gd-include],
  41             AC_HELP_STRING([--with-gd-include=DIR],
  42                            [find libgd include files in DIR]),
  43             [dnl
  44 case "$with_gd_include" in
  45 ''|no) ;;
  46 *) libgd_include="-I$withval" ;;
  47 esac
  48 ])
  49 AC_ARG_WITH([gd-lib],
  50             AC_HELP_STRING([--with-gd-lib=DIR],
  51                            [find libgd library files in DIR]),
  52             [dnl
  53 case "$with_gd_lib" in
  54 ''|no) ;;
  55 *) libgd_ldflags="-L$withval" ;;
  56 esac
  57 ])
  58
  59 if test -n "$libgd_include"; then
  60   config_vars="$config_vars
  61 CFLAGS-memusagestat.c = $libgd_include"
  62 fi
  63 if test -n "$libgd_ldflags"; then
  64   config_vars="$config_vars
  65 libgd-LDFLAGS = $libgd_ldflags"
  66 fi
  67
  68 dnl Arguments to specify presence of other packages/features.
  69 AC_ARG_WITH([fp],
  70             AC_HELP_STRING([--with-fp],
  71                            [if using floating-point hardware @<:@default=yes@:>@]),
  72             [with_fp=$withval],
  73             [with_fp=yes])
  74 AC_SUBST(with_fp)
  75 AC_ARG_WITH([binutils],
  76             AC_HELP_STRING([--with-binutils=PATH],
  77                            [specify location of binutils (as and ld)]),
  78             [path_binutils=$withval],
  79             [path_binutils=''])
  80 AC_ARG_WITH([selinux],
  81             AC_HELP_STRING([--with-selinux],
  82                            [if building with SELinux support]),
  83             [with_selinux=$withval],
  84             [with_selinux=auto])
  85
  86 AC_ARG_WITH([headers],
  87             AC_HELP_STRING([--with-headers=PATH],
  88                            [location of system headers to use
  89                             (for example /usr/src/linux/include)
  90                             @<:@default=compiler default@:>@]),
  91             [sysheaders=$withval],
  92             [sysheaders=''])
  93
  94 AC_SUBST(use_default_link)
  95 AC_ARG_WITH([default-link],
  96             AC_HELP_STRING([--with-default-link],
  97                            [do not use explicit linker scripts]),
  98             [use_default_link=$withval],
  99             [use_default_link=default])
 100
 101 AC_ARG_ENABLE([sanity-checks],
 102               AC_HELP_STRING([--disable-sanity-checks],
 103                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
 104               [enable_sanity=$enableval],
 105               [enable_sanity=yes])
 106
 107 AC_SUBST(enable_check_abi)
 108 AC_ARG_ENABLE([check-abi],
 109               AC_HELP_STRING([--enable-check-abi],
 110                              [do "make check-abi" in "make check" (no/warn/yes)
 111                               @<:@default=no@:>@]),
 112               [enable_check_abi=$enableval],
 113               [enable_check_abi=no])
 114
 115 AC_ARG_ENABLE([shared],
 116               AC_HELP_STRING([--enable-shared],
 117                              [build shared library @<:@default=yes if GNU ld@:>@]),
 118               [shared=$enableval],
 119               [shared=yes])
 120 AC_ARG_ENABLE([profile],
 121               AC_HELP_STRING([--enable-profile],
 122                              [build profiled library @<:@default=no@:>@]),
 123               [profile=$enableval],
 124               [profile=no])
 125 AC_ARG_ENABLE([versioning],
 126               AC_HELP_STRING([--disable-versioning],
 127                              [do not include versioning information in the library objects @<:@default=yes if supported@:>@]),
 128               [enable_versioning=$enableval],
 129               [enable_versioning=yes])
 130
 131 AC_ARG_ENABLE([oldest-abi],
 132               AC_HELP_STRING([--enable-oldest-abi=ABI],
 133                              [configure the oldest ABI supported @<:@e.g. 2.2@:>@ @<:@default=glibc default@:>@]),
 134               [oldest_abi=$enableval],
 135               [oldest_abi=no])
 136 if test "$oldest_abi" = yes || test "$oldest_abi" = no; then
 137   oldest_abi=default
 138 else
 139   AC_DEFINE_UNQUOTED(GLIBC_OLDEST_ABI, "$oldest_abi")
 140 fi
 141 AC_SUBST(oldest_abi)
 142
 143 AC_ARG_ENABLE([stackguard-randomization],
 144               AC_HELP_STRING([--enable-stackguard-randomization],
 145                              [initialize __stack_chk_guard canary with a random number at program start]),
 146               [enable_stackguard_randomize=$enableval],
 147               [enable_stackguard_randomize=no])
 148 if test "$enable_stackguard_randomize" = yes; then
 149   AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
 150 fi
 151
 152 dnl Generic infrastructure for drop-in additions to libc.
 153 AC_ARG_ENABLE([add-ons],
 154               AC_HELP_STRING([--enable-add-ons@<:@=DIRS...@:>@],
 155                              [configure and build add-ons in DIR1,DIR2,...
 156                               search for add-ons if no parameter given]),
 157                              , [enable_add_ons=yes])
 158
 159 AC_ARG_ENABLE([hidden-plt],
 160               AC_HELP_STRING([--disable-hidden-plt],
 161                              [do not hide internal function calls to avoid PLT]),
 162               [hidden=$enableval],
 163               [hidden=yes])
 164 if test "x$hidden" = xno; then
 165   AC_DEFINE(NO_HIDDEN)
 166 fi
 167
 168 AC_ARG_ENABLE([bind-now],
 169               AC_HELP_STRING([--enable-bind-now],
 170                              [disable lazy relocations in DSOs]),
 171               [bindnow=$enableval],
 172               [bindnow=no])
 173 AC_SUBST(bindnow)
 174
 175 dnl On some platforms we cannot use dynamic loading.  We must provide
 176 dnl static NSS modules.
 177 AC_ARG_ENABLE([static-nss],
 178               AC_HELP_STRING([--enable-static-nss],
 179                              [build static NSS modules @<:@default=no@:>@]),
 180               [static_nss=$enableval],
 181               [static_nss=no])
 182 dnl Enable static NSS also if we build no shared objects.
 183 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 184   static_nss=yes
 185   AC_DEFINE(DO_STATIC_NSS)
 186 fi
 187
 188 AC_ARG_ENABLE([force-install],
 189               AC_HELP_STRING([--disable-force-install],
 190                              [don't force installation of files from this package, even if they are older than the installed files]),
 191               [force_install=$enableval],
 192               [force_install=yes])
 193 AC_SUBST(force_install)
 194
 195 dnl On some platforms we allow dropping compatibility with all kernel
 196 dnl versions.
 197 AC_ARG_ENABLE([kernel],
 198               AC_HELP_STRING([--enable-kernel=VERSION],
 199                              [compile for compatibility with kernel not older than VERSION]),
 200               [minimum_kernel=$enableval],
 201               [])
 202 dnl Prevent unreasonable values.
 203 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 204   # Better nothing than this.
 205   minimum_kernel=""
 206 else
 207   if test "$minimum_kernel" = current; then
 208     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 209   fi
 210 fi
 211
 212 dnl For the development we sometimes want gcc to issue even more warnings.
 213 dnl This is not the default since many of the extra warnings are not
 214 dnl appropriate.
 215 AC_ARG_ENABLE([all-warnings],
 216               AC_HELP_STRING([--enable-all-warnings],
 217                              [enable all useful warnings gcc can issue]),
 218               [all_warnings=$enableval],
 219               [])
 220 AC_SUBST(all_warnings)
 221
 222 AC_ARG_ENABLE([multi-arch],
 223               AC_HELP_STRING([--enable-multi-arch],
 224                              [enable single DSO with optimizations for multiple architectures]),
 225               [multi_arch=$enableval],
 226               [multi_arch=default])
 227
 228 AC_ARG_ENABLE([nss-crypt],
 229               AC_HELP_STRING([--enable-nss-crypt],
 230                              [enable libcrypt to use nss]),
 231               [nss_crypt=$enableval],
 232               [nss_crypt=no])
 233 if test x$nss_crypt = xyes; then
 234   nss_includes=-I$(nss-config --includedir 2>/dev/null)
 235   if test $? -ne 0; then
 236     AC_MSG_ERROR([cannot find include directory with nss-config])
 237   fi
 238   old_CFLAGS="$CFLAGS"
 239   CFLAGS="$CFLAGS $nss_includes"
 240   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 241 #include <hasht.h>
 242 #include <nsslowhash.h>
 243 void f (void) { NSSLOW_Init (); }])],
 244              libc_cv_nss_crypt=yes,
 245              AC_MSG_ERROR([
 246 cannot find NSS headers with lowlevel hash function interfaces]))
 247   old_LIBS="$LIBS"
 248   LIBS="$LIBS -lfreebl3"
 249   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 250 #include <hasht.h>
 251 #include <nsslowhash.h>],
 252                                   [NSSLOW_Init();])],
 253                  libc_cv_nss_crypt=yes,
 254                  AC_MSG_ERROR([
 255 cannot link program using lowlevel NSS hash functions]))
 256   CFLAGS="$old_CFLAGS"
 257   LIBS="$old_LIBS"
 258 else
 259   libc_cv_nss_crypt=no
 260 fi
 261 AC_SUBST(libc_cv_nss_crypt)
 262
 263 # The way shlib-versions is used to generate soversions.mk uses a
 264 # fairly simplistic model for name recognition that can't distinguish
 265 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 266 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 267 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 268 case "$host_os" in
 269 linux*)
 270   ;;
 271 gnu*)
 272   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 273   ;;
 274 esac
 275
 276 # We keep the original values in `$config_*' and never modify them, so we
 277 # can write them unchanged into config.make.  Everything else uses
 278 # $machine, $vendor, and $os, and changes them whenever convenient.
 279 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 280
 281 # Don't allow vendor == "unknown"
 282 test "$config_vendor" = unknown && config_vendor=
 283 config_os="`echo $config_os | sed 's/^unknown-//'`"
 284
 285 # Some configurations imply other options.
 286 elf=yes
 287
 288 # The configure fragment of an add-on port can modify these to supplement
 289 # or override the table in the case statement below.  No fragment should
 290 # ever change the config_* variables, however.
 291 machine=$config_machine
 292 vendor=$config_vendor
 293 os=$config_os
 294 base_os=''
 295
 296 # config.guess on some IBM machines says `rs6000' instead of `powerpc'.
 297 # Unify this here.
 298 if test "$machine" = rs6000; then
 299   machine="powerpc"
 300 fi
 301
 302 # Braindead PowerPC box with absolutely no FPU.
 303 case "$machine-$host_os" in
 304   powerpc*-*soft)
 305     with_fp=no
 306     ;;
 307 esac
 308
 309 submachine=
 310 AC_ARG_WITH([cpu],
 311             AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
 312             [dnl
 313   case "$withval" in
 314   yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
 315   no) ;;
 316   *) submachine="$withval" ;;
 317   esac
 318 ])
 319
 320 # An add-on can set this when it wants to disable the sanity check below.
 321 libc_config_ok=no
 322
 323 dnl Having this here, though empty, makes sure that if add-ons' fragments
 324 dnl do AC_CONFIG_SUBDIRS([some-dir]), which just sets $subdirs, then
 325 dnl our AC_OUTPUT will actually use it.
 326 AC_CONFIG_SUBDIRS()
 327
 328 case "$enable_add_ons" in
 329 ''|no) add_ons= ;;
 330 yes|'*')
 331  add_ons=`cd $srcdir && ls -d 2> /dev/null */configure */sysdeps |
 332           sed 's@/[[^/]]*$@@' | sort | uniq`
 333          add_ons_automatic=yes
 334          ;;
 335 *) add_ons=`echo "$enable_add_ons" | sed 's/,/ /g'`
 336        add_ons_automatic=no ;;
 337 esac
 338
 339 configured_add_ons=
 340 add_ons_sfx=
 341 add_ons_pfx=
 342 if test x"$add_ons" != x; then
 343   for f in $add_ons; do
 344     # Some sanity checks
 345     case "$f" in
 346     crypt)
 347       AC_MSG_ERROR([
 348 *** It seems that you're using an old \`crypt' add-on.  crypt is now
 349 *** part of glibc and using the old add-on will not work with this
 350 *** release.  Start again with fresh sources and without the old
 351 *** \`crypt' add-on.])
 352     ;;
 353     localedata)
 354       AC_MSG_ERROR([
 355 *** It seems that you're using an old \`localedata' add-on.  localedata
 356 *** is now part of glibc and using the old add-on will not work with
 357 *** this release.  Start again with fresh sources and without the old
 358 *** \`localedata' add-on.])
 359     ;;
 360     esac
 361   done
 362
 363   # Now source each add-on's configure fragment.
 364   # The fragments can use $srcdir/$libc_add_on to find themselves,
 365   # and test $add_ons_automatic to see if they were explicitly requested.
 366   # A fragment can clear (or even change) $libc_add_on to affect
 367   # whether it goes into the list to be actually used in the build.
 368   use_add_ons=
 369   for libc_add_on in $add_ons; do
 370     # Test whether such a directory really exists.
 371     # It can be absolute, or relative to $srcdir, or relative to the build dir.
 372     case "$libc_add_on" in
 373     /*)
 374       libc_add_on_srcdir=$libc_add_on
 375       ;;
 376     *)
 377       test -d "$srcdir/$libc_add_on" || {
 378         if test -d "$libc_add_on"; then
 379           libc_add_on="`pwd`/$libc_add_on"
 380         else
 381           AC_MSG_ERROR(add-on directory \"$libc_add_on\" does not exist)
 382         fi
 383       }
 384       libc_add_on_srcdir=$srcdir/$libc_add_on
 385       ;;
 386     esac
 387
 388     libc_add_on_frag=$libc_add_on_srcdir/configure
 389     libc_add_on_canonical=
 390     libc_add_on_config_subdirs=
 391     if test -r "$libc_add_on_frag"; then
 392       AC_MSG_NOTICE(running configure fragment for add-on $libc_add_on)
 393       libc_add_on_canonical=unknown
 394       libc_add_on_subdirs=
 395       . "$libc_add_on_frag"
 396       test -z "$libc_add_on" || {
 397         configured_add_ons="$configured_add_ons $libc_add_on"
 398         if test "x$libc_add_on_canonical" = xunknown; then
 399           AC_MSG_ERROR(fragment must set \$libc_add_on_canonical)
 400         fi
 401         for d in $libc_add_on_subdirs; do
 402           case "$libc_add_on" in
 403           /*) subdir_srcdir="$libc_add_on" ;;
 404           *) subdir_srcdir="\$(..)$libc_add_on" ;;
 405           esac
 406           case "$d" in
 407           .)
 408             d="${libc_add_on_canonical:-$libc_add_on}"
 409             ;;
 410           /*)
 411             subdir_srcdir="$d"
 412             ;;
 413           *)
 414             subdir_srcdir="$subdir_srcdir/$d"
 415             ;;
 416           esac
 417           d=`echo "$d" | sed 's@/*$@@;s@^.*/@@'`
 418           add_on_subdirs="$add_on_subdirs $d"
 419           test "$subdir_srcdir" = "\$(..)$d" || config_vars="$config_vars
 420 $d-srcdir = $subdir_srcdir"
 421         done
 422         for d in $libc_add_on_config_subdirs; do
 423           case "$d" in
 424           /*) AC_MSG_ERROR(dnl
 425 fragment uses absolute path in \$libc_add_on_config_subdirs) ;;
 426           esac
 427           if test ! -d "$libc_add_on_srcdir/$d"; then
 428             AC_MSG_ERROR(fragment wants to configure missing directory $d)
 429           fi
 430           case "$libc_add_on" in
 431           /*) AC_MSG_ERROR(dnl
 432 relative path required for add-on using \$libc_add_on_config_subdirs) ;;
 433           esac
 434           subdirs="$subdirs $libc_add_on/$d"
 435         done
 436       }
 437     fi
 438     if test -n "$libc_add_on"; then
 439       if frags=`ls -d $libc_add_on_srcdir/sysdeps/*/preconfigure 2> /dev/null`
 440       then
 441         AC_MSG_CHECKING(add-on $libc_add_on for preconfigure fragments)
 442         for frag in $frags; do
 443           name=`echo "$frag" | sed 's@/[[^/]]*$@@;s@^.*/@@'`
 444           echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 445           . "$frag"
 446         done
 447         AC_MSG_RESULT()
 448       fi
 449       use_add_ons="$use_add_ons $libc_add_on"
 450       add_ons_pfx="$add_ons_pfx $libc_add_on/"
 451       test -z "$libc_add_on_canonical" ||
 452       add_ons_sfx="$add_ons_sfx /$libc_add_on_canonical"
 453     fi
 454   done
 455   # Use echo to strip excess whitespace.
 456   add_ons="`echo $use_add_ons`"
 457 fi
 458 AC_SUBST(add_ons)
 459 AC_SUBST(add_on_subdirs)
 460
 461
 462 ###
 463 ### I put this here to prevent those annoying emails from people who cannot
 464 ### read and try to compile glibc on unsupported platforms.  --drepper
 465 ###
 466 ### By using the undocumented --enable-hacker-mode option for configure
 467 ### one can skip this test to make the configuration not fail for unsupported
 468 ### platforms.
 469 ###
 470 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
 471   case "$machine-$host_os" in
 472   *-linux* | *-gnu* | arm*-none*)
 473     ;;
 474   *)
 475     echo "*** The GNU C library is currently not available for this platform."
 476     echo "*** So far nobody cared to port it and if there is no volunteer it"
 477     echo "*** might never happen.  So, if you have interest to see glibc on"
 478     echo "*** this platform visit"
 479     echo "***   http://www.gnu.org/software/libc/porting.html"
 480     echo "*** and join the group of porters"
 481     exit 1
 482     ;;
 483   esac
 484 fi
 485
 486 dnl We need to use [ and ] for other purposes for a while now.
 487 changequote(,)dnl
 488 # Expand the configuration machine name into a subdirectory by architecture
 489 # type and particular chip.  If an add-on configure fragment already set
 490 # base_machine, we don't change it.
 491 test -n "$base_machine" || case "$machine" in
 492 i[34567]86)     base_machine=i386 machine=i386/$machine ;;
 493 powerpc)        base_machine=powerpc machine=powerpc/powerpc32 ;;
 494 powerpc64)      base_machine=powerpc machine=powerpc/powerpc64 ;;
 495 s390)           base_machine=s390 machine=s390/s390-32 ;;
 496 s390x)          base_machine=s390 machine=s390/s390-64 ;;
 497 sh3*)           base_machine=sh machine=sh/sh3 ;;
 498 sh4*)           base_machine=sh machine=sh/sh4 ;;
 499 sparc | sparcv[67])
 500                 base_machine=sparc machine=sparc/sparc32 ;;
 501 sparcv8 | supersparc | hypersparc)
 502                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 503 sparcv8plus | sparcv8plusa | sparcv9)
 504                 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
 505 sparcv8plusb | sparcv9b)
 506                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9b ;;
 507 sparcv9v)
 508                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v ;;
 509 sparcv9v2)
 510                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v2 ;;
 511 sparc64)
 512                 base_machine=sparc machine=sparc/sparc64 ;;
 513 sparc64b)
 514                 base_machine=sparc machine=sparc/sparc64/sparcv9b ;;
 515 sparc64v)
 516                 base_machine=sparc machine=sparc/sparc64/sparcv9v ;;
 517 sparc64v2)
 518                 base_machine=sparc machine=sparc/sparc64/sparcv9v2 ;;
 519 *)              base_machine=$machine ;;
 520 esac
 521 changequote([,])dnl
 522 AC_SUBST(base_machine)
 523
 524 if test "$base_machine" = "i386"; then
 525   AC_DEFINE(USE_REGPARMS)
 526 fi
 527
 528 # For the multi-arch option we need support in the assembler.
 529 AC_CACHE_CHECK([for assembler gnu_indirect_function symbol type support],
 530                libc_cv_asm_gnu_indirect_function, [dnl
 531 cat > conftest.s <<EOF
 532 .type foo,%gnu_indirect_function
 533 EOF
 534 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD;
 535 then
 536   libc_cv_asm_gnu_indirect_function=yes
 537 else
 538   libc_cv_asm_gnu_indirect_function=no
 539 fi
 540 rm -f conftest*])
 541
 542 AC_MSG_CHECKING(whether .text pseudo-op must be used)
 543 AC_CACHE_VAL(libc_cv_dot_text, [dnl
 544 cat > conftest.s <<EOF
 545 .text
 546 EOF
 547 libc_cv_dot_text=
 548 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
 549   libc_cv_dot_text=.text
 550 fi
 551 rm -f conftest*])
 552 if test -z "$libc_cv_dot_text"; then
 553   AC_MSG_RESULT(no)
 554 else
 555   AC_MSG_RESULT(yes)
 556 fi
 557
 558 AC_CACHE_CHECK(for assembler global-symbol directive,
 559                libc_cv_asm_global_directive, [dnl
 560 libc_cv_asm_global_directive=UNKNOWN
 561 for ac_globl in .globl .global .EXPORT; do
 562   cat > conftest.s <<EOF
 563         ${libc_cv_dot_text}
 564         ${ac_globl} foo
 565 foo:
 566 EOF
 567   if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
 568     libc_cv_asm_global_directive=${ac_globl}
 569   fi
 570   rm -f conftest*
 571   test $libc_cv_asm_global_directive != UNKNOWN && break
 572 done])
 573 if test $libc_cv_asm_global_directive = UNKNOWN; then
 574   AC_MSG_ERROR(cannot determine asm global directive)
 575 else
 576   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 577 fi
 578
 579 AC_CACHE_CHECK(for assembler .type directive prefix,
 580                libc_cv_asm_type_prefix, [dnl
 581 libc_cv_asm_type_prefix=no
 582 for ac_try_prefix in '@' '%' '#'; do
 583   cat > conftest.s <<EOF
 584         ${libc_cv_dot_text}
 585         ${libc_cv_asm_global_directive} foo
 586         .type foo, ${ac_try_prefix}object
 587         .size foo, 1
 588 foo:
 589         .byte 1
 590 EOF
 591   if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
 592     libc_cv_asm_type_prefix=${ac_try_prefix}
 593   fi
 594   rm -f conftest*
 595   test "x$libc_cv_asm_type_prefix" != xno && break
 596 done])
 597 if test "x$libc_cv_asm_type_prefix" != xno; then
 598   AC_DEFINE_UNQUOTED(ASM_TYPE_DIRECTIVE_PREFIX, ${libc_cv_asm_type_prefix})
 599 fi
 600
 601 if test x"$libc_cv_asm_gnu_indirect_function" != xyes -o x"$libc_cv_asm_type_prefix" = xno; then
 602   if test x"$multi_arch" = xyes; then
 603     AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
 604   else
 605     multi_arch=no
 606   fi
 607 fi
 608 if test x"$multi_arch" != xno; then
 609   multi_arch_d=/multiarch
 610 fi
 611
 612 # Compute the list of sysdep directories for this configuration.
 613 # This can take a while to compute.
 614 sysdep_dir=$srcdir/sysdeps
 615 AC_MSG_CHECKING(sysdep dirs)
 616 dnl We need to use [ and ] for other purposes for a while now.
 617 changequote(,)dnl
 618 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 619 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 620
 621 test "x$base_os" != x || case "$os" in
 622 gnu*)
 623   base_os=mach/hurd ;;
 624 netbsd* | 386bsd* | freebsd* | bsdi*)
 625   base_os=unix/bsd/bsd4.4 ;;
 626 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 627   base_os=unix/bsd ;;
 628 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 629   base_os=unix/sysv ;;
 630 irix6*)
 631   base_os=unix/sysv/irix6/$os ;;
 632 solaris[2-9]*)
 633   base_os=unix/sysv/sysv4 ;;
 634 none)
 635   base_os=standalone ;;
 636 esac
 637
 638 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 639 tail=$os
 640 ostry=$os
 641 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 642   ostry="$ostry /$o"
 643   tail=$o
 644 done
 645 o=`echo $tail | sed 's/[0-9]*$//'`
 646 if test $o != $tail; then
 647   ostry="$ostry /$o"
 648 fi
 649 # For linux-gnu, try linux-gnu, then linux.
 650 o=`echo $tail | sed 's/-.*$//'`
 651 if test $o != $tail; then
 652   ostry="$ostry /$o"
 653 fi
 654
 655 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 656 base=
 657 tail=$base_os
 658 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 659   set $b
 660   base="$base /$1"
 661   tail="$2"
 662 done
 663
 664 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 665 mach=
 666 tail=$machine${submachine:+/$submachine}
 667 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 668   set $m
 669   # Prepend the machine's FPU directory unless --without-fp.
 670   if test "$with_fp" = yes; then
 671     mach="$mach /$1/fpu"
 672   else
 673     mach="$mach /$1/nofpu"
 674   fi
 675   mach="$mach /$1"
 676   tail="$2"
 677 done
 678
 679 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 680 changequote([,])dnl
 681
 682 # Find what sysdep directories exist.
 683 sysnames_add_ons=
 684 sysnames=
 685 for b in $base ''; do
 686   for m0 in $mach ''; do
 687     for v in /$vendor ''; do
 688       test "$v" = / && continue
 689       for o in /$ostry ''; do
 690         test "$o" = / && continue
 691         for m in $multi_arch_d $mach ''; do
 692           for d in $add_ons_pfx ''; do
 693             for a in $add_ons_sfx ''; do
 694               if test -n "$m0$m0sub$b$v$o$m$msub"; then
 695                 try_srcdir="${srcdir}/"
 696                 case "$d" in
 697                 /*) try_srcdir= ;;
 698                 esac
 699                 try="${d}sysdeps$m0$m0sub$b$v$o$m$msub$a"
 700                 test -n "$enable_debug_configure" &&
 701                 echo "$0 [DEBUG]: try $try" >&2
 702                 if test -d "$try_srcdir$try"; then
 703                   sysnames="$sysnames $try"
 704                   { test -n "$o" || test -n "$b"; } && os_used=t
 705                   { test -n "$m" || test -n "$m0"; } && machine_used=t
 706                   case x${m0:-$m} in
 707                   x*/$submachine) submachine_used=t ;;
 708                   esac
 709                   if test -n "$d"; then
 710                     case "$sysnames_add_ons" in
 711                     *" $d "*) ;;
 712                     *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 713                     esac
 714                   fi
 715                 fi
 716               fi
 717             done
 718           done
 719         done
 720       done
 721     done
 722   done
 723 done
 724
 725 # If the assembler supports gnu_indirect_function symbol type and the
 726 # architecture supports multi-arch, we enable multi-arch by default.
 727 case $sysnames_add_ons$sysnames in
 728 *"$multi_arch_d"*)
 729   ;;
 730 *)
 731   test x"$multi_arch" = xdefault && multi_arch=no
 732   ;;
 733 esac
 734 if test x"$multi_arch" != xno; then
 735   AC_DEFINE(USE_MULTIARCH)
 736 fi
 737 AC_SUBST(multi_arch)
 738
 739 if test -z "$os_used" && test "$os" != none; then
 740   AC_MSG_ERROR(Operating system $os is not supported.)
 741 fi
 742 if test -z "$machine_used" && test "$machine" != none; then
 743   AC_MSG_ERROR(The $machine is not supported.)
 744 fi
 745 if test -z "$submachine_used" && test -n "$submachine"; then
 746   AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
 747 fi
 748 AC_SUBST(submachine)
 749
 750 # We have now validated the configuration.
 751
 752
 753 # Look for an `elf' subdirectory of each machine directory.
 754 # We prepend these rather than inserting them whereever the machine appears
 755 # because things specified by the machine's ELF ABI should override
 756 # OS-specific things, and should always be the same for any OS on the
 757 # machine (otherwise what's the point of an ABI?).
 758 elf_dirs=
 759 for d in $add_ons_pfx ''; do
 760   for m in $mach; do
 761     if test -d $srcdir/${d}sysdeps$m/elf; then
 762       elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 763     fi
 764   done
 765 done
 766 sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 767
 768
 769 # Expand the list of system names into a full list of directories
 770 # from each element's parent name and Implies file (if present).
 771 set $sysnames
 772 names=
 773 while test $# -gt 0; do
 774   name=$1
 775   shift
 776
 777   case " $names " in *" $name "*)
 778     # Already in the list.
 779     continue
 780   esac
 781
 782   # Report each name as we discover it, so there is no long pause in output.
 783   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 784
 785   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 786
 787   case $name in
 788     /*) xsrcdir= ;;
 789     *)  xsrcdir=$srcdir/ ;;
 790   esac
 791   test -n "$enable_debug_configure" &&
 792   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 793
 794   if test -f $xsrcdir$name/Implies; then
 795     # Collect more names from the `Implies' file (removing comments).
 796     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 797     implied=
 798     for x in $implied_candidate; do
 799       found=no
 800       if test -d $xsrcdir$name_base/$x; then
 801         implied="$implied $name_base/$x";
 802         found=yes
 803       fi
 804       for d in $add_ons_pfx ''; do
 805         try="${d}sysdeps/$x"
 806         case $d in
 807          /*) try_srcdir= ;;
 808          *) try_srcdir=$srcdir/ ;;
 809         esac
 810         test -n "$enable_debug_configure" &&
 811          echo "[DEBUG]: $name implied $x try($d) {$try_srcdir}$try" >&2
 812         if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 813         then
 814           implied="$implied $try"
 815           found=yes
 816           case "$sysnames_add_ons" in
 817           *" $d "*) ;;
 818           *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 819           esac
 820         fi
 821       done
 822       if test $found = no; then
 823         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 824       fi
 825     done
 826   else
 827     implied=
 828   fi
 829
 830   # Add NAME to the list of names.
 831   names="$names $name"
 832
 833   # Find the parent of NAME, using the empty string if it has none.
 834 changequote(,)dnl
 835   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 836 changequote([,])dnl
 837
 838   # Add the names implied by NAME, and NAME's parent (if it has one), to
 839   # the list of names to be processed (the argument list).  We prepend the
 840   # implied names to the list and append the parent.  We want implied
 841   # directories to come before further directories inferred from the
 842   # configuration components; this ensures that for sysv4, unix/common
 843   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 844   # after sysv4).
 845   sysnames="`echo $implied $* $parent`"
 846   test -n "$sysnames" && set $sysnames
 847 done
 848
 849 # Add the default directories.
 850 default_sysnames="sysdeps/generic/elf sysdeps/generic"
 851 sysnames="$names $default_sysnames"
 852 AC_SUBST(sysnames)
 853 # The other names were emitted during the scan.
 854 AC_MSG_RESULT($default_sysnames)
 855
 856 # Collect the list of add-ons that supply partial sysdeps trees.
 857 sysdeps_add_ons=
 858 for add_on in $add_ons; do
 859   case "$add_on" in
 860   /*) xsrcdir= ;;
 861   *) xsrcdir="$srcdir/" ;;
 862   esac
 863
 864   test -d "$xsrcdir$add_on/sysdeps" || {
 865     case "$configured_add_ons " in
 866     *" $add_on "*) ;;
 867     *|'')
 868       AC_MSG_ERROR(add-on $add_on has no configure fragment or sysdeps tree)
 869       ;;
 870     esac
 871     continue
 872   }
 873
 874   sysdeps_add_ons="$sysdeps_add_ons $add_on"
 875   case "$sysnames_add_ons" in
 876   *" $add_on/ "*) ;;
 877   *|'')
 878     AC_MSG_WARN(add-on $add_on contributed no sysdeps directories)
 879     continue ;;
 880   esac
 881
 882   found=no
 883   for d in $sysnames; do
 884     case "$d" in
 885     $add_on/sysdeps/*) ;;
 886     *) continue ;;
 887     esac
 888     (cd "$xsrcdir$d" && for f in *[[!~]]; do
 889        case "$f" in
 890        sys|bits)
 891          for ff in $f/*.h; do
 892            test -d "$ff" || { test -e "$ff" && exit 88; }
 893          done
 894          ;;
 895        *)
 896          test -d "$f" || { test -e "$f" && exit 88; }
 897          ;;
 898        esac
 899      done)
 900     if test $? -eq 88; then
 901       found=yes
 902       break
 903     fi
 904   done
 905   if test $found = no; then
 906     AC_MSG_WARN(add-on $add_on contributed no useful sysdeps directories)
 907   fi
 908 done
 909 AC_SUBST(sysdeps_add_ons)
 910
 911
 912 ### Locate tools.
 913
 914 AC_PROG_INSTALL
 915 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 916   # The makefiles need to use a different form to find it in $srcdir.
 917   INSTALL='\$(..)./scripts/install-sh -c'
 918 fi
 919 AC_PROG_LN_S
 920
 921 LIBC_PROG_BINUTILS
 922 AC_SUBST(MIG)dnl Needed by sysdeps/mach/configure.in
 923
 924 # Accept binutils 2.20 or newer.
 925 AC_CHECK_PROG_VER(AS, $AS, --version,
 926                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
 927                   [2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], AS=: critic_missing="$critic_missing as")
 928 AC_CHECK_PROG_VER(LD, $LD, --version,
 929                   [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
 930                   [2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], LD=: critic_missing="$critic_missing ld")
 931
 932 # These programs are version sensitive.
 933 AC_CHECK_TOOL_PREFIX
 934 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 935   [version \([egcygnustpi-]*[0-9.]*\)], [4.[3-9].* | 4.[1-9][0-9].* | [5-9].* ],
 936   critic_missing="$critic_missing gcc")
 937 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 938   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 939   [3.79* | 3.[89]*], critic_missing="$critic_missing make")
 940
 941 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 942   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 943   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
 944   MSGFMT=: aux_missing="$aux_missing msgfmt")
 945 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 946   [GNU texinfo.* \([0-9][0-9.]*\)],
 947   [4.*],
 948   MAKEINFO=: aux_missing="$aux_missing makeinfo")
 949 AC_CHECK_PROG_VER(SED, sed, --version,
 950   [GNU sed version \([0-9]*\.[0-9.]*\)],
 951   [3.0[2-9]*|3.[1-9]*|[4-9]*],
 952   SED=: aux_missing="$aux_missing sed")
 953
 954 AC_CHECK_TOOL(READELF, readelf, false)
 955
 956 AC_CHECK_PROGS(AUTOCONF, autoconf, no)
 957 case "x$AUTOCONF" in
 958 xno|x|x:) AUTOCONF=no ;;
 959 *)
 960   AC_CACHE_CHECK(dnl
 961 whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
 962   if (cd $srcdir; $AUTOCONF $ACFLAGS configure.in > /dev/null 2>&1); then
 963     libc_cv_autoconf_works=yes
 964   else
 965     libc_cv_autoconf_works=no
 966   fi])
 967   test $libc_cv_autoconf_works = yes || AUTOCONF=no
 968   ;;
 969 esac
 970 if test "x$AUTOCONF" = xno; then
 971   aux_missing="$aux_missing autoconf"
 972 fi
 973
 974 test -n "$critic_missing" && AC_MSG_ERROR([
 975 *** These critical programs are missing or too old:$critic_missing
 976 *** Check the INSTALL file for required versions.])
 977
 978 test -n "$aux_missing" && AC_MSG_WARN([
 979 *** These auxiliary programs are missing or incompatible versions:$aux_missing
 980 *** some features will be disabled.
 981 *** Check the INSTALL file for required versions.])
 982
 983 # if using special system headers, find out the compiler's sekrit
 984 # header directory and add that to the list.  NOTE: Only does the right
 985 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
 986 if test -n "$sysheaders"; then
 987   SYSINCLUDES=-nostdinc
 988   for d in include include-fixed; do
 989     i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
 990     SYSINCLUDES="$SYSINCLUDES -isystem $i"
 991   done
 992   SYSINCLUDES="$SYSINCLUDES \
 993 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
 994   if test -n "$CXX"; then
 995     CXX_SYSINCLUDES=
 996     cxxversion=`$CXX -dumpversion 2>&AS_MESSAGE_LOG_FD` &&
 997     cxxmachine=`$CXX -dumpmachine 2>&AS_MESSAGE_LOG_FD` &&
 998     for d in include "$cxxmachine/include"; do
 999       i=../../../../$d/c++/$cxxversion
1000       cxxheaders=`$CXX -print-file-name="$i"` &&
1001       test "x$cxxheaders" != x && test "x$i" != "x$cxxheaders" &&
1002       CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders \
1003 -isystem $cxxheaders/$cxxmachine -isystem $cxxheaders/backward"
1004     done
1005   fi
1006 fi
1007 AC_SUBST(SYSINCLUDES)
1008 AC_SUBST(CXX_SYSINCLUDES)
1009
1010 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1011 # since this would lead to problems installing/building glibc.
1012 # LD_LIBRARY_PATH contains the current directory if one of the following
1013 # is true:
1014 # - one of the terminals (":" and ";") is the first or last sign
1015 # - two terminals occur directly after each other
1016 # - the path contains an element with a dot in it
1017 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1018 changequote(,)dnl
1019 case ${LD_LIBRARY_PATH} in
1020   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1021     ld_library_path_setting="contains current directory"
1022     ;;
1023   *)
1024     ld_library_path_setting="ok"
1025     ;;
1026 esac
1027 changequote([,])dnl
1028 AC_MSG_RESULT($ld_library_path_setting)
1029 if test "$ld_library_path_setting" != "ok"; then
1030 AC_MSG_ERROR([
1031 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1032 *** building glibc. Please change the environment variable
1033 *** and run configure again.])
1034 fi
1035
1036 AC_CACHE_CHECK(whether GCC supports -static-libgcc, libc_cv_gcc_static_libgcc, [dnl
1037 if $CC -v -static-libgcc 2>&1 | grep -q 'unrecognized option.*static-libgcc'; then
1038   libc_cv_gcc_static_libgcc=
1039 else
1040   libc_cv_gcc_static_libgcc=-static-libgcc
1041 fi])
1042 AC_SUBST(libc_cv_gcc_static_libgcc)
1043
1044 AC_PATH_PROG(BASH_SHELL, bash, no)
1045 if test "$BASH_SHELL" != no &&
1046    $BASH_SHELL -c 'test "$BASH_VERSINFO" \
1047              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
1048   libc_cv_have_bash2=yes
1049 else
1050   libc_cv_have_bash2=no
1051 fi
1052 AC_SUBST(libc_cv_have_bash2)
1053
1054 dnl We need a ksh compatible shell for tzselect.
1055 if test "$BASH_SHELL" = no; then
1056   AC_PATH_PROG(KSH, ksh, no)
1057   if test "$KSH" = no; then
1058     libc_cv_have_ksh=no
1059   else
1060     libc_cv_have_ksh=yes
1061   fi
1062 else
1063   KSH="$BASH_SHELL"
1064   AC_SUBST(KSH)
1065   libc_cv_have_ksh=yes
1066 fi
1067 AC_SUBST(libc_cv_have_ksh)
1068
1069 AC_PROG_AWK
1070 AC_PATH_PROG(PERL, perl, no)
1071 if test "$PERL" != no &&
1072    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1073   PERL=no
1074 fi
1075 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1076              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1077 AC_PATH_PROG(BISON, bison, no, $PATH:/usr/local/bin:/usr/bin:/bin)
1078
1079 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
1080 AC_TRY_COMPILE(dnl
1081 [#define __need_size_t
1082 #define __need_wchar_t
1083 #include <stddef.h>
1084 #define __need_NULL
1085 #include <stddef.h>], [size_t size; wchar_t wchar;
1086 #ifdef offsetof
1087 #error stddef.h ignored __need_*
1088 #endif
1089 if (&size == NULL || &wchar == NULL) abort ();],
1090                libc_cv_friendly_stddef=yes,
1091                libc_cv_friendly_stddef=no)])
1092 if test $libc_cv_friendly_stddef = yes; then
1093   config_vars="$config_vars
1094 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
1095 fi
1096
1097 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
1098                libc_cv_need_minus_P, [dnl
1099 cat > conftest.S <<EOF
1100 #include "confdefs.h"
1101 /* Nothing whatsoever.  */
1102 EOF
1103 if AC_TRY_COMMAND(${CC-cc} $CPPFLAGS $ASFLAGS -c conftest.S 1>&AS_MESSAGE_LOG_FD); then
1104   libc_cv_need_minus_P=no
1105 else
1106   libc_cv_need_minus_P=yes
1107 fi
1108 rm -f conftest*])
1109 if test $libc_cv_need_minus_P = yes; then
1110   config_vars="$config_vars
1111 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
1112 fi
1113
1114 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1115 cat > conftest.s <<EOF
1116 ${libc_cv_dot_text}
1117 foo:
1118 .set glibc_conftest_frobozz,foo
1119 $libc_cv_asm_global_directive glibc_conftest_frobozz
1120 EOF
1121 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1122 # (but it doesn't work), so we must do a linking check to be sure.
1123 cat > conftest1.c <<\EOF
1124 extern int glibc_conftest_frobozz;
1125 void _start() { glibc_conftest_frobozz = 1; }
1126 EOF
1127 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1128             -nostartfiles -nostdlib \
1129             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1130   libc_cv_asm_set_directive=yes
1131 else
1132   libc_cv_asm_set_directive=no
1133 fi
1134 rm -f conftest*])
1135 if test $libc_cv_asm_set_directive = yes; then
1136   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1137 fi
1138
1139 AC_CACHE_CHECK(for assembler gnu_unique_object symbol type,
1140                libc_cv_asm_unique_object, [dnl
1141 cat > conftest.s <<EOF
1142 ${libc_cv_dot_text}
1143 _sym:
1144 .type _sym, ${libc_cv_asm_type_prefix}gnu_unique_object
1145 EOF
1146 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1147   libc_cv_asm_unique_object=yes
1148 else
1149   libc_cv_asm_unique_object=no
1150 fi
1151 rm -f conftest*])
1152 if test $libc_cv_asm_unique_object = yes; then
1153   AC_DEFINE(HAVE_ASM_UNIQUE_OBJECT)
1154 fi
1155
1156 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
1157 [cat > conftest.s <<EOF
1158 ${libc_cv_dot_text}
1159 _sym:
1160 .symver _sym,sym@VERS
1161 EOF
1162 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1163   libc_cv_asm_symver_directive=yes
1164 else
1165   libc_cv_asm_symver_directive=no
1166 fi
1167 rm -f conftest*])
1168 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
1169 if test $libc_cv_asm_symver_directive = yes; then
1170   cat > conftest.s <<EOF
1171 ${libc_cv_dot_text}
1172 _sym:
1173 .symver _sym,sym@VERS
1174 EOF
1175   cat > conftest.map <<EOF
1176 VERS_1 {
1177         global: sym;
1178 };
1179
1180 VERS_2 {
1181         global: sym;
1182 } VERS_1;
1183 EOF
1184   if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1185     if AC_TRY_COMMAND([${CC-cc} $CFLAGS $LDFLAGS -shared
1186                                 -o conftest.so conftest.o
1187                                 -nostartfiles -nostdlib
1188                                 -Wl,--version-script,conftest.map
1189                        1>&AS_MESSAGE_LOG_FD]);
1190     then
1191       libc_cv_ld_version_script_option=yes
1192     else
1193       libc_cv_ld_version_script_option=no
1194     fi
1195   else
1196     libc_cv_ld_version_script_option=no
1197   fi
1198 else
1199   libc_cv_ld_version_script_option=no
1200 fi
1201 rm -f conftest*])
1202 if test $shared != no &&
1203    test $libc_cv_asm_symver_directive = yes &&
1204    test $libc_cv_ld_version_script_option = yes &&
1205    test $enable_versioning = yes; then
1206   VERSIONING=yes
1207   AC_DEFINE(DO_VERSIONING)
1208 else
1209   VERSIONING=no
1210 fi
1211 AC_SUBST(VERSIONING)
1212
1213 if test $shared != no && test $VERSIONING = no; then
1214   echo "\
1215 *** WARNING: You should not compile GNU libc without versioning. Not using
1216 *** versioning will introduce incompatibilities so that old binaries
1217 *** will not run anymore.
1218 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
1219 fi
1220 AC_CACHE_CHECK(for .previous assembler directive,
1221                libc_cv_asm_previous_directive, [dnl
1222 cat > conftest.s <<EOF
1223 .section foo_section
1224 .previous
1225 EOF
1226 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1227   libc_cv_asm_previous_directive=yes
1228 else
1229   libc_cv_asm_previous_directive=no
1230 fi
1231 rm -f conftest*])
1232 if test $libc_cv_asm_previous_directive = yes; then
1233   AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
1234 else
1235   AC_CACHE_CHECK(for .popsection assembler directive,
1236                  libc_cv_asm_popsection_directive, [dnl
1237   cat > conftest.s <<EOF
1238 .pushsection foo_section
1239 .popsection
1240 EOF
1241   if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1242     libc_cv_asm_popsection_directive=yes
1243   else
1244     libc_cv_asm_popsection_directive=no
1245   fi
1246   rm -f conftest*])
1247   if test $libc_cv_asm_popsection_directive = yes; then
1248     AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
1249   fi
1250 fi
1251 AC_CACHE_CHECK(for .protected and .hidden assembler directive,
1252                libc_cv_asm_protected_directive, [dnl
1253 cat > conftest.s <<EOF
1254 .protected foo
1255 foo:
1256 .hidden bar
1257 bar:
1258 EOF
1259 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1260   libc_cv_asm_protected_directive=yes
1261 else
1262   AC_MSG_ERROR(assembler support for symbol visibility is required)
1263 fi
1264 rm -f conftest*])
1265
1266 if test $libc_cv_asm_protected_directive = yes; then
1267   AC_CACHE_CHECK(whether __attribute__((visibility())) is supported,
1268                  libc_cv_visibility_attribute,
1269                  [cat > conftest.c <<EOF
1270                   int foo __attribute__ ((visibility ("hidden"))) = 1;
1271                   int bar __attribute__ ((visibility ("protected"))) = 1;
1272 EOF
1273                   libc_cv_visibility_attribute=no
1274                   if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1275                     if grep '\.hidden.*foo' conftest.s >/dev/null; then
1276                       if grep '\.protected.*bar' conftest.s >/dev/null; then
1277                         libc_cv_visibility_attribute=yes
1278                       fi
1279                     fi
1280                   fi
1281                   rm -f conftest.{c,s}
1282                  ])
1283   if test $libc_cv_visibility_attribute != yes; then
1284     AC_MSG_ERROR(compiler support for visibility attribute is required)
1285   fi
1286 fi
1287
1288 if test $libc_cv_visibility_attribute = yes; then
1289   AC_CACHE_CHECK(for broken __attribute__((visibility())),
1290                  libc_cv_broken_visibility_attribute,
1291                  [cat > conftest.c <<EOF
1292                   int foo (int x);
1293                   int bar (int x) __asm__ ("foo") __attribute__ ((visibility ("hidden")));
1294                   int bar (int x) { return x; }
1295 EOF
1296                   libc_cv_broken_visibility_attribute=yes
1297                   if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1298 changequote(,)dnl
1299                     if grep '\.hidden[  _]foo' conftest.s >/dev/null; then
1300 changequote([,])dnl
1301                       libc_cv_broken_visibility_attribute=no
1302                     fi
1303                   fi
1304                   rm -f conftest.c conftest.s
1305                  ])
1306   if test $libc_cv_broken_visibility_attribute = yes; then
1307     AC_MSG_ERROR(working compiler support for visibility attribute is required)
1308   fi
1309 fi
1310
1311 AC_CACHE_CHECK(for broken __attribute__((alias())),
1312                libc_cv_broken_alias_attribute,
1313                [cat > conftest.c <<EOF
1314                extern int foo (int x) __asm ("xyzzy");
1315                int bar (int x) { return x; }
1316                extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1317                extern int dfoo;
1318                extern __typeof (dfoo) dfoo __asm ("abccb");
1319                int dfoo = 1;
1320 EOF
1321                libc_cv_broken_alias_attribute=yes
1322                if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1323                  if grep 'xyzzy' conftest.s >/dev/null &&
1324                     grep 'abccb' conftest.s >/dev/null; then
1325                    libc_cv_broken_alias_attribute=no
1326                  fi
1327                fi
1328                rm -f conftest.c conftest.s
1329                ])
1330 if test $libc_cv_broken_alias_attribute = yes; then
1331   AC_MSG_ERROR(working alias attribute support required)
1332 fi
1333
1334 if test $libc_cv_visibility_attribute = yes; then
1335   AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1336                  libc_cv_have_sdata_section,
1337                  [echo "int i;" > conftest.c
1338                   libc_cv_have_sdata_section=no
1339                   if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1340                      | grep '\.sdata' >/dev/null; then
1341                     libc_cv_have_sdata_section=yes
1342                   fi
1343                   rm -f conftest.c conftest.so
1344                  ])
1345   if test $libc_cv_have_sdata_section = yes; then
1346     AC_DEFINE(HAVE_SDATA_SECTION)
1347   fi
1348 fi
1349
1350 AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
1351                libc_cv_initfini_array, [dnl
1352 LIBC_TRY_LINK_STATIC([
1353 int foo (void) { return 1; }
1354 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;
1355 ],
1356   [if $READELF -S conftest | fgrep INIT_ARRAY > /dev/null; then
1357     libc_cv_initfini_array=yes
1358   else
1359     libc_cv_initfini_array=no
1360   fi],
1361   [libc_cv_initfini_array=no])
1362 ])
1363 if test $libc_cv_initfini_array != yes; then
1364   AC_MSG_ERROR([Need linker with .init_array/.fini_array support.])
1365 fi
1366
1367 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1368                libc_cv_ctors_header, [dnl
1369   libc_cv_ctors_header=yes
1370   LIBC_TRY_LINK_STATIC([
1371 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1372 __attribute__ ((destructor))  void dtor (void) { asm (""); }
1373 ],
1374               [dnl
1375       AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1376         { gsub(/\@<:@ */, "@<:@") }
1377         $2 == ".ctors" || $2 == ".dtors" {
1378           size = strtonum("0x" $6)
1379           align = strtonum("0x" $NF)
1380           seen@<:@$2@:>@ = 1
1381           stub@<:@$2@:>@ = size == align * 2
1382         }
1383         END {
1384           ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1385           dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1386           exit ((ctors_ok && dtors_ok) ? 0 : 1)
1387         }
1388       '], [libc_cv_ctors_header=no])
1389     ], [dnl
1390       AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1391     ])
1392 ])
1393 if test $libc_cv_ctors_header = no; then
1394   AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1395 fi
1396
1397 AC_CACHE_CHECK(for libunwind-support in compiler,
1398                libc_cv_cc_with_libunwind, [
1399   cat > conftest.c <<EOF
1400 int main (void) { return 0; }
1401 EOF
1402   if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1403      conftest.c -v 2>&1 >/dev/null | grep -q " -lunwind "; then
1404     libc_cv_cc_with_libunwind=yes
1405   else
1406     libc_cv_cc_with_libunwind=no
1407   fi
1408   rm -f conftest*])
1409 AC_SUBST(libc_cv_cc_with_libunwind)
1410 if test $libc_cv_cc_with_libunwind = yes; then
1411   AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1412 fi
1413
1414 AC_CACHE_CHECK(for -z nodelete option,
1415                libc_cv_z_nodelete, [dnl
1416 cat > conftest.c <<EOF
1417 int _start (void) { return 42; }
1418 EOF
1419 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1420                    -fPIC -shared -o conftest.so conftest.c
1421                    -nostartfiles -nostdlib
1422                    -Wl,--enable-new-dtags,-z,nodelete 1>&AS_MESSAGE_LOG_FD])
1423 then
1424   libc_cv_z_nodelete=yes
1425 else
1426   AC_MSG_ERROR(linker with -z nodelete support required)
1427 fi
1428 rm -f conftest*])
1429
1430 AC_CACHE_CHECK(for -z nodlopen option,
1431                libc_cv_z_nodlopen, [dnl
1432 cat > conftest.c <<EOF
1433 int _start (void) { return 42; }
1434 EOF
1435 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1436                         -fPIC -shared -o conftest.so conftest.c
1437                         -nostartfiles -nostdlib
1438                         -Wl,--enable-new-dtags,-z,nodlopen 1>&AS_MESSAGE_LOG_FD])
1439 then
1440   libc_cv_z_nodlopen=yes
1441 else
1442   AC_MSG_ERROR(linker with -z nodlopen support required)
1443 fi
1444 rm -f conftest*])
1445
1446 AC_CACHE_CHECK(for -z initfirst option,
1447                libc_cv_z_initfirst, [dnl
1448 cat > conftest.c <<EOF
1449 int _start (void) { return 42; }
1450 EOF
1451 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1452                         -fPIC -shared -o conftest.so conftest.c
1453                         -nostartfiles -nostdlib
1454                         -Wl,--enable-new-dtags,-z,initfirst 1>&AS_MESSAGE_LOG_FD])
1455 then
1456   libc_cv_z_initfirst=yes
1457 else
1458   AC_MSG_ERROR(linker with -z initfirst support required)
1459 fi
1460 rm -f conftest*])
1461
1462 # Add-on fragments can set these for other machines.
1463 libc_commonpagesize=${libc_commonpagesize:-no}
1464 libc_relro_required=${libc_relro_required:-no}
1465 case "$base_machine" in
1466   i[[34567]]86 | x86_64 | powerpc* | s390*)
1467     libc_commonpagesize=0x1000
1468     libc_relro_required=yes
1469     ;;
1470   sparc*)
1471     libc_commonpagesize=0x2000
1472     libc_relro_required=yes
1473     ;;
1474 esac
1475
1476 if test $libc_commonpagesize != no; then
1477   AC_CACHE_CHECK(for -z relro option,
1478                  libc_cv_z_relro, [dnl
1479   libc_cv_z_relro=no
1480   AC_LANG_CONFTEST([AC_LANG_SOURCE([[
1481 int _start (void) { return 42; }
1482 extern void _exit (int);
1483 /* Since these pointers are const, they should go in rodata.
1484    Since they refer to functions that have to be resolved by
1485    dynamic linking, they should instead go in RELRO data.  */
1486 const void *const relro[] = { &_start, &_exit, 0 };
1487 /* GNU ld fails to produce RELRO data when it's very small and there is no
1488    normal writable data following it, or if only uninitialized (.bss) data
1489    follows it, or only very small writable data.  */
1490 int data[0x10000] = { 1, };
1491 ]])])
1492   cat > conftest.awk <<\EOF
1493 BEGIN {
1494   result = "no"
1495   commonpagesize = strtonum(commonpagesize)
1496 }
1497 { print "LINE:", $0 > "/dev/stderr" }
1498 $1 == "GNU_RELRO" {
1499   vaddr = strtonum($3)
1500   memsz = strtonum($6)
1501   end = vaddr + memsz
1502   printf "vaddr %#x memsz %#x end %#x commonpagesize %#x\n", \
1503     vaddr, memsz, end, commonpagesize > "/dev/stderr"
1504   result = (end % commonpagesize == 0) ? "yes" : "broken"
1505 }
1506 END { print result }
1507 EOF
1508   AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1509                     -fPIC -shared -o conftest.so conftest.c
1510                     -nostartfiles -nostdlib
1511                     -Wl,-z,relro 1>&AS_MESSAGE_LOG_FD]) &&
1512   AC_TRY_COMMAND([$READELF -Wl conftest.so > conftest.ph]) &&
1513   AC_TRY_COMMAND([
1514       $AWK -v commonpagesize=$libc_commonpagesize -f conftest.awk
1515            conftest.ph > conftest.cps
1516     ]) &&
1517   libc_cv_z_relro=`cat conftest.cps 2>&AS_MESSAGE_LOG_FD`
1518   rm -f conftest*])
1519   if { test "x$libc_relro_required" = xyes &&
1520        test "x$libc_cv_z_relro" != xyes
1521      }
1522   then
1523     AC_MSG_ERROR(linker with -z relro support required)
1524   fi
1525 else
1526   AC_MSG_WARN([missing architecture parameter to check for working -z relro])
1527 fi
1528
1529 AC_CACHE_CHECK(for -Bgroup option,
1530                libc_cv_Bgroup, [dnl
1531 cat > conftest.c <<EOF
1532 int _start (void) { return 42; }
1533 EOF
1534 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1535                             -fPIC -shared -o conftest.so conftest.c
1536                             -Wl,-Bgroup -nostdlib 1>&AS_MESSAGE_LOG_FD])
1537 then
1538   libc_cv_Bgroup=yes
1539 else
1540   libc_cv_Bgroup=no
1541 fi
1542 rm -f conftest*])
1543 AC_SUBST(libc_cv_Bgroup)
1544
1545 AC_CACHE_CHECK(for libgcc_s suffix,
1546                libc_cv_libgcc_s_suffix, [dnl
1547 cat > conftest.c <<EOF
1548 int main (void) { return 0; }
1549 EOF
1550 changequote(,)dnl
1551 libc_cv_libgcc_s_suffix=`${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1552                            -fPIC -shared -shared-libgcc -o conftest.so \
1553                            conftest.c -v 2>&1 >/dev/null \
1554                            | sed -n 's/^.* -lgcc_s\([^ ]*\) .*$/\1/p'`
1555 changequote([,])dnl
1556 rm -f conftest*])
1557 AC_SUBST(libc_cv_libgcc_s_suffix)
1558
1559 AC_CACHE_CHECK(for --as-needed option,
1560                libc_cv_as_needed, [dnl
1561 cat > conftest.c <<EOF
1562 int main (void) { return 0; }
1563 EOF
1564 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1565                               -fPIC -shared -o conftest.so conftest.c
1566                               -lgcc_s$libc_cv_libgcc_s_suffix -Wl,--as-needed
1567                               -nostdlib 1>&AS_MESSAGE_LOG_FD])
1568 then
1569   libc_cv_as_needed=yes
1570 else
1571   libc_cv_as_needed=no
1572 fi
1573 rm -f conftest*])
1574 AC_SUBST(libc_cv_as_needed)
1575
1576 ASFLAGS_config=
1577 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1578                libc_cv_as_noexecstack, [dnl
1579 cat > conftest.c <<EOF
1580 void foo (void) { }
1581 EOF
1582 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1583                    -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1584    && grep -q .note.GNU-stack conftest.s \
1585    && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1586                       -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1587 then
1588   libc_cv_as_noexecstack=yes
1589 else
1590   libc_cv_as_noexecstack=no
1591 fi
1592 rm -f conftest*])
1593 if test $libc_cv_as_noexecstack = yes; then
1594   ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1595 fi
1596 AC_SUBST(ASFLAGS_config)
1597
1598 AC_CACHE_CHECK(for -z combreloc,
1599                libc_cv_z_combreloc, [dnl
1600 cat > conftest.c <<EOF
1601 extern int bar (int);
1602 extern int mumble;
1603 int foo (void) { return bar (mumble); }
1604 EOF
1605 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1606                         -fPIC -shared -o conftest.so conftest.c
1607                         -nostdlib -nostartfiles
1608                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1609 then
1610 dnl The following test is a bit weak.  We must use a tool which can test
1611 dnl cross-platform since the gcc used can be a cross compiler.  Without
1612 dnl introducing new options this is not easily doable.  Instead use a tool
1613 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1614 dnl look for a section named .rel.dyn.
1615   if $READELF -S conftest.so | grep '\.rel\(a\|\)\.dyn' > /dev/null; then
1616     libc_cv_z_combreloc=yes
1617   else
1618     libc_cv_z_combreloc=no
1619   fi
1620 else
1621   libc_cv_z_combreloc=no
1622 fi
1623 rm -f conftest*])
1624 if test "$libc_cv_z_combreloc" = yes; then
1625   AC_DEFINE(HAVE_Z_COMBRELOC)
1626 fi
1627 AC_SUBST(libc_cv_z_combreloc)
1628
1629 AC_CACHE_CHECK(for -z execstack,
1630                libc_cv_z_execstack, [dnl
1631 cat > conftest.c <<EOF
1632 int _start (void) { return 42; }
1633 EOF
1634 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1635                             -fPIC -shared -o conftest.so conftest.c
1636                             -Wl,-z,execstack -nostdlib
1637                             1>&AS_MESSAGE_LOG_FD])
1638 then
1639   libc_cv_z_execstack=yes
1640 else
1641   libc_cv_z_execstack=no
1642 fi
1643 rm -f conftest*])
1644 AC_SUBST(libc_cv_z_execstack)
1645
1646 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1647 cat > conftest.c <<EOF
1648 int foo;
1649 main () { return 0;}
1650 EOF
1651 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -pie -fpie
1652                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD])
1653 then
1654   libc_cv_fpie=yes
1655 else
1656   libc_cv_fpie=no
1657 fi
1658 rm -f conftest*])
1659
1660 AC_SUBST(libc_cv_fpie)
1661
1662 AC_CACHE_CHECK(for --hash-style option,
1663                libc_cv_hashstyle, [dnl
1664 cat > conftest.c <<EOF
1665 int _start (void) { return 42; }
1666 EOF
1667 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1668                             -fPIC -shared -o conftest.so conftest.c
1669                             -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1670 then
1671   libc_cv_hashstyle=yes
1672 else
1673   libc_cv_hashstyle=no
1674 fi
1675 rm -f conftest*])
1676 AC_SUBST(libc_cv_hashstyle)
1677
1678 # The linker's default -shared behavior is good enough if it
1679 # does these things that our custom linker scripts ensure that
1680 # all allocated NOTE sections come first.
1681 if test "$use_default_link" = default; then
1682   AC_CACHE_CHECK([for sufficient default -shared layout],
1683                   libc_cv_use_default_link, [dnl
1684   libc_cv_use_default_link=no
1685   cat > conftest.s <<\EOF
1686           .section .note.a,"a",%note
1687           .balign 4
1688           .long 4,4,9
1689           .string "GNU"
1690           .string "foo"
1691           .section .note.b,"a",%note
1692           .balign 4
1693           .long 4,4,9
1694           .string "GNU"
1695           .string "bar"
1696 EOF
1697   if AC_TRY_COMMAND([dnl
1698   ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1699        ac_try=`$READELF -S conftest.so | sed -n \
1700          ['${x;p;}
1701           s/^ *\[ *[1-9][0-9]*\]  *\([^ ][^ ]*\)  *\([^ ][^ ]*\) .*$/\2 \1/
1702           t a
1703           b
1704           : a
1705           H']`
1706   then
1707     libc_seen_a=no libc_seen_b=no
1708     set -- $ac_try
1709     while test $# -ge 2 -a "$1" = NOTE; do
1710       case "$2" in
1711       .note.a) libc_seen_a=yes ;;
1712       .note.b) libc_seen_b=yes ;;
1713       esac
1714       shift 2
1715     done
1716     case "$libc_seen_a$libc_seen_b" in
1717     yesyes)
1718       libc_cv_use_default_link=yes
1719       ;;
1720     *)
1721       echo >&AS_MESSAGE_LOG_FD "\
1722 $libc_seen_a$libc_seen_b from:
1723 $ac_try"
1724       ;;
1725     esac
1726   fi
1727   rm -f conftest*])
1728   use_default_link=$libc_cv_use_default_link
1729 fi
1730
1731 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1732 if libc_cv_output_format=`
1733 ${CC-cc} -nostartfiles -nostdlib -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1734 then
1735   :
1736 else
1737   libc_cv_output_format=
1738 fi
1739 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1740 AC_SUBST(libc_cv_output_format)
1741
1742 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1743 cat > conftest.c <<EOF
1744 int foo;
1745 EOF
1746 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1747                             conftest.c 1>&AS_MESSAGE_LOG_FD])
1748 then
1749   libc_cv_fno_toplevel_reorder=yes
1750 else
1751   libc_cv_fno_toplevel_reorder=no
1752 fi
1753 rm -f conftest*])
1754 if test $libc_cv_fno_toplevel_reorder = yes; then
1755   fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1756 else
1757   fno_unit_at_a_time=-fno-unit-at-a-time
1758 fi
1759 AC_SUBST(fno_unit_at_a_time)
1760
1761 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
1762 cat > conftest.c <<EOF
1763 int foo;
1764 main () { return 0;}
1765 EOF
1766 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -Werror -fstack-protector
1767                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD])
1768 then
1769   libc_cv_ssp=yes
1770 else
1771   libc_cv_ssp=no
1772 fi
1773 rm -f conftest*])
1774 AC_SUBST(libc_cv_ssp)
1775
1776 AC_CACHE_CHECK(for -fgnu89-inline, libc_cv_gnu89_inline, [dnl
1777 cat > conftest.c <<EOF
1778 int foo;
1779 #ifdef __GNUC_GNU_INLINE__
1780 main () { return 0;}
1781 #else
1782 #error
1783 #endif
1784 EOF
1785 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -std=gnu99 -fgnu89-inline
1786                             -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD])
1787 then
1788   libc_cv_gnu89_inline=yes
1789 else
1790   libc_cv_gnu89_inline=no
1791 fi
1792 rm -f conftest*])
1793 if test $libc_cv_gnu89_inline = yes; then
1794   gnu89_inline=-fgnu89-inline
1795 else
1796   gnu89_inline=
1797 fi
1798 AC_SUBST(gnu89_inline)
1799
1800 AC_CACHE_CHECK(whether cc puts quotes around section names,
1801                libc_cv_have_section_quotes,
1802                [cat > conftest.c <<EOF
1803                 static const int foo
1804                 __attribute__ ((section ("bar"))) = 1;
1805 EOF
1806                 if ${CC-cc} -S conftest.c -o conftest.s; then
1807                   if grep '\.section.*"bar"' conftest.s >/dev/null; then
1808                     libc_cv_have_section_quotes=yes
1809                   else
1810                     libc_cv_have_section_quotes=no
1811                   fi
1812                 else
1813                   libc_cv_have_section_quotes=unknown
1814                 fi
1815                 rm -f conftest.{c,s}
1816                 ])
1817 if test $libc_cv_have_section_quotes = yes; then
1818   AC_DEFINE(HAVE_SECTION_QUOTES)
1819 fi
1820
1821 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
1822                [dnl
1823 cat > conftest.s <<EOF
1824 ${libc_cv_dot_text}
1825 ${libc_cv_asm_global_directive} foo
1826 foo:
1827 .weak foo
1828 .weak bar; bar = foo
1829 EOF
1830 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1831   libc_cv_asm_weak_directive=yes
1832 else
1833   libc_cv_asm_weak_directive=no
1834 fi
1835 rm -f conftest*])
1836
1837 if test $libc_cv_asm_weak_directive = no; then
1838   AC_CACHE_CHECK(for assembler .weakext directive,
1839                  libc_cv_asm_weakext_directive,
1840                  [dnl
1841 cat > conftest.s <<EOF
1842 ${libc_cv_dot_text}
1843 ${libc_cv_asm_global_directive} foo
1844 foo:
1845 .weakext bar foo
1846 .weakext baz
1847 ${libc_cv_asm_global_directive} baz
1848 baz:
1849 EOF
1850   if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1851     libc_cv_asm_weakext_directive=yes
1852   else
1853     libc_cv_asm_weakext_directive=no
1854   fi
1855   rm -f conftest*])
1856
1857 fi # no .weak
1858
1859 if test $libc_cv_asm_weak_directive = yes; then
1860   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
1861 elif test $libc_cv_asm_weakext_directive = yes; then
1862   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
1863 fi
1864
1865 AC_CACHE_CHECK(whether CFI directives are supported, libc_cv_asm_cfi_directives, [dnl
1866 case $machine in
1867   sparc/sparc64*) cfi_offset=2047;;
1868   *) cfi_offset=0;;
1869 esac
1870 cat > conftest.s <<EOF
1871         .text
1872         .type   func,%function
1873 func:
1874         .cfi_startproc
1875         .cfi_remember_state
1876         .cfi_rel_offset 1, $cfi_offset
1877         .cfi_endproc
1878 EOF
1879 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1880   libc_cv_asm_cfi_directives=yes
1881 else
1882   libc_cv_asm_cfi_directives=no
1883 fi
1884 rm -f conftest*])
1885 if test $libc_cv_asm_cfi_directives = yes; then
1886   AC_DEFINE(HAVE_ASM_CFI_DIRECTIVES)
1887 fi
1888
1889 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
1890 cat > conftest.c <<\EOF
1891 _start () {}
1892 int __eh_pc;
1893 __throw () {}
1894 EOF
1895 dnl No \ in command here because it ends up inside ''.
1896 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1897                             -nostdlib -nostartfiles -Wl,--no-whole-archive
1898                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1899   libc_cv_ld_no_whole_archive=yes
1900 else
1901   libc_cv_ld_no_whole_archive=no
1902 fi
1903 rm -f conftest*])
1904 if test $libc_cv_ld_no_whole_archive = no; then
1905   AC_MSG_ERROR([support for --no-whole-archive is needed])
1906 fi
1907
1908 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1909 cat > conftest.c <<\EOF
1910 _start () {}
1911 int __eh_pc;
1912 __throw () {}
1913 EOF
1914 dnl No \ in command here because it ends up inside ''.
1915 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1916                             -nostdlib -nostartfiles -fexceptions
1917                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1918   libc_cv_gcc_exceptions=yes
1919 else
1920   libc_cv_gcc_exceptions=no
1921 fi
1922 rm -f conftest*])
1923 if test $libc_cv_gcc_exceptions = yes; then
1924   exceptions=-fexceptions
1925 fi
1926 AC_SUBST(exceptions)dnl
1927
1928 if test "$host_cpu" = powerpc ; then
1929 # Check for a bug present in at least versions 2.8.x of GCC
1930 # and versions 1.0.x of EGCS.
1931 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1932 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1933                libc_cv_c_asmcr0_bug='no',
1934                libc_cv_c_asmcr0_bug='yes')])
1935 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1936   AC_DEFINE(BROKEN_PPC_ASM_CR0)
1937 fi
1938 fi
1939
1940 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1941 cat > conftest.c <<\EOF
1942 void zero (void *x)
1943 {
1944   __builtin_memset (x, 0, 1000);
1945 }
1946 EOF
1947 dnl
1948 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "memset" > /dev/null]);
1949 then
1950   libc_cv_gcc_builtin_memset=no
1951 else
1952   libc_cv_gcc_builtin_memset=yes
1953 fi
1954 rm -f conftest* ])
1955 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1956   AC_DEFINE(HAVE_BUILTIN_MEMSET)
1957 fi
1958
1959 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1960 cat > conftest.c <<\EOF
1961 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1962 char *foo (const char *a, const char *b)
1963 {
1964   return __builtin_strstr (a, b);
1965 }
1966 EOF
1967 dnl
1968 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "my_strstr" > /dev/null]);
1969 then
1970   libc_cv_gcc_builtin_redirection=yes
1971 else
1972   libc_cv_gcc_builtin_redirection=no
1973 fi
1974 rm -f conftest* ])
1975 if test "$libc_cv_gcc_builtin_redirection" = no; then
1976   AC_MSG_ERROR([support for the symbol redirection needed])
1977 fi
1978
1979 dnl Check whether the compiler supports the __thread keyword.
1980 AC_CACHE_CHECK([for __thread], libc_cv_gcc___thread,
1981 [cat > conftest.c <<\EOF
1982 __thread int a = 42;
1983 EOF
1984 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
1985   libc_cv_gcc___thread=yes
1986 else
1987   libc_cv_gcc___thread=no
1988 fi
1989 rm -f conftest*])
1990 if test "$libc_cv_gcc___thread" = no; then
1991   AC_MSG_ERROR([support for the __thread keyword is required])
1992 fi
1993
1994 dnl Check whether the compiler supports the tls_model attribute.
1995 AC_CACHE_CHECK([for tls_model attribute], libc_cv_gcc_tls_model_attr, [dnl
1996 cat > conftest.c <<\EOF
1997 extern __thread int a __attribute__((tls_model ("initial-exec")));
1998 EOF
1999 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -Werror conftest.c >&AS_MESSAGE_LOG_FD]); then
2000   libc_cv_gcc_tls_model_attr=yes
2001 else
2002   libc_cv_gcc_tls_model_attr=no
2003 fi
2004 rm -f conftest*])
2005 if test "$libc_cv_gcc_tls_model_attr" = no; then
2006   AC_MSG_ERROR([support for the tls_model attribute is required])
2007 fi
2008
2009 if test -n "$submachine"; then
2010   AC_CACHE_CHECK([for compiler option for CPU variant],
2011                  libc_cv_cc_submachine, [dnl
2012   libc_cv_cc_submachine=no
2013   for opt in "-march=$submachine" "-mcpu=$submachine"; do
2014     if AC_TRY_COMMAND([${CC-cc} $opt -xc /dev/null -S -o /dev/null]); then
2015       libc_cv_cc_submachine="$opt"
2016       break
2017     fi
2018   done])
2019   if test "x$libc_cv_cc_submachine" = xno; then
2020     AC_MSG_ERROR([${CC-cc} does not support $submachine])
2021   fi
2022 fi
2023 AC_SUBST(libc_cv_cc_submachine)
2024
2025 dnl Check whether we have the gd library available.
2026 AC_MSG_CHECKING(for libgd)
2027 if test "$with_gd" != "no"; then
2028   old_CFLAGS="$CFLAGS"
2029   CFLAGS="$CFLAGS $libgd_include"
2030   old_LDFLAGS="$LDFLAGS"
2031   LDFLAGS="$LDFLAGS $libgd_ldflags"
2032   old_LIBS="$LIBS"
2033   LIBS="$LIBS -lgd -lpng -lz -lm"
2034   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
2035   CFLAGS="$old_CFLAGS"
2036   LDFLAGS="$old_LDFLAGS"
2037   LIBS="$old_LIBS"
2038 else
2039   LIBGD=no
2040 fi
2041 AC_MSG_RESULT($LIBGD)
2042 AC_SUBST(LIBGD)
2043
2044 # SELinux detection
2045 if test x$with_selinux = xno ; then
2046   have_selinux=no;
2047 else
2048   # See if we have the SELinux library
2049   AC_CHECK_LIB(selinux, is_selinux_enabled,
2050                have_selinux=yes, have_selinux=no)
2051   # See if we have the SELinux header with the NSCD permissions in it.
2052   if test x$have_selinux = xyes ; then
2053     AC_MSG_CHECKING([for NSCD Flask permissions in selinux/av_permissions.h])
2054     AC_TRY_COMPILE([#include <selinux/av_permissions.h>],
2055                     [#ifdef NSCD__SHMEMHOST
2056                      return 0;
2057                      #else
2058                      #error NSCD__SHMEMHOST not defined
2059                      #endif],
2060                     have_selinux=yes, have_selinux=no)
2061     AC_MSG_RESULT($have_selinux)
2062   fi
2063
2064   if test x$with_selinux = xyes ; then
2065     if test x$have_selinux = xno ; then
2066       AC_MSG_ERROR([SELinux explicitly required, but sufficiently recent SELinux library not found])
2067     fi
2068   fi
2069 fi
2070 # Check if we're building with SELinux support.
2071 if test "x$have_selinux" = xyes; then
2072   AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
2073
2074   # See if we have the libaudit library
2075   AC_CHECK_LIB(audit, audit_log_user_avc_message,
2076                have_libaudit=yes, have_libaudit=no)
2077   if test "x$have_libaudit" = xyes; then
2078     AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
2079   fi
2080   AC_SUBST(have_libaudit)
2081
2082   # See if we have the libcap library
2083   AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
2084   if test "x$have_libcap" = xyes; then
2085     AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
2086   fi
2087   AC_SUBST(have_libcap)
2088 fi
2089 AC_SUBST(have_selinux)
2090
2091 dnl check for the size of 'long double'.
2092 AC_CHECK_SIZEOF(long double, 0)
2093 sizeof_long_double=$ac_cv_sizeof_long_double
2094 AC_SUBST(sizeof_long_double)
2095
2096 ### End of automated tests.
2097 ### Now run sysdeps configure fragments.
2098
2099 # They also can set these variables.
2100 use_ldconfig=no
2101 ldd_rewrite_script=no
2102 libc_cv_sysconfdir=$sysconfdir
2103 libc_cv_gcc_unwind_find_fde=no
2104 libc_cv_idn=no
2105
2106 # Iterate over all the sysdep directories we will use, running their
2107 # configure fragments.
2108 for dir in $sysnames; do
2109   case $dir in
2110     /*) dest=$dir ;;
2111     *)  dest=$srcdir/$dir ;;
2112   esac
2113   if test -r $dest/configure; then
2114     AC_MSG_RESULT(running configure fragment for $dir)
2115     . $dest/configure
2116   fi
2117 done
2118
2119 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
2120   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
2121 fi
2122 AC_SUBST(libc_cv_gcc_unwind_find_fde)
2123
2124 # Test for old glibc 2.0.x headers so that they can be removed properly
2125 # Search only in includedir.
2126 AC_MSG_CHECKING(for old glibc 2.0.x headers)
2127 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
2128 then
2129   old_glibc_headers=yes
2130 else
2131   old_glibc_headers=no
2132 fi
2133 AC_MSG_RESULT($old_glibc_headers)
2134 if test ${old_glibc_headers} = yes; then
2135   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
2136   AC_MSG_WARN(*** be removed.)
2137 fi
2138 AC_SUBST(old_glibc_headers)
2139
2140 AC_SUBST(libc_cv_slibdir)
2141 AC_SUBST(libc_cv_localedir)
2142 AC_SUBST(libc_cv_sysconfdir)
2143 AC_SUBST(libc_cv_rootsbindir)
2144 AC_SUBST(libc_cv_forced_unwind)
2145
2146 dnl sysdeps/CPU/configure.in checks set this via arch-specific asm tests
2147 AC_SUBST(libc_cv_cpp_asm_debuginfo)
2148 AC_SUBST(libc_cv_cc_sse4)
2149 AC_SUBST(libc_cv_cc_avx)
2150 AC_SUBST(libc_cv_cc_sse2avx)
2151 AC_SUBST(libc_cv_cc_novzeroupper)
2152 AC_SUBST(libc_cv_cc_fma4)
2153 AC_SUBST(libc_cv_as_i686)
2154 AC_SUBST(libc_cv_sparc_as_vis3)
2155
2156 AC_SUBST(use_ldconfig)
2157 AC_SUBST(ldd_rewrite_script)
2158
2159 AC_SUBST(static)
2160 AC_SUBST(shared)
2161
2162 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
2163 [libc_cv_pic_default=yes
2164 cat > conftest.c <<EOF
2165 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
2166 # error PIC is default.
2167 #endif
2168 EOF
2169 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
2170   libc_cv_pic_default=no
2171 fi
2172 rm -f conftest.*])
2173 AC_SUBST(libc_cv_pic_default)
2174
2175 AC_SUBST(profile)
2176 AC_SUBST(static_nss)
2177
2178 AC_SUBST(DEFINES)
2179
2180 dnl See sysdeps/mach/configure.in for this variable.
2181 AC_SUBST(mach_interface_list)
2182
2183 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
2184   config_makefile=
2185 else
2186   config_makefile=Makefile
2187 fi
2188
2189 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
2190 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
2191 AC_SUBST(VERSION)
2192 AC_SUBST(RELEASE)
2193
2194 AC_CONFIG_FILES([config.make ${config_makefile}])
2195 AC_CONFIG_COMMANDS([default],[[
2196 case $CONFIG_FILES in *config.make*)
2197 echo "$config_vars" >> config.make;;
2198 esac
2199 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
2200 AC_OUTPUT