configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 # require autoconf 2.54
   3 AC_PREREQ(2.54)
   4
   5 dnl ***********************************
   6 dnl *** include special GLib macros ***
   7 dnl ***********************************
   8
   9 m4_define(glib_configure_in)
  10
  11 #
  12 # The following version number definitions apply to GLib, GModule, GObject,
  13 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  14 # all treated with the same interface and binary age.
  15 #
  16 # Making releases:
  17 #   glib_micro_version += 1;
  18 #   glib_interface_age += 1;
  19 #   glib_binary_age += 1;
  20 # if any functions have been added, set glib_interface_age to 0.
  21 # if backwards compatibility has been broken,
  22 # set glib_binary_age _and_ glib_interface_age to 0.
  23 #
  24 m4_define([glib_major_version], [2])
  25 m4_define([glib_minor_version], [22])
  26 m4_define([glib_micro_version], [1])
  27 m4_define([glib_interface_age], [1])
  28 m4_define([glib_binary_age],
  29           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  30 m4_define([glib_version],
  31           [glib_major_version.glib_minor_version.glib_micro_version])
  32
  33 # libtool version related macros
  34 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  35 m4_define([glib_lt_current],
  36           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  37 m4_define([glib_lt_revision], [glib_interface_age])
  38 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  39 m4_define([glib_lt_current_minus_age],
  40           [m4_eval(glib_lt_current - glib_lt_age)])
  41
  42 # if the minor version number is odd, then we want debugging.  Otherwise
  43 # we only want minimal debugging support.
  44 m4_define([glib_debug_default],
  45           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  46
  47
  48 AC_INIT(glib, [glib_version],
  49         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  50
  51 AC_CONFIG_SRCDIR([glib/glib.h])
  52
  53 # Save this value here, since automake will set cflags later
  54 cflags_set=${CFLAGS+set}
  55
  56 AM_INIT_AUTOMAKE([no-define])
  57
  58 # Specify a configuration file
  59 AM_CONFIG_HEADER([config.h])
  60
  61 # Support silent build rules, requires at least automake-1.11. Enable
  62 # by either passing --enable-silent-rules to configure or passing V=0
  63 # to make
  64 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([no])])
  65
  66 GLIB_MAJOR_VERSION=glib_major_version
  67 GLIB_MINOR_VERSION=glib_minor_version
  68 GLIB_MICRO_VERSION=glib_micro_version
  69 GLIB_INTERFACE_AGE=glib_interface_age
  70 GLIB_BINARY_AGE=glib_binary_age
  71 GLIB_VERSION=glib_version
  72
  73 AC_SUBST(GLIB_MAJOR_VERSION)
  74 AC_SUBST(GLIB_MINOR_VERSION)
  75 AC_SUBST(GLIB_MICRO_VERSION)
  76 AC_SUBST(GLIB_VERSION)
  77 AC_SUBST(GLIB_INTERFACE_AGE)
  78 AC_SUBST(GLIB_BINARY_AGE)
  79
  80 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  81           [Define to the GLIB major version])
  82 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  83           [Define to the GLIB minor version])
  84 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  85           [Define to the GLIB micro version])
  86 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  87           [Define to the GLIB interface age])
  88 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  89           [Define to the GLIB binary age])
  90
  91 # libtool versioning
  92 LT_RELEASE=glib_lt_release
  93 LT_CURRENT=glib_lt_current
  94 LT_REVISION=glib_lt_revision
  95 LT_AGE=glib_lt_age
  96 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
  97 AC_SUBST(LT_RELEASE)
  98 AC_SUBST(LT_CURRENT)
  99 AC_SUBST(LT_REVISION)
 100 AC_SUBST(LT_AGE)
 101 AC_SUBST(LT_CURRENT_MINUS_AGE)
 102
 103 dnl Initialize maintainer mode
 104 AM_MAINTAINER_MODE
 105
 106 AC_CANONICAL_HOST
 107
 108 AC_MSG_CHECKING([for the BeOS])
 109 case $host in
 110   *-*-beos*)
 111     glib_native_beos="yes"
 112     ;;
 113   *)
 114     glib_native_beos="no"
 115     ;;
 116 esac
 117 AC_MSG_RESULT([$glib_native_beos])
 118
 119 dnl
 120
 121 AC_MSG_CHECKING([for Win32])
 122 LIB_EXE_MACHINE_FLAG=X86
 123 case "$host" in
 124   *-*-mingw*)
 125     glib_native_win32=yes
 126     glib_pid_type='void *'
 127     glib_cv_stack_grows=no
 128     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 129     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 130     # (Sorry, I don't know exactly what is the problem, but it is related to
 131     # floating point formatting and decimal point vs. comma.)
 132     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 133     # rigorous enough to notice, though.
 134     # So preset the autoconf cache variables.
 135     ac_cv_func_vsnprintf_c99=no
 136     ac_cv_func_snprintf_c99=no
 137     case "$host" in
 138     x86_64-*-*)
 139       LIB_EXE_MACHINE_FLAG=X64
 140       ;;
 141     esac
 142     ;;
 143   *)
 144     glib_native_win32=no
 145     glib_pid_type=int
 146     ;;
 147 esac
 148 case $host in
 149   *-*-linux*)
 150     glib_os_linux=yes
 151     ;;
 152 esac
 153
 154 AC_MSG_RESULT([$glib_native_win32])
 155
 156 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 157
 158 glib_have_carbon=no
 159 AC_MSG_CHECKING([for Mac OS X Carbon support])
 160 AC_TRY_CPP([
 161 #include <Carbon/Carbon.h>
 162 #include <CoreServices/CoreServices.h>
 163 ], glib_have_carbon=yes)
 164
 165 AC_MSG_RESULT([$glib_have_carbon])
 166
 167 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 168 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 169 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 170 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 171 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 172
 173 if test "$glib_native_win32" = "yes"; then
 174   AC_CHECK_TOOL(WINDRES, windres, no)
 175   if test "$WINDRES" = no; then
 176     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 177   fi
 178   AC_CHECK_TOOL(NM, nm, no)
 179   if test "$NM" = no; then
 180     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 181   fi
 182   AC_CHECK_TOOL(RANLIB, ranlib, :)
 183   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 184 fi
 185 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 186
 187 if test "$glib_native_win32" != yes; then
 188     # libtool option to control which symbols are exported
 189     # right now, symbols starting with _ are not exported
 190     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 191 else
 192     # We currently use .def files on Windows
 193     LIBTOOL_EXPORT_OPTIONS=
 194 fi
 195 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 196
 197 if test "x$glib_have_carbon" = "xyes"; then
 198   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 199   LDFLAGS="$LDFLAGS -framework Carbon"
 200 fi
 201
 202
 203 dnl declare --enable-* args and collect ac_help strings
 204 AC_ARG_ENABLE(debug,
 205               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 206                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 207               enable_debug=glib_debug_default)
 208
 209 AC_ARG_ENABLE(gc_friendly,
 210               [AC_HELP_STRING([--enable-gc-friendly],
 211                               [turn on garbage collector friendliness [default=no]])],,
 212               [enable_gc_friendly=no])
 213 AC_ARG_ENABLE(mem_pools,
 214               [AC_HELP_STRING([--disable-mem-pools],
 215                               [disable all glib memory pools])],,
 216               [disable_mem_pools=no])
 217 AC_ARG_ENABLE(threads,
 218               [AC_HELP_STRING([--enable-threads],
 219                               [turn on basic thread support [default=yes]
 220 ([=no] will override --with-threads)])],,
 221               [enable_threads=yes])
 222 AC_ARG_ENABLE(rebuilds,
 223               [AC_HELP_STRING([--disable-rebuilds],
 224                               [disable all source autogeneration rules])],,
 225               [enable_rebuilds=yes])
 226 AC_ARG_ENABLE(visibility,
 227               [AC_HELP_STRING([--disable-visibility],
 228                               [don't use ELF visibility attributes])],,
 229               [enable_visibility=yes])
 230
 231 if test "x$enable_threads" != "xyes"; then
 232   enable_threads=no
 233 fi
 234
 235 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 236 if test "x$enable_gc_friendly" = "xyes"; then
 237   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 238   AC_MSG_RESULT([yes])
 239 else
 240   AC_MSG_RESULT([no])
 241 fi
 242
 243 AC_MSG_CHECKING([whether to disable memory pools])
 244 if test "x$disable_mem_pools" = "xno"; then
 245   AC_MSG_RESULT([no])
 246 else
 247   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 248   AC_SUBST(DISABLE_MEM_POOLS)
 249   AC_MSG_RESULT([yes])
 250 fi
 251
 252 dnl location to install runtime libraries, e.g. ../../lib to install
 253 dnl to /lib if libdir is /usr/lib
 254 AC_ARG_WITH(runtime-libdir,
 255            [AC_HELP_STRING([--with-runtime-libdir=RELPATH],
 256                            [Install runtime libraries relative to libdir])],
 257            [],
 258            [with_runtime_libdir=""])
 259 GLIB_RUNTIME_LIBDIR=$with_runtime_libdir
 260 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 261 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 262
 263 dnl Checks for programs.
 264 AC_PROG_CC
 265 AC_PROG_CPP
 266
 267 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 268 AC_CHECK_PROGS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 269 AC_LANG_SAVE
 270 AC_LANG_CPLUSPLUS
 271 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 272 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 273 AC_LANG_RESTORE
 274
 275 AM_PROG_CC_STDC
 276 AM_PROG_CC_C_O
 277 AC_PROG_INSTALL
 278
 279 AC_SYS_LARGEFILE
 280
 281 #
 282 # Find pkg-config
 283 #
 284 AC_PATH_PROG(PKG_CONFIG, [pkg-config], [no])
 285 if test x$PKG_CONFIG = xno ; then
 286   AC_MSG_ERROR([*** pkg-config not found. See http://www.freedesktop.org/software/pkgconfig/])
 287 fi
 288
 289 if $PKG_CONFIG --atleast-pkgconfig-version 0.16 ; then
 290   :
 291 else
 292   AC_MSG_ERROR([*** pkg-config too old; version 0.16 or better required.])
 293 fi
 294
 295 if test "x$enable_debug" = "xyes"; then
 296   if test x$cflags_set != xset ; then
 297       case " $CFLAGS " in
 298       *[[\ \    ]]-g[[\ \       ]]*) ;;
 299       *) CFLAGS="$CFLAGS -g" ;;
 300       esac
 301   fi
 302
 303   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 304 else
 305   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 306
 307   if test "x$enable_debug" = "xno"; then
 308     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 309   fi
 310 fi
 311
 312 if test "x$enable_visibility" = "xno"; then
 313   GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DDISABLE_VISIBILITY"
 314 fi
 315
 316 # Ensure MSVC-compatible struct packing convention is used when
 317 # compiling for Win32 with gcc.
 318 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 319 # gcc2 uses "-fnative-struct".
 320 if test x"$glib_native_win32" = xyes; then
 321   if test x"$GCC" = xyes; then
 322     msnative_struct=''
 323     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 324     if test -z "$ac_cv_prog_CC"; then
 325       our_gcc="$CC"
 326     else
 327       our_gcc="$ac_cv_prog_CC"
 328     fi
 329     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 330       2.)
 331         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 332           msnative_struct='-fnative-struct'
 333         fi
 334         ;;
 335       *)
 336         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 337           msnative_struct='-mms-bitfields'
 338         fi
 339         ;;
 340     esac
 341     if test x"$msnative_struct" = x ; then
 342       AC_MSG_RESULT([no way])
 343       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 344     else
 345       CFLAGS="$CFLAGS $msnative_struct"
 346       AC_MSG_RESULT([${msnative_struct}])
 347     fi
 348   fi
 349 fi
 350 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 351 AC_SUBST(GLIB_EXTRA_CFLAGS)
 352
 353 AC_EXEEXT
 354
 355 # define a MAINT-like variable REBUILD which is set if Perl
 356 # and awk are found, so autogenerated sources can be rebuilt
 357 AC_PROG_AWK
 358 AC_CHECK_PROGS(PERL, [perl5 perl])
 359 # We would like indent, but don't require it.
 360 AC_CHECK_PROG(INDENT, indent, indent)
 361 REBUILD=\#
 362 if test "x$enable_rebuilds" = "xyes" && \
 363      test -n "$PERL" && \
 364      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 365      test -n "$AWK" ; then
 366   REBUILD=
 367 fi
 368 AC_SUBST(REBUILD)
 369
 370 # Need full path to Perl for glib-mkenums
 371 #
 372 if test "x$PERL" != x ; then
 373   AC_PATH_PROG(PERL_PATH, [$PERL])
 374 fi
 375 if test "x$PERL_PATH" = x ; then
 376   PERL_PATH="/usr/bin/env perl"
 377 fi
 378 AC_SUBST(PERL_PATH)
 379
 380 # Need suitable python path for greport
 381 AM_PATH_PYTHON(2.4,,PYTHON="/usr/bin/env python2.4")
 382
 383
 384 dnl ***********************
 385 dnl *** Tests for iconv ***
 386 dnl ***********************
 387 dnl
 388 dnl We do this before the gettext checks, to avoid distortion
 389
 390 dnl On Windows we use a native implementation
 391
 392 if test x"$glib_native_win32" = xyes; then
 393   with_libiconv=native
 394 else
 395   AC_ARG_WITH(libiconv,
 396               [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 397                               [use the libiconv library])],,
 398               [with_libiconv=maybe])
 399
 400   found_iconv=no
 401   case $with_libiconv in
 402     maybe)
 403       # Check in the C library first
 404       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 405       # Check if we have GNU libiconv
 406       if test $found_iconv = "no"; then
 407         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 408       fi
 409       # Check if we have a iconv in -liconv, possibly from vendor
 410       if test $found_iconv = "no"; then
 411         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 412       fi
 413       ;;
 414     no)
 415       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 416       ;;
 417     gnu|yes)
 418       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 419       ;;
 420     native)
 421       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 422       ;;
 423   esac
 424
 425   if test "x$found_iconv" = "xno" ; then
 426      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 427   fi
 428 fi
 429
 430 gl_GLIBC21
 431 AC_ARG_ENABLE(iconv-cache,
 432               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 433                               [cache iconv descriptors [default=auto]])],,
 434               [enable_iconv_cache=auto])
 435
 436 AC_MSG_CHECKING([Whether to cache iconv descriptors])
 437 case $enable_iconv_cache in
 438   auto)
 439     if test $ac_cv_gnu_library_2_1 = yes; then
 440       enable_iconv_cache=no
 441     else
 442       enable_iconv_cache=yes
 443     fi
 444   ;;
 445   yes|no)
 446   ;;
 447   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 448   ;;
 449 esac
 450
 451 if test $enable_iconv_cache = yes; then
 452    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 453 fi
 454
 455 AC_MSG_RESULT($enable_iconv_cache)
 456
 457
 458 dnl
 459 dnl gettext support
 460 dnl
 461
 462 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 463 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 464 GLIB_GNU_GETTEXT
 465
 466 if test "$gt_cv_have_gettext" != "yes" ; then
 467   AC_MSG_ERROR([
 468 *** You must have either have gettext support in your C library, or use the
 469 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 470 ])
 471 fi
 472
 473 LIBS="$INTLLIBS $LIBS"
 474
 475 GETTEXT_PACKAGE=glib20
 476 AC_SUBST(GETTEXT_PACKAGE)
 477 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 478   [Define the gettext package to be used])
 479
 480 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 481
 482 dnl
 483 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 484 dnl
 485
 486 if test x"$glib_native_win32" != xyes; then
 487   if test x$with_libiconv != xno ; then
 488     case " $INTLLIBS " in
 489     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 490     *) ICONV_LIBS="-liconv" ;;
 491     esac
 492   fi
 493 fi
 494 AC_SUBST(ICONV_LIBS)
 495
 496 case $with_libiconv in
 497   gnu)
 498     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 499     ;;
 500   native)
 501     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 502     ;;
 503 esac
 504
 505 dnl Initialize libtool
 506 AM_DISABLE_STATIC
 507 AC_LIBTOOL_WIN32_DLL
 508 AM_PROG_LIBTOOL
 509 dnl when using libtool 2.x create libtool early, because it's used in configure
 510 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 511
 512
 513 if test "x$GCC" = "xyes"; then
 514   case " $CFLAGS " in
 515   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 516   *) CFLAGS="$CFLAGS -Wall" ;;
 517   esac
 518 fi
 519
 520 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES"
 521
 522 if test "$glib_native_win32" = "yes"; then
 523   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 524     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 525   fi
 526   if test x$enable_static = xyes; then
 527     glib_win32_static_compilation=yes
 528     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 529 #define GOBJECT_STATIC_COMPILATION 1"
 530     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 531   fi
 532 fi
 533 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 534
 535 dnl
 536 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 537 dnl
 538 if test $cross_compiling != yes ; then
 539     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 540     glib_save_LIBS=$LIBS
 541     LIBS="$LIBS -lm"
 542     AC_TRY_RUN([#include <math.h>
 543                  int main (void) { return (log(1) != log(1.)); }],
 544          AC_MSG_RESULT(none needed),
 545          glib_save_CFLAGS=$CFLAGS
 546          CFLAGS="$CFLAGS -std1"
 547          AC_TRY_RUN([#include <math.h>
 548                      int main (void) { return (log(1) != log(1.)); }],
 549              AC_MSG_RESULT(-std1),
 550              AC_MSG_RESULT()
 551              CFLAGS=$glib_save_CFLAGS
 552              AC_MSG_WARN(
 553                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 554          )
 555     )
 556     LIBS=$glib_save_LIBS
 557 fi
 558
 559 dnl NeXTStep cc seems to need this
 560 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 561 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 562   AC_MSG_RESULT(none needed),
 563   glib_save_CFLAGS=$CFLAGS
 564   CFLAGS="$CFLAGS -posix"
 565   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 566     AC_MSG_RESULT(-posix),
 567     AC_MSG_RESULT()
 568     CFLAGS=$glib_save_CFLAGS
 569     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 570
 571 # Checks for header files.
 572 AC_HEADER_STDC
 573
 574 # Checks for library functions.
 575 AC_FUNC_VPRINTF
 576 AC_FUNC_ALLOCA
 577 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2)
 578 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 579
 580 AC_CHECK_SIZEOF(char)
 581 AC_CHECK_SIZEOF(short)
 582 AC_CHECK_SIZEOF(long)
 583 AC_CHECK_SIZEOF(int)
 584 AC_CHECK_SIZEOF(void *)
 585 AC_CHECK_SIZEOF(long long)
 586 AC_CHECK_SIZEOF(__int64)
 587
 588 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 589   :
 590 else
 591   AC_MSG_ERROR([
 592 *** GLib requires a 64 bit type. You might want to consider
 593 *** using the GNU C compiler.
 594 ])
 595 fi
 596
 597 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 598         # long long is a 64 bit integer.
 599         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 600         AC_CACHE_VAL(glib_cv_long_long_format,[
 601                 for format in ll q I64; do
 602                   AC_TRY_RUN([#include <stdio.h>
 603                         int main()
 604                         {
 605                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 606                           char buffer[1000];
 607                           sprintf (buffer, "%${format}u", a);
 608                           sscanf (buffer, "%${format}u", &b);
 609                           exit (b!=a);
 610                         }
 611                         ],
 612                         [glib_cv_long_long_format=${format}
 613                         break],
 614                         [],[:])
 615                 done])
 616         if test -n "$glib_cv_long_long_format"; then
 617           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 618           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 619           if test x"$glib_cv_long_long_format" = xI64; then
 620             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 621           fi
 622         else
 623           AC_MSG_RESULT(none)
 624         fi
 625 elif test x$ac_cv_sizeof___int64 = x8; then
 626         # __int64 is a 64 bit integer.
 627         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 628         # We know this is MSVCRT.DLL, and what the formats are
 629         glib_cv_long_long_format=I64
 630         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 631         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 632         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 633 fi
 634
 635 dnl long doubles were not used, and a portability problem
 636 dnl AC_C_LONG_DOUBLE
 637 AC_C_CONST
 638
 639 dnl ok, here we try to check whether the systems prototypes for
 640 dnl malloc and friends actually match the prototypes provided
 641 dnl by gmem.h (keep in sync). i currently only know how to check
 642 dnl this reliably with gcc (-Werror), improvements for other
 643 dnl compilers are apprechiated.
 644 SANE_MALLOC_PROTOS=no
 645 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 646 glib_save_CFLAGS=$CFLAGS
 647 if test "x$GCC" = "xyes"; then
 648   CFLAGS="$CFLAGS -Werror"
 649   AC_TRY_COMPILE([#include <stdlib.h>], [
 650     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 651     void* (*my_malloc_p)  (size_t)         = malloc;
 652     void  (*my_free_p)    (void*)          = free;
 653     void* (*my_realloc_p) (void*, size_t)  = realloc;
 654     my_calloc_p = 0;
 655     my_malloc_p = 0;
 656     my_free_p = 0;
 657     my_realloc_p = 0;
 658   ],
 659     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 660       [Define if you have correct malloc prototypes])
 661     SANE_MALLOC_PROTOS=yes)
 662 fi
 663 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 664 CFLAGS=$glib_save_CFLAGS
 665
 666 dnl
 667 dnl check in which direction the stack grows
 668 dnl
 669 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 670         AC_TRY_RUN([
 671         volatile int *a = 0, *b = 0;
 672         void foo (void);
 673         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 674         void foo (void) { volatile int x = 5; b = &x; }
 675         ],
 676         glib_cv_stack_grows=no
 677         ,
 678         glib_cv_stack_grows=yes
 679         ,)
 680 ])
 681
 682 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 683 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 684 dnl actually supported.
 685 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 686         AC_COMPILE_IFELSE([
 687         __inline int foo () { return 0; }
 688         int main () { return foo (); }
 689         ],
 690         glib_cv_has__inline=yes
 691         ,
 692         glib_cv_has__inline=no
 693         ,)
 694 ])
 695 case x$glib_cv_has__inline in
 696 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 697 esac
 698 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 699         AC_COMPILE_IFELSE([
 700         __inline__ int foo () { return 0; }
 701         int main () { return foo (); }
 702         ],
 703         glib_cv_has__inline__=yes
 704         ,
 705         glib_cv_has__inline__=no
 706         ,)
 707 ])
 708 case x$glib_cv_has__inline__ in
 709 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 710 esac
 711 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 712         AC_COMPILE_IFELSE([
 713         #undef inline
 714         inline int foo () { return 0; }
 715         int main () { return foo (); }
 716         ],
 717         glib_cv_hasinline=yes
 718         ,
 719         glib_cv_hasinline=no
 720         ,)
 721 ])
 722 case x$glib_cv_hasinline in
 723 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 724 esac
 725
 726 # if we can use inline functions in headers
 727 AC_MSG_CHECKING(if inline functions in headers work)
 728 AC_LINK_IFELSE([
 729 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 730 #  undef inline
 731 #  define inline __inline__
 732 #elif !defined (G_HAVE_INLINE)
 733 #  undef inline
 734 #  if defined (G_HAVE___INLINE__)
 735 #    define inline __inline__
 736 #  elif defined (G_HAVE___INLINE)
 737 #    define inline __inline
 738 #  endif
 739 #endif
 740
 741 int glib_test_func2 (int);
 742
 743 static inline int
 744 glib_test_func1 (void) {
 745   return glib_test_func2 (1);
 746 }
 747
 748 int
 749 main (void) {
 750   int i = 1;
 751 }],[g_can_inline=yes],[g_can_inline=no])
 752 AC_MSG_RESULT($g_can_inline)
 753
 754 dnl *** check for working do while(0) macros ***
 755 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 756         AC_TRY_COMPILE([],[
 757         #define STMT_START do
 758         #define STMT_END while(0)
 759         #define STMT_TEST STMT_START { i = 0; } STMT_END
 760         int main(void) { int i = 1; STMT_TEST; return i; }],
 761         [g_cv_support_dowhile_macros=yes],
 762         [g_cv_support_dowhile_macros=no],
 763         [g_cv_support_dowhile_macros=yes])
 764 ])
 765 if test x$g_cv_support_dowhile_macros = xyes; then
 766   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 767 fi
 768
 769 # check for flavours of varargs macros
 770 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 771 AC_TRY_COMPILE([],[
 772 int a(int p1, int p2, int p3);
 773 #define call_a(...) a(1,__VA_ARGS__)
 774 call_a(2,3);
 775 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 776 AC_MSG_RESULT($g_have_iso_c_varargs)
 777
 778 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 779 if test "$CXX" = ""; then
 780 dnl No C++ compiler
 781   g_have_iso_cxx_varargs=no
 782 else
 783   AC_LANG_CPLUSPLUS
 784   AC_TRY_COMPILE([],[
 785 int a(int p1, int p2, int p3);
 786 #define call_a(...) a(1,__VA_ARGS__)
 787 call_a(2,3);
 788 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 789   AC_LANG_C
 790 fi
 791 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 792
 793 AC_MSG_CHECKING(for GNUC varargs macros)
 794 AC_TRY_COMPILE([],[
 795 int a(int p1, int p2, int p3);
 796 #define call_a(params...) a(1,params)
 797 call_a(2,3);
 798 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 799 AC_MSG_RESULT($g_have_gnuc_varargs)
 800
 801 # check for GNUC visibility support
 802 AC_MSG_CHECKING(for GNUC visibility attribute)
 803 GLIB_CHECK_COMPILE_WARNINGS([
 804 void
 805 __attribute__ ((visibility ("hidden")))
 806      f_hidden (void)
 807 {
 808 }
 809 void
 810 __attribute__ ((visibility ("internal")))
 811      f_internal (void)
 812 {
 813 }
 814 void
 815 __attribute__ ((visibility ("protected")))
 816      f_protected (void)
 817 {
 818 }
 819 void
 820 __attribute__ ((visibility ("default")))
 821      f_default (void)
 822 {
 823 }
 824 int main (int argc, char **argv)
 825 {
 826         f_hidden();
 827         f_internal();
 828         f_protected();
 829         f_default();
 830         return 0;
 831 }
 832 ],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 833 AC_MSG_RESULT($g_have_gnuc_visibility)
 834 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 835
 836 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 837 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 838 #else
 839 # include "error: this is not Sun Studio."
 840 #endif
 841 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 842 AC_MSG_RESULT($g_have_sunstudio_visibility)
 843 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 844
 845 # check for bytesex stuff
 846 AC_C_BIGENDIAN
 847 if test x$ac_cv_c_bigendian = xuniversal ; then
 848 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 849 #else
 850 #error Not a big endian.
 851 #endif],
 852     ac_cv_c_bigendian=yes
 853     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 854 #else
 855 #error Not a little endian.
 856 #endif],
 857     ac_cv_c_bigendian=no
 858     ,AC_MSG_WARN([Could not determine endianness.])))
 859 fi
 860
 861
 862 # check for header files
 863 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 864 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 865 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h sched.h malloc.h])
 866 AC_CHECK_HEADERS([sys/vfs.h sys/mount.h sys/vmount.h sys/statfs.h sys/statvfs.h])
 867 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h sys/sysctl.h fstab.h])
 868 AC_CHECK_HEADERS([sys/uio.h])
 869
 870 # check for structure fields
 871 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 872 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 873 #include <sys/stat.h>
 874 #include <unistd.h>
 875 #ifdef HAVE_SYS_STATFS_H
 876 #include <sys/statfs.h>
 877 #endif
 878 #ifdef HAVE_SYS_PARAM_H
 879 #include <sys/param.h>
 880 #endif
 881 #ifdef HAVE_SYS_MOUNT_H
 882 #include <sys/mount.h>
 883 #endif])
 884 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 885 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 886
 887 # Checks for libcharset
 888 AM_LANGINFO_CODESET
 889 gl_GLIBC21
 890 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 891 AC_CHECK_FUNCS(setlocale)
 892
 893 # check additional type sizes
 894 AC_CHECK_SIZEOF(size_t)
 895
 896 dnl Try to figure out whether gsize, gssize should be long or int
 897 AC_MSG_CHECKING([for the appropriate definition for size_t])
 898
 899 case $ac_cv_sizeof_size_t in
 900   $ac_cv_sizeof_short)
 901       glib_size_type=short
 902       ;;
 903   $ac_cv_sizeof_int)
 904       glib_size_type=int
 905       ;;
 906   $ac_cv_sizeof_long)
 907       glib_size_type=long
 908       ;;
 909   $ac_cv_sizeof_long_long)
 910       glib_size_type='long long'
 911       ;;
 912   $ac_cv_sizeof__int64)
 913       glib_size_type='__int64'
 914       ;;
 915   *)  AC_MSG_ERROR([No type matching size_t in size])
 916       ;;
 917 esac
 918
 919 dnl If int/long are the same size, we see which one produces
 920 dnl warnings when used in the location as size_t. (This matters
 921 dnl on AIX with xlc)
 922 dnl
 923 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 924    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 925   GLIB_CHECK_COMPILE_WARNINGS([
 926 #if defined(_AIX) && !defined(__GNUC__)
 927 #pragma options langlvl=stdc89
 928 #endif
 929 #include <stddef.h>
 930 int main ()
 931 {
 932   size_t s = 1;
 933   unsigned int *size_int = &s;
 934   return (int)*size_int;
 935 }
 936     ],glib_size_type=int,
 937       [GLIB_CHECK_COMPILE_WARNINGS([
 938 #if defined(_AIX) && !defined(__GNUC__)
 939 #pragma options langlvl=stdc89
 940 #endif
 941 #include <stddef.h>
 942 int main ()
 943 {
 944    size_t s = 1;
 945    unsigned long *size_long = &s;
 946    return (int)*size_long;
 947 }
 948         ],glib_size_type=long)])
 949 fi
 950
 951 AC_MSG_RESULT(unsigned $glib_size_type)
 952
 953 # Check for some functions
 954 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk)
 955 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link statvfs statfs utimes getgrgid getpwuid)
 956 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getmntinfo)
 957 # Check for high-resolution sleep functions
 958 AC_CHECK_FUNCS(nanosleep nsleep)
 959
 960 AC_CHECK_HEADERS(crt_externs.h)
 961 AC_CHECK_FUNCS(_NSGetEnviron)
 962
 963 AC_FUNC_VSNPRINTF_C99
 964 AC_FUNC_PRINTF_UNIX98
 965
 966 # Internet address families
 967 if test $glib_native_win32 = yes; then
 968   glib_inet_includes=["
 969 #include <winsock2.h>
 970   "]
 971 else
 972   glib_inet_includes=["
 973 #include <sys/types.h>
 974 #include <sys/socket.h>
 975   "]
 976 fi
 977
 978 glib_failed=false
 979 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
 980 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
 981 # winsock defines this even though it doesn't support it
 982 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
 983 if $glib_failed ; then
 984   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
 985 fi
 986
 987 glib_failed=false
 988 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
 989 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
 990 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
 991 if $glib_failed ; then
 992   AC_MSG_ERROR([Could not determine values for MSG_* constants])
 993 fi
 994
 995 AC_CHECK_FUNCS(getprotobyname_r endservent)
 996 AC_CHECK_HEADERS([netdb.h winsock2.h mswsock.h])
 997
 998 # For gio/libasyncns
 999 if test $glib_native_win32 = no; then
1000   AC_CHECK_FUNCS(strndup setresuid setreuid)
1001   AC_CHECK_HEADERS(sys/prctl.h arpa/nameser_compat.h)
1002   AC_CHECK_FUNC(res_query, ,
1003     [AC_CHECK_LIB(resolv, res_query, [ LIBASYNCNS_LIBADD="-lresolv" ],
1004       [ save_libs="$LIBS"
1005         LIBS="-lresolv $LIBS"
1006         AC_MSG_CHECKING([for res_query in -lresolv (alternate version)])
1007         AC_LINK_IFELSE(
1008           [AC_LANG_PROGRAM([[#include <resolv.h>]], [[res_query(0,0,0,0,0)]])],
1009           [ AC_MSG_RESULT(yes)
1010           LIBASYNCNS_LIBADD="-lresolv" ],
1011           [ AC_MSG_RESULT(no)
1012             AC_CHECK_LIB(bind, res_query,
1013               [ LIBASYNCNS_LIBADD="-lbind" ],
1014             [ AC_MSG_ERROR(res_query not found) ] ) ] )
1015         LIBS="$save_libs"
1016       ] )
1017     ]
1018   )
1019   AC_SUBST(LIBASYNCNS_LIBADD)
1020 fi
1021
1022 case $host in
1023   *-*-solaris* )
1024      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1025      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1026      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1027      ;;
1028 esac
1029
1030 dnl
1031 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1032 dnl
1033 if test "$ac_cv_func_statfs" = yes ; then
1034   AC_MSG_CHECKING([number of arguments to statfs()])
1035   AC_TRY_COMPILE([#include <unistd.h>
1036   #ifdef HAVE_SYS_PARAM_H
1037   #include <sys/param.h>
1038   #endif
1039   #ifdef HAVE_SYS_VFS_H
1040   #include <sys/vfs.h>
1041   #endif
1042   #ifdef HAVE_SYS_MOUNT_H
1043   #include <sys/mount.h>
1044   #endif
1045   #ifdef HAVE_SYS_STATFS_H
1046   #include <sys/statfs.h>
1047   #endif], [struct statfs st;
1048   statfs(NULL, &st);],[
1049     AC_MSG_RESULT([2])
1050     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1051     AC_TRY_COMPILE([#include <unistd.h>
1052   #ifdef HAVE_SYS_PARAM_H
1053   #include <sys/param.h>
1054   #endif
1055   #ifdef HAVE_SYS_VFS_H
1056   #include <sys/vfs.h>
1057   #endif
1058   #ifdef HAVE_SYS_MOUNT_H
1059   #include <sys/mount.h>
1060   #endif
1061   #ifdef HAVE_SYS_STATFS_H
1062   #include <sys/statfs.h>
1063   #endif], [struct statfs st;
1064   statfs(NULL, &st, sizeof (st), 0);],[
1065       AC_MSG_RESULT([4])
1066       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1067       AC_MSG_RESULT(unknown)
1068       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1069 fi
1070
1071 #
1072 # Check whether to use an included printf
1073 #
1074
1075 AC_ARG_ENABLE(included-printf,
1076               [AC_HELP_STRING([--enable-included-printf],
1077                               [use included printf [default=auto]])],
1078               enable_included_printf="$enableval")
1079
1080 need_included_printf=no
1081 if test "x$enable_included_printf" = "xyes" ; then
1082   need_included_printf=yes
1083 fi
1084 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1085   need_included_printf=yes
1086 fi
1087 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1088   need_included_printf=yes
1089 fi
1090 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1091    test -z "$glib_cv_long_long_format" ; then
1092   need_included_printf=yes
1093 fi
1094
1095 if test "x$enable_included_printf" = "xno" &&
1096    test "x$need_included_printf" = "xyes" ; then
1097   AC_MSG_ERROR([
1098 *** Your C library's printf doesn't appear to have the features that
1099 *** GLib needs, but you specified --enable-included-printf=no.])
1100 fi
1101
1102 enable_included_printf=$need_included_printf
1103
1104 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1105 if test "$enable_included_printf" != "yes" ; then
1106   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1107 else
1108   if test -z "$glib_cv_long_long_format" ; then
1109     glib_cv_long_long_format="ll"
1110   fi
1111   AC_DEFINE(HAVE_VASPRINTF,1)
1112 fi
1113
1114 # Checks needed for gnulib vasnprintf
1115 bh_C_SIGNED
1116 jm_AC_TYPE_LONG_LONG
1117 gt_TYPE_LONGDOUBLE
1118 gt_TYPE_WCHAR_T
1119 gt_TYPE_WINT_T
1120 AC_TYPE_SIZE_T
1121 AC_CHECK_TYPES(ptrdiff_t)
1122 jm_AC_TYPE_INTMAX_T
1123 AC_CHECK_FUNCS([snprintf wcslen])
1124 AC_FUNC_SNPRINTF_C99
1125
1126 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1127 # The check is borrowed from the PERL Configure script.
1128 if test "$ac_cv_func_memmove" != "yes"; then
1129   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1130     glib_cv_working_bcopy,[AC_TRY_RUN([
1131       int main() {
1132         char buf[128], abc[128], *b;
1133         int len, off, align;
1134         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1135         for (align = 7; align >= 0; align--) {
1136           for (len = 36; len; len--) {
1137             b = buf+align; bcopy(abc, b, len);
1138             for (off = 1; off <= len; off++) {
1139               bcopy(b, b+off, len); bcopy(b+off, b, len);
1140                 if (bcmp(b, abc, len)) return(1);
1141             }
1142           }
1143         }
1144         return(0);
1145       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1146
1147   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1148   if test "$glib_cv_working_bcopy" = "yes"; then
1149     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1150   fi
1151 fi
1152
1153 # Check for sys_errlist
1154 AC_MSG_CHECKING(for sys_errlist)
1155 AC_TRY_LINK(, [
1156 extern char *sys_errlist[];
1157 extern int sys_nerr;
1158 sys_errlist[sys_nerr-1][0] = 0;
1159 ], glib_ok=yes, glib_ok=no)
1160 AC_MSG_RESULT($glib_ok)
1161 if test "$glib_ok" = "no"; then
1162     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
1163 fi
1164
1165 # Check for sys_siglist
1166 AC_MSG_CHECKING(for sys_siglist)
1167 AC_TRY_LINK(, [
1168 extern char *sys_siglist[];
1169 exit (sys_siglist[0]);
1170 ], glib_ok=yes, glib_ok=no)
1171 AC_MSG_RESULT($glib_ok)
1172 if test "$glib_ok" = "no"; then
1173     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
1174 fi
1175
1176 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
1177 AC_MSG_CHECKING(for sys_siglist declaration)
1178 AC_TRY_COMPILE([#include <signal.h>], [
1179 strlen (sys_siglist[0]);
1180 ], glib_ok=yes, glib_ok=no)
1181 AC_MSG_RESULT($glib_ok)
1182 if test "$glib_ok" = "no"; then
1183     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
1184 fi
1185
1186 # Check if <sys/select.h> needs to be included for fd_set
1187 AC_MSG_CHECKING([for fd_set])
1188 AC_TRY_COMPILE([#include <sys/types.h>],
1189         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1190 if test "$gtk_ok" = "yes"; then
1191     AC_MSG_RESULT([yes, found in sys/types.h])
1192 else
1193     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1194     if test "$gtk_ok" = "yes"; then
1195         # *** FIXME: give it a different name
1196         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1197         AC_MSG_RESULT([yes, found in sys/select.h])
1198     else
1199         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1200         AC_MSG_RESULT(no)
1201     fi
1202 fi
1203
1204 dnl *** check for sane realloc() ***
1205 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1206         AC_TRY_RUN([#include <stdlib.h>
1207         int main() {
1208           return realloc (0, sizeof (int)) == 0;
1209         }],
1210         [glib_cv_sane_realloc=yes],
1211         [glib_cv_sane_realloc=no],
1212         [glib_cv_sane_realloc=yes])
1213 ])
1214 if test x$glib_cv_sane_realloc = xyes; then
1215   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1216 fi
1217
1218 dnl Check for nl_langinfo and CODESET
1219 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1220         AC_TRY_COMPILE([#include <langinfo.h>],
1221                 [char *codeset = nl_langinfo (CODESET);],
1222                 [glib_cv_langinfo_codeset=yes],
1223                 [glib_cv_langinfo_codeset=no])])
1224 if test x$glib_cv_langinfo_codeset = xyes; then
1225   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1226 fi
1227
1228 dnl ****************************************
1229 dnl *** posix_memalign                   ***
1230 dnl ****************************************
1231 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1232 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1233     glib_cv_compliant_posix_memalign=0
1234     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1235         AC_TRY_RUN([
1236                 #define _XOPEN_SOURCE 600
1237                 #include <stdlib.h> /* posix_memalign() should be defined here */
1238                 /* some systems break if #include <malloc.h> used */
1239                 static void test_memalign (size_t boundary, size_t size) {
1240                     void *mem = 0;
1241                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1242                         exit (1);
1243                     else
1244                       free (mem);
1245                 }
1246                 int main() {
1247                     test_memalign (  128,   128 - 2 * sizeof (void*));
1248                     test_memalign (  256,   256 - 2 * sizeof (void*));
1249                     test_memalign (  512,   512 - 2 * sizeof (void*));
1250                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1251                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1252                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1253                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1254                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1255                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1256                     exit (0); /* success */
1257                 }
1258                 ],
1259             [glib_cv_compliant_posix_memalign=1], [], [:])
1260       :
1261     fi
1262     ])
1263 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1264     AC_MSG_RESULT(yes)
1265     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1266 else
1267     AC_MSG_RESULT(no)
1268 fi
1269
1270
1271 dnl ****************************************
1272 dnl *** strlcpy/strlcat                  ***
1273 dnl ****************************************
1274 # Check for strlcpy
1275 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1276 AC_TRY_RUN([#include <stdlib.h>
1277 #include <string.h>
1278 int main() {
1279   char p[10];
1280   (void) strlcpy (p, "hi", 10);
1281   if (strlcat (p, "bye", 0) != 3)
1282     return 1;
1283   return 0;
1284 }], glib_cv_have_strlcpy=yes,
1285     glib_cv_have_strlcpy=no,
1286     glib_cv_have_strlcpy=no)])
1287 if test "$glib_cv_have_strlcpy" = "yes"; then
1288     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1289 fi
1290
1291
1292 dnl **********************
1293 dnl *** va_copy checks ***
1294 dnl **********************
1295 dnl we currently check for all three va_copy possibilities, so we get
1296 dnl all results in config.log for bug reports.
1297 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1298         AC_LINK_IFELSE([#include <stdarg.h>
1299 #include <stdlib.h>
1300         void f (int i, ...) {
1301         va_list args1, args2;
1302         va_start (args1, i);
1303         va_copy (args2, args1);
1304         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1305           exit (1);
1306         va_end (args1); va_end (args2);
1307         }
1308         int main() {
1309           f (0, 42);
1310           return 0;
1311         }],
1312         [glib_cv_va_copy=yes],
1313         [glib_cv_va_copy=no])
1314 ])
1315 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1316         AC_LINK_IFELSE([#include <stdarg.h>
1317 #include <stdlib.h>
1318         void f (int i, ...) {
1319         va_list args1, args2;
1320         va_start (args1, i);
1321         __va_copy (args2, args1);
1322         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1323           exit (1);
1324         va_end (args1); va_end (args2);
1325         }
1326         int main() {
1327           f (0, 42);
1328           return 0;
1329         }],
1330         [glib_cv___va_copy=yes],
1331         [glib_cv___va_copy=no])
1332 ])
1333
1334 if test "x$glib_cv_va_copy" = "xyes"; then
1335   g_va_copy_func=va_copy
1336 else if test "x$glib_cv___va_copy" = "xyes"; then
1337   g_va_copy_func=__va_copy
1338 fi
1339 fi
1340
1341 if test -n "$g_va_copy_func"; then
1342   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1343 fi
1344
1345 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1346         AC_TRY_RUN([#include <stdarg.h>
1347 #include <stdlib.h>
1348         void f (int i, ...) {
1349         va_list args1, args2;
1350         va_start (args1, i);
1351         args2 = args1;
1352         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1353           exit (1);
1354         va_end (args1); va_end (args2);
1355         }
1356         int main() {
1357           f (0, 42);
1358           return 0;
1359         }],
1360         [glib_cv_va_val_copy=yes],
1361         [glib_cv_va_val_copy=no],
1362         [glib_cv_va_val_copy=yes])
1363 ])
1364
1365 if test "x$glib_cv_va_val_copy" = "xno"; then
1366   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1367 fi
1368
1369 dnl ***********************
1370 dnl *** g_module checks ***
1371 dnl ***********************
1372 G_MODULE_LIBS=
1373 G_MODULE_LIBS_EXTRA=
1374 G_MODULE_PLUGIN_LIBS=
1375 if test x"$glib_native_win32" = xyes; then
1376   dnl No use for this on Win32
1377   G_MODULE_LDFLAGS=
1378 else
1379   export SED
1380   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1381 fi
1382 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1383 G_MODULE_NEED_USCORE=0
1384 G_MODULE_BROKEN_RTLD_GLOBAL=0
1385 G_MODULE_HAVE_DLERROR=0
1386 dnl *** force native WIN32 shared lib loader
1387 if test -z "$G_MODULE_IMPL"; then
1388   case "$host" in
1389   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1390   esac
1391 fi
1392 dnl *** force native AIX library loader
1393 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1394 if test -z "$G_MODULE_IMPL"; then
1395   case "$host" in
1396   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1397   esac
1398 fi
1399 dnl *** dlopen() and dlsym() in system libraries
1400 if test -z "$G_MODULE_IMPL"; then
1401         AC_CHECK_FUNC(dlopen,
1402                       [AC_CHECK_FUNC(dlsym,
1403                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1404                       [])
1405 fi
1406 dnl *** load_image (BeOS)
1407 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1408   AC_CHECK_LIB(root, load_image,
1409       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1410       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1411       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1412       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1413       [])
1414 fi
1415 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1416 if test -z "$G_MODULE_IMPL"; then
1417         AC_CHECK_FUNC(NSLinkModule,
1418                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1419                        G_MODULE_NEED_USCORE=1],
1420                       [])
1421 fi
1422 dnl *** dlopen() and dlsym() in libdl
1423 if test -z "$G_MODULE_IMPL"; then
1424         AC_CHECK_LIB(dl, dlopen,
1425                      [AC_CHECK_LIB(dl, dlsym,
1426                                    [G_MODULE_LIBS=-ldl
1427                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1428                      [])
1429 fi
1430 dnl *** shl_load() in libdld (HP-UX)
1431 if test -z "$G_MODULE_IMPL"; then
1432         AC_CHECK_LIB(dld, shl_load,
1433                 [G_MODULE_LIBS=-ldld
1434                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1435                 [])
1436 fi
1437 dnl *** additional checks for G_MODULE_IMPL_DL
1438 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1439         LIBS_orig="$LIBS"
1440         LDFLAGS_orig="$LDFLAGS"
1441         LIBS="$G_MODULE_LIBS $LIBS"
1442         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1443 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1444         echo "void glib_plugin_test(void) { }" > plugin.c
1445         ${SHELL} ./libtool --mode=compile ${CC} -shared \
1446                 -export-dynamic -o plugin.o plugin.c 2>&1 >/dev/null
1447         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1448                 glib_cv_rtldglobal_broken,[
1449                 AC_TRY_RUN([
1450 #include <dlfcn.h>
1451 #ifndef RTLD_GLOBAL
1452 #  define RTLD_GLOBAL 0
1453 #endif
1454 #ifndef RTLD_LAZY
1455 #  define RTLD_LAZY 0
1456 #endif
1457 int glib_plugin_test;
1458 int main () {
1459     void *handle, *global, *local;
1460     global = &glib_plugin_test;
1461     handle = dlopen ("./.libs/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1462     if (!handle) return 0;
1463     local = dlsym (handle, "glib_plugin_test");
1464     return global == local;
1465 }                       ],
1466                         [glib_cv_rtldglobal_broken=no],
1467                         [glib_cv_rtldglobal_broken=yes],
1468                         [glib_cv_rtldglobal_broken=no])
1469                 rm -f plugin.c plugin.o plugin.lo .libs/plugin.o
1470                 rmdir .libs 2>/dev/null
1471         ])
1472         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1473                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1474         else
1475                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1476         fi
1477 dnl *** check whether we need preceeding underscores
1478         AC_CACHE_CHECK([for preceeding underscore in symbols],
1479                 glib_cv_uscore,[
1480                 AC_TRY_RUN([#include <dlfcn.h>
1481                 int glib_underscore_test (void) { return 42; }
1482                 int main() {
1483                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1484                   handle = dlopen ((void*)0, 0);
1485                   if (handle) {
1486                     f1 = dlsym (handle, "glib_underscore_test");
1487                     f2 = dlsym (handle, "_glib_underscore_test");
1488                   } return (!f2 || f1);
1489                 }],
1490                         [glib_cv_uscore=yes],
1491                         [glib_cv_uscore=no],
1492                         [])
1493                 rm -f plugin.c plugin.$ac_objext plugin.lo
1494         ])
1495         GLIB_ASSERT_SET(glib_cv_uscore)
1496         if test "x$glib_cv_uscore" = "xyes"; then
1497                 G_MODULE_NEED_USCORE=1
1498         else
1499                 G_MODULE_NEED_USCORE=0
1500         fi
1501
1502         LDFLAGS="$LDFLAGS_orig"
1503 dnl *** check for having dlerror()
1504         AC_CHECK_FUNC(dlerror,
1505                 [G_MODULE_HAVE_DLERROR=1],
1506                 [G_MODULE_HAVE_DLERROR=0])
1507         LIBS="$LIBS_orig"
1508 fi
1509 dnl *** done, have we got an implementation?
1510 if test -z "$G_MODULE_IMPL"; then
1511         G_MODULE_IMPL=0
1512         G_MODULE_SUPPORTED=false
1513 else
1514         G_MODULE_SUPPORTED=true
1515 fi
1516
1517 AC_MSG_CHECKING(for the suffix of module shared libraries)
1518 export SED
1519 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1520 eval $shrext_cmds
1521 module=yes eval std_shrext=$shrext_cmds
1522 # chop the initial dot
1523 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1524 AC_MSG_RESULT(.$glib_gmodule_suffix)
1525 # any reason it may fail?
1526 if test "x$glib_gmodule_suffix" = x; then
1527         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1528 fi
1529
1530 AC_SUBST(G_MODULE_SUPPORTED)
1531 AC_SUBST(G_MODULE_IMPL)
1532 AC_SUBST(G_MODULE_LIBS)
1533 AC_SUBST(G_MODULE_LIBS_EXTRA)
1534 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1535 AC_SUBST(G_MODULE_LDFLAGS)
1536 AC_SUBST(G_MODULE_HAVE_DLERROR)
1537 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1538 AC_SUBST(G_MODULE_NEED_USCORE)
1539 AC_SUBST(GLIB_DEBUG_FLAGS)
1540
1541 dnl **********************
1542 dnl *** g_spawn checks ***
1543 dnl **********************
1544
1545 AC_MSG_CHECKING(for gspawn implementation)
1546 case "$host" in
1547   *-*-mingw*)
1548     GSPAWN=gspawn-win32.lo
1549     ;;
1550   *)
1551     GSPAWN=gspawn.lo
1552     ;;
1553 esac
1554 AC_MSG_RESULT($GSPAWN)
1555 AC_SUBST(GSPAWN)
1556
1557 dnl *************************
1558 dnl *** GIOChannel checks ***
1559 dnl *************************
1560
1561 AC_MSG_CHECKING(for GIOChannel implementation)
1562 case "$host" in
1563   *-*-mingw*)
1564     GIO=giowin32.lo
1565     ;;
1566   *)
1567     GIO=giounix.lo
1568     ;;
1569 esac
1570 AC_MSG_RESULT($GIO)
1571 AC_SUBST(GIO)
1572
1573 dnl *********************************
1574 dnl *** Directory for GIO modules ***
1575 dnl *********************************
1576
1577 AC_ARG_WITH(gio-module-dir,
1578            [AC_HELP_STRING([--with-gio-module-dir=PATH],
1579                            [Load gio modules from this directory [LIBDIR/gio/modules]])],
1580            [],
1581            [with_gio_module_dir='${libdir}/gio/modules'])
1582 GIO_MODULE_DIR=$with_gio_module_dir
1583 AC_SUBST(GIO_MODULE_DIR)
1584
1585 dnl **********************************
1586 dnl *** Check for libselinux (GIO) ***
1587 dnl **********************************
1588 AC_ARG_ENABLE(selinux, [  --disable-selinux       build without selinux support])
1589 msg_selinux=no
1590 SELINUX_LIBS=
1591 if test "x$enable_selinux" != "xno"; then
1592
1593  AC_CHECK_LIB(selinux, is_selinux_enabled,
1594    [AC_CHECK_HEADERS(selinux/selinux.h,
1595      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1596        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1597         SELINUX_LIBS="-lselinux"
1598         msg_selinux=yes])
1599      ])
1600    ])
1601 fi
1602 AC_SUBST(SELINUX_LIBS)
1603
1604 dnl *****************************
1605 dnl ** Check for inotify (GIO) **
1606 dnl *****************************
1607 inotify_support=no
1608 AC_CHECK_HEADERS([sys/inotify.h],
1609 [
1610         inotify_support=yes
1611         AC_CHECK_FUNCS(inotify_init1)
1612 ])
1613
1614 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1615
1616 dnl *********************************
1617 dnl ** Check for Solaris FEN (GIO) **
1618 dnl *********************************
1619 fen_support=no
1620 AC_COMPILE_IFELSE([
1621 #include <port.h>
1622 #ifndef PORT_SOURCE_FILE
1623 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1624 #endif
1625 int main() { return 0; } ],
1626 [
1627         fen_support=yes
1628 ],)
1629
1630 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1631
1632 dnl ****************************
1633 dnl *** Checks for FAM (GIO) ***
1634 dnl ****************************
1635
1636 should_disable_fam=no
1637
1638 AC_ARG_ENABLE(fam, [  --disable-fam          build without enabling fam for file system monitoring],
1639                          [
1640                                 if test "x$enable_fam" = "xno"; then
1641                                         should_disable_fam=yes
1642                                         echo "Not building FAM support"
1643                                 fi
1644                          ]
1645                          )
1646 fam_support=no
1647 FAM_LIBS=
1648 if test "x$should_disable_fam" = "xno"; then
1649 AC_CHECK_LIB(fam, FAMOpen,
1650   [AC_CHECK_HEADERS(fam.h,
1651     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1652      AC_CHECK_LIB(fam, FAMNoExists,
1653                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1654      FAM_LIBS="-lfam"]
1655      fam_support=yes,
1656     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1657   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1658 AC_SUBST(FAM_LIBS)
1659 fi
1660 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1661
1662
1663 dnl *****************************
1664 dnl *** Check for xattr (GIO) ***
1665 dnl *****************************
1666 AC_ARG_ENABLE(xattr, [  --disable-xattr           build without xattr support])
1667 msg_xattr=no
1668 XATTR_LIBS=
1669 if test "x$enable_xattr" != "xno"; then
1670
1671 dnl either glibc or libattr can provide xattr support
1672
1673 dnl for both of them, we check for getxattr being in
1674 dnl the library and a valid xattr header.
1675
1676 dnl try glibc
1677  AC_CHECK_LIB(c, getxattr,
1678    [AC_CHECK_HEADERS(sys/xattr.h,
1679      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1680       msg_xattr=yes])
1681    ])
1682
1683   if test "x$msg_xattr" != "xyes"; then
1684 dnl   failure. try libattr
1685    AC_CHECK_LIB(attr, getxattr,
1686       [AC_CHECK_HEADERS(attr/xattr.h,
1687        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1688         XATTR_LIBS="-lattr"
1689         msg_xattr=yes])
1690       ])
1691   fi
1692
1693   if test "x$msg_xattr" = "xyes"; then
1694     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1695     AC_TRY_COMPILE([
1696       #include <stdio.h>
1697       #ifdef HAVE_SYS_TYPES_H
1698       #include <sys/types.h>
1699       #endif
1700       #ifdef HAVE_SYS_XATTR_H
1701       #include <sys/xattr.h>
1702       #elif HAVE_ATTR_XATTR_H
1703       #include <attr/xattr.h>
1704       #endif
1705     ],
1706     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1707     [
1708       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1709       AC_MSG_RESULT([yes])
1710     ],
1711     [AC_MSG_RESULT([no])]
1712     )
1713   fi
1714
1715 fi
1716 AC_SUBST(XATTR_LIBS)
1717
1718 dnl ****************************************
1719 dnl *** platform dependent source checks ***
1720 dnl ****************************************
1721
1722 AC_MSG_CHECKING(for platform-dependent source)
1723 case "$host" in
1724   *-*-cygwin*|*-*-mingw*)
1725     PLATFORMDEP=gwin32.lo
1726     ;;
1727   *)
1728     PLATFORMDEP=
1729     ;;
1730 esac
1731 AC_MSG_RESULT($PLATFORMDEP)
1732 AC_SUBST(PLATFORMDEP)
1733
1734 AC_MSG_CHECKING([whether to compile timeloop])
1735 case "$host" in
1736   *-*-cygwin*|*-*-mingw*|*-*-minix)
1737     enable_timeloop=no
1738     ;;
1739   *)
1740     enable_timeloop=yes
1741     ;;
1742 esac
1743 AC_MSG_RESULT($enable_timeloop)
1744 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1745
1746 AC_MSG_CHECKING([if building for some Win32 platform])
1747 case "$host" in
1748   *-*-mingw*|*-*-cygwin*)
1749     platform_win32=yes
1750     ;;
1751   *)
1752     platform_win32=no
1753     ;;
1754 esac
1755 AC_MSG_RESULT($platform_win32)
1756 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1757
1758 dnl ***********************
1759 dnl *** g_thread checks ***
1760 dnl ***********************
1761
1762 AC_ARG_WITH(threads,
1763            [AC_HELP_STRING([--with-threads=@<:@none/posix/dce/win32@:>@],
1764                            [specify a thread implementation to use])],
1765            [if test "x$with_threads" = x; then
1766                 want_threads=yes
1767             else
1768                 want_threads=$with_threads
1769             fi],
1770            [want_threads=yes])
1771 if test "x$enable_threads" = "xno"; then
1772         want_threads=no
1773 fi
1774
1775 dnl error and warning message
1776 dnl *************************
1777
1778 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1779                 computer. GLib will not have a default thread implementation."
1780
1781 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1782                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1783                 compilation now, but then your programs might not work.
1784                 Please provide information on how it is done on your system."
1785
1786 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1787                 "
1788
1789 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1790                 provide information on your thread implementation.
1791                 You can also run 'configure --disable-threads'
1792                 to compile without thread support."
1793
1794 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1795                 functions will not be MT-safe during their first call because
1796                 there is no working 'getpwuid_r' on your system."
1797
1798 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1799                 because there is no 'localtime_r' on your system."
1800
1801 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1802                 crude surrogate will be used. If you happen to know a
1803                 yield function for your system, please inform the GLib
1804                 developers."
1805
1806 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1807                 threads on your system. Thus threads can only have the default
1808                 priority. If you happen to know these main/max
1809                 priorities, please inform the GLib developers."
1810
1811 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1812                 linking threaded applications. As GLib cannot do that
1813                 automatically, you will get an linkg error everytime you are
1814                 not using the right compiler. In that case you have to relink
1815                 with the right compiler. Ususally just '_r' is appended
1816                 to the compiler name."
1817
1818 dnl determination of thread implementation
1819 dnl ***************************************
1820
1821 # have_threads=no   means no thread support
1822 # have_threads=none means no default thread implementation
1823
1824 have_threads=no
1825 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1826                                 || test "x$want_threads" = xdce; then
1827         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1828         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1829         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1830         glib_save_CPPFLAGS="$CPPFLAGS"
1831         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1832         if test "x$have_threads" = xno; then
1833                 AC_TRY_COMPILE([#include <pthread.h>],
1834                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1835                         have_threads=posix)
1836         fi
1837         if test "x$have_threads" = xno; then
1838                 AC_TRY_COMPILE([#include <pthread.h>],
1839                         [pthread_mutex_t m;
1840                          pthread_mutex_init (&m, pthread_mutexattr_default);],
1841                         have_threads=dce)
1842         fi
1843         # Tru64Unix requires -pthread to find pthread.h. See #103020
1844         CPPFLAGS="$CPPFLAGS -pthread"
1845         if test "x$have_threads" = xno; then
1846         AC_TRY_COMPILE([#include <pthread.h>],
1847                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1848                        have_threads=posix)
1849         fi
1850         CPPFLAGS="$glib_save_CPPFLAGS"
1851 fi
1852 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1853         case $host in
1854                 *-*-mingw*)
1855                 have_threads=win32
1856                 ;;
1857         esac
1858 fi
1859 if test "x$want_threads" = xnone; then
1860         have_threads=none
1861 fi
1862
1863 AC_MSG_CHECKING(for thread implementation)
1864
1865 if test "x$have_threads" = xno && test "x$want_threads" != xno; then
1866         AC_MSG_RESULT(none available)
1867         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
1868 else
1869         AC_MSG_RESULT($have_threads)
1870 fi
1871
1872
1873 dnl determination of G_THREAD_CFLAGS
1874 dnl ********************************
1875
1876 G_THREAD_LIBS=
1877 G_THREAD_LIBS_EXTRA=
1878 G_THREAD_CFLAGS=
1879
1880 dnl
1881 dnl Test program for basic POSIX threads functionality
1882 dnl
1883 m4_define([glib_thread_test],[
1884 #include <pthread.h>
1885 int check_me = 0;
1886 void* func(void* data) {check_me = 42; return &check_me;}
1887 int main()
1888  { pthread_t t;
1889    void *ret;
1890    pthread_create (&t, $1, func, 0);
1891    pthread_join (t, &ret);
1892    return (check_me != 42 || ret != &check_me);
1893 }])
1894
1895 dnl
1896 dnl Test program for sched_get_priority_min()
1897 dnl
1898 m4_define([glib_sched_priority_test],[
1899 #include <sched.h>
1900 #include <errno.h>
1901 int main() {
1902     errno = 0;
1903     return sched_get_priority_min(SCHED_OTHER)==-1
1904            && errno != 0;
1905 }])
1906
1907 if test x"$have_threads" != xno; then
1908
1909   if test x"$have_threads" = xposix; then
1910     # First we test for posix, whether -pthread or -pthreads do the trick as
1911     # both CPPFLAG and LIBS.
1912     # One of them does for most gcc versions and some other platforms/compilers
1913     # too and could be considered as the canonical way to go.
1914     case $host in
1915       *-*-cygwin*|*-*-darwin*)
1916          # skip cygwin and darwin -pthread or -pthreads test
1917          ;;
1918       *-solaris*)
1919         # These compiler/linker flags work with both Sun Studio and gcc
1920         # Sun Studio expands -mt to -D_REENTRANT and -lthread
1921         # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1922         G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1923         G_THREAD_LIBS="-lpthread -lthread"
1924         ;;
1925       *)
1926         for flag in pthread pthreads mt; do
1927           glib_save_CFLAGS="$CFLAGS"
1928           CFLAGS="$CFLAGS -$flag"
1929           AC_TRY_RUN(glib_thread_test(0),
1930                      glib_flag_works=yes,
1931                      glib_flag_works=no,
1932                      [AC_LINK_IFELSE(glib_thread_test(0),
1933                                      glib_flag_works=yes,
1934                                      glib_flag_works=no)])
1935           CFLAGS="$glib_save_CFLAGS"
1936           if test $glib_flag_works = yes ; then
1937              G_THREAD_CFLAGS=-$flag
1938              G_THREAD_LIBS=-$flag
1939              break;
1940           fi
1941         done
1942          ;;
1943     esac
1944   fi
1945
1946   if test x"$G_THREAD_CFLAGS" = x; then
1947
1948     # The canonical -pthread[s] does not work. Try something different.
1949
1950     case $host in
1951         *-aix*)
1952                 if test x"$GCC" = xyes; then
1953                         # GCC 3.0 and above needs -pthread.
1954                         # Should be coverd by the case above.
1955                         # GCC 2.x and below needs -mthreads
1956                         G_THREAD_CFLAGS="-mthreads"
1957                         G_THREAD_LIBS=$G_THREAD_CFLAGS
1958                 else
1959                         # We are probably using the aix compiler. Normaly a
1960                         # program would have to be compiled with the _r variant
1961                         # of the corresponding compiler, but we as GLib cannot
1962                         # do that: but the good news is that for compiling the
1963                         # only difference is the added -D_THREAD_SAFE compile
1964                         # option. This is according to the "C for AIX User's
1965                         # Guide".
1966                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
1967                 fi
1968                 ;;
1969         *-dg-dgux*)  # DG/UX
1970                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
1971                 ;;
1972         *-osf*)
1973                 # So we are using dce threads. posix threads are already
1974                 # catched above.
1975                 G_THREAD_CFLAGS="-threads"
1976                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1977                 ;;
1978         *-sysv5uw7*) # UnixWare 7
1979                 # We are not using gcc with -pthread. Catched above.
1980                 G_THREAD_CFLAGS="-Kthread"
1981                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1982                 ;;
1983         *-mingw*)
1984                 # No flag needed when using MSVCRT.DLL
1985                 G_THREAD_CFLAGS=""
1986                 ;;
1987         *)
1988                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
1989                 ;;
1990     esac
1991
1992   fi
1993
1994     # if we are not finding the localtime_r function, then we probably are
1995     # not using the proper multithread flag
1996
1997     glib_save_CPPFLAGS="$CPPFLAGS"
1998     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1999
2000     # First we test, whether localtime_r is declared in time.h
2001     # directly. Then we test whether a macro localtime_r exists, in
2002     # which case localtime_r in the test program is replaced and thus
2003     # if we still find localtime_r in the output, it is not defined as
2004     # a macro.
2005
2006     AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2007       [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2008                                                            localtime_r(a,b)],
2009                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2010
2011     CPPFLAGS="$glib_save_CPPFLAGS"
2012
2013     AC_MSG_CHECKING(thread related cflags)
2014     AC_MSG_RESULT($G_THREAD_CFLAGS)
2015     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2016 fi
2017
2018 dnl determination of G_THREAD_LIBS
2019 dnl ******************************
2020
2021 mutex_has_default=no
2022 case $have_threads in
2023         posix|dce)
2024           glib_save_CPPFLAGS="$CPPFLAGS"
2025           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2026           if test x"$G_THREAD_LIBS" = x; then
2027             case $host in
2028               *-aix*)
2029                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2030                 # probably using the aix compiler.
2031                 AC_MSG_WARN($AIX_COMPILE_INFO)
2032                 ;;
2033               *)
2034                 G_THREAD_LIBS=error
2035                 glib_save_LIBS="$LIBS"
2036                 for thread_lib in "" pthread pthread32 pthreads thread dce; do
2037                         if test x"$thread_lib" = x; then
2038                                 add_thread_lib=""
2039                                 IN=""
2040                         else
2041                                 add_thread_lib="-l$thread_lib"
2042                                 IN=" in -l$thread_lib"
2043                         fi
2044                         if test x"$have_threads" = xposix; then
2045                                 defattr=0
2046                         else
2047                                 defattr=pthread_attr_default
2048                         fi
2049
2050                         LIBS="$add_thread_lib $glib_save_LIBS"
2051
2052                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2053                         AC_TRY_RUN(glib_thread_test($defattr),
2054                                    glib_result=yes,
2055                                    glib_result=no,
2056                                    [AC_LINK_IFELSE(glib_thread_test($defattr),
2057                                                    glib_result=yes,
2058                                                    glib_result=no)])
2059                         AC_MSG_RESULT($glib_result)
2060
2061                         if test "$glib_result" = "yes" ; then
2062                           G_THREAD_LIBS="$add_thread_lib"
2063                           break
2064                         fi
2065                 done
2066                 if test "x$G_THREAD_LIBS" = xerror; then
2067                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2068                 fi
2069                 LIBS="$glib_save_LIBS"
2070                 ;;
2071             esac
2072           fi
2073
2074           glib_save_LIBS="$LIBS"
2075           for thread_lib in "" rt rte; do
2076             if test x"$thread_lib" = x; then
2077               add_thread_lib=""
2078               IN=""
2079             else
2080               add_thread_lib="-l$thread_lib"
2081               IN=" in -l$thread_lib"
2082             fi
2083             LIBS="$add_thread_lib $glib_save_LIBS"
2084
2085             AC_MSG_CHECKING(for sched_get_priority_min$IN)
2086             AC_TRY_RUN(glib_sched_priority_test,
2087                        glib_result=yes,
2088                        glib_result=no,
2089                        [AC_LINK_IFELSE(glib_sched_priority_test,
2090                                        glib_result=yes,
2091                                        glib_result=no)])
2092             AC_MSG_RESULT($glib_result)
2093
2094             if test "$glib_result" = "yes" ; then
2095                G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
2096                posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
2097                posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
2098                break
2099             fi
2100           done
2101           LIBS="$glib_save_LIBS"
2102           mutex_has_default=yes
2103           mutex_default_type='pthread_mutex_t'
2104           mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
2105           mutex_header_file='pthread.h'
2106           if test "x$have_threads" = "xposix"; then
2107             g_threads_impl="POSIX"
2108           else
2109             g_threads_impl="DCE"
2110             have_threads="posix"
2111           fi
2112           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2113           CPPFLAGS="$glib_save_CPPFLAGS"
2114           ;;
2115         win32)
2116            g_threads_impl="WIN32"
2117            ;;
2118         none|no)
2119            g_threads_impl="NONE"
2120            ;;
2121         *)
2122            g_threads_impl="NONE"
2123            G_THREAD_LIBS=error
2124            ;;
2125 esac
2126
2127 if test "x$G_THREAD_LIBS" = xerror; then
2128         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2129 fi
2130
2131 case $host in
2132   *-*-beos*)
2133     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2134     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2135     ;;
2136   *)
2137     ;;
2138 esac
2139
2140 AC_MSG_CHECKING(thread related libraries)
2141 AC_MSG_RESULT($G_THREAD_LIBS)
2142
2143 dnl check for mt safe function variants and some posix functions
2144 dnl ************************************************************
2145
2146 if test x"$have_threads" != xno; then
2147         glib_save_LIBS="$LIBS"
2148         # we are not doing the following for now, as this might require glib
2149         # to always be linked with the thread libs on some platforms.
2150         # LIBS="$LIBS $G_THREAD_LIBS"
2151         AC_CHECK_FUNCS(localtime_r gmtime_r)
2152         if test "$ac_cv_header_pwd_h" = "yes"; then
2153                 AC_CACHE_CHECK([for posix getpwuid_r],
2154                         ac_cv_func_posix_getpwuid_r,
2155                         [AC_TRY_RUN([
2156 #include <errno.h>
2157 #include <pwd.h>
2158 int main () {
2159     char buffer[10000];
2160     struct passwd pwd, *pwptr = &pwd;
2161     int error;
2162     errno = 0;
2163     error = getpwuid_r (0, &pwd, buffer,
2164                         sizeof (buffer), &pwptr);
2165    return (error < 0 && errno == ENOSYS)
2166            || error == ENOSYS;
2167 }                               ],
2168                                 [ac_cv_func_posix_getpwuid_r=yes],
2169                                 [ac_cv_func_posix_getpwuid_r=no])])
2170                 GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2171                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2172                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2173                                 [Have POSIX function getpwuid_r])
2174                 else
2175                         AC_CACHE_CHECK([for nonposix getpwuid_r],
2176                                 ac_cv_func_nonposix_getpwuid_r,
2177                                 [AC_TRY_LINK([#include <pwd.h>],
2178                                         [char buffer[10000];
2179                                         struct passwd pwd;
2180                                         getpwuid_r (0, &pwd, buffer,
2181                                                         sizeof (buffer));],
2182                                         [ac_cv_func_nonposix_getpwuid_r=yes],
2183                                         [ac_cv_func_nonposix_getpwuid_r=no])])
2184                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2185                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2186                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2187                                         [Have non-POSIX function getpwuid_r])
2188                         fi
2189                 fi
2190         fi
2191         if test "$ac_cv_header_grp_h" = "yes"; then
2192                 AC_CACHE_CHECK([for posix getgrgid_r],
2193                         ac_cv_func_posix_getgrgid_r,
2194                         [AC_TRY_RUN([
2195 #include <errno.h>
2196 #include <grp.h>
2197 int main () {
2198     char buffer[10000];
2199     struct group grp, *grpptr = &grp;
2200     int error;
2201     errno = 0;
2202     error = getgrgid_r (0, &grp, buffer,
2203                         sizeof (buffer), &grpptr);
2204    return (error < 0 && errno == ENOSYS)
2205            || error == ENOSYS;
2206 }                              ],
2207                                [ac_cv_func_posix_getgrgid_r=yes],
2208                                [ac_cv_func_posix_getgrgid_r=no])])
2209                 GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2210                 if test "$ac_cv_func_posix_getgrgid_r" = yes; then
2211                         AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2212                                 [Have POSIX function getgrgid_r])
2213                 else
2214                         AC_CACHE_CHECK([for nonposix getgrgid_r],
2215                                 ac_cv_func_nonposix_getgrgid_r,
2216                                 [AC_TRY_LINK([#include <grp.h>],
2217                                         [char buffer[10000];
2218                                         struct group grp;
2219                                         getgrgid_r (0, &grp, buffer,
2220                                         sizeof (buffer));],
2221                                 [ac_cv_func_nonposix_getgrgid_r=yes],
2222                                 [ac_cv_func_nonposix_getgrgid_r=no])])
2223                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2224                         if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2225                                 AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2226                                         [Have non-POSIX function getgrgid_r])
2227                         fi
2228                 fi
2229         fi
2230         LIBS="$G_THREAD_LIBS $LIBS"
2231         if test x"$have_threads" = xposix; then
2232                 glib_save_CPPFLAGS="$CPPFLAGS"
2233                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2234                 dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
2235                 GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
2236                 # This is not AC_CHECK_FUNC to also work with function
2237                 # name mangling in header files.
2238                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
2239                 AC_TRY_LINK([#include <pthread.h>],
2240                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
2241                         [AC_MSG_RESULT(yes)
2242                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2243                                   [Have function pthread_attr_setstacksize])],
2244                         [AC_MSG_RESULT(no)])
2245                 AC_MSG_CHECKING(for minimal/maximal thread priority)
2246                 if test x"$posix_priority_min" = x; then
2247                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
2248                                 PX_PRIO_MIN],,[
2249                                 posix_priority_min=PX_PRIO_MIN
2250                                 posix_priority_max=PX_PRIO_MAX])
2251                 fi
2252                 if test x"$posix_priority_min" = x; then
2253                         # AIX
2254                         AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
2255                                 PTHREAD_PRIO_MIN],,[
2256                                 posix_priority_min=PTHREAD_PRIO_MIN
2257                                 posix_priority_max=PTHREAD_PRIO_MAX])
2258                 fi
2259                 if test x"$posix_priority_min" = x; then
2260                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
2261                                 PRI_OTHER_MIN],,[
2262                                 posix_priority_min=PRI_OTHER_MIN
2263                                 posix_priority_max=PRI_OTHER_MAX])
2264                 fi
2265                 if test x"$posix_priority_min" = x; then
2266                         AC_MSG_RESULT(none found)
2267                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
2268                         posix_priority_min=-1
2269                         posix_priority_max=-1
2270                 else
2271                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
2272                         AC_MSG_CHECKING(for pthread_setschedparam)
2273                         AC_TRY_LINK([#include <pthread.h>],
2274                           [pthread_t t; pthread_setschedparam(t, 0, NULL)],
2275                           [AC_MSG_RESULT(yes)
2276                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
2277                            AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
2278                           [AC_MSG_RESULT(no)
2279                            AC_MSG_WARN($POSIX_NO_PRIORITIES)])
2280                 fi
2281                 posix_yield_func=none
2282                 AC_MSG_CHECKING(for posix yield function)
2283                 for yield_func in sched_yield pthread_yield_np pthread_yield \
2284                                                         thr_yield; do
2285                         AC_TRY_LINK([#include <pthread.h>],
2286                                 [$yield_func()],
2287                                 [posix_yield_func="$yield_func"
2288                                 break])
2289                 done
2290                 if test x"$posix_yield_func" = xnone; then
2291                         AC_MSG_RESULT(none found)
2292                         AC_MSG_WARN($POSIX_NO_YIELD)
2293                         posix_yield_func="g_usleep(1000)"
2294                 else
2295                         AC_MSG_RESULT($posix_yield_func)
2296                         posix_yield_func="$posix_yield_func()"
2297                 fi
2298                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
2299                 CPPFLAGS="$glib_save_CPPFLAGS"
2300
2301         elif test x"$have_threads" = xwin32; then
2302                 # It's a pointer to a private struct
2303                 GLIB_SIZEOF(,struct _GThreadData *, system_thread)
2304         fi
2305
2306         LIBS="$glib_save_LIBS"
2307
2308         # now spit out all the warnings.
2309         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2310            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2311                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2312         fi
2313         if test "$ac_cv_func_localtime_r" != "yes"; then
2314                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2315         fi
2316 fi
2317
2318 if test x"$glib_cv_sizeof_system_thread" = x; then
2319    # use a pointer as a fallback.
2320    GLIB_SIZEOF(,void *, system_thread)
2321 fi
2322
2323 #
2324 # Hack to deal with:
2325 #
2326 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2327 #     building shared libraries with linux.
2328 #  b) FreeBSD doesn't do this either.
2329 #
2330 case $host in
2331   *-*-freebsd*|*-*-linux*)
2332     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2333     ;;
2334   *)
2335     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2336     ;;
2337 esac
2338
2339 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
2340                    [Source file containing theread implementation])
2341 AC_SUBST(G_THREAD_CFLAGS)
2342 AC_SUBST(G_THREAD_LIBS)
2343 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2344 AC_SUBST(G_THREAD_LIBS_EXTRA)
2345
2346 dnl **********************************************
2347 dnl *** GDefaultMutex setup and initialization ***
2348 dnl **********************************************
2349 dnl
2350 dnl if mutex_has_default = yes, we also got
2351 dnl mutex_default_type, mutex_default_init and mutex_header_file
2352 if test $mutex_has_default = yes ; then
2353         glib_save_CPPFLAGS="$CPPFLAGS"
2354         glib_save_LIBS="$LIBS"
2355         LIBS="$G_THREAD_LIBS $LIBS"
2356         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2357         GLIB_SIZEOF([#include <$mutex_header_file>],
2358                     $mutex_default_type,
2359                     gmutex)
2360         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
2361                            $mutex_default_type,
2362                            gmutex,
2363                            $glib_cv_sizeof_gmutex,
2364                            $mutex_default_init)
2365         if test x"$glib_cv_byte_contents_gmutex" = xno; then
2366                 mutex_has_default=no
2367         fi
2368         CPPFLAGS="$glib_save_CPPFLAGS"
2369         LIBS="$glib_save_LIBS"
2370 fi
2371
2372 AC_CHECK_FUNCS(clock_gettime, [], [
2373   AC_CHECK_LIB(rt, clock_gettime, [
2374     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2375     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2376     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2377   ])
2378 ])
2379
2380 AC_CACHE_CHECK(for monotonic clocks,
2381     glib_cv_monotonic_clock,AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
2382 #include <time.h>
2383 #include <unistd.h>
2384 int main() {
2385 #if !(defined(_POSIX_MONOTONIC_CLOCK) && _POSIX_MONOTONIC_CLOCK >= 0 && defined(CLOCK_MONOTONIC))
2386         #error No monotonic clock
2387 #endif
2388         return 0;
2389 }
2390 ]])],glib_cv_monotonic_clock=yes,glib_cv_monotonic_clock=no))
2391 if test "$glib_cv_monotonic_clock" = "yes"; then
2392   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
2393 fi
2394
2395
2396 dnl ********************************
2397 dnl *** g_atomic_* tests for gcc ***
2398 dnl ********************************
2399
2400 AC_MSG_CHECKING([whether to use assembler code for atomic operations])
2401
2402 if test x"$GCC" = xyes; then
2403   case $host_cpu in
2404     i386)
2405       AC_MSG_RESULT([none])
2406       glib_memory_barrier_needed=no
2407       ;;
2408     i?86)
2409       AC_MSG_RESULT([i486])
2410       AC_DEFINE_UNQUOTED(G_ATOMIC_I486, 1,
2411                          [i486 atomic implementation])
2412       glib_memory_barrier_needed=no
2413       ;;
2414     sparc*)
2415       SPARCV9_WARNING="Try to rerun configure with CFLAGS='-mcpu=v9',
2416                 when you are using a sparc with v9 instruction set (most
2417                 sparcs nowadays). This will make the code for atomic
2418                 operations much faster. The resulting code will not run
2419                 on very old sparcs though."
2420
2421       AC_LINK_IFELSE([[
2422         main ()
2423         {
2424           int tmp1, tmp2, tmp3;
2425           __asm__ __volatile__("casx [%2], %0, %1"
2426                                : "=&r" (tmp1), "=&r" (tmp2) : "r" (&tmp3));
2427         }]],
2428         AC_MSG_RESULT([sparcv9])
2429         AC_DEFINE_UNQUOTED(G_ATOMIC_SPARCV9, 1,
2430                            [sparcv9 atomic implementation]),
2431         AC_MSG_RESULT([no])
2432         AC_MSG_WARN([[$SPARCV9_WARNING]]))
2433       glib_memory_barrier_needed=yes
2434       ;;
2435     alpha*)
2436       AC_MSG_RESULT([alpha])
2437       AC_DEFINE_UNQUOTED(G_ATOMIC_ALPHA, 1,
2438                          [alpha atomic implementation])
2439       glib_memory_barrier_needed=yes
2440       ;;
2441     x86_64)
2442       AC_MSG_RESULT([x86_64])
2443       AC_DEFINE_UNQUOTED(G_ATOMIC_X86_64, 1,
2444                          [x86_64 atomic implementation])
2445       glib_memory_barrier_needed=no
2446      ;;
2447     powerpc*)
2448       AC_MSG_RESULT([powerpc])
2449       AC_DEFINE_UNQUOTED(G_ATOMIC_POWERPC, 1,
2450                          [powerpc atomic implementation])
2451       glib_memory_barrier_needed=yes
2452       AC_MSG_CHECKING([whether asm supports numbered local labels])
2453       AC_TRY_COMPILE(
2454                 ,[
2455                         __asm__ __volatile__ ("1:       nop\n"
2456                                               "         bne-    1b")
2457                 ],[
2458                         AC_DEFINE_UNQUOTED(ASM_NUMERIC_LABELS, 1, [define if asm blocks can use numeric local labels])
2459                         AC_MSG_RESULT([yes])
2460                 ],[
2461                         AC_MSG_RESULT([no])
2462                 ])
2463       ;;
2464     ia64)
2465       AC_MSG_RESULT([ia64])
2466       AC_DEFINE_UNQUOTED(G_ATOMIC_IA64, 1,
2467                          [ia64 atomic implementation])
2468       glib_memory_barrier_needed=yes
2469       ;;
2470     s390|s390x)
2471       AC_MSG_RESULT([s390])
2472       AC_DEFINE_UNQUOTED(G_ATOMIC_S390, 1,
2473                          [s390 atomic implementation])
2474       glib_memory_barrier_needed=no
2475       ;;
2476     arm*)
2477       AC_MSG_RESULT([arm])
2478       AC_DEFINE_UNQUOTED(G_ATOMIC_ARM, 1,
2479                          [arm atomic implementation])
2480       glib_memory_barrier_needed=no
2481       ;;
2482     crisv32*|etraxfs*)
2483       AC_MSG_RESULT([crisv32])
2484       AC_DEFINE_UNQUOTED(G_ATOMIC_CRISV32, 1,
2485                          [crisv32 atomic implementation])
2486       glib_memory_barrier_needed=no
2487       ;;
2488     cris*|etrax*)
2489       AC_MSG_RESULT([cris])
2490       AC_DEFINE_UNQUOTED(G_ATOMIC_CRIS, 1,
2491                          [cris atomic implementation])
2492       glib_memory_barrier_needed=no
2493       ;;
2494     *)
2495       AC_MSG_RESULT([none])
2496       glib_memory_barrier_needed=yes
2497       ;;
2498   esac
2499 else
2500   if test $glib_native_win32 = yes; then
2501     # For Windows but not using gcc. No barriers needed then either.
2502     glib_memory_barrier_needed=no
2503   fi
2504 fi
2505
2506 dnl ****************************************
2507 dnl *** GLib POLL* compatibility defines ***
2508 dnl ****************************************
2509
2510 glib_poll_includes=["
2511 #include <sys/types.h>
2512 #include <sys/poll.h>
2513 "]
2514
2515 if test $ac_cv_header_sys_types_h = yes &&
2516    test $ac_cv_header_sys_poll_h = yes ; then
2517   glib_failed=false
2518   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2519   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2520   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2521   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2522   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2523   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2524   if $glib_failed ; then
2525     AC_MSG_ERROR([Could not determine values for POLL* constants])
2526   fi
2527 else
2528   glib_cv_value_POLLIN=1
2529   glib_cv_value_POLLOUT=4
2530   glib_cv_value_POLLPRI=2
2531   glib_cv_value_POLLERR=8
2532   glib_cv_value_POLLHUP=16
2533   glib_cv_value_POLLNVAL=32
2534 fi
2535
2536 AC_MSG_CHECKING([for broken poll])
2537 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2538         #include <stdlib.h>
2539         #include <fcntl.h>
2540         #include <poll.h>
2541         #ifdef HAVE_SYS_POLL_H
2542         #include <sys/poll.h>
2543         #endif
2544         int main(void) {
2545           struct pollfd fds[1];
2546           int fd;
2547           fd = open("/dev/null", 1);
2548           fds[0].fd = fd;
2549           fds[0].events = POLLIN;
2550           fds[0].revents = 0;
2551           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2552                 exit(1);  /* Does not work for devices -- fail */
2553           }
2554           exit(0);
2555         }]])],
2556   [broken_poll=no],
2557   [broken_poll=yes
2558    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2559   [broken_poll="no (cross compiling)"])
2560 AC_MSG_RESULT($broken_poll)
2561
2562 dnl *********************
2563 dnl *** GRegex checks ***
2564 dnl *********************
2565 PCRE_REQUIRED_VERSION=7.2
2566
2567 # Check if we should compile GRegex
2568 AC_ARG_ENABLE(regex, AC_HELP_STRING([--disable-regex],
2569               [disable the compilation of GRegex]),
2570 [case "${enableval}" in
2571   yes) enable_regex=true ;;
2572   no)  enable_regex=false ;;
2573   *) AC_MSG_ERROR(bad value ${enableval} for --enable-regex) ;;
2574 esac],
2575 [enable_regex=true])
2576
2577 AM_CONDITIONAL(ENABLE_REGEX, $enable_regex)
2578
2579 if test x$enable_regex = xtrue; then
2580   AC_DEFINE(ENABLE_REGEX, [], [include GRegex])
2581   # Check if we should use the internal or the system-supplied pcre
2582   AC_ARG_WITH(pcre,
2583              [AC_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2584                              [specify whether to use the internal or the
2585                               system-supplied PCRE library])])
2586
2587   AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2588
2589   if test "x$with_pcre" = xsystem; then
2590     PKG_CHECK_MODULES(PCRE,
2591                       libpcre >= $PCRE_REQUIRED_VERSION)
2592     AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2593                    glib_save_CFLAGS="$CFLAGS"
2594                    glib_save_LIBS="$LIBS"
2595                    CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2596                    AC_TRY_RUN([#include <pcre.h>
2597                                int main () {
2598                                  int support;
2599                                  pcre_config (PCRE_CONFIG_UTF8, &support);
2600                                  if (!support)
2601                                    return 1;
2602                                  pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2603                                  if (!support)
2604                                    return 1;
2605                                  return 0;
2606                                }],
2607                    glib_cv_pcre_has_unicode=yes,
2608                    glib_cv_pcre_has_unicode=no,
2609                    glib_cv_pcre_has_unicode=yes)
2610                    CFLAGS="$glib_save_CFLAGS"
2611                    LIBS="$glib_save_LIBS"
2612         ])
2613     if test "$glib_cv_pcre_has_unicode" = "no"; then
2614       AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2615     fi
2616     AC_SUBST(PCRE_CFLAGS)
2617     AC_SUBST(PCRE_LIBS)
2618     AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2619     PCRE_REQUIRES=libpcre
2620     AC_SUBST(PCRE_REQUIRES)
2621   else
2622     # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2623     if test x"$GCC" = xyes; then
2624       AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2625       save_CFLAGS="$CFLAGS"
2626       CFLAGS="$CFLAGS -Wno-pointer-sign"
2627       AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2628                             AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2629       CFLAGS="$save_CFLAGS"
2630     fi
2631   fi
2632   AC_SUBST(PCRE_WARN_CFLAGS)
2633 else
2634   AM_CONDITIONAL(USE_SYSTEM_PCRE, false])
2635 fi
2636
2637 dnl **********************
2638 dnl *** Win32 API libs ***
2639 dnl **********************
2640
2641 case $host in
2642   *-*-cygwin*)
2643         G_LIBS_EXTRA="-luser32 -lkernel32"
2644     ;;
2645   *-*-mingw*)
2646         G_LIBS_EXTRA="-lws2_32 -lole32"
2647     ;;
2648   *)
2649         G_LIBS_EXTRA=""
2650     ;;
2651 esac
2652 AC_SUBST(G_LIBS_EXTRA)
2653
2654 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2655 dnl since we need it for g_iconv()
2656
2657 AC_MSG_CHECKING([for EILSEQ])
2658 AC_TRY_COMPILE([
2659 #include <errno.h>
2660 ],
2661 [
2662 int error = EILSEQ;
2663 ], have_eilseq=yes, have_eilseq=no);
2664 AC_MSG_RESULT($have_eilseq)
2665
2666 dnl ******************************************************************
2667 dnl *** Look for glib-genmarshal in PATH if we are cross-compiling ***
2668 dnl ******************************************************************
2669
2670 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2671
2672 if test $cross_compiling = yes; then
2673   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2674   if test x$GLIB_GENMARSHAL = xno; then
2675     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2676   fi
2677 fi
2678
2679 dnl **************************
2680 dnl *** Checks for gtk-doc ***
2681 dnl **************************
2682
2683 GTK_DOC_CHECK([1.11])
2684
2685 AC_ARG_ENABLE(man,
2686               [AC_HELP_STRING([--enable-man],
2687                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2688               enable_man=no)
2689
2690 if test "${enable_man}" != no; then
2691 dnl
2692 dnl Check for xsltproc
2693 dnl
2694 AC_PATH_PROG([XSLTPROC], [xsltproc])
2695   if test -z "$XSLTPROC"; then
2696     enable_man=no
2697   fi
2698
2699   dnl check for DocBook DTD and stylesheets in the local catalog.
2700   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2701      [DocBook XML DTD V4.1.2],,enable_man=no)
2702   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2703      [DocBook XSL Stylesheets],,enable_man=no)
2704 fi
2705
2706 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2707
2708 dnl ******************************
2709 dnl *** output the whole stuff ***
2710 dnl ******************************
2711
2712 dnl this section will only be run if config.status is invoked with no
2713 dnl arguments, or with "glibconfig.h" as an argument.
2714 AC_CONFIG_COMMANDS([glibconfig.h],
2715 [
2716         outfile=glibconfig.h-tmp
2717         cat > $outfile <<\_______EOF
2718 /* glibconfig.h
2719  *
2720  * This is a generated file.  Please modify 'configure.in'
2721  */
2722
2723 #ifndef __G_LIBCONFIG_H__
2724 #define __G_LIBCONFIG_H__
2725
2726 #include <glib/gmacros.h>
2727
2728 _______EOF
2729
2730         if test x$glib_limits_h = xyes; then
2731           echo '#include <limits.h>' >> $outfile
2732         fi
2733         if test x$glib_float_h = xyes; then
2734           echo '#include <float.h>' >> $outfile
2735         fi
2736         if test x$glib_values_h = xyes; then
2737           echo '#include <values.h>' >> $outfile
2738         fi
2739         if test "$glib_header_alloca_h" = "yes"; then
2740           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2741         fi
2742         if test x$glib_sys_poll_h = xyes; then
2743           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2744         fi
2745         if test x$glib_included_printf != xyes; then
2746           echo "
2747 /* Specifies that GLib's g_print*() functions wrap the
2748  * system printf functions.  This is useful to know, for example,
2749  * when using glibc's register_printf_function().
2750  */" >> $outfile
2751           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2752         fi
2753
2754         cat >> $outfile <<_______EOF
2755
2756 G_BEGIN_DECLS
2757
2758 #define G_MINFLOAT      $glib_mf
2759 #define G_MAXFLOAT      $glib_Mf
2760 #define G_MINDOUBLE     $glib_md
2761 #define G_MAXDOUBLE     $glib_Md
2762 #define G_MINSHORT      $glib_ms
2763 #define G_MAXSHORT      $glib_Ms
2764 #define G_MAXUSHORT     $glib_Mus
2765 #define G_MININT        $glib_mi
2766 #define G_MAXINT        $glib_Mi
2767 #define G_MAXUINT       $glib_Mui
2768 #define G_MINLONG       $glib_ml
2769 #define G_MAXLONG       $glib_Ml
2770 #define G_MAXULONG      $glib_Mul
2771
2772 _______EOF
2773
2774
2775         ### this should always be true in a modern C/C++ compiler
2776         cat >>$outfile <<_______EOF
2777 typedef signed char gint8;
2778 typedef unsigned char guint8;
2779 _______EOF
2780
2781
2782         if test -n "$gint16"; then
2783           cat >>$outfile <<_______EOF
2784 typedef signed $gint16 gint16;
2785 typedef unsigned $gint16 guint16;
2786 #define G_GINT16_MODIFIER $gint16_modifier
2787 #define G_GINT16_FORMAT $gint16_format
2788 #define G_GUINT16_FORMAT $guint16_format
2789 _______EOF
2790         fi
2791
2792
2793         if test -n "$gint32"; then
2794           cat >>$outfile <<_______EOF
2795 typedef signed $gint32 gint32;
2796 typedef unsigned $gint32 guint32;
2797 #define G_GINT32_MODIFIER $gint32_modifier
2798 #define G_GINT32_FORMAT $gint32_format
2799 #define G_GUINT32_FORMAT $guint32_format
2800 _______EOF
2801         fi
2802
2803         cat >>$outfile <<_______EOF
2804 #define G_HAVE_GINT64 1          /* deprecated, always true */
2805
2806 ${glib_extension}typedef signed $gint64 gint64;
2807 ${glib_extension}typedef unsigned $gint64 guint64;
2808
2809 #define G_GINT64_CONSTANT(val)  $gint64_constant
2810 #define G_GUINT64_CONSTANT(val) $guint64_constant
2811 _______EOF
2812
2813         if test x$gint64_format != x ; then
2814           cat >>$outfile <<_______EOF
2815 #define G_GINT64_MODIFIER $gint64_modifier
2816 #define G_GINT64_FORMAT $gint64_format
2817 #define G_GUINT64_FORMAT $guint64_format
2818 _______EOF
2819         else
2820           cat >>$outfile <<_______EOF
2821 #undef G_GINT64_MODIFIER
2822 #undef G_GINT64_FORMAT
2823 #undef G_GUINT64_FORMAT
2824 _______EOF
2825         fi
2826
2827         cat >>$outfile <<_______EOF
2828
2829 #define GLIB_SIZEOF_VOID_P $glib_void_p
2830 #define GLIB_SIZEOF_LONG   $glib_long
2831 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2832
2833 _______EOF
2834
2835         cat >>$outfile <<_______EOF
2836 typedef signed $glib_size_type_define gssize;
2837 typedef unsigned $glib_size_type_define gsize;
2838 #define G_GSIZE_MODIFIER $gsize_modifier
2839 #define G_GSSIZE_FORMAT $gssize_format
2840 #define G_GSIZE_FORMAT $gsize_format
2841
2842 #define G_MAXSIZE       G_MAXU$glib_msize_type
2843 #define G_MINSSIZE      G_MIN$glib_msize_type
2844 #define G_MAXSSIZE      G_MAX$glib_msize_type
2845
2846 typedef gint64 goffset;
2847 #define G_MINOFFSET     G_MININT64
2848 #define G_MAXOFFSET     G_MAXINT64
2849
2850 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
2851 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
2852 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2853
2854 _______EOF
2855
2856         if test -z "$glib_unknown_void_p"; then
2857           cat >>$outfile <<_______EOF
2858
2859 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2860 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2861
2862 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2863 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2864
2865 typedef signed $glib_intptr_type_define gintptr;
2866 typedef unsigned $glib_intptr_type_define guintptr;
2867
2868 #define G_GINTPTR_MODIFIER      $gintptr_modifier
2869 #define G_GINTPTR_FORMAT        $gintptr_format
2870 #define G_GUINTPTR_FORMAT       $guintptr_format
2871 _______EOF
2872         else
2873           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2874         fi
2875
2876
2877
2878         cat >>$outfile <<_______EOF
2879 $glib_atexit
2880 $glib_memmove
2881 $glib_defines
2882 $glib_os
2883 $glib_static_compilation
2884
2885 $glib_vacopy
2886
2887 #ifdef  __cplusplus
2888 #define G_HAVE_INLINE   1
2889 #else   /* !__cplusplus */
2890 $glib_inline
2891 #endif  /* !__cplusplus */
2892
2893 #ifdef  __cplusplus
2894 #define G_CAN_INLINE    1
2895 _______EOF
2896
2897         if test x$g_can_inline = xyes ; then
2898                 cat >>$outfile <<_______EOF
2899 #else   /* !__cplusplus */
2900 #define G_CAN_INLINE    1
2901 _______EOF
2902         fi
2903
2904         cat >>$outfile <<_______EOF
2905 #endif
2906
2907 _______EOF
2908
2909         if test x$g_have_iso_c_varargs = xyes ; then
2910                 cat >>$outfile <<_______EOF
2911 #ifndef __cplusplus
2912 # define G_HAVE_ISO_VARARGS 1
2913 #endif
2914 _______EOF
2915         fi
2916         if test x$g_have_iso_cxx_varargs = xyes ; then
2917                 cat >>$outfile <<_______EOF
2918 #ifdef __cplusplus
2919 # define G_HAVE_ISO_VARARGS 1
2920 #endif
2921 _______EOF
2922         fi
2923         if test x$g_have_gnuc_varargs = xyes ; then
2924                 cat >>$outfile <<_______EOF
2925
2926 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2927  * is passed ISO vararg support is turned off, and there is no work
2928  * around to turn it on, so we unconditionally turn it off.
2929  */
2930 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2931 #  undef G_HAVE_ISO_VARARGS
2932 #endif
2933
2934 #define G_HAVE_GNUC_VARARGS 1
2935 _______EOF
2936         fi
2937
2938         case x$g_stack_grows in
2939         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2940         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2941         esac
2942
2943
2944         echo >>$outfile
2945         if test x$g_have_eilseq = xno; then
2946                 cat >>$outfile <<_______EOF
2947 #ifndef EILSEQ
2948 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
2949  * The correspondence between this and the corresponding definition
2950  * in libiconv is essential.
2951  */
2952 #  define EILSEQ ENOENT
2953 #endif
2954 _______EOF
2955
2956         fi
2957
2958         if test x$g_have_gnuc_visibility = xyes; then
2959                 cat >>$outfile <<_______EOF
2960 #define G_HAVE_GNUC_VISIBILITY 1
2961 _______EOF
2962         fi
2963                 cat >>$outfile <<_______EOF
2964 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
2965 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2966 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
2967 #define G_GNUC_INTERNAL __hidden
2968 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
2969 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2970 #else
2971 #define G_GNUC_INTERNAL
2972 #endif
2973 _______EOF
2974
2975
2976         echo >>$outfile
2977         if test x$g_mutex_has_default = xyes; then
2978                 cat >>$outfile <<_______EOF
2979 $g_enable_threads_def G_THREADS_ENABLED
2980 #define G_THREADS_IMPL_$g_threads_impl_def
2981 typedef struct _GStaticMutex GStaticMutex;
2982 struct _GStaticMutex
2983 {
2984   struct _GMutex *runtime_mutex;
2985   union {
2986     char   pad[[$g_mutex_sizeof]];
2987     double dummy_double;
2988     void  *dummy_pointer;
2989     long   dummy_long;
2990   } static_mutex;
2991 };
2992 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
2993 #define g_static_mutex_get_mutex(mutex) \\
2994   (g_thread_use_default_impl ? ((GMutex*)(gpointer) ((mutex)->static_mutex.pad)) : \\
2995    g_static_mutex_get_mutex_impl_shortcut (&((mutex)->runtime_mutex)))
2996 _______EOF
2997         else
2998                 cat >>$outfile <<_______EOF
2999 $g_enable_threads_def G_THREADS_ENABLED
3000 #define G_THREADS_IMPL_$g_threads_impl_def
3001 typedef struct _GMutex* GStaticMutex;
3002 #define G_STATIC_MUTEX_INIT NULL
3003 #define g_static_mutex_get_mutex(mutex) \\
3004   (g_static_mutex_get_mutex_impl_shortcut (mutex))
3005 _______EOF
3006         fi
3007
3008         cat >>$outfile <<_______EOF
3009 /* This represents a system thread as used by the implementation. An
3010  * alien implementaion, as loaded by g_thread_init can only count on
3011  * "sizeof (gpointer)" bytes to store their info. We however need more
3012  * for some of our native implementations. */
3013 typedef union _GSystemThread GSystemThread;
3014 union _GSystemThread
3015 {
3016   char   data[[$g_system_thread_sizeof]];
3017   double dummy_double;
3018   void  *dummy_pointer;
3019   long   dummy_long;
3020 };
3021 _______EOF
3022         if test x"$g_memory_barrier_needed" != xno; then
3023           echo >>$outfile
3024           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3025         fi
3026
3027         echo >>$outfile
3028         g_bit_sizes="16 32 64"
3029         for bits in $g_bit_sizes; do
3030           cat >>$outfile <<_______EOF
3031 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3032 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3033 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3034 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3035 _______EOF
3036         done
3037
3038         cat >>$outfile <<_______EOF
3039 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3040 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3041 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3042 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3043 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3044 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3045 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3046 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3047 #define G_BYTE_ORDER $g_byte_order
3048
3049 #define GLIB_SYSDEF_POLLIN =$g_pollin
3050 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3051 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3052 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3053 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3054 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3055
3056 #define G_MODULE_SUFFIX "$g_module_suffix"
3057
3058 /* A GPid is an abstraction for a process "handle". It is *not* an
3059  * abstraction for a process identifier in general. GPid is used in
3060  * GLib only for descendant processes spawned with the g_spawn*
3061  * functions. On POSIX there is no "process handle" concept as such,
3062  * but on Windows a GPid is a handle to a process, a kind of pointer,
3063  * not a process identifier.
3064  */
3065 typedef $g_pid_type GPid;
3066
3067 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3068 #define GLIB_SYSDEF_AF_INET $g_af_inet
3069 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3070
3071 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3072 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3073 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3074
3075 G_END_DECLS
3076
3077 #endif /* GLIBCONFIG_H */
3078 _______EOF
3079
3080
3081         if cmp -s $outfile glibconfig.h; then
3082           AC_MSG_NOTICE([glibconfig.h is unchanged])
3083           rm -f $outfile
3084         else
3085           mv $outfile glibconfig.h
3086         fi
3087 ],[
3088
3089 # Note that if two cases are the same, case goes with the first one.
3090 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3091 # on variable expansion in case labels.  Look at the generated config.status
3092 # for a hint.
3093
3094 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3095   glib_header_alloca_h="$ac_cv_working_alloca_h"
3096 else
3097   glib_header_alloca_h="$ac_cv_header_alloca_h"
3098 fi
3099
3100 case xyes in
3101 x$ac_cv_header_float_h)
3102   glib_float_h=yes
3103   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3104   glib_md=DBL_MIN glib_Md=DBL_MAX
3105   ;;
3106 x$ac_cv_header_values_h)
3107   glib_values_h=yes
3108   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3109   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3110   ;;
3111 esac
3112
3113 case xyes in
3114 x$ac_cv_header_limits_h)
3115   glib_limits_h=yes
3116   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3117   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3118   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3119   ;;
3120 x$ac_cv_header_values_h)
3121   glib_values_h=yes
3122   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3123   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3124   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3125   ;;
3126 esac
3127
3128 if test x$ac_cv_header_sys_poll_h = xyes ; then
3129   glib_sys_poll_h=yes
3130 fi
3131
3132 if test x$enable_included_printf = xyes ; then
3133   glib_included_printf=yes
3134 fi
3135
3136 case 2 in
3137 $ac_cv_sizeof_short)
3138   gint16=short
3139   gint16_modifier='"h"'
3140   gint16_format='"hi"'
3141   guint16_format='"hu"'
3142   ;;
3143 $ac_cv_sizeof_int)
3144   gint16=int
3145   gint16_modifier='""'
3146   gint16_format='"i"'
3147   guint16_format='"u"'
3148   ;;
3149 esac
3150 case 4 in
3151 $ac_cv_sizeof_short)
3152   gint32=short
3153   gint32_modifier='"h"'
3154   gint32_format='"hi"'
3155   guint32_format='"hu"'
3156   ;;
3157 $ac_cv_sizeof_int)
3158   gint32=int
3159   gint32_modifier='""'
3160   gint32_format='"i"'
3161   guint32_format='"u"'
3162   ;;
3163 $ac_cv_sizeof_long)
3164   gint32=long
3165   gint32_modifier='"l"'
3166   gint32_format='"li"'
3167   guint32_format='"lu"'
3168   ;;
3169 esac
3170 case 8 in
3171 $ac_cv_sizeof_int)
3172   gint64=int
3173   gint64_modifier='""'
3174   gint64_format='"i"'
3175   guint64_format='"u"'
3176   glib_extension=
3177   gint64_constant='(val)'
3178   guint64_constant='(val)'
3179   ;;
3180 $ac_cv_sizeof_long)
3181   gint64=long
3182   gint64_modifier='"l"'
3183   gint64_format='"li"'
3184   guint64_format='"lu"'
3185   glib_extension=
3186   gint64_constant='(val##L)'
3187   guint64_constant='(val##UL)'
3188   ;;
3189 $ac_cv_sizeof_long_long)
3190   gint64='long long'
3191   if test -n "$glib_cv_long_long_format"; then
3192     gint64_modifier='"'$glib_cv_long_long_format'"'
3193     gint64_format='"'$glib_cv_long_long_format'i"'
3194     guint64_format='"'$glib_cv_long_long_format'u"'
3195   fi
3196   glib_extension='G_GNUC_EXTENSION '
3197   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3198   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3199   ;;
3200 $ac_cv_sizeof___int64)
3201   gint64='__int64'
3202   if test -n "$glib_cv_long_long_format"; then
3203     gint64_modifier='"'$glib_cv_long_long_format'"'
3204     gint64_format='"'$glib_cv_long_long_format'i"'
3205     guint64_format='"'$glib_cv_long_long_format'u"'
3206   fi
3207   glib_extension=
3208   gint64_constant='(val##i64)'
3209   guint64_constant='(val##ui64)'
3210   ;;
3211 esac
3212 glib_size_t=$ac_cv_sizeof_size_t
3213 glib_size_type_define="$glib_size_type"
3214 glib_void_p=$ac_cv_sizeof_void_p
3215 glib_long=$ac_cv_sizeof_long
3216
3217 case "$glib_size_type" in
3218 short)
3219   gsize_modifier='"h"'
3220   gsize_format='"hu"'
3221   gssize_format='"hi"'
3222   glib_msize_type='SHRT'
3223   ;;
3224 int)
3225   gsize_modifier='""'
3226   gsize_format='"u"'
3227   gssize_format='"i"'
3228   glib_msize_type='INT'
3229   ;;
3230 long)
3231   gsize_modifier='"l"'
3232   gsize_format='"lu"'
3233   gssize_format='"li"'
3234   glib_msize_type='LONG'
3235   ;;
3236 "long long"|__int64)
3237   gsize_modifier='"I64"'
3238   gsize_format='"I64u"'
3239   gssize_format='"I64i"'
3240   glib_msize_type='INT64'
3241   ;;
3242 esac
3243
3244 gintbits=`expr $ac_cv_sizeof_int \* 8`
3245 glongbits=`expr $ac_cv_sizeof_long \* 8`
3246
3247 case $ac_cv_sizeof_void_p in
3248 $ac_cv_sizeof_int)
3249   glib_intptr_type_define=int
3250   gintptr_modifier='""'
3251   gintptr_format='"i"'
3252   guintptr_format='"u"'
3253   glib_gpi_cast=''
3254   glib_gpui_cast=''
3255   ;;
3256 $ac_cv_sizeof_long)
3257   glib_intptr_type_define=long
3258   gintptr_modifier='"l"'
3259   gintptr_format='"li"'
3260   guintptr_format='"lu"'
3261   glib_gpi_cast='(glong)'
3262   glib_gpui_cast='(gulong)'
3263   ;;
3264 $ac_cv_sizeof_long_long)
3265   glib_intptr_type_define='long long'
3266   gintptr_modifier='"I64"'
3267   gintptr_format='"I64i"'
3268   guintptr_format='"I64u"'
3269   glib_gpi_cast='(gint64)'
3270   glib_gpui_cast='(guint64)'
3271   ;;
3272 $ac_cv_sizeof___int64)
3273   glib_intptr_type_define=__int64
3274   gintptr_modifier='"I64"'
3275   gintptr_format='"I64i"'
3276   guintptr_format='"I64u"'
3277   glib_gpi_cast='(gint64)'
3278   glib_gpui_cast='(guint64)'
3279   ;;
3280 *)
3281   glib_unknown_void_p=yes
3282   ;;
3283 esac
3284
3285
3286 case xyes in
3287 x$ac_cv_func_atexit)
3288   glib_atexit="
3289 #ifdef NeXT /* @#%@! NeXTStep */
3290 # define g_ATEXIT(proc) (!atexit (proc))
3291 #else
3292 # define g_ATEXIT(proc) (atexit (proc))
3293 #endif"
3294   ;;
3295 x$ac_cv_func_on_exit)
3296   glib_atexit="
3297 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3298   ;;
3299 esac
3300
3301 case xyes in
3302 x$ac_cv_func_memmove)
3303   glib_memmove='
3304 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3305   ;;
3306 x$glib_cv_working_bcopy)
3307   glib_memmove="
3308 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3309 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3310   ;;
3311 *)
3312   glib_memmove="
3313 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3314  * so we have to roll our own copy routine. */
3315 void g_memmove (void* dest, const void * src, unsigned long len);"
3316   ;;
3317 esac
3318
3319 glib_defines="
3320 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3321 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3322 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3323 "
3324
3325 case xyes in
3326 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3327 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3328 *)                      glib_vacopy=''
3329 esac
3330
3331 if test x$glib_cv_va_val_copy = xno; then
3332   glib_vacopy="\$glib_vacopy
3333 #define G_VA_COPY_AS_ARRAY 1"
3334 fi
3335
3336 if test x$glib_cv_hasinline = xyes; then
3337     glib_inline='#define G_HAVE_INLINE 1'
3338 fi
3339 if test x$glib_cv_has__inline = xyes; then
3340     glib_inline="\$glib_inline
3341 #define G_HAVE___INLINE 1"
3342 fi
3343 if test x$glib_cv_has__inline__ = xyes; then
3344     glib_inline="\$glib_inline
3345 #define G_HAVE___INLINE__ 1"
3346 fi
3347
3348 g_have_gnuc_varargs=$g_have_gnuc_varargs
3349 g_have_iso_c_varargs=$g_have_iso_c_varargs
3350 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3351
3352 g_can_inline=$g_can_inline
3353 g_have_gnuc_visibility=$g_have_gnuc_visibility
3354 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3355
3356 if test x$ac_cv_c_bigendian = xyes; then
3357   g_byte_order=G_BIG_ENDIAN
3358   g_bs_native=BE
3359   g_bs_alien=LE
3360 else
3361   g_byte_order=G_LITTLE_ENDIAN
3362   g_bs_native=LE
3363   g_bs_alien=BE
3364 fi
3365
3366 g_pollin=$glib_cv_value_POLLIN
3367 g_pollout=$glib_cv_value_POLLOUT
3368 g_pollpri=$glib_cv_value_POLLPRI
3369 g_pollhup=$glib_cv_value_POLLHUP
3370 g_pollerr=$glib_cv_value_POLLERR
3371 g_pollnval=$glib_cv_value_POLLNVAL
3372
3373 g_af_unix=$glib_cv_value_AF_UNIX
3374 g_af_inet=$glib_cv_value_AF_INET
3375 g_af_inet6=$glib_cv_value_AF_INET6
3376
3377 g_msg_peek=$glib_cv_value_MSG_PEEK
3378 g_msg_oob=$glib_cv_value_MSG_OOB
3379 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3380
3381 g_stack_grows=$glib_cv_stack_grows
3382
3383 g_have_eilseq=$have_eilseq
3384
3385 case x$have_threads in
3386 xno)    g_enable_threads_def="#undef";;
3387 *)      g_enable_threads_def="#define";;
3388 esac
3389
3390 g_threads_impl_def=$g_threads_impl
3391
3392 g_mutex_has_default="$mutex_has_default"
3393 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
3394 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
3395 g_mutex_contents="$glib_cv_byte_contents_gmutex"
3396
3397 g_memory_barrier_needed="$glib_memory_barrier_needed"
3398
3399 g_module_suffix="$glib_gmodule_suffix"
3400
3401 g_pid_type="$glib_pid_type"
3402 case $host in
3403   *-*-beos*)
3404     glib_os="#define G_OS_BEOS"
3405     ;;
3406   *-*-cygwin*)
3407     glib_os="#define G_OS_UNIX
3408 #define G_PLATFORM_WIN32
3409 #define G_WITH_CYGWIN"
3410     ;;
3411   *-*-mingw*)
3412     glib_os="#define G_OS_WIN32
3413 #define G_PLATFORM_WIN32"
3414     ;;
3415   *)
3416     glib_os="#define G_OS_UNIX"
3417     ;;
3418 esac
3419 glib_static_compilation=""
3420 if test x$glib_win32_static_compilation = xyes; then
3421   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3422 #define GOBJECT_STATIC_COMPILATION 1"
3423 fi
3424 ])
3425
3426 AC_CONFIG_FILES([
3427 glib-2.0.pc
3428 glib-2.0-uninstalled.pc
3429 gmodule-2.0.pc
3430 gmodule-export-2.0.pc
3431 gmodule-no-export-2.0.pc
3432 gmodule-2.0-uninstalled.pc
3433 gmodule-no-export-2.0-uninstalled.pc
3434 gthread-2.0.pc
3435 gthread-2.0-uninstalled.pc
3436 gobject-2.0.pc
3437 gobject-2.0-uninstalled.pc
3438 gio-2.0.pc
3439 gio-unix-2.0.pc
3440 gio-2.0-uninstalled.pc
3441 gio-unix-2.0-uninstalled.pc
3442 glib-zip
3443 glib-gettextize
3444 Makefile
3445 build/Makefile
3446 build/win32/Makefile
3447 build/win32/dirent/Makefile
3448 build/win32/vs8/Makefile
3449 build/win32/vs9/Makefile
3450 glib/Makefile
3451 glib/libcharset/Makefile
3452 glib/gnulib/Makefile
3453 glib/pcre/Makefile
3454 glib/update-pcre/Makefile
3455 glib/tests/Makefile
3456 gmodule/Makefile
3457 gmodule/gmoduleconf.h
3458 gobject/Makefile
3459 gobject/glib-mkenums
3460 gobject/tests/Makefile
3461 gthread/Makefile
3462 gio/Makefile
3463 gio/xdgmime/Makefile
3464 gio/inotify/Makefile
3465 gio/libasyncns/Makefile
3466 gio/fen/Makefile
3467 gio/fam/Makefile
3468 gio/win32/Makefile
3469 gio/tests/Makefile
3470 po/Makefile.in
3471 docs/Makefile
3472 docs/reference/Makefile
3473 docs/reference/glib/Makefile
3474 docs/reference/glib/version.xml
3475 docs/reference/gobject/Makefile
3476 docs/reference/gobject/version.xml
3477 docs/reference/gio/Makefile
3478 docs/reference/gio/version.xml
3479 tests/Makefile
3480 tests/gobject/Makefile
3481 tests/refcount/Makefile
3482 m4macros/Makefile
3483 ])
3484
3485 AC_CONFIG_COMMANDS([chmod-scripts],
3486 [chmod 0755 glib-zip
3487 chmod 0755 glib-gettextize
3488 chmod 0755 gobject/glib-mkenums])
3489
3490 # we want to invoke this macro solely so that the config.status script
3491 # and automake generated makefiles know about these generated files.
3492 # They are only needed to distcheck the package
3493 if false; then
3494   AC_CONFIG_FILES([
3495     INSTALL
3496     README
3497     config.h.win32
3498     glibconfig.h.win32
3499     glib/makefile.msc
3500     glib/glib.rc
3501     gmodule/makefile.msc
3502     gmodule/gmodule.rc
3503     gobject/makefile.msc
3504     gobject/gobject.rc
3505     gthread/makefile.msc
3506     gthread/gthread.rc
3507     tests/makefile.msc
3508   ])
3509 fi
3510
3511 AC_OUTPUT