configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 # require autoconf 2.54
   3 AC_PREREQ(2.54)
   4
   5 dnl ***********************************
   6 dnl *** include special GLib macros ***
   7 dnl ***********************************
   8
   9 m4_define(glib_configure_in)
  10 m4_include(acglib.m4)dnl
  11 m4_include(glib/libcharset/codeset.m4)dnl
  12 m4_include(glib/libcharset/glibc21.m4)dnl
  13 m4_include(m4macros/glib-gettext.m4)dnl
  14
  15 #
  16 # The following version number definitions apply to GLib, GModule, GObject
  17 # and GThread as a whole, so if changes occoured in any of them, they are all
  18 # treated with the same interface and binary age.
  19 #
  20 # Making releases:
  21 #   glib_micro_version += 1;
  22 #   glib_interface_age += 1;
  23 #   glib_binary_age += 1;
  24 # if any functions have been added, set glib_interface_age to 0.
  25 # if backwards compatibility has been broken,
  26 # set glib_binary_age _and_ glib_interface_age to 0.
  27 #
  28 m4_define([glib_major_version], [2])
  29 m4_define([glib_minor_version], [3])
  30 m4_define([glib_micro_version], [0])
  31 m4_define([glib_interface_age], [0])
  32 m4_define([glib_binary_age],
  33           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  34 m4_define([glib_version],
  35           [glib_major_version.glib_minor_version.glib_micro_version])
  36
  37 # libtool version related macros
  38 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  39 m4_define([glib_lt_current],
  40           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  41 m4_define([glib_lt_revision], [glib_interface_age])
  42 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  43 m4_define([glib_lt_current_minus_age],
  44           [m4_eval(glib_lt_current - glib_lt_age)])
  45
  46 # if the minor version number is odd, then we want debugging.  Otherwise
  47 # we only want minimal debugging support.
  48 m4_define([glib_debug_default],
  49           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  50
  51
  52 AC_INIT(glib, [glib_version],
  53         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  54
  55 AC_CONFIG_SRCDIR([glib/glib.h])
  56
  57 # Save this value here, since automake will set cflags later
  58 cflags_set=${CFLAGS+set}
  59
  60 AM_INIT_AUTOMAKE([no-define])
  61
  62 # Specify a configuration file
  63 AM_CONFIG_HEADER([config.h])
  64
  65
  66 GLIB_MAJOR_VERSION=glib_major_version
  67 GLIB_MINOR_VERSION=glib_minor_version
  68 GLIB_MICRO_VERSION=glib_micro_version
  69 GLIB_INTERFACE_AGE=glib_interface_age
  70 GLIB_BINARY_AGE=glib_binary_age
  71 GLIB_VERSION=glib_version
  72
  73 AC_SUBST(GLIB_MAJOR_VERSION)
  74 AC_SUBST(GLIB_MINOR_VERSION)
  75 AC_SUBST(GLIB_MICRO_VERSION)
  76 AC_SUBST(GLIB_VERSION)
  77 AC_SUBST(GLIB_INTERFACE_AGE)
  78 AC_SUBST(GLIB_BINARY_AGE)
  79
  80 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  81           [Define to the GLIB major version])
  82 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  83           [Define to the GLIB minor version])
  84 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  85           [Define to the GLIB micro version])
  86 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  87           [Define to the GLIB interface age])
  88 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  89           [Define to the GLIB binary age])
  90
  91 # libtool versioning
  92 LT_RELEASE=glib_lt_release
  93 LT_CURRENT=glib_lt_current
  94 LT_REVISION=glib_lt_revision
  95 LT_AGE=glib_lt_age
  96 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
  97 AC_SUBST(LT_RELEASE)
  98 AC_SUBST(LT_CURRENT)
  99 AC_SUBST(LT_REVISION)
 100 AC_SUBST(LT_AGE)
 101 AC_SUBST(LT_CURRENT_MINUS_AGE)
 102
 103 dnl Initialize maintainer mode
 104 AM_MAINTAINER_MODE
 105
 106 AC_CANONICAL_HOST
 107
 108 AC_MSG_CHECKING([for the BeOS])
 109 case $host in
 110   *-*-beos*)
 111     glib_native_beos="yes"
 112     ;;
 113   *)
 114     glib_native_beos="no"
 115     ;;
 116 esac
 117 AC_MSG_RESULT([$glib_native_beos])
 118
 119 dnl
 120
 121 AC_MSG_CHECKING([for Win32])
 122 case "$host" in
 123   *-*-mingw*)
 124     glib_native_win32=yes
 125     G_LIB_WIN32_RESOURCE=glib-win32res.lo
 126     G_MODULE_WIN32_RESOURCE=gmodule-win32res.lo
 127     G_OBJECT_WIN32_RESOURCE=gobject-win32res.lo
 128     G_THREAD_WIN32_RESOURCE=gthread-win32res.lo
 129     GLIB_DEF=glib.def
 130     GMODULE_DEF=gmodule.def
 131     GOBJECT_DEF=gobject.def
 132     GTHREAD_DEF=gthread.def
 133     TESTGMODULE_EXP=testgmodule.exp
 134     ;;
 135   *)
 136     glib_native_win32=no
 137     G_LIB_WIN32_RESOURCE=
 138     G_MODULE_WIN32_RESOURCE=
 139     G_OBJECT_WIN32_RESOURCE=
 140     G_THREAD_WIN32_RESOURCE=
 141     GLIB_DEF=
 142     GMODULE_DEF=
 143     GOBJECT_DEF=
 144     GTHREAD_DEF=
 145     TESTGMODULE_EXP=
 146     ;;
 147 esac
 148 AC_MSG_RESULT([$glib_native_win32])
 149 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 150 AC_SUBST(G_LIB_WIN32_RESOURCE)
 151 AC_SUBST(G_MODULE_WIN32_RESOURCE)
 152 AC_SUBST(G_OBJECT_WIN32_RESOURCE)
 153 AC_SUBST(G_THREAD_WIN32_RESOURCE)
 154 AC_SUBST(GLIB_DEF)
 155 AC_SUBST(GMODULE_DEF)
 156 AC_SUBST(GOBJECT_DEF)
 157 AC_SUBST(GTHREAD_DEF)
 158 AC_SUBST(TESTGMODULE_EXP)
 159
 160 if test "$glib_native_win32" = "yes"; then
 161   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 162 fi
 163 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 164
 165 dnl declare --enable-* args and collect ac_help strings
 166 AC_ARG_ENABLE(debug,
 167               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 168                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 169               enable_debug=glib_debug_default)
 170
 171 AC_ARG_ENABLE(gc_friendly,
 172               [AC_HELP_STRING([--enable-gc-friendly],
 173                               [turn on garbage collector friendliness [default=no]])],,
 174               [enable_gc_friendly=no])
 175 AC_ARG_ENABLE(mem_pools,
 176               [AC_HELP_STRING([--disable-mem-pools],
 177                               [disable all glib memory pools])],,
 178               [disable_mem_pools=no])
 179 AC_ARG_ENABLE(ansi,
 180               [AC_HELP_STRING([--enable-ansi],
 181                               [turn on strict ansi [default=no]])],,
 182               [enable_ansi=no])
 183 AC_ARG_ENABLE(threads,
 184               [AC_HELP_STRING([--enable-threads],
 185                               [turn on basic thread support [default=yes]
 186 ([=no] will override --with-threads)])],,
 187               [enable_threads=yes])
 188 AC_ARG_ENABLE(rebuilds,
 189               [AC_HELP_STRING([--disable-rebuilds],
 190                               [disable all source autogeneration rules])],,
 191               [enable_rebuilds=yes])
 192
 193 if test "x$enable_threads" != "xyes"; then
 194   enable_threads=no
 195 fi
 196
 197 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, ["${enable_debug}"],
 198         [Whether glib was compiled with debugging enabled])
 199
 200 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 201 if test "x$enable_gc_friendly" = "xyes"; then
 202   AC_DEFINE(ENABLE_GC_FRIENDLY, 1, [Whether to enable GC friendliness])
 203   AC_SUBST(ENABLE_GC_FRIENDLY)
 204   AC_MSG_RESULT([yes])
 205 else
 206   AC_MSG_RESULT([no])
 207 fi
 208
 209 AC_MSG_CHECKING([whether to disable memory pools])
 210 if test "x$disable_mem_pools" = "xno"; then
 211   AC_MSG_RESULT([no])
 212 else
 213   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 214   AC_SUBST(DISABLE_MEM_POOLS)
 215   AC_MSG_RESULT([yes])
 216 fi
 217
 218 dnl Checks for programs.
 219 AC_PROG_CC
 220
 221 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 222 AC_CHECK_PROGS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 223 AC_LANG_SAVE
 224 AC_LANG_CPLUSPLUS
 225 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 226 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 227 AC_LANG_RESTORE
 228
 229 AM_PROG_CC_STDC
 230 AC_PROG_INSTALL
 231
 232 AC_SYS_LARGEFILE
 233
 234 #
 235 # Find pkg-config
 236 #
 237 AC_PATH_PROG(PKG_CONFIG, [pkg-config], [no])
 238 if test x$PKG_CONFIG = xno ; then
 239   AC_MSG_ERROR([*** pkg-config not found. See http://www.freedesktop.org/software/pkgconfig/])
 240 fi
 241
 242 if $PKG_CONFIG --atleast-pkgconfig-version 0.14 ; then
 243   :
 244 else
 245   AC_MSG_ERROR([*** pkg-config too old; version 0.14 or better required.])
 246 fi
 247
 248 if test "x$enable_debug" = "xyes"; then
 249   if test x$cflags_set != xset ; then
 250       case " $CFLAGS " in
 251       *[[\ \    ]]-g[[\ \       ]]*) ;;
 252       *) CFLAGS="$CFLAGS -g" ;;
 253       esac
 254   fi
 255
 256   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 257 else
 258   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 259
 260   if test "x$enable_debug" = "xno"; then
 261     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 262   fi
 263 fi
 264
 265 # Ensure MSVC-compatible struct packing convention is used when
 266 # compiling for Win32 with gcc.
 267 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 268 # gcc2 uses "-fnative-struct".
 269 if test x"$glib_native_win32" = xyes; then
 270   if test x"$GCC" = xyes; then
 271     msnative_struct=''
 272     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 273     if test -z "$ac_cv_prog_CC"; then
 274       our_gcc="$CC"
 275     else
 276       our_gcc="$ac_cv_prog_CC"
 277     fi
 278     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 279       2.)
 280         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 281           msnative_struct='-fnative-struct'
 282         fi
 283         ;;
 284       *)
 285         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 286           msnative_struct='-mms-bitfields'
 287         fi
 288         ;;
 289     esac
 290     if test x"$msnative_struct" = x ; then
 291       AC_MSG_RESULT([no way])
 292       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 293     else
 294       CFLAGS="$CFLAGS $msnative_struct"
 295       AC_MSG_RESULT([${msnative_struct}])
 296     fi
 297   fi
 298 fi
 299
 300 AC_CYGWIN
 301 AC_EXEEXT
 302
 303 # define a MAINT-like variable REBUILD which is set if Perl
 304 # and awk are found, so autogenerated sources can be rebuilt
 305 AC_PROG_AWK
 306 AC_CHECK_PROGS(PERL, [perl5 perl])
 307 # We would like indent, but don't require it.
 308 AC_CHECK_PROG(INDENT, indent, indent)
 309 REBUILD=\#
 310 if test "x$enable_rebuilds" = "xyes" && \
 311      test -n "$PERL" && \
 312      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 313      test -n "$AWK" ; then
 314   REBUILD=
 315 fi
 316 AC_SUBST(REBUILD)
 317
 318 # Need full path to Perl for glib-mkenums
 319 #
 320 if test "x$PERL" != x ; then
 321   AC_PATH_PROG(PERL_PATH, [$PERL])
 322 else
 323   PERL_PATH="/usr/bin/env perl"
 324 fi
 325 AC_SUBST(PERL_PATH)
 326
 327 dnl ***********************
 328 dnl *** Tests for iconv ***
 329 dnl ***********************
 330 dnl
 331 dnl We do this before the gettext checks, to avoid distortion
 332
 333 AC_ARG_WITH(libiconv,
 334             [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 335                             [use the libiconv library])],,
 336             [with_libiconv=maybe])
 337
 338 found_iconv=no
 339 case $with_libiconv in
 340   maybe)
 341     # Check in the C library first
 342     AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 343     # Check if we have GNU libiconv
 344     if test $found_iconv = "no"; then
 345       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 346     fi
 347     # Check if we have a iconv in -liconv, possibly from vendor
 348     if test $found_iconv = "no"; then
 349       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 350     fi
 351     ;;
 352   no)
 353     AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 354     ;;
 355   gnu|yes)
 356     AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 357     ;;
 358   native)
 359     AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 360     ;;
 361 esac
 362
 363 if test "x$found_iconv" = "xno" ; then
 364    AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 365 fi
 366
 367 dnl
 368 dnl gettext support
 369 dnl
 370
 371 ALL_LINGUAS="am ar az be bg bn ca cs cy da de el eo es et eu fa fi fr gl he hi id is it ja ko lt lv mk mn ms nl nn no pl pt pt_BR ro ru sk sl sq sr sr@Latn sv ta tr uk vi yi zh_CN zh_TW"
 372 GLIB_GNU_GETTEXT
 373
 374 if test "$gt_cv_have_gettext" != "yes" ; then
 375   AC_MSG_ERROR([
 376 *** You must have either have gettext support in your C library, or use the
 377 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 378 ])
 379 fi
 380
 381 LIBS="$INTLLIBS $LIBS"
 382
 383 GETTEXT_PACKAGE=glib20
 384 AC_SUBST(GETTEXT_PACKAGE)
 385 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 386   [Define the gettext package to be used])
 387
 388 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 389
 390 dnl
 391 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 392 dnl
 393
 394 if test x$with_libiconv != xno ; then
 395   case " $INTLLIBS " in
 396   *[[\ \        ]]-liconv[[\ \  ]]*) ;;
 397   *) ICONV_LIBS="-liconv" ;;
 398   esac
 399 fi
 400 AC_SUBST(ICONV_LIBS)
 401
 402 case $with_libiconv in
 403   gnu)
 404     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 405     ;;
 406   native)
 407     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 408     ;;
 409 esac
 410
 411 dnl Initialize libtool
 412 AM_DISABLE_STATIC
 413 AC_LIBTOOL_WIN32_DLL
 414 AM_PROG_LIBTOOL
 415
 416 if test "x$GCC" = "xyes"; then
 417   case " $CFLAGS " in
 418   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 419   *) CFLAGS="$CFLAGS -Wall" ;;
 420   esac
 421
 422   if test "x$enable_ansi" = "xyes"; then
 423     case " $CFLAGS " in
 424     *[[\ \      ]]-ansi[[\ \    ]]*) ;;
 425     *) CFLAGS="$CFLAGS -ansi" ;;
 426     esac
 427
 428     case " $CFLAGS " in
 429     *[[\ \      ]]-pedantic[[\ \        ]]*) ;;
 430     *) CFLAGS="$CFLAGS -pedantic" ;;
 431     esac
 432   fi
 433 fi
 434
 435 dnl
 436 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 437 dnl
 438 if test $cross_compiling != yes ; then
 439     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 440     glib_save_LIBS=$LIBS
 441     LIBS="$LIBS -lm"
 442     AC_TRY_RUN([#include <math.h>
 443                  int main (void) { return (log(1) != log(1.)); }],
 444          AC_MSG_RESULT(none needed),
 445          glib_save_CFLAGS=$CFLAGS
 446          CFLAGS="$CFLAGS -std1"
 447          AC_TRY_RUN([#include <math.h>
 448                      int main (void) { return (log(1) != log(1.)); }],
 449              AC_MSG_RESULT(-std1),
 450              AC_MSG_RESULT()
 451              CFLAGS=$glib_save_CFLAGS
 452              AC_MSG_WARN(
 453                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 454          )
 455     )
 456     LIBS=$glib_save_LIBS
 457 fi
 458
 459 dnl NeXTStep cc seems to need this
 460 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 461 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 462   AC_MSG_RESULT(none needed),
 463   glib_save_CFLAGS=$CFLAGS
 464   CFLAGS="$CFLAGS -posix"
 465   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 466     AC_MSG_RESULT(-posix),
 467     AC_MSG_RESULT()
 468     CFLAGS=$glib_save_CFLAGS
 469     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 470
 471 # Checks for header files.
 472 AC_HEADER_STDC
 473
 474 # Checks for library functions.
 475 AC_FUNC_VPRINTF
 476
 477 AC_FUNC_ALLOCA
 478
 479 AC_CHECK_FUNCS(atexit on_exit)
 480
 481 AC_CHECK_SIZEOF(char)
 482 AC_CHECK_SIZEOF(short)
 483 AC_CHECK_SIZEOF(long)
 484 AC_CHECK_SIZEOF(int)
 485 AC_CHECK_SIZEOF(void *)
 486 AC_CHECK_SIZEOF(long long)
 487 AC_CHECK_SIZEOF(__int64)
 488
 489 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 490   :
 491 else
 492   AC_MSG_ERROR([
 493 *** GLib requires a 64 bit type. You might want to consider
 494 *** using the GNU C compiler.
 495 ])
 496 fi
 497
 498 if test x$ac_cv_sizeof_long_long = x8; then
 499         # long long is a 64 bit integer.
 500         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 501         AC_CACHE_VAL(glib_cv_long_long_format,[
 502                 for format in ll q I64; do
 503                   AC_TRY_RUN([#include <stdio.h>
 504                         int main()
 505                         {
 506                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 507                           char buffer[1000];
 508                           sprintf (buffer, "%${format}u", a);
 509                           sscanf (buffer, "%${format}u", &b);
 510                           exit (b!=a);
 511                         }
 512                         ],
 513                         [glib_cv_long_long_format=${format}
 514                         break],
 515                         [],[:])
 516                 done])
 517         if test -n "$glib_cv_long_long_format"; then
 518           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 519           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 520         else
 521           AC_MSG_RESULT(none)
 522         fi
 523 elif test x$ac_cv_sizeof___int64 = x8; then
 524         # __int64 is a 64 bit integer.
 525         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 526         # We know this is MSVC, and what the formats are
 527         glib_cv_long_long_format=I64
 528         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 529         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 530 fi
 531
 532 dnl long doubles were not used, and a portability problem
 533 dnl AC_C_LONG_DOUBLE
 534 AC_C_CONST
 535
 536 dnl ok, here we try to check whether the systems prototypes for
 537 dnl malloc and friends actually match the prototypes provided
 538 dnl by gmem.h (keep in sync). i currently only know how to check
 539 dnl this reliably with gcc (-Werror), improvements for other
 540 dnl compilers are apprechiated.
 541 SANE_MALLOC_PROTOS=no
 542 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 543 glib_save_CFLAGS=$CFLAGS
 544 if test "x$GCC" = "xyes"; then
 545   CFLAGS="$CFLAGS -Werror"
 546   AC_TRY_COMPILE([#include <stdlib.h>], [
 547     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 548     void* (*my_malloc_p)  (size_t)         = malloc;
 549     void  (*my_free_p)    (void*)          = free;
 550     void* (*my_realloc_p) (void*, size_t)  = realloc;
 551     my_calloc_p = 0;
 552     my_malloc_p = 0;
 553     my_free_p = 0;
 554     my_realloc_p = 0;
 555   ],
 556     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 557       [Define if you have correct malloc prototypes])
 558     SANE_MALLOC_PROTOS=yes)
 559 fi
 560 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 561 CFLAGS=$glib_save_CFLAGS
 562
 563 dnl
 564 dnl check in which direction the stack grows
 565 dnl
 566 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 567         AC_TRY_RUN([
 568         volatile int *a = 0, *b = 0;
 569         void foo (void);
 570         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 571         void foo (void) { volatile int x = 5; b = &x; }
 572         ],
 573         glib_cv_stack_grows=no
 574         ,
 575         glib_cv_stack_grows=yes
 576         ,)
 577 ])
 578
 579 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 580 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 581 dnl actually supported.
 582 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 583         AC_COMPILE_IFELSE([
 584         __inline int foo () { return 0; }
 585         int main () { return foo (); }
 586         ],
 587         glib_cv_has__inline=yes
 588         ,
 589         glib_cv_has__inline=no
 590         ,)
 591 ])
 592 case x$glib_cv_has__inline in
 593 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 594 esac
 595 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 596         AC_COMPILE_IFELSE([
 597         __inline__ int foo () { return 0; }
 598         int main () { return foo (); }
 599         ],
 600         glib_cv_has__inline__=yes
 601         ,
 602         glib_cv_has__inline__=no
 603         ,)
 604 ])
 605 case x$glib_cv_has__inline__ in
 606 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 607 esac
 608 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 609         AC_COMPILE_IFELSE([
 610         #undef inline
 611         inline int foo () { return 0; }
 612         int main () { return foo (); }
 613         ],
 614         glib_cv_hasinline=yes
 615         ,
 616         glib_cv_hasinline=no
 617         ,)
 618 ])
 619 case x$glib_cv_hasinline in
 620 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 621 esac
 622
 623 # check for flavours of varargs macros
 624 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 625 AC_TRY_COMPILE([],[
 626 int a(int p1, int p2, int p3);
 627 #define call_a(...) a(1,__VA_ARGS__)
 628 call_a(2,3);
 629 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 630 AC_MSG_RESULT($g_have_iso_c_varargs)
 631
 632 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 633 if test "$CXX" = ""; then
 634 dnl No C++ compiler
 635   g_have_iso_cxx_varargs=no
 636 else
 637   AC_LANG_CPLUSPLUS
 638   AC_TRY_COMPILE([],[
 639 int a(int p1, int p2, int p3);
 640 #define call_a(...) a(1,__VA_ARGS__)
 641 call_a(2,3);
 642 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 643   AC_LANG_C
 644 fi
 645 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 646
 647 AC_MSG_CHECKING(for GNUC varargs macros)
 648 AC_TRY_COMPILE([],[
 649 int a(int p1, int p2, int p3);
 650 #define call_a(params...) a(1,params)
 651 call_a(2,3);
 652 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 653 AC_MSG_RESULT($g_have_gnuc_varargs)
 654
 655 # check for bytesex stuff
 656 AC_C_BIGENDIAN
 657
 658 # check for header files
 659 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h sys/param.h sys/poll.h sys/select.h sys/types.h])
 660 AC_CHECK_HEADERS([sys/time.h sys/times.h unistd.h values.h stdint.h sched.h])
 661
 662 # Checks for libcharset
 663 jm_LANGINFO_CODESET
 664 jm_GLIBC21
 665 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 666 AC_CHECK_FUNCS(setlocale)
 667
 668 AC_MSG_CHECKING(whether make is GNU Make)
 669 STRIP_BEGIN=
 670 STRIP_END=
 671 if $ac_make --version 2>/dev/null | grep '^GNU Make ' >/dev/null ; then
 672         STRIP_BEGIN='$(strip $(STRIP_DUMMY)'
 673         STRIP_END=')'
 674         AC_MSG_RESULT(yes)
 675 else
 676         AC_MSG_RESULT(no)
 677 fi
 678 STRIP_DUMMY=
 679 AC_SUBST(STRIP_DUMMY)
 680 AC_SUBST(STRIP_BEGIN)
 681 AC_SUBST(STRIP_END)
 682
 683 # check additional type sizes
 684 AC_CHECK_SIZEOF(size_t)
 685
 686 dnl Try to figure out whether gsize, gssize should be long or int
 687 AC_MSG_CHECKING([for the appropriate definition for size_t])
 688
 689 case $ac_cv_sizeof_size_t in
 690   $ac_cv_sizeof_short)
 691       glib_size_type=short
 692       ;;
 693   $ac_cv_sizeof_int)
 694       glib_size_type=int
 695       ;;
 696   $ac_cv_sizeof_long)
 697       glib_size_type=long
 698       ;;
 699   *)  AC_MSG_ERROR([No type matching size_t in size])
 700       ;;
 701 esac
 702
 703 dnl If int/long are the same size, we see which one produces
 704 dnl warnings when used in the location as size_t. (This matters
 705 dnl on AIX with xlc)
 706 dnl
 707 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 708    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 709   GLIB_CHECK_COMPILE_WARNINGS([
 710 #include <stddef.h>
 711 int main ()
 712 {
 713   size_t s = 1;
 714   unsigned int *size_int = &s;
 715   return (int)*size_int;
 716 }
 717     ],glib_size_type=int,
 718       [GLIB_CHECK_COMPILE_WARNINGS([
 719 #include <stddef.h>
 720 int main ()
 721 {
 722    size_t s = 1;
 723    unsigned long *size_long = &s;
 724    return (int)*size_long;
 725 }
 726         ],glib_size_type=long)])
 727 fi
 728
 729 AC_MSG_RESULT(unsigned $glib_size_type)
 730
 731 # Check for some functions
 732 AC_CHECK_FUNCS(lstat strerror strsignal memmove mkstemp vsnprintf stpcpy strcasecmp strncasecmp poll getcwd nanosleep vasprintf setenv unsetenv getc_unlocked readlink symlink)
 733
 734 AC_FUNC_VSNPRINTF_C99
 735 AC_FUNC_PRINTF_UNIX98
 736
 737 #
 738 # Check whether to use an included printf
 739 #
 740
 741 AC_ARG_ENABLE(included-printf,
 742               [AC_HELP_STRING([--enable-included-printf],
 743                               [use included printf [default=auto]])],
 744               enable_included_printf="$enableval")
 745
 746 need_included_printf=no
 747 if test "x$enable_included_printf" = "xyes" ; then
 748   need_included_printf=yes
 749 fi
 750 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
 751   need_included_printf=yes
 752 fi
 753 if test "$ac_cv_func_printf_unix98" != "yes" ; then
 754   need_included_printf=yes
 755 fi
 756 if test "x$ac_cv_sizeof_long_long" = "x8" &&
 757    test -z "$glib_cv_long_long_format" ; then
 758   need_included_printf=yes
 759 fi
 760
 761 if test "x$enable_included_printf" = "xno" &&
 762    test "x$need_included_printf" = "xyes" ; then
 763   AC_MSG_ERROR([
 764 *** Your C library's printf doesn't appear to have the features that
 765 *** GLib needs, but you specified --enable-included-printf=no.])
 766 fi
 767
 768 enable_included_printf=$need_included_printf
 769
 770 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
 771 if test "$enable_included_printf" != "yes" ; then
 772   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
 773 else
 774   glib_cv_long_long_format="ll"
 775   AC_DEFINE(HAVE_VASPRINTF,1)
 776   AC_DEFINE(HAVE_C99_VSNPRINTF,1)
 777   AC_DEFINE(HAVE_C99_SNPRINTF,1)
 778   AC_DEFINE(HAVE_UNIX98_PRINTF,1)
 779 fi
 780
 781 # Checks needed for gnulib vasnprintf
 782 bh_C_SIGNED
 783 jm_AC_TYPE_LONG_LONG
 784 gt_TYPE_LONGDOUBLE
 785 gt_TYPE_WCHAR_T
 786 gt_TYPE_WINT_T
 787 AC_TYPE_SIZE_T
 788 AC_CHECK_TYPES(ptrdiff_t)
 789 jm_AC_TYPE_INTMAX_T
 790 AC_CHECK_FUNCS(snprintf)
 791 AC_FUNC_SNPRINTF_C99
 792
 793 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
 794 # The check is borrowed from the PERL Configure script.
 795 if test "$ac_cv_func_memmove" != "yes"; then
 796   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
 797     glib_cv_working_bcopy,[AC_TRY_RUN([
 798       int main() {
 799         char buf[128], abc[128], *b;
 800         int len, off, align;
 801         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
 802         for (align = 7; align >= 0; align--) {
 803           for (len = 36; len; len--) {
 804             b = buf+align; bcopy(abc, b, len);
 805             for (off = 1; off <= len; off++) {
 806               bcopy(b, b+off, len); bcopy(b+off, b, len);
 807                 if (bcmp(b, abc, len)) return(1);
 808             }
 809           }
 810         }
 811         return(0);
 812       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
 813
 814   GLIB_ASSERT_SET(glib_cv_working_bcopy)
 815   if test "$glib_cv_working_bcopy" = "yes"; then
 816     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
 817   fi
 818 fi
 819
 820 # Check for sys_errlist
 821 AC_MSG_CHECKING(for sys_errlist)
 822 AC_TRY_LINK(, [
 823 extern char *sys_errlist[];
 824 extern int sys_nerr;
 825 sys_errlist[sys_nerr-1][0] = 0;
 826 ], glib_ok=yes, glib_ok=no)
 827 AC_MSG_RESULT($glib_ok)
 828 if test "$glib_ok" = "no"; then
 829     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
 830 fi
 831
 832 # Check for sys_siglist
 833 AC_MSG_CHECKING(for sys_siglist)
 834 AC_TRY_LINK(, [
 835 extern char *sys_siglist[];
 836 exit (sys_siglist[0]);
 837 ], glib_ok=yes, glib_ok=no)
 838 AC_MSG_RESULT($glib_ok)
 839 if test "$glib_ok" = "no"; then
 840     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
 841 fi
 842
 843 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
 844 AC_MSG_CHECKING(for sys_siglist declaration)
 845 AC_TRY_COMPILE([#include <signal.h>], [
 846 strlen (sys_siglist[0]);
 847 ], glib_ok=yes, glib_ok=no)
 848 AC_MSG_RESULT($glib_ok)
 849 if test "$glib_ok" = "no"; then
 850     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
 851 fi
 852
 853 # Check if <sys/select.h> needs to be included for fd_set
 854 AC_MSG_CHECKING([for fd_set])
 855 AC_TRY_COMPILE([#include <sys/types.h>],
 856         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 857 if test "$gtk_ok" = "yes"; then
 858     AC_MSG_RESULT([yes, found in sys/types.h])
 859 else
 860     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
 861     if test "$gtk_ok" = "yes"; then
 862         # *** FIXME: give it a different name
 863         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
 864         AC_MSG_RESULT([yes, found in sys/select.h])
 865     else
 866         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
 867         AC_MSG_RESULT(no)
 868     fi
 869 fi
 870
 871 dnl *** check for sane realloc() ***
 872 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
 873         AC_TRY_RUN([#include <stdlib.h>
 874         int main() {
 875           return realloc (0, sizeof (int)) == 0;
 876         }],
 877         [glib_cv_sane_realloc=yes],
 878         [glib_cv_sane_realloc=no],
 879         [glib_cv_sane_realloc=yes])
 880 ])
 881 if test x$glib_cv_sane_realloc = xyes; then
 882   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
 883 fi
 884
 885 dnl Check for nl_langinfo and CODESET
 886
 887 AC_MSG_CHECKING([for nl_langinfo (CODESET)])
 888 AC_TRY_COMPILE([#include <langinfo.h>],
 889         [char *codeset = nl_langinfo (CODESET);],
 890    AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
 891    have_codeset=yes,
 892    have_codeset=no)
 893 AC_MSG_RESULT($have_codeset)
 894
 895
 896 dnl ****************************************
 897 dnl *** strlcpy/strlcat                  ***
 898 dnl ****************************************
 899 # Check for strlcpy
 900 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
 901 AC_TRY_RUN([#include <stdlib.h>
 902 #include <string.h>
 903 int main() {
 904   char p[10];
 905   (void) strlcpy (p, "hi", 10);
 906   if (strlcat (p, "bye", 0) != 3)
 907     return 1;
 908   return 0;
 909 }], glib_cv_have_strlcpy=yes,
 910     glib_cv_have_strlcpy=no,
 911     glib_cv_have_strlcpy=no)])
 912 if test "$glib_cv_have_strlcpy" = "yes"; then
 913     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
 914 fi
 915
 916
 917 dnl **********************
 918 dnl *** va_copy checks ***
 919 dnl **********************
 920 dnl we currently check for all three va_copy possibilities, so we get
 921 dnl all results in config.log for bug reports.
 922 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
 923         AC_LINK_IFELSE([#include <stdarg.h>
 924         void f (int i, ...) {
 925         va_list args1, args2;
 926         va_start (args1, i);
 927         va_copy (args2, args1);
 928         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 929           exit (1);
 930         va_end (args1); va_end (args2);
 931         }
 932         int main() {
 933           f (0, 42);
 934           return 0;
 935         }],
 936         [glib_cv_va_copy=yes],
 937         [glib_cv_va_copy=no])
 938 ])
 939 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
 940         AC_LINK_IFELSE([#include <stdarg.h>
 941         void f (int i, ...) {
 942         va_list args1, args2;
 943         va_start (args1, i);
 944         __va_copy (args2, args1);
 945         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 946           exit (1);
 947         va_end (args1); va_end (args2);
 948         }
 949         int main() {
 950           f (0, 42);
 951           return 0;
 952         }],
 953         [glib_cv___va_copy=yes],
 954         [glib_cv___va_copy=no])
 955 ])
 956
 957 if test "x$glib_cv_va_copy" = "xyes"; then
 958   g_va_copy_func=va_copy
 959 else if test "x$glib_cv___va_copy" = "xyes"; then
 960   g_va_copy_func=__va_copy
 961 fi
 962 fi
 963
 964 if test -n "$g_va_copy_func"; then
 965   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
 966 fi
 967
 968 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
 969         AC_TRY_RUN([#include <stdarg.h>
 970         void f (int i, ...) {
 971         va_list args1, args2;
 972         va_start (args1, i);
 973         args2 = args1;
 974         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 975           exit (1);
 976         va_end (args1); va_end (args2);
 977         }
 978         int main() {
 979           f (0, 42);
 980           return 0;
 981         }],
 982         [glib_cv_va_val_copy=yes],
 983         [glib_cv_va_val_copy=no],
 984         [glib_cv_va_val_copy=yes])
 985 ])
 986
 987 if test "x$glib_cv_va_val_copy" = "xno"; then
 988   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 989 fi
 990
 991 dnl ***********************
 992 dnl *** g_module checks ***
 993 dnl ***********************
 994 G_MODULE_LIBS=
 995 G_MODULE_LIBS_EXTRA=
 996 G_MODULE_PLUGIN_LIBS=
 997 if test x"$glib_native_win32" = xyes; then
 998   dnl No use for this on Win32
 999   G_MODULE_LDFLAGS=
1000 else
1001   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1002 fi
1003 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1004 G_MODULE_NEED_USCORE=0
1005 G_MODULE_BROKEN_RTLD_GLOBAL=0
1006 G_MODULE_HAVE_DLERROR=0
1007 dnl *** force native WIN32 shared lib loader
1008 if test -z "$G_MODULE_IMPL"; then
1009   case "$host" in
1010   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1011   esac
1012 fi
1013 dnl *** dlopen() and dlsym() in system libraries
1014 if test -z "$G_MODULE_IMPL"; then
1015         AC_CHECK_FUNC(dlopen,
1016                       [AC_CHECK_FUNC(dlsym,
1017                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1018                       [])
1019 fi
1020 dnl *** load_image (BeOS)
1021 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1022   AC_CHECK_LIB(root, load_image,
1023       [G_MODULE_LIBS="-lbe -lroot -lglib"
1024       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1025       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1026       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1027       [])
1028 fi
1029 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1030 if test -z "$G_MODULE_IMPL"; then
1031         AC_CHECK_FUNC(NSLinkModule,
1032                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1033                        G_MODULE_NEED_USCORE=1],
1034                       [])
1035 fi
1036 dnl *** dlopen() and dlsym() in libdl
1037 if test -z "$G_MODULE_IMPL"; then
1038         AC_CHECK_LIB(dl, dlopen,
1039                      [AC_CHECK_LIB(dl, dlsym,
1040                                    [G_MODULE_LIBS=-ldl
1041                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1042                      [])
1043 fi
1044 dnl *** shl_load() in libdld (HP-UX)
1045 if test -z "$G_MODULE_IMPL"; then
1046         AC_CHECK_LIB(dld, shl_load,
1047                 [G_MODULE_LIBS=-ldld
1048                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1049                 [])
1050 fi
1051 dnl *** additional checks for G_MODULE_IMPL_DL
1052 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1053         LIBS_orig="$LIBS"
1054         LDFLAGS_orig="$LDFLAGS"
1055         LIBS="$G_MODULE_LIBS $LIBS"
1056         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1057 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1058         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1059                 glib_cv_rtldglobal_broken,[
1060                 AC_TRY_RUN([
1061 #include <dlfcn.h>
1062 #ifndef RTLD_GLOBAL
1063 #  define RTLD_GLOBAL 0
1064 #endif
1065 #ifndef RTLD_LAZY
1066 #  define RTLD_LAZY 0
1067 #endif
1068 int pthread_create;
1069 int main () {
1070     void *handle, *global, *local;
1071     global = &pthread_create;
1072     handle = dlopen ("libpthread.so", RTLD_GLOBAL | RTLD_LAZY);
1073     if (!handle) return 0;
1074     local = dlsym (handle, "pthread_create");
1075     return global == local;
1076 }                       ],
1077                         [glib_cv_rtldglobal_broken=no],
1078                         [glib_cv_rtldglobal_broken=yes],
1079                         [glib_cv_rtldglobal_broken=no])
1080                 rm -f plugin.c plugin.o plugin.lo
1081         ])
1082         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1083                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1084         else
1085                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1086         fi
1087 dnl *** check whether we need preceeding underscores
1088         AC_CACHE_CHECK([for preceeding underscore in symbols],
1089                 glib_cv_uscore,[
1090                 AC_TRY_RUN([#include <dlfcn.h>
1091                 int glib_underscore_test (void) { return 42; }
1092                 int main() {
1093                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1094                   handle = dlopen ((void*)0, 0);
1095                   if (handle) {
1096                     f1 = dlsym (handle, "glib_underscore_test");
1097                     f2 = dlsym (handle, "_glib_underscore_test");
1098                   } return (!f2 || f1);
1099                 }],
1100                         [glib_cv_uscore=yes],
1101                         [glib_cv_uscore=no],
1102                         [])
1103                 rm -f plugin.c plugin.$ac_objext plugin.lo
1104         ])
1105         GLIB_ASSERT_SET(glib_cv_uscore)
1106         if test "x$glib_cv_uscore" = "xyes"; then
1107                 G_MODULE_NEED_USCORE=1
1108         else
1109                 G_MODULE_NEED_USCORE=0
1110         fi
1111
1112         LDFLAGS="$LDFLAGS_orig"
1113 dnl *** check for having dlerror()
1114         AC_CHECK_FUNC(dlerror,
1115                 [G_MODULE_HAVE_DLERROR=1],
1116                 [G_MODULE_HAVE_DLERROR=0])
1117         LIBS="$LIBS_orig"
1118 fi
1119 dnl *** done, have we got an implementation?
1120 if test -z "$G_MODULE_IMPL"; then
1121         G_MODULE_IMPL=0
1122         G_MODULE_SUPPORTED=false
1123 else
1124         G_MODULE_SUPPORTED=true
1125 fi
1126
1127 AC_MSG_CHECKING(for the suffix of shared libraries)
1128 case "$host_os" in
1129   hpux9* | hpux10* | hpux11*)  # taken from ltconfig
1130     glib_gmodule_suffix='sl'
1131     ;;
1132   cygwin* | mingw*)
1133     glib_gmodule_suffix='dll'
1134     ;;
1135   *)
1136     glib_gmodule_suffix='so'
1137     ;;
1138 esac
1139 AC_MSG_RESULT(.$glib_gmodule_suffix)
1140
1141 AC_SUBST(G_MODULE_SUPPORTED)
1142 AC_SUBST(G_MODULE_IMPL)
1143 AC_SUBST(G_MODULE_LIBS)
1144 AC_SUBST(G_MODULE_LIBS_EXTRA)
1145 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1146 AC_SUBST(G_MODULE_LDFLAGS)
1147 AC_SUBST(G_MODULE_HAVE_DLERROR)
1148 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1149 AC_SUBST(G_MODULE_NEED_USCORE)
1150 AC_SUBST(GLIB_DEBUG_FLAGS)
1151
1152 dnl **********************
1153 dnl *** g_spawn checks ***
1154 dnl **********************
1155
1156 AC_MSG_CHECKING(for gspawn implementation)
1157 case "$host" in
1158   *-*-mingw*)
1159     GSPAWN=gspawn-win32.lo
1160     ;;
1161   *)
1162     GSPAWN=gspawn.lo
1163     ;;
1164 esac
1165 AC_MSG_RESULT($GSPAWN)
1166 AC_SUBST(GSPAWN)
1167
1168 dnl *************************
1169 dnl *** GIOChannel checks ***
1170 dnl *************************
1171
1172 AC_MSG_CHECKING(for GIOChannel implementation)
1173 case "$host" in
1174   *-*-mingw*)
1175     GIO=giowin32.lo
1176     ;;
1177   *)
1178     GIO=giounix.lo
1179     ;;
1180 esac
1181 AC_MSG_RESULT($GIO)
1182 AC_SUBST(GIO)
1183
1184 dnl check for cpu to enable double checked locking when possible
1185 dnl ************************************************************
1186
1187 if test x"$have_threads" != xno; then
1188         AC_MSG_CHECKING(whether double checked locking is safe)
1189         # According to glibc/linuxthreads the following platforms do
1190         # not have the notion of a read or write memory barrier and
1191         # therefore the double checked locking should be safe. Have a
1192         # look at pthread_once in glibc/linuxthreads/mutex.c to see,
1193         # what this means.
1194         case $host_cpu in
1195                 arm|hppa|i386|i686|ia64|m68k|sh|cris|x86_64)
1196                         g_use_double_checked_locking=yes
1197                 ;;
1198                 *)
1199                         g_use_double_checked_locking=no
1200                 ;;
1201         esac
1202         AC_MSG_RESULT($g_use_double_checked_locking)
1203 fi
1204
1205 dnl ****************************************
1206 dnl *** platform dependent source checks ***
1207 dnl ****************************************
1208
1209 AC_MSG_CHECKING(for platform-dependent source)
1210 case "$host" in
1211   *-*-cygwin*|*-*-mingw*)
1212     PLATFORMDEP=gwin32.lo
1213     ;;
1214   *)
1215     PLATFORMDEP=
1216     ;;
1217 esac
1218 AC_MSG_RESULT($PLATFORMDEP)
1219 AC_SUBST(PLATFORMDEP)
1220
1221 AC_MSG_CHECKING([whether to compile timeloop])
1222 case "$host" in
1223   *-*-cygwin*|*-*-mingw*)
1224     enable_timeloop=no
1225     ;;
1226   *)
1227     enable_timeloop=yes
1228     ;;
1229 esac
1230 AC_MSG_RESULT($enable_timeloop)
1231 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1232
1233 AC_MSG_CHECKING([if building for some Win32 platform])
1234 case "$host" in
1235   *-*-mingw*|*-*-cygwin*)
1236     platform_win32=yes
1237     ;;
1238   *)
1239     platform_win32=no
1240     ;;
1241 esac
1242 AC_MSG_RESULT($platform_win32)
1243 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1244
1245 dnl ***********************
1246 dnl *** g_thread checks ***
1247 dnl ***********************
1248
1249 AC_ARG_WITH(threads,
1250            [AC_HELP_STRING([--with-threads=@<:@none/posix/dce/solaris/win32@:>@],
1251                            [specify a thread implementation to use])],
1252            [if test "x$with_threads" = x; then
1253                 want_threads=yes
1254             else
1255                 want_threads=$with_threads
1256             fi],
1257            [want_threads=yes])
1258 if test "x$enable_threads" = "xno"; then
1259         want_threads=no
1260 fi
1261
1262 dnl error and warning message
1263 dnl *************************
1264
1265 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1266                 computer. GLib will not have a default thread implementation."
1267
1268 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1269                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1270                 compilation now, but then your programs might not work.
1271                 Please provide information on how it is done on your system."
1272
1273 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1274                 "
1275
1276 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1277                 provide information on your thread implementation.
1278                 You can also run 'configure --disable-threads'
1279                 to compile without thread support."
1280
1281 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1282                 functions will not be MT-safe during their first call because
1283                 there is no working 'getpwuid_r' on your system."
1284
1285 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1286                 because there is no 'localtime_r' on your system."
1287
1288 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1289                 crude surrogate will be used. If you happen to know a
1290                 yield function for your system, please inform the GLib
1291                 developers."
1292
1293 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1294                 threads on your system. Thus threads can only have the default
1295                 priority. If you happen to know these main/max
1296                 priorities, please inform the GLib developers."
1297
1298 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1299                 linking threaded applications. As GLib cannot do that
1300                 automatically, you will get an linkg error everytime you are
1301                 not using the right compiler. In that case you have to relink
1302                 with the right compiler. Ususally just '_r' is appended
1303                 to the compiler name."
1304
1305 dnl determination of thread implementation
1306 dnl ***************************************
1307
1308 # have_threads=no   means no thread support
1309 # have_threads=none means no default thread implementation
1310
1311 have_threads=no
1312 if test "x$want_threads" = xyes || test "x$want_threads" = xsolaris; then
1313         case $host in
1314                 *-*-solaris*)
1315                 AC_CHECK_LIB(thread, cond_init, have_threads=solaris)
1316                 ;;
1317         esac
1318 fi
1319 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1320                                 || test "x$want_threads" = xdce; then
1321         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1322         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1323         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1324         glib_save_CPPFLAGS="$CPPFLAGS"
1325         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1326         if test "x$have_threads" = xno; then
1327                 AC_TRY_COMPILE([#include <pthread.h>],
1328                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1329                         have_threads=posix)
1330         fi
1331         if test "x$have_threads" = xno; then
1332                 AC_TRY_COMPILE([#include <pthread.h>],
1333                         [pthread_mutex_t m;
1334                          pthread_mutex_init (&m, pthread_mutexattr_default);],
1335                         have_threads=dce)
1336         fi
1337         # Tru64Unix requires -pthread to find pthread.h. See #103020
1338         CPPFLAGS="$CPPFLAGS -pthread"
1339         if test "x$have_threads" = xno; then
1340         AC_TRY_COMPILE([#include <pthread.h>],
1341                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1342                        have_threads=posix)
1343         fi
1344         CPPFLAGS="$glib_save_CPPFLAGS"
1345 fi
1346 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1347         case $host in
1348                 *-*-mingw*)
1349                 have_threads=win32
1350                 ;;
1351         esac
1352 fi
1353 if test "x$want_threads" = xnone; then
1354         have_threads=none
1355 fi
1356
1357 AC_MSG_CHECKING(for thread implementation)
1358
1359 if test "x$have_threads" = xno && test "x$want_threads" != xno; then
1360         AC_MSG_RESULT(none available)
1361         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
1362 else
1363         AC_MSG_RESULT($have_threads)
1364 fi
1365
1366
1367 dnl determination of G_THREAD_CFLAGS
1368 dnl ********************************
1369
1370 G_THREAD_LIBS=
1371 G_THREAD_LIBS_EXTRA=
1372 G_THREAD_CFLAGS=
1373
1374 dnl
1375 dnl Test program for basic POSIX threads functionality
1376 dnl
1377 m4_define([glib_thread_test],[
1378 #include <pthread.h>
1379 int check_me = 0;
1380 void* func(void* data) {check_me = 42; return &check_me;}
1381 int main()
1382  { pthread_t t;
1383    void *ret;
1384    pthread_create (&t, $1, func, 0);
1385    pthread_join (t, &ret);
1386    exit (check_me != 42 || ret != &check_me);
1387 }])
1388
1389 dnl
1390 dnl Test program for sched_get_priority_min()
1391 dnl
1392 m4_define([glib_sched_priority_test],[
1393 #include <sched.h>
1394 #include <errno.h>
1395 int main() {
1396     errno = 0;
1397     return sched_get_priority_min(SCHED_OTHER)==-1
1398            && errno != 0;
1399 }])
1400
1401 if test x"$have_threads" != xno; then
1402
1403   if test x"$have_threads" = xposix; then
1404     # First we test for posix, whether -pthread or -pthreads do the trick as
1405     # both CPPFLAG and LIBS.
1406     # One of them does for most gcc versions and some other platforms/compilers
1407     # too and could be considered as the canonical way to go.
1408     for flag in pthread pthreads; do
1409       glib_save_CFLAGS="$CFLAGS"
1410       CFLAGS="$CFLAGS -$flag"
1411       AC_TRY_RUN(glib_thread_test(0),
1412                  glib_flag_works=yes,
1413                  glib_flag_works=no,
1414                  [AC_LINK_IFELSE(glib_thread_test(0),
1415                                  glib_flag_works=yes,
1416                                  glib_flag_works=no)])
1417       CFLAGS="$glib_save_CFLAGS"
1418       if test $glib_flag_works = yes ; then
1419          G_THREAD_CFLAGS=-$flag
1420          G_THREAD_LIBS=-$flag
1421       fi
1422     done
1423   fi
1424
1425   if test x"$G_THREAD_CFLAGS" = x; then
1426
1427     # The canonical -pthread[s] does not work. Try something different.
1428
1429     case $host in
1430         *-aix*)
1431                 if test x"$GCC" = xyes; then
1432                         # GCC 3.0 and above needs -pthread.
1433                         # Should be coverd by the case above.
1434                         # GCC 2.x and below needs -mthreads
1435                         G_THREAD_CFLAGS="-mthreads"
1436                         G_THREAD_LIBS=$G_THREAD_CFLAGS
1437                 else
1438                         # We are probably using the aix compiler. Normaly a
1439                         # program would have to be compiled with the _r variant
1440                         # of the corresponding compiler, but we as GLib cannot
1441                         # do that: but the good news is that for compiling the
1442                         # only difference is the added -D_THREAD_SAFE compile
1443                         # option. This is according to the "C for AIX User's
1444                         # Guide".
1445                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
1446                 fi
1447                 ;;
1448         *-dg-dgux*)  # DG/UX
1449                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
1450                 ;;
1451         *-osf*)
1452                 # So we are using dce threads. posix threads are already
1453                 # catched above.
1454                 G_THREAD_CFLAGS="-threads"
1455                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1456                 ;;
1457         *-solaris*)
1458                 if test x"$GCC" = xyes; then
1459                    # We are using solaris threads. posix threads are
1460                    # already catched above.
1461                         G_THREAD_CFLAGS="-threads"
1462                 else
1463                         G_THREAD_CFLAGS="-mt"
1464                 fi
1465                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1466                 ;;
1467         *-sysv5uw7*) # UnixWare 7
1468                 # We are not using gcc with -pthread. Catched above.
1469                 G_THREAD_CFLAGS="-Kthread"
1470                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1471                 ;;
1472         *)
1473                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
1474                 ;;
1475     esac
1476
1477   fi
1478
1479     # if we are not finding the localtime_r function, then we probably are
1480     # not using the proper multithread flag
1481
1482     glib_save_CPPFLAGS="$CPPFLAGS"
1483     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1484
1485     # First we test, whether localtime_r is declared in time.h
1486     # directly. Then we test whether a macro localtime_r exists, in
1487     # which case localtime_r in the test program is replaced and thus
1488     # if we still find localtime_r in the output, it is not defined as
1489     # a macro.
1490
1491     AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
1492       [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
1493                                                            localtime_r(a,b)],
1494                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
1495
1496     CPPFLAGS="$glib_save_CPPFLAGS"
1497
1498     AC_MSG_CHECKING(thread related cflags)
1499     AC_MSG_RESULT($G_THREAD_CFLAGS)
1500     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1501 fi
1502
1503 dnl determination of G_THREAD_LIBS
1504 dnl ******************************
1505
1506 mutex_has_default=no
1507 case $have_threads in
1508         posix|dce)
1509           glib_save_CPPFLAGS="$CPPFLAGS"
1510           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1511           if test x"$G_THREAD_LIBS" = x; then
1512             case $host in
1513               *-aix*)
1514                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
1515                 # probably using the aix compiler.
1516                 AC_MSG_WARN($AIX_COMPILE_INFO)
1517                 ;;
1518               *)
1519                 G_THREAD_LIBS=error
1520                 glib_save_LIBS="$LIBS"
1521                 for thread_lib in "" pthread pthread32 pthreads thread dce; do
1522                         if test x"$thread_lib" = x; then
1523                                 add_thread_lib=""
1524                                 IN=""
1525                         else
1526                                 add_thread_lib="-l$thread_lib"
1527                                 IN=" in -l$thread_lib"
1528                         fi
1529                         if test x"$have_threads" = xposix; then
1530                                 defattr=0
1531                         else
1532                                 defattr=pthread_attr_default
1533                         fi
1534
1535                         LIBS="$add_thread_lib $glib_save_LIBS"
1536
1537                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
1538                         AC_TRY_RUN(glib_thread_test($defattr),
1539                                    glib_result=yes,
1540                                    glib_result=no,
1541                                    [AC_LINK_IFELSE(glib_thread_test($defattr),
1542                                                    glib_result=yes,
1543                                                    glib_result=no)])
1544                         AC_MSG_RESULT($glib_result)
1545
1546                         if test "$glib_result" = "yes" ; then
1547                           G_THREAD_LIBS="$add_thread_lib"
1548                           break
1549                         fi
1550                 done
1551                 if test "x$G_THREAD_LIBS" = xerror; then
1552                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1553                 fi
1554                 LIBS="$glib_save_LIBS"
1555                 ;;
1556             esac
1557           fi
1558
1559           glib_save_LIBS="$LIBS"
1560           for thread_lib in "" rt rte; do
1561             if test x"$thread_lib" = x; then
1562               add_thread_lib=""
1563               IN=""
1564             else
1565               add_thread_lib="-l$thread_lib"
1566               IN=" in -l$thread_lib"
1567             fi
1568             LIBS="$add_thread_lib $glib_save_LIBS"
1569
1570             AC_MSG_CHECKING(for sched_get_priority_min$IN)
1571             AC_TRY_RUN(glib_sched_priority_test,
1572                        glib_result=yes,
1573                        glib_result=no,
1574                        [AC_LINK_IFELSE(glib_sched_priority_test,
1575                                        glib_result=yes,
1576                                        glib_result=no)])
1577             AC_MSG_RESULT($glib_result)
1578
1579             if test "$glib_result" = "yes" ; then
1580                G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
1581                posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
1582                posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
1583                break
1584             fi
1585           done
1586           LIBS="$glib_save_LIBS"
1587           mutex_has_default=yes
1588           mutex_default_type='pthread_mutex_t'
1589           mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
1590           mutex_header_file='pthread.h'
1591           if test "x$have_threads" = "xposix"; then
1592             g_threads_impl="POSIX"
1593           else
1594             g_threads_impl="DCE"
1595             have_threads="posix"
1596           fi
1597           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
1598           CPPFLAGS="$glib_save_CPPFLAGS"
1599           ;;
1600         solaris)
1601            mutex_has_default=yes
1602            mutex_default_type='mutex_t'
1603            mutex_default_init="DEFAULTMUTEX"
1604            mutex_header_file='thread.h'
1605            g_threads_impl="SOLARIS"
1606            ;;
1607         win32)
1608            g_threads_impl="WIN32"
1609            ;;
1610         none|no)
1611            g_threads_impl="NONE"
1612            ;;
1613         *)
1614            g_threads_impl="NONE"
1615            G_THREAD_LIBS=error
1616            ;;
1617 esac
1618
1619 if test "x$G_THREAD_LIBS" = xerror; then
1620         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1621 fi
1622
1623 case $host in
1624   *-*-beos*)
1625     G_THREAD_LIBS="-lbe -lroot -lglib "
1626     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1627     ;;
1628   *)
1629     ;;
1630 esac
1631
1632 AC_MSG_CHECKING(thread related libraries)
1633 AC_MSG_RESULT($G_THREAD_LIBS)
1634
1635 dnl check for mt safe function variants and some posix functions
1636 dnl ************************************************************
1637
1638 if test x"$have_threads" != xno; then
1639         glib_save_LIBS="$LIBS"
1640         # we are not doing the following for now, as this might require glib
1641         # to always be linked with the thread libs on some platforms.
1642         # LIBS="$LIBS $G_THREAD_LIBS"
1643         AC_CHECK_FUNCS(localtime_r)
1644         if test "$ac_cv_header_pwd_h" = "yes"; then
1645                 AC_CACHE_CHECK([for posix getpwuid_r],
1646                         ac_cv_func_posix_getpwuid_r,
1647                         [AC_TRY_RUN([
1648 #include <errno.h>
1649 #include <pwd.h>
1650 int main () {
1651     char buffer[10000];
1652     struct passwd pwd, *pwptr = &pwd;
1653     int error;
1654     errno = 0;
1655     error = getpwuid_r (0, &pwd, buffer,
1656                         sizeof (buffer), &pwptr);
1657    return (error < 0 && errno == ENOSYS)
1658            || error == ENOSYS;
1659 }                               ],
1660                                 [ac_cv_func_posix_getpwuid_r=yes],
1661                                 [ac_cv_func_posix_getpwuid_r=no])])
1662                 GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
1663                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
1664                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
1665                                 [Have POSIX function getpwuid_r])
1666                 else
1667                         AC_CACHE_CHECK([for nonposix getpwuid_r],
1668                                 ac_cv_func_nonposix_getpwuid_r,
1669                                 [AC_TRY_LINK([#include <pwd.h>],
1670                                         [char buffer[10000];
1671                                         struct passwd pwd;
1672                                         getpwuid_r (0, &pwd, buffer,
1673                                                         sizeof (buffer));],
1674                                         [ac_cv_func_nonposix_getpwuid_r=yes],
1675                                         [ac_cv_func_nonposix_getpwuid_r=no])])
1676                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
1677                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
1678                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
1679                                         [Have non-POSIX function getpwuid_r])
1680                         fi
1681                 fi
1682         fi
1683         LIBS="$G_THREAD_LIBS $LIBS"
1684         if test x"$have_threads" = xposix; then
1685                 glib_save_CPPFLAGS="$CPPFLAGS"
1686                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1687                 dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
1688                 GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
1689                 # This is not AC_CHECK_FUNC to also work with function
1690                 # name mangling in header files.
1691                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
1692                 AC_TRY_LINK([#include <pthread.h>],
1693                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
1694                         [AC_MSG_RESULT(yes)
1695                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
1696                                   [Have function pthread_attr_setstacksize])],
1697                         [AC_MSG_RESULT(no)])
1698                 AC_MSG_CHECKING(for minimal/maximal thread priority)
1699                 if test x"$posix_priority_min" = x; then
1700                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
1701                                 PX_PRIO_MIN],,[
1702                                 posix_priority_min=PX_PRIO_MIN
1703                                 posix_priority_max=PX_PRIO_MAX])
1704                 fi
1705                 if test x"$posix_priority_min" = x; then
1706                         # AIX
1707                         AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
1708                                 PTHREAD_PRIO_MIN],,[
1709                                 posix_priority_min=PTHREAD_PRIO_MIN
1710                                 posix_priority_max=PTHREAD_PRIO_MAX])
1711                 fi
1712                 if test x"$posix_priority_min" = x; then
1713                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
1714                                 PRI_OTHER_MIN],,[
1715                                 posix_priority_min=PRI_OTHER_MIN
1716                                 posix_priority_max=PRI_OTHER_MAX])
1717                 fi
1718                 if test x"$posix_priority_min" = x; then
1719                         AC_MSG_RESULT(none found)
1720                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
1721                         posix_priority_min=-1
1722                         posix_priority_max=-1
1723                 else
1724                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
1725                         AC_MSG_CHECKING(for pthread_setschedparam)
1726                         AC_TRY_LINK([#include <pthread.h>],
1727                           [pthread_t t; pthread_setschedparam(t, 0, NULL)],
1728                           [AC_MSG_RESULT(yes)
1729                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
1730                            AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
1731                           [AC_MSG_RESULT(no)
1732                            AC_MSG_WARN($POSIX_NO_PRIORITIES)])
1733                 fi
1734                 posix_yield_func=none
1735                 AC_MSG_CHECKING(for posix yield function)
1736                 for yield_func in sched_yield pthread_yield_np pthread_yield \
1737                                                         thr_yield; do
1738                         AC_TRY_LINK([#include <pthread.h>],
1739                                 [$yield_func()],
1740                                 [posix_yield_func="$yield_func"
1741                                 break])
1742                 done
1743                 if test x"$posix_yield_func" = xnone; then
1744                         AC_MSG_RESULT(none found)
1745                         AC_MSG_WARN($POSIX_NO_YIELD)
1746                         posix_yield_func="g_usleep(1000)"
1747                 else
1748                         AC_MSG_RESULT($posix_yield_func)
1749                         posix_yield_func="$posix_yield_func()"
1750                 fi
1751                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
1752                 CPPFLAGS="$glib_save_CPPFLAGS"
1753
1754                 AC_CACHE_CHECK([whether to use the PID niceness surrogate for thread priorities],
1755                                glib_cv_use_pid_surrogate,
1756                  [AC_TRY_RUN([
1757 #include <pthread.h>
1758 #include <sys/types.h>
1759 #include <unistd.h>
1760 pid_t other_pid = 0;
1761
1762 void* func(void* data) {other_pid = getpid();}
1763 main()
1764 { pthread_t t;
1765   void *ret;
1766   pthread_create (&t, 0, func, NULL);
1767   pthread_join (t, &ret);
1768   exit (getpid()==other_pid ||
1769         $posix_priority_min != $posix_priority_max);
1770 }               ],
1771                 [glib_cv_use_pid_surrogate=yes],
1772                 [glib_cv_use_pid_surrogate=no],
1773                 [])])
1774           GLIB_ASSERT_SET(glib_cv_use_pid_surrogate)
1775           if test "$glib_cv_use_pid_surrogate" = "yes" ; then
1776             AC_DEFINE(G_THREAD_USE_PID_SURROGATE, 1,
1777                       [whether to use the PID niceness surrogate for thread priorities])
1778           fi
1779
1780         elif test x"$have_threads" = xwin32; then
1781                 # It's a pointer to a private struct
1782                 GLIB_SIZEOF(,struct _GThreadData *, system_thread)
1783         elif test x"$have_threads" = xsolaris; then
1784                 GLIB_SIZEOF([#include <thread.h>], thread_t, system_thread)
1785         fi
1786
1787         LIBS="$glib_save_LIBS"
1788
1789         # now spit out all the warnings.
1790         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
1791            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
1792                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
1793         fi
1794         if test "$ac_cv_func_localtime_r" != "yes"; then
1795                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
1796         fi
1797 fi
1798
1799 if test x"$glib_cv_sizeof_system_thread" = x; then
1800    # use a pointer as a fallback.
1801    GLIB_SIZEOF(,void *, system_thread)
1802 fi
1803
1804 #
1805 # Hack to deal with:
1806 #
1807 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
1808 #     building shared libraries with linux.
1809 #  b) libtool doesn't recognize -pthread as a library dependency.
1810 #
1811 case $host in
1812   *-*-linux*)
1813     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
1814     ;;
1815   *)
1816     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-Wc,-pthread/`"
1817     ;;
1818 esac
1819
1820 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
1821                    [Source file containing theread implementation])
1822 AC_SUBST(G_THREAD_CFLAGS)
1823 AC_SUBST(G_THREAD_LIBS)
1824 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
1825 AC_SUBST(G_THREAD_LIBS_EXTRA)
1826
1827 dnl **********************************************
1828 dnl *** GDefaultMutex setup and initialization ***
1829 dnl **********************************************
1830 dnl
1831 dnl if mutex_has_default = yes, we also got
1832 dnl mutex_default_type, mutex_default_init and mutex_header_file
1833 if test $mutex_has_default = yes ; then
1834         glib_save_CPPFLAGS="$CPPFLAGS"
1835         glib_save_LIBS="$LIBS"
1836         LIBS="$G_THREAD_LIBS $LIBS"
1837         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1838         GLIB_SIZEOF([#include <$mutex_header_file>],
1839                     $mutex_default_type,
1840                     gmutex)
1841         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
1842                            $mutex_default_type,
1843                            gmutex,
1844                            $glib_cv_sizeof_gmutex,
1845                            $mutex_default_init)
1846         if test x"$glib_cv_byte_contents_gmutex" = xno; then
1847                 mutex_has_default=no
1848         fi
1849         CPPFLAGS="$glib_save_CPPFLAGS"
1850         LIBS="$glib_save_LIBS"
1851 fi
1852
1853 dnl ****************************************
1854 dnl *** GLib POLL* compatibility defines ***
1855 dnl ****************************************
1856
1857 glib_poll_includes=["
1858 #include <sys/types.h>
1859 #include <sys/poll.h>
1860 "]
1861
1862 if test $ac_cv_header_sys_types_h = yes &&
1863    test $ac_cv_header_sys_poll_h = yes ; then
1864   glib_failed=false
1865   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
1866   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
1867   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
1868   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
1869   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
1870   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
1871   if $glib_failed ; then
1872     AC_MSG_ERROR([Could not determine values for POLL* constants])
1873   fi
1874 else
1875   glib_cv_value_POLLIN=1
1876   glib_cv_value_POLLOUT=4
1877   glib_cv_value_POLLPRI=2
1878   glib_cv_value_POLLERR=8
1879   glib_cv_value_POLLHUP=16
1880   glib_cv_value_POLLNVAL=32
1881 fi
1882
1883 dnl **********************
1884 dnl *** Win32 API libs ***
1885 dnl **********************
1886
1887 case $host in
1888   *-*-cygwin*)
1889         G_LIBS_EXTRA="-luser32 -lkernel32"
1890     ;;
1891   *-*-mingw*)
1892         G_LIBS_EXTRA="-lwsock32"
1893     ;;
1894   *)
1895         G_LIBS_EXTRA=""
1896     ;;
1897 esac
1898 AC_SUBST(G_LIBS_EXTRA)
1899
1900 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
1901 dnl since we need it for g_iconv()
1902
1903 AC_MSG_CHECKING([for EILSEQ])
1904 AC_TRY_COMPILE([
1905 #include <errno.h>
1906 ],
1907 [
1908 int error = EILSEQ;
1909 ], have_eilseq=yes, have_eilseq=no);
1910 AC_MSG_RESULT($have_eilseq)
1911
1912 dnl ******************************************************************
1913 dnl *** Look for glib-genmarshal in PATH if we are cross-compiling ***
1914 dnl ******************************************************************
1915
1916 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
1917
1918 if test $cross_compiling = yes; then
1919   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
1920   if test x$GLIB_GENMARSHAL = xno; then
1921     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
1922   fi
1923 fi
1924
1925 dnl **************************
1926 dnl *** Checks for gtk-doc ***
1927 dnl **************************
1928
1929 GTK_DOC_CHECK([1.0])
1930
1931 AC_ARG_ENABLE(man,
1932               [AC_HELP_STRING([--enable-man],
1933                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
1934               enable_man=no)
1935
1936 dnl
1937 dnl Check for xsltproc
1938 dnl
1939 AC_PATH_PROG([XSLTPROC], [xsltproc])
1940 if test -z "$XSLTPROC"; then
1941   enable_man=no
1942 fi
1943
1944 dnl check for DocBook DTD and stylesheets in the local catalog.
1945 JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1946    [DocBook XML DTD V4.1.2],,enable_man=no)
1947 JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1948    [DocBook XSL Stylesheets],,enable_man=no)
1949 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1950
1951 dnl ******************************
1952 dnl *** output the whole stuff ***
1953 dnl ******************************
1954
1955 dnl this section will only be run if config.status is invoked with no
1956 dnl arguments, or with "glibconfig.h" as an argument.
1957 AC_CONFIG_COMMANDS([glibconfig.h],
1958 [
1959         outfile=glibconfig.h-tmp
1960         cat > $outfile <<\_______EOF
1961 /* glibconfig.h
1962  *
1963  * This is a generated file.  Please modify 'configure.in'
1964  */
1965
1966 #ifndef __G_LIBCONFIG_H__
1967 #define __G_LIBCONFIG_H__
1968
1969 #include <glib/gmacros.h>
1970
1971 _______EOF
1972
1973         if test x$glib_limits_h = xyes; then
1974           echo '#include <limits.h>' >> $outfile
1975         fi
1976         if test x$glib_float_h = xyes; then
1977           echo '#include <float.h>' >> $outfile
1978         fi
1979         if test x$glib_values_h = xyes; then
1980           echo '#include <values.h>' >> $outfile
1981         fi
1982         if test "$glib_header_alloca_h" = "yes"; then
1983           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
1984         fi
1985         if test x$glib_sys_poll_h = xyes; then
1986           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
1987         fi
1988
1989         cat >> $outfile <<_______EOF
1990
1991 G_BEGIN_DECLS
1992
1993 #define G_MINFLOAT      $glib_mf
1994 #define G_MAXFLOAT      $glib_Mf
1995 #define G_MINDOUBLE     $glib_md
1996 #define G_MAXDOUBLE     $glib_Md
1997 #define G_MINSHORT      $glib_ms
1998 #define G_MAXSHORT      $glib_Ms
1999 #define G_MAXUSHORT     $glib_Mus
2000 #define G_MININT        $glib_mi
2001 #define G_MAXINT        $glib_Mi
2002 #define G_MAXUINT       $glib_Mui
2003 #define G_MINLONG       $glib_ml
2004 #define G_MAXLONG       $glib_Ml
2005 #define G_MAXULONG      $glib_Mul
2006
2007 #define G_MININT64      G_GINT64_CONSTANT(0x8000000000000000)
2008 #define G_MAXINT64      G_GINT64_CONSTANT(0x7fffffffffffffff)
2009 #define G_MAXUINT64     G_GINT64_CONSTANT(0xffffffffffffffffU)
2010
2011 _______EOF
2012
2013
2014         ### this should always be true in a modern C/C++ compiler
2015         cat >>$outfile <<_______EOF
2016 typedef signed char gint8;
2017 typedef unsigned char guint8;
2018 _______EOF
2019
2020
2021         if test -n "$gint16"; then
2022           cat >>$outfile <<_______EOF
2023 typedef signed $gint16 gint16;
2024 typedef unsigned $gint16 guint16;
2025 #define G_GINT16_MODIFIER $gint16_modifier
2026 #define G_GINT16_FORMAT $gint16_format
2027 #define G_GUINT16_FORMAT $guint16_format
2028 _______EOF
2029         fi
2030
2031
2032         if test -n "$gint32"; then
2033           cat >>$outfile <<_______EOF
2034 typedef signed $gint32 gint32;
2035 typedef unsigned $gint32 guint32;
2036 #define G_GINT32_MODIFIER $gint32_modifier
2037 #define G_GINT32_FORMAT $gint32_format
2038 #define G_GUINT32_FORMAT $guint32_format
2039 _______EOF
2040         fi
2041
2042         cat >>$outfile <<_______EOF
2043 #define G_HAVE_GINT64 1          /* deprecated, always true */
2044
2045 ${glib_extension}typedef signed $gint64 gint64;
2046 ${glib_extension}typedef unsigned $gint64 guint64;
2047
2048 #define G_GINT64_CONSTANT(val)  $gint64_constant
2049 _______EOF
2050
2051         if test x$gint64_format != x ; then
2052           cat >>$outfile <<_______EOF
2053 #define G_GINT64_MODIFIER $gint64_modifier
2054 #define G_GINT64_FORMAT $gint64_format
2055 #define G_GUINT64_FORMAT $guint64_format
2056 _______EOF
2057         else
2058           cat >>$outfile <<_______EOF
2059 #undef G_GINT64_MODIFIER
2060 #undef G_GINT64_FORMAT
2061 #undef G_GUINT64_FORMAT
2062 _______EOF
2063         fi
2064
2065         cat >>$outfile <<_______EOF
2066
2067 #define GLIB_SIZEOF_VOID_P $glib_void_p
2068 #define GLIB_SIZEOF_LONG   $glib_long
2069 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2070
2071 _______EOF
2072
2073 echo "typedef signed $glib_size_type_define gssize;" >> $outfile
2074 echo "typedef unsigned $glib_size_type_define gsize;" >> $outfile
2075
2076         if test -z "$glib_unknown_void_p"; then
2077           cat >>$outfile <<_______EOF
2078
2079 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2080 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2081
2082 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2083 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2084 _______EOF
2085         else
2086           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2087         fi
2088
2089
2090
2091         cat >>$outfile <<_______EOF
2092 $glib_atexit
2093 $glib_memmove
2094 $glib_defines
2095 $glib_os
2096
2097 $glib_vacopy
2098
2099 #ifdef  __cplusplus
2100 #define G_HAVE_INLINE   1
2101 #else   /* !__cplusplus */
2102 $glib_inline
2103 #endif  /* !__cplusplus */
2104
2105 _______EOF
2106
2107         if test x$g_have_iso_c_varargs = xyes ; then
2108                 cat >>$outfile <<_______EOF
2109 #ifndef __cplusplus
2110 # define G_HAVE_ISO_VARARGS 1
2111 #endif
2112 _______EOF
2113         fi
2114         if test x$g_have_iso_cxx_varargs = xyes ; then
2115                 cat >>$outfile <<_______EOF
2116 #ifdef __cplusplus
2117 # define G_HAVE_ISO_VARARGS 1
2118 #endif
2119 _______EOF
2120         fi
2121         if test x$g_have_gnuc_varargs = xyes ; then
2122                 cat >>$outfile <<_______EOF
2123
2124 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2125  * is passed ISO vararg support is turned off, and there is no work
2126  * around to turn it on, so we unconditionally turn it off.
2127  */
2128 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2129 #  undef G_HAVE_ISO_VARARGS
2130 #endif
2131
2132 #define G_HAVE_GNUC_VARARGS 1
2133 _______EOF
2134         fi
2135
2136         case x$g_stack_grows in
2137         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2138         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2139         esac
2140
2141
2142         echo >>$outfile
2143         if test x$g_have_eilseq = xno; then
2144                 cat >>$outfile <<_______EOF
2145 #ifndef EILSEQ
2146 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
2147  * The correspondence between this and the corresponding definition
2148  * in libiconv is essential.
2149  */
2150 #  define EILSEQ ENOENT
2151 #endif
2152 _______EOF
2153
2154         fi
2155
2156         echo >>$outfile
2157         if test x$g_mutex_has_default = xyes; then
2158                 cat >>$outfile <<_______EOF
2159 $g_enable_threads_def G_THREADS_ENABLED
2160 #define G_THREADS_IMPL_$g_threads_impl_def
2161 typedef struct _GStaticMutex GStaticMutex;
2162 struct _GStaticMutex
2163 {
2164   struct _GMutex *runtime_mutex;
2165   union {
2166     char   pad[[$g_mutex_sizeof]];
2167     double dummy_double;
2168     void  *dummy_pointer;
2169     long   dummy_long;
2170   } static_mutex;
2171 };
2172 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
2173 #define g_static_mutex_get_mutex(mutex) \\
2174   (g_thread_use_default_impl ? ((GMutex*) &((mutex)->static_mutex)) : \\
2175    g_static_mutex_get_mutex_impl_shortcut (&((mutex)->runtime_mutex)))
2176 _______EOF
2177         else
2178                 cat >>$outfile <<_______EOF
2179 $g_enable_threads_def G_THREADS_ENABLED
2180 #define G_THREADS_IMPL_$g_threads_impl_def
2181 typedef struct _GMutex* GStaticMutex;
2182 #define G_STATIC_MUTEX_INIT NULL
2183 #define g_static_mutex_get_mutex(mutex) \\
2184   (g_static_mutex_get_mutex_impl_shortcut (mutex))
2185 _______EOF
2186         fi
2187
2188         if test x$g_use_double_checked_locking = xyes; then
2189                 cat >>$outfile <<_______EOF
2190 /* double checked locking can be used on this platform */
2191 #define g_once(once, func, arg) \\
2192   ((once)->status == G_ONCE_STATUS_READY ? (once)->retval : \\
2193    g_once_impl (once, func, arg));
2194 #define g_static_mutex_get_mutex_impl_shortcut(mutex) \\
2195   (*(mutex) ? *(mutex) : g_static_mutex_get_mutex_impl (mutex))
2196 _______EOF
2197         else
2198                 cat >>$outfile <<_______EOF
2199 /* double checked locking is unsafe to use on this platform, do full locking */
2200 #define g_once(once, func, arg) (g_once_impl(once, func, arg))
2201 #define g_static_mutex_get_mutex_impl_shortcut(mutex) \\
2202   (g_static_mutex_get_mutex_impl (mutex))
2203 _______EOF
2204 fi
2205
2206         cat >>$outfile <<_______EOF
2207 /* This represents a system thread as used by the implementation. An
2208  * alien implementaion, as loaded by g_thread_init can only count on
2209  * "sizeof (gpointer)" bytes to store their info. We however need more
2210  * for some of our native implementations. */
2211 typedef union _GSystemThread GSystemThread;
2212 union _GSystemThread
2213 {
2214   char   data[[$g_system_thread_sizeof]];
2215   double dummy_double;
2216   void  *dummy_pointer;
2217   long   dummy_long;
2218 };
2219 _______EOF
2220
2221         echo >>$outfile
2222         g_bit_sizes="16 32 64"
2223         for bits in $g_bit_sizes; do
2224           cat >>$outfile <<_______EOF
2225 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
2226 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
2227 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
2228 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
2229 _______EOF
2230         done
2231
2232         cat >>$outfile <<_______EOF
2233 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
2234 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
2235 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
2236 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
2237 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
2238 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
2239 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
2240 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
2241 #define G_BYTE_ORDER $g_byte_order
2242
2243 #define GLIB_SYSDEF_POLLIN =$g_pollin
2244 #define GLIB_SYSDEF_POLLOUT =$g_pollout
2245 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
2246 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
2247 #define GLIB_SYSDEF_POLLERR =$g_pollerr
2248 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
2249
2250 #define G_MODULE_SUFFIX "$g_module_suffix"
2251
2252 G_END_DECLS
2253
2254 #endif /* GLIBCONFIG_H */
2255 _______EOF
2256
2257
2258         if cmp -s $outfile glibconfig.h; then
2259           AC_MSG_NOTICE([glibconfig.h is unchanged])
2260           rm -f $outfile
2261         else
2262           mv $outfile glibconfig.h
2263         fi
2264 ],[
2265
2266 # Note that if two cases are the same, case goes with the first one.
2267 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
2268 # on variable expansion in case labels.  Look at the generated config.status
2269 # for a hint.
2270
2271 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
2272   glib_header_alloca_h="$ac_cv_working_alloca_h"
2273 else
2274   glib_header_alloca_h="$ac_cv_header_alloca_h"
2275 fi
2276
2277 case xyes in
2278 x$ac_cv_header_float_h)
2279   glib_float_h=yes
2280   glib_mf=FLT_MIN glib_Mf=FLT_MAX
2281   glib_md=DBL_MIN glib_Md=DBL_MAX
2282   ;;
2283 x$ac_cv_header_values_h)
2284   glib_values_h=yes
2285   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
2286   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
2287   ;;
2288 esac
2289
2290 case xyes in
2291 x$ac_cv_header_limits_h)
2292   glib_limits_h=yes
2293   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
2294   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
2295   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
2296   ;;
2297 x$ac_cv_header_values_h)
2298   glib_values_h=yes
2299   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
2300   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
2301   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
2302   ;;
2303 esac
2304
2305 if test x$ac_cv_header_sys_poll_h = xyes ; then
2306   glib_sys_poll_h=yes
2307 fi
2308
2309 case 2 in
2310 $ac_cv_sizeof_short)
2311   gint16=short
2312   gint16_modifier='"h"'
2313   gint16_format='"hi"'
2314   guint16_format='"hu"'
2315   ;;
2316 $ac_cv_sizeof_int)
2317   gint16=int
2318   gint16_modifier='""'
2319   gint16_format='"i"'
2320   guint16_format='"u"'
2321   ;;
2322 esac
2323 case 4 in
2324 $ac_cv_sizeof_short)
2325   gint32=short
2326   gint32_modifier='"h"'
2327   gint32_format='"hi"'
2328   guint32_format='"hu"'
2329   ;;
2330 $ac_cv_sizeof_int)
2331   gint32=int
2332   gint32_modifier='""'
2333   gint32_format='"i"'
2334   guint32_format='"u"'
2335   ;;
2336 $ac_cv_sizeof_long)
2337   gint32=long
2338   gint32_modifier='"l"'
2339   gint32_format='"li"'
2340   guint32_format='"lu"'
2341   ;;
2342 esac
2343 case 8 in
2344 $ac_cv_sizeof_int)
2345   gint64=int
2346   gint64_modifier='""'
2347   gint64_format='"i"'
2348   guint64_format='"u"'
2349   glib_extension=
2350   gint64_constant='(val)'
2351   ;;
2352 $ac_cv_sizeof_long)
2353   gint64=long
2354   gint64_modifier='"l"'
2355   gint64_format='"li"'
2356   guint64_format='"lu"'
2357   glib_extension=
2358   gint64_constant='(val##L)'
2359   ;;
2360 $ac_cv_sizeof_long_long)
2361   gint64='long long'
2362   if test -n "$glib_cv_long_long_format"; then
2363     gint64_modifier='"'$glib_cv_long_long_format'"'
2364     gint64_format='"'$glib_cv_long_long_format'i"'
2365     guint64_format='"'$glib_cv_long_long_format'u"'
2366   fi
2367   glib_extension='G_GNUC_EXTENSION '
2368   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
2369   ;;
2370 $ac_cv_sizeof___int64)
2371   gint64='__int64'
2372   if test -n "$glib_cv_long_long_format"; then
2373     gint64_modifier='"'$glib_cv_long_long_format'"'
2374     gint64_format='"'$glib_cv_long_long_format'i"'
2375     guint64_format='"'$glib_cv_long_long_format'u"'
2376   fi
2377   glib_extension=
2378   gint64_constant='(val##i64)'
2379   ;;
2380 esac
2381 glib_size_t=$ac_cv_sizeof_size_t
2382 glib_size_type_define=$glib_size_type
2383 glib_void_p=$ac_cv_sizeof_long
2384 glib_long=$ac_cv_sizeof_void_p
2385
2386 gintbits=`expr $ac_cv_sizeof_int \* 8`
2387 glongbits=`expr $ac_cv_sizeof_long \* 8`
2388
2389
2390 case $ac_cv_sizeof_void_p in
2391 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
2392 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
2393 *)                      glib_unknown_void_p=yes ;;
2394 esac
2395
2396
2397 case xyes in
2398 x$ac_cv_func_atexit)
2399   glib_atexit="
2400 #ifdef NeXT /* @#%@! NeXTStep */
2401 # define g_ATEXIT(proc) (!atexit (proc))
2402 #else
2403 # define g_ATEXIT(proc) (atexit (proc))
2404 #endif"
2405   ;;
2406 x$ac_cv_func_on_exit)
2407   glib_atexit="
2408 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
2409   ;;
2410 esac
2411
2412 case xyes in
2413 x$ac_cv_func_memmove)
2414   glib_memmove='
2415 #define g_memmove(d,s,n) G_STMT_START { memmove ((d), (s), (n)); } G_STMT_END'
2416   ;;
2417 x$glib_cv_working_bcopy)
2418   glib_memmove="
2419 /* memmove isn't available, but bcopy can copy overlapping memory regions */
2420 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
2421   ;;
2422 *)
2423   glib_memmove="
2424 /* memmove isn't found and bcopy can't copy overlapping memory regions,
2425  * so we have to roll our own copy routine. */
2426 void g_memmove (void* dest, const void * src, unsigned long len);"
2427   ;;
2428 esac
2429
2430 glib_defines="
2431 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
2432 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
2433 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
2434 "
2435
2436 case xyes in
2437 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
2438 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
2439 *)                      glib_vacopy=''
2440 esac
2441
2442 if test x$glib_cv_va_val_copy = xno; then
2443   glib_vacopy="\$glib_vacopy
2444 #define G_VA_COPY_AS_ARRAY 1"
2445 fi
2446
2447 if test x$glib_cv_hasinline = xyes; then
2448     glib_inline='#define G_HAVE_INLINE 1'
2449 fi
2450 if test x$glib_cv_has__inline = xyes; then
2451     glib_inline="\$glib_inline
2452 #define G_HAVE___INLINE 1"
2453 fi
2454 if test x$glib_cv_has__inline__ = xyes; then
2455     glib_inline="\$glib_inline
2456 #define G_HAVE___INLINE__ 1"
2457 fi
2458
2459 g_have_gnuc_varargs=$g_have_gnuc_varargs
2460 g_have_iso_c_varargs=$g_have_iso_c_varargs
2461 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
2462
2463 case xyes in
2464 x$ac_cv_c_bigendian)
2465   g_byte_order=G_BIG_ENDIAN
2466   g_bs_native=BE
2467   g_bs_alien=LE
2468   ;;
2469 *)
2470   g_byte_order=G_LITTLE_ENDIAN
2471   g_bs_native=LE
2472   g_bs_alien=BE
2473   ;;
2474 esac
2475
2476 g_pollin=$glib_cv_value_POLLIN
2477 g_pollout=$glib_cv_value_POLLOUT
2478 g_pollpri=$glib_cv_value_POLLPRI
2479 g_pollhup=$glib_cv_value_POLLHUP
2480 g_pollerr=$glib_cv_value_POLLERR
2481 g_pollnval=$glib_cv_value_POLLNVAL
2482
2483 g_stack_grows=$glib_cv_stack_grows
2484
2485 g_have_eilseq=$have_eilseq
2486
2487 case x$have_threads in
2488 xno)    g_enable_threads_def="#undef";;
2489 *)      g_enable_threads_def="#define";;
2490 esac
2491
2492 g_threads_impl_def=$g_threads_impl
2493 g_use_double_checked_locking=$g_use_double_checked_locking
2494
2495 g_mutex_has_default="$mutex_has_default"
2496 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
2497 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
2498 g_mutex_contents="$glib_cv_byte_contents_gmutex"
2499
2500 g_module_suffix="$glib_gmodule_suffix"
2501
2502 case $host in
2503   *-*-beos*)
2504     glib_os="#define G_OS_BEOS"
2505     ;;
2506   *-*-cygwin*)
2507     glib_os="#define G_OS_UNIX
2508 #define G_PLATFORM_WIN32
2509 #define G_WITH_CYGWIN"
2510     ;;
2511   *-*-mingw*)
2512     glib_os="#define G_OS_WIN32
2513 #define G_PLATFORM_WIN32"
2514     ;;
2515   *)
2516     glib_os="#define G_OS_UNIX"
2517     ;;
2518 esac
2519 ])
2520
2521 AC_CONFIG_FILES([
2522 glib-2.0.pc
2523 glib-2.0-uninstalled.pc
2524 gmodule-2.0.pc
2525 gmodule-2.0-uninstalled.pc
2526 gthread-2.0.pc
2527 gthread-2.0-uninstalled.pc
2528 gobject-2.0.pc
2529 gobject-2.0-uninstalled.pc
2530 glib-zip
2531 glib-gettextize
2532 Makefile
2533 build/Makefile
2534 build/win32/Makefile
2535 build/win32/dirent/Makefile
2536 glib/Makefile
2537 glib/libcharset/Makefile
2538 glib/gnulib/Makefile
2539 gmodule/Makefile
2540 gmodule/gmoduleconf.h
2541 gobject/Makefile
2542 gobject/glib-mkenums
2543 gthread/Makefile
2544 po/Makefile.in
2545 docs/Makefile
2546 docs/reference/Makefile
2547 docs/reference/glib/Makefile
2548 docs/reference/glib/version.xml
2549 docs/reference/gobject/Makefile
2550 docs/reference/gobject/version.xml
2551 tests/Makefile
2552 tests/gobject/Makefile
2553 m4macros/Makefile
2554 ])
2555
2556 AC_CONFIG_COMMANDS([chmod-scripts],
2557 [chmod 0755 glib-zip
2558 chmod 0755 glib-gettextize
2559 chmod 0755 gobject/glib-mkenums])
2560
2561 # we want to invoke this macro solely so that the config.status script
2562 # and automake generated makefiles know about these generated files.
2563 # They are only needed to distcheck the package
2564 if false; then
2565   AC_CONFIG_FILES([
2566     INSTALL
2567     README
2568     config.h.win32
2569     glibconfig.h.win32
2570     glib/makefile.mingw
2571     glib/makefile.msc
2572     glib/glib.rc
2573     gmodule/makefile.mingw
2574     gmodule/makefile.msc
2575     gmodule/gmodule.rc
2576     gobject/makefile.mingw
2577     gobject/makefile.msc
2578     gobject/gobject.rc
2579     gthread/makefile.mingw
2580     gthread/makefile.msc
2581     gthread/gthread.rc
2582     tests/makefile.mingw
2583     tests/makefile.msc
2584   ])
2585 fi
2586
2587 AC_OUTPUT