configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 AC_INIT(glist.c)
   3
   4 # Save this value here, since automake will set cflags later
   5 cflags_set=${CFLAGS+set}
   6
   7 # The following version number definitions apply to GLib and GModule
   8 # as a whole, so if changes occoured in either of them, they are both
   9 # treated with the same interface and binary age.
  10 #
  11 # Making releases:
  12 #   GLIB_MICRO_VERSION += 1;
  13 #   GLIB_INTERFACE_AGE += 1;
  14 #   GLIB_BINARY_AGE += 1;
  15 # if any functions have been added, set GLIB_INTERFACE_AGE to 0.
  16 # if backwards compatibility has been broken,
  17 # set GLIB_BINARY_AGE and GLIB_INTERFACE_AGE to 0.
  18 #
  19 GLIB_MAJOR_VERSION=1
  20 GLIB_MINOR_VERSION=1
  21 GLIB_MICRO_VERSION=9
  22 GLIB_INTERFACE_AGE=0
  23 GLIB_BINARY_AGE=0
  24 GLIB_VERSION=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION.$GLIB_MICRO_VERSION
  25 AC_SUBST(GLIB_VERSION)
  26
  27 # libtool versioning
  28 LT_RELEASE=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION
  29 LT_CURRENT=`expr $GLIB_MICRO_VERSION - $GLIB_INTERFACE_AGE`
  30 LT_REVISION=$GLIB_INTERFACE_AGE
  31 LT_AGE=`expr $GLIB_BINARY_AGE - $GLIB_INTERFACE_AGE`
  32 AC_SUBST(LT_RELEASE)
  33 AC_SUBST(LT_CURRENT)
  34 AC_SUBST(LT_REVISION)
  35 AC_SUBST(LT_AGE)
  36
  37 VERSION=$GLIB_VERSION
  38 PACKAGE=glib
  39
  40 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  41
  42 # Specify a configuration file
  43 AM_CONFIG_HEADER(config.h)
  44
  45 AC_DEFINE_UNQUOTED(GLIB_MAJOR_VERSION, $GLIB_MAJOR_VERSION)
  46 AC_DEFINE_UNQUOTED(GLIB_MINOR_VERSION, $GLIB_MINOR_VERSION)
  47 AC_DEFINE_UNQUOTED(GLIB_MICRO_VERSION, $GLIB_MICRO_VERSION)
  48 AC_DEFINE_UNQUOTED(GLIB_INTERFACE_AGE, $GLIB_INTERFACE_AGE)
  49 AC_DEFINE_UNQUOTED(GLIB_BINARY_AGE, $GLIB_BINARY_AGE)
  50
  51 dnl Initialize libtool
  52 AM_PROG_LIBTOOL
  53
  54 dnl Initialize maintainer mode
  55 AM_MAINTAINER_MODE
  56
  57 AC_CANONICAL_HOST
  58
  59 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=minimum]],,enable_debug=minimum)
  60 AC_ARG_ENABLE(mem_check, [  --enable-mem-check      turn on malloc/free sanity checking [default=no]],,enable_mem_check=no)
  61 AC_ARG_ENABLE(mem_profile, [  --enable-mem-profile    turn on malloc profiling atexit [default=no]],,enable_mem_profile=no)
  62 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
  63                     , enable_ansi=no)
  64 AC_ARG_ENABLE(threads, [  --enable-threads        turn on basic thread support [default=yes]
  65                           ([=no] will override --with-threads)],,enable_threads=yes)
  66
  67 if test "x$enable_threads" != "xyes"; then
  68   enable_threads=no
  69 fi
  70
  71 AC_MSG_CHECKING(whether to enable memory checking)
  72 if test "x$enable_mem_check" = "xyes"; then
  73   AC_DEFINE(ENABLE_MEM_CHECK, 1)
  74   AC_SUBST(ENABLE_MEM_CHECK)
  75   AC_MSG_RESULT(yes)
  76 else
  77   AC_MSG_RESULT(no)
  78 fi
  79
  80 AC_MSG_CHECKING(whether to enable memory profiling)
  81 if test "x$enable_mem_profile" = "xyes"; then
  82   AC_DEFINE(ENABLE_MEM_PROFILE, 1)
  83   AC_SUBST(ENABLE_MEM_PROFILE)
  84   AC_MSG_RESULT(yes)
  85 else
  86   AC_MSG_RESULT(no)
  87 fi
  88
  89 if test "x$enable_debug" = "xyes"; then
  90   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
  91   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
  92 else
  93   if test "x$enable_debug" = "xno"; then
  94     GLIB_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
  95   fi
  96 fi
  97
  98 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, "${enable_debug}")
  99
 100 # Checks for programs.
 101 AC_PROG_CC
 102 AM_PROG_CC_STDC
 103 AC_PROG_INSTALL
 104
 105 changequote(,)dnl
 106 if test "x$GCC" = "xyes"; then
 107   case " $CFLAGS " in
 108   *[\ \ ]-Wall[\ \      ]*) ;;
 109   *) CFLAGS="$CFLAGS -Wall" ;;
 110   esac
 111
 112   if test "x$enable_ansi" = "xyes"; then
 113     case " $CFLAGS " in
 114     *[\ \       ]-ansi[\ \      ]*) ;;
 115     *) CFLAGS="$CFLAGS -ansi" ;;
 116     esac
 117
 118     case " $CFLAGS " in
 119     *[\ \       ]-pedantic[\ \  ]*) ;;
 120     *) CFLAGS="$CFLAGS -pedantic" ;;
 121     esac
 122   fi
 123 fi
 124 changequote([,])dnl
 125
 126 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 127 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 128 glib_save_LIBS=$LIBS
 129 LIBS="$LIBS -lm"
 130 AC_TRY_RUN([#include <math.h>
 131              int main (void) { return (log(1) != log(1.)); }],
 132      AC_MSG_RESULT(none needed),
 133      glib_save_CFLAGS=$CFLAGS
 134      CFLAGS="$CFLAGS -std1"
 135      AC_TRY_RUN([#include <math.h>
 136                  int main (void) { return (log(1) != log(1.)); }],
 137          AC_MSG_RESULT(-std1),
 138          AC_MSG_RESULT()
 139          CFLAGS=$glib_save_CFLAGS
 140          AC_MSG_WARN(
 141                 [No ANSI prototypes found in library. (-std1 didn't work.)])
 142      )
 143 )
 144 LIBS=$glib_save_LIBS
 145
 146 dnl NeXTStep cc seems to need this
 147 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 148 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 149   AC_MSG_RESULT(none needed),
 150   glib_save_CFLAGS=$CFLAGS
 151   CFLAGS="$CFLAGS -posix"
 152   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 153     AC_MSG_RESULT(-posix),
 154     AC_MSG_RESULT()
 155     CFLAGS=$glib_save_CFLAGS
 156     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 157
 158 # Checks for header files.
 159 AC_HEADER_STDC
 160
 161 # Checks for library functions.
 162 AC_FUNC_VPRINTF
 163
 164 AC_CHECK_FUNCS(atexit on_exit)
 165
 166 AC_CHECK_SIZEOF(char)
 167 AC_CHECK_SIZEOF(short)
 168 AC_CHECK_SIZEOF(long)
 169 AC_CHECK_SIZEOF(int)
 170 AC_CHECK_SIZEOF(void *)
 171 AC_CHECK_SIZEOF(long long)
 172
 173 dnl long doubles were not used, and a portability problem
 174 dnl AC_C_LONG_DOUBLE
 175 AC_C_CONST
 176
 177 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 178 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 179 dnl actually supported.
 180 AC_MSG_CHECKING(for __inline)
 181 AC_CACHE_VAL(glib_cv_has__inline,[
 182         AC_TRY_RUN([
 183         __inline int foo () { return 0; }
 184         int main () { return foo (); }
 185         ],
 186         glib_cv_has__inline=yes
 187         ,
 188         glib_cv_has__inline=no
 189         ,)
 190 ])
 191 AC_MSG_RESULT($glib_cv_has__inline)
 192 case x$glib_cv_has__inline in
 193 xyes) AC_DEFINE(G_HAVE___INLINE)
 194 esac
 195 AC_MSG_CHECKING(for __inline__)
 196 AC_CACHE_VAL(glib_cv_has__inline__,[
 197         AC_TRY_RUN([
 198         __inline__ int foo () { return 0; }
 199         int main () { return foo (); }
 200         ],
 201         glib_cv_has__inline__=yes
 202         ,
 203         glib_cv_has__inline__=no
 204         ,)
 205 ])
 206 AC_MSG_RESULT($glib_cv_has__inline__)
 207 case x$glib_cv_has__inline__ in
 208 xyes) AC_DEFINE(G_HAVE___INLINE__)
 209 esac
 210 AC_MSG_CHECKING(for inline)
 211 AC_CACHE_VAL(glib_cv_hasinline,[
 212         AC_TRY_RUN([
 213         inline int foo () { return 0; }
 214         int main () { return foo (); }
 215         ],
 216         glib_cv_hasinline=yes
 217         ,
 218         glib_cv_hasinline=no
 219         ,)
 220 ])
 221 AC_MSG_RESULT($glib_cv_hasinline)
 222 case x$glib_cv_hasinline in
 223 xyes) AC_DEFINE(G_HAVE_INLINE)
 224 esac
 225
 226 dnl for bytesex stuff
 227 AC_C_BIGENDIAN
 228
 229 dnl header file checks
 230 AC_CHECK_HEADERS(float.h, AC_DEFINE(HAVE_FLOAT_H))
 231 AC_CHECK_HEADERS(limits.h, AC_DEFINE(HAVE_LIMITS_H))
 232 AC_CHECK_HEADERS(pwd.h, AC_DEFINE(HAVE_PWD_H))
 233 AC_CHECK_HEADERS(sys/param.h, AC_DEFINE(HAVE_SYS_PARAM_H))
 234 AC_CHECK_HEADERS(sys/poll.h, AC_DEFINE(HAVE_SYS_POLL_H))
 235 AC_CHECK_HEADERS(sys/select.h, AC_DEFINE(HAVE_SYS_SELECT_H))
 236 AC_CHECK_HEADERS(sys/time.h, AC_DEFINE(HAVE_SYS_TIME_H))
 237 AC_CHECK_HEADERS(sys/times.h, AC_DEFINE(HAVE_SYS_TIMES_H))
 238 AC_CHECK_HEADERS(unistd.h, AC_DEFINE(HAVE_UNISTD_H))
 239 AC_CHECK_HEADERS(values.h, AC_DEFINE(HAVE_VALUES_H))
 240
 241 # Check for some functions
 242 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf strcasecmp strncasecmp poll)
 243
 244 # Check for sys_errlist
 245 AC_MSG_CHECKING(for sys_errlist)
 246 AC_TRY_LINK(, [
 247 extern char *sys_errlist[];
 248 extern int sys_nerr;
 249 sys_errlist[sys_nerr-1][0] = 0;
 250 ], glib_ok=yes, glib_ok=no)
 251 AC_MSG_RESULT($glib_ok)
 252 if test $glib_ok = no; then
 253     AC_DEFINE(NO_SYS_ERRLIST)
 254 fi
 255
 256 # Check for sys_siglist
 257 AC_MSG_CHECKING(for sys_siglist)
 258 AC_TRY_LINK(, [
 259 extern char *sys_siglist[];
 260 sys_siglist[1][0] = 0;
 261 ], glib_ok=yes, glib_ok=no)
 262 AC_MSG_RESULT($glib_ok)
 263 if test $glib_ok = no; then
 264     AC_DEFINE(NO_SYS_SIGLIST)
 265 fi
 266
 267 # Check if <sys/select.h> needs to be included for fd_set
 268 AC_MSG_CHECKING([for fd_set])
 269 AC_TRY_COMPILE([#include <sys/types.h>],
 270         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 271 if test $gtk_ok = yes; then
 272     AC_MSG_RESULT([yes, found in sys/types.h])
 273 else
 274     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 275     if test $gtk_ok = yes; then
 276         AC_DEFINE(HAVE_SYS_SELECT_H)
 277         AC_MSG_RESULT([yes, found in sys/select.h])
 278     else
 279         AC_DEFINE(NO_FD_SET)
 280         AC_MSG_RESULT(no)
 281     fi
 282 fi
 283
 284 # These are used only in GDK (gdki18n.h)
 285 # This stuff is here only so that we can define these
 286 # things in glibconfig.h. If gtk+ started using an installed
 287 # gdkconfig.h file, then the definitions would belong there.
 288
 289 # Check for wchar.h
 290
 291 AC_MSG_CHECKING(for wchar.h)
 292 AC_TRY_CPP([#include <wchar.h>], glib_wchar_h=yes, glib_wchar_h=no)
 293 if test $glib_wchar_h = yes; then
 294    AC_DEFINE(HAVE_WCHAR_H)
 295 fi
 296 AC_MSG_RESULT($glib_wchar_h)
 297
 298 # Check for wctype.h (for iswalnum)
 299
 300 AC_MSG_CHECKING(for wctype.h)
 301 AC_TRY_CPP([#include <wctype.h>], glib_wctype_h=yes, glib_wctype_h=no)
 302 if test $glib_wctype_h = yes; then
 303    AC_DEFINE(HAVE_WCTYPE_H)
 304 fi
 305 AC_MSG_RESULT($glib_wctype_h)
 306
 307 oLIBS="$LIBS"
 308 # in Solaris 2.5, `iswalnum' is in -lw
 309 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum)])
 310
 311 # The following is necessary for Linux libc-5.4.38
 312 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 313 AC_TRY_LINK([#include <stdlib.h>],[
 314 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 315 #  ifdef HAVE_WCTYPE_H
 316 #    include <wctype.h>
 317 #  else
 318 #    ifdef HAVE_WCHAR_H
 319 #      include <wchar.h>
 320 #    endif
 321 #  endif
 322 #else
 323 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 324 #endif
 325 iswalnum((wchar_t) 0);
 326 ], glib_working_wctype=yes, glib_working_wctype=no)
 327 LIBS="$oLIBS"
 328
 329 if test $glib_working_wctype = no; then
 330    AC_DEFINE(HAVE_BROKEN_WCTYPE)
 331 fi
 332 AC_MSG_RESULT($glib_working_wctype)
 333
 334
 335 dnl **********************
 336 dnl *** va_copy checks ***
 337 dnl **********************
 338 dnl we currently check for all three va_copy possibilities, so we get
 339 dnl all results in config.log for bug reports.
 340 AC_MSG_CHECKING(for an implementation of va_copy())
 341 AC_CACHE_VAL(glib_cv_va_copy,[
 342         AC_TRY_RUN([
 343         #include <stdarg.h>
 344         void f (int i, ...) {
 345         va_list args1, args2;
 346         va_start (args1, i);
 347         va_copy (args2, args1);
 348         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 349           exit (1);
 350         va_end (args1); va_end (args2);
 351         }
 352         int main() {
 353           f (0, 42);
 354           return 0;
 355         }],
 356         glib_cv_va_copy=yes
 357         ,
 358         glib_cv_va_copy=no
 359         ,)
 360 ])
 361 AC_MSG_RESULT($glib_cv_va_copy)
 362 AC_MSG_CHECKING(for an implementation of __va_copy())
 363 AC_CACHE_VAL(glib_cv___va_copy,[
 364         AC_TRY_RUN([
 365         #include <stdarg.h>
 366         void f (int i, ...) {
 367         va_list args1, args2;
 368         va_start (args1, i);
 369         __va_copy (args2, args1);
 370         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 371           exit (1);
 372         va_end (args1); va_end (args2);
 373         }
 374         int main() {
 375           f (0, 42);
 376           return 0;
 377         }],
 378         glib_cv___va_copy=yes
 379         ,
 380         glib_cv___va_copy=no
 381         ,)
 382 ])
 383 AC_MSG_RESULT($glib_cv___va_copy)
 384 AC_MSG_CHECKING(whether va_lists can be copied by value)
 385 AC_CACHE_VAL(glib_cv_va_val_copy,[
 386         AC_TRY_RUN([
 387         #include <stdarg.h>
 388         void f (int i, ...) {
 389         va_list args1, args2;
 390         va_start (args1, i);
 391         args2 = args1;
 392         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 393           exit (1);
 394         va_end (args1); va_end (args2);
 395         }
 396         int main() {
 397           f (0, 42);
 398           return 0;
 399         }],
 400         glib_cv_va_val_copy=yes
 401         ,
 402         glib_cv_va_val_copy=no
 403         ,)
 404 ])
 405 if test "x$glib_cv_va_copy" = "xyes"; then
 406   AC_DEFINE(G_VA_COPY, va_copy)
 407 else if test "x$glib_cv___va_copy" = "xyes"; then
 408   AC_DEFINE(G_VA_COPY, __va_copy)
 409 fi
 410 fi
 411 if test "x$glib_cv_va_val_copy" = "xno"; then
 412   AC_DEFINE(G_VA_COPY_AS_ARRAY)
 413 fi
 414 AC_MSG_RESULT($glib_cv_va_val_copy)
 415
 416
 417 dnl ***********************
 418 dnl *** g_module checks ***
 419 dnl ***********************
 420 G_MODULE_LIBS=
 421 G_MODULE_LDFLAGS=
 422 G_MODULE_IMPL=
 423 G_MODULE_NEED_USCORE=0
 424 G_MODULE_HAVE_DLERROR=0
 425 dnl *** dlopen() in system libraries
 426 if test -z "$G_MODULE_IMPL"; then
 427         AC_CHECK_FUNC(dlopen,
 428                 G_MODULE_IMPL=G_MODULE_IMPL_DL
 429         ,)
 430 fi
 431 dnl *** dlopen() in libdl
 432 if test -z "$G_MODULE_IMPL"; then
 433         AC_CHECK_LIB(dl, dlopen,
 434                 G_MODULE_LIBS=-ldl
 435                 G_MODULE_IMPL=G_MODULE_IMPL_DL
 436         ,)
 437 fi
 438 dnl *** shl_load() in libdld (HP-UX)
 439 if test -z "$G_MODULE_IMPL"; then
 440         AC_MSG_CHECKING(how to export all symbols)
 441         SAVED_LDFLAGS=$LDFLAGS
 442         LDFLAGS="$LDFLAGS -Wl,-E"
 443         AC_TRY_LINK(,[ return 0; ],
 444                 [ G_MODULE_LDFLAGS="-Wl,-E" ],[
 445                 LDFLAGS="$SAVED_LDFLAGS -bexpall"
 446                 AC_TRY_LINK(,[ return 0; ],
 447                         G_MODULE_LDFLAGS="-bexpall",
 448                         G_MODULE_LDFLAGS="none"
 449                 )
 450         ])
 451         LDFLAGS=$SAVED_LDFLAGS
 452         AC_MSG_RESULT($G_MODULE_LDFLAGS)
 453         if test "x$G_MODULE_LDFLAGS" = "xnone"; then
 454                 G_MODULE_LDFLAGS=
 455         fi
 456         AC_CHECK_LIB(dld, shl_load,
 457                 G_MODULE_LIBS=-ldld
 458                 G_MODULE_IMPL=G_MODULE_IMPL_DLD
 459         ,)
 460 fi
 461 dnl *** additional checks for G_MODULE_IMPL_DL
 462 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
 463         case "$host_os" in
 464           linux*)
 465             G_MODULE_LDFLAGS='-rdynamic'
 466             ;;
 467         esac
 468         LIBS_orig="$LIBS"
 469         LDFLAGS_orig="$LDFLAGS"
 470         LIBS="$LIBS $G_MODULE_LIBS"
 471         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
 472 dnl *** check whether we need preceeding underscores
 473         AC_MSG_CHECKING(for preceeding underscore in symbols)
 474         AC_CACHE_VAL(glib_cv_uscore,[
 475                 AC_TRY_RUN([
 476                 #include <dlfcn.h>
 477                 int glib_underscore_test (void) { return 42; }
 478                 int main() {
 479                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
 480                   handle = dlopen ((void*)0, 0);
 481                   if (handle) {
 482                     f1 = dlsym (handle, "glib_underscore_test");
 483                     f2 = dlsym (handle, "_glib_underscore_test");
 484                   } return (!f2 || f1);
 485                 }],
 486                         glib_cv_uscore=yes,
 487                         glib_cv_uscore=no,
 488                 )
 489                 rm -f plugin.c plugin.o plugin.lo
 490         ])
 491         AC_MSG_RESULT($glib_cv_uscore)
 492         if test "x$glib_cv_uscore" = "xyes"; then
 493                 G_MODULE_NEED_USCORE=1
 494         else
 495                 G_MODULE_NEED_USCORE=0
 496         fi
 497
 498         LDFLAGS="$LDFLAGS_orig"
 499 dnl *** check for having dlerror()
 500         AC_CHECK_FUNC(dlerror,
 501                 G_MODULE_HAVE_DLERROR=1,
 502                 G_MODULE_HAVE_DLERROR=0)
 503         LIBS="$LIBS_orig"
 504 fi
 505 dnl *** done, have e got an implementation?
 506 if test -z "$G_MODULE_IMPL"; then
 507         G_MODULE_IMPL=0
 508 fi
 509 AC_SUBST(G_MODULE_IMPL)
 510 AC_SUBST(G_MODULE_LIBS)
 511 AC_SUBST(G_MODULE_LDFLAGS)
 512 AC_SUBST(G_MODULE_HAVE_DLERROR)
 513 AC_SUBST(G_MODULE_NEED_USCORE)
 514 AC_SUBST(GLIB_DEBUG_FLAGS)
 515
 516
 517 dnl ***********************
 518 dnl *** g_thread checks ***
 519 dnl ***********************
 520
 521 AC_ARG_WITH(threads, [  --with-threads=[none/posix/solaris/nspr] specify a thread implementation to use],
 522         if test "x$with_threads" = x; then
 523                 want_threads=yes
 524         else
 525                 want_threads=$with_threads
 526         fi,
 527         want_threads=yes)
 528 if test "x$enable_threads" = "xno"; then
 529         want_threads=no
 530 fi
 531 if test "x$want_threads" = "xnone"; then
 532         want_threads=no
 533 fi
 534
 535 dnl error and warning message
 536 dnl *************************
 537
 538 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
 539                 computer. glib will not be thread safe on your computer."
 540
 541 THREAD_UNKNOWN_COMPILER="Your compiler is not known, so I cannot
 542                 determine the necessary compiler options to compile programs
 543                 which are using threads. Please provide such information."
 544
 545 FLAG_DOES_NOT_WORK="I can't find the MACRO, that enables thread safety on your
 546                 platform (normaly it's "_REENTRANT"). I'll not use any flag on
 547                 compilation now, but then your programs might not work.
 548                 Please provide information on how it is done on your system."
 549
 550 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
 551                 "
 552
 553 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
 554                 provide informationon your thread implementation."
 555
 556 dnl determination of thread implementation
 557 dnl ***************************************
 558
 559 have_threads=none
 560 if test "x$want_threads" = xyes || test "x$want_threads" = xsolaris; then
 561         case $host in
 562                 *-*-solaris*)
 563                 AC_CHECK_LIB(thread, cond_init, have_threads=solaris)
 564                 ;;
 565         esac
 566 fi
 567 if test "x$want_threads" = xyes || test "x$want_threads" = xposix; then
 568         if test "x$have_threads" = xnone; then
 569                 AC_CHECK_LIB(pthread, pthread_attr_init, have_threads=posix)
 570         fi
 571         if test "x$have_threads" = xnone; then
 572                 AC_CHECK_LIB(pthreads, pthread_attr_init, have_threads=posix)
 573         fi
 574         if test "x$have_threads" = xnone; then
 575                 # dont let us be fooled by a defined pthread_cond_init
 576                 # function in the standard c-lib, that doesn't have too mean,
 577                 # there is full thread support, it might be a weak symbol.
 578                 AC_CHECK_FUNC(pthread_attr_init, have_threads=posix)
 579         fi
 580 fi
 581 if test "x$want_threads" = xyes || test "x$want_threads" = xnspr; then
 582         if test "x$have_threads" = xnone; then
 583                 AC_CHECK_LIB(nspr21, PRP_NewNakedCondVar, have_threads=nspr)
 584         fi
 585 fi
 586
 587 AC_MSG_CHECKING(for thread implementation)
 588
 589 if test "x$have_threads" = xnone && test "x$want_threads" != xno; then
 590         AC_MSG_RESULT(none available)
 591         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
 592 else
 593         AC_MSG_RESULT($have_threads)
 594 fi
 595
 596
 597 dnl determination of G_THREAD_LIBS
 598 dnl ******************************
 599
 600 G_THREAD_LIBS=
 601
 602 case $have_threads in
 603         posix)
 604                 G_THREAD_LIBS=error
 605                 AC_CHECK_LIB(pthread, pthread_attr_init,
 606                              G_THREAD_LIBS="-lpthread")
 607                 if test "x$G_THREAD_LIBS" = xerror; then
 608                         AC_CHECK_LIB(pthreads, pthread_attr_init,
 609                                 G_THREAD_LIBS="-lpthreads")
 610                 fi
 611                 if test "x$G_THREAD_LIBS" = xerror; then
 612                         AC_CHECK_FUNC(pthread_cond_init, G_THREAD_LIBS="")
 613                 fi
 614                 ;;
 615         solaris)
 616                 G_THREAD_LIBS=error
 617                 AC_CHECK_LIB(thread, cond_init, G_THREAD_LIBS="-lthread")
 618                 # solaris has a broken initializer for mutexes, if we find it,
 619                 # we will replace it.
 620                 AC_MSG_CHECKING(for broken solaris mutex initialization)
 621                 AC_EGREP_CPP([ *begin *{ *0 *, *0 *, *0 *, *0 *, *0 *, *0 *, *0 *, *0 *, *0 *, *0 *, *0 *, *0 *, *0 *, *0 *} *end *],
 622                              [#include <thread.h>
 623                              begin DEFAULTMUTEX end],
 624                              [solaris_mutex_init_broken=yes],
 625                              [solaris_mutex_init_broken=no])
 626                 AC_MSG_RESULT($solaris_mutex_init_broken)
 627                 ;;
 628         nspr)
 629                 AC_CHECK_LIB(nspr21, PRP_NewNakedCondVar,
 630                              G_THREAD_LIBS="-lnspr21")
 631                 ;;
 632         none)
 633                 ;;
 634         *)
 635                 G_THREAD_LIBS=error
 636                 ;;
 637 esac
 638
 639 if test "x$G_THREAD_LIBS" = xerror; then
 640         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
 641 fi
 642
 643 AC_MSG_CHECKING(necessary linker options)
 644 AC_MSG_RESULT($G_THREAD_LIBS)
 645
 646 dnl determination of G_THREAD_CFLAGS
 647 dnl ********************************
 648
 649 if test x"$have_threads" != xnone; then
 650         G_THREAD_CFLAGS="-D_REENTRANT" # good default
 651
 652         case $host in
 653                *-aix*)
 654                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 655                         if test x"$GCC" = xyes; then
 656                                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -mthreads"
 657                         fi
 658                         ;;
 659         esac
 660
 661         # if we are not finding the ctime_r function, then we probably are
 662         # not using the proper multithread flag
 663         old_CPPFLAGS=$CPPFLAGS
 664         CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
 665         AC_EGREP_HEADER([[^a-zA-Z_]ctime_r[^a-zA-Z_]], time.h, ,
 666                 G_THREAD_CFLAGS=
 667                 AC_MSG_WARN($FLAG_DOES_NOT_WORK))
 668         CPPFLAGS=$old_CPPFLAGS
 669
 670 #       if test x"$GCC" = xyes; then
 671 #               # older gcc's do not know the -fstack-check option and will
 672 #               # stop compiling, so just check this here
 673 #               old_CPPFLAGS="$CPPFLAGS"
 674 #               CPPFLAGS="$CPPFLAGS -fstack-check"
 675 #               AC_TRY_COMPILE(,,
 676 #                       G_THREAD_CFLAGS="$G_THREAD_CFLAGS -fstack-check")
 677 #               CPPFLAGS=$old_CPPFLAGS
 678 #       else
 679 #               AC_MSG_WARN($THREAD_UNKNOWN_COMPILER)
 680 #       fi
 681
 682         AC_MSG_CHECKING(necessary compiler options)
 683
 684         AC_MSG_RESULT($G_THREAD_CFLAGS)
 685 else
 686         G_THREAD_CFLAGS=
 687 fi
 688
 689 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c")
 690 AC_SUBST(G_THREAD_CFLAGS)
 691 AC_SUBST(G_THREAD_LIBS)
 692
 693 CFLAGS="$CFLAGS $G_THREAD_CFLAGS"
 694
 695 dnl ******************************
 696 dnl *** output the whole stuff ***
 697 dnl ******************************
 698
 699 AC_OUTPUT_COMMANDS([
 700
 701 ## Generate `glibconfig.h' in two cases
 702 ## 1. `config.status' is run either explicitly, or via configure.
 703 ##     Esp. not when it is run in `Makefile' to generate makefiles and
 704 ##     config.h
 705 ## 2. CONFIG_OTHER is set explicitly
 706 ##
 707 ## Case 1 is difficult.  We know that `automake' sets one of
 708 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
 709 ## only when AM_CONFIG_HEADER is set, however.
 710
 711 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
 712   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
 713   CONFIG_OTHER=${CONFIG_OTHER:-glibconfig.h}
 714 fi
 715 case "$CONFIG_OTHER" in
 716 *glibconfig.h*)
 717   echo creating glibconfig.h
 718   outfile=glibconfig.h-tmp
 719   cat > $outfile <<\outfile_EOF
 720 /* glibconfig.h */
 721 /* This is a generated file.  Please modify `configure.in' */
 722
 723 #ifndef GLIBCONFIG_H
 724 #define GLIBCONFIG_H
 725
 726 #ifdef __cplusplus
 727 extern "C" {
 728 #endif /* __cplusplus */
 729
 730 outfile_EOF
 731
 732   if test x$glib_limits_h = xyes; then
 733     echo '#include <limits.h>' >> $outfile
 734   fi
 735   if test x$glib_float_h = xyes; then
 736     echo '#include <float.h>' >> $outfile
 737   fi
 738   if test x$glib_values_h = xyes; then
 739     echo '#include <values.h>' >> $outfile
 740   fi
 741   if test x$g_mutex_header_file != x; then
 742     echo '#include <'"$g_mutex_header_file"'>' >> $outfile
 743   fi
 744   if test x$glib_sys_poll_h = xyes; then
 745     echo '#include <sys/types.h>' >> $outfile
 746     echo '#include <sys/poll.h>' >> $outfile
 747   fi
 748
 749   cat >> $outfile <<outfile_EOF
 750
 751 #define G_MINFLOAT $glib_mf
 752 #define G_MAXFLOAT $glib_Mf
 753 #define G_MINDOUBLE $glib_md
 754 #define G_MAXDOUBLE $glib_Md
 755 #define G_MINSHORT $glib_ms
 756 #define G_MAXSHORT $glib_Ms
 757 #define G_MININT $glib_mi
 758 #define G_MAXINT $glib_Mi
 759 #define G_MINLONG $glib_ml
 760 #define G_MAXLONG $glib_Ml
 761
 762 outfile_EOF
 763
 764   ## this should always be true in a modern C/C++ compiler
 765   cat >>$outfile <<outfile_EOF
 766 typedef signed char gint8;
 767 typedef unsigned char guint8;
 768 outfile_EOF
 769
 770   if test -n "$gint16"; then
 771     cat >>$outfile <<outfile_EOF
 772 typedef signed $gint16 gint16;
 773 typedef unsigned $gint16 guint16;
 774 outfile_EOF
 775   fi
 776   if test -n "$gint32"; then
 777     cat >>$outfile <<outfile_EOF
 778 typedef signed $gint32 gint32;
 779 typedef unsigned $gint32 guint32;
 780 outfile_EOF
 781   fi
 782   if test -n "$gint64"; then
 783     cat >>$outfile <<outfile_EOF
 784 ${glib_warning_guard}#define G_HAVE_GINT64 1
 785
 786 ${glib_extension}typedef signed $gint64 gint64;
 787 ${glib_extension}typedef unsigned $gint64 guint64;
 788
 789 #define G_GINT64_CONSTANT(val)  $gint64_constant
 790 outfile_EOF
 791   fi
 792
 793   if test -z "$glib_unknown_void_p"; then
 794     cat >>$outfile <<outfile_EOF
 795
 796 #define GPOINTER_TO_INT(p)      ((gint)${glib_gpi_cast}(p))
 797 #define GPOINTER_TO_UINT(p)     ((guint)${glib_gpui_cast}(p))
 798
 799 #define GINT_TO_POINTER(i)      ((gpointer)${glib_gpi_cast}(i))
 800 #define GUINT_TO_POINTER(u)     ((gpointer)${glib_gpui_cast}(u))
 801 outfile_EOF
 802   else
 803     echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
 804   fi
 805
 806   cat >>$outfile <<outfile_EOF
 807 $glib_atexit
 808 $glib_memmove
 809 $glib_defines
 810
 811 $glib_vacopy
 812
 813 #ifdef  __cplusplus
 814 #define G_HAVE_INLINE   1
 815 #else   /* !__cplusplus */
 816 $glib_inline
 817 #endif  /* !__cplusplus */
 818
 819 #define G_BYTE_ORDER $g_byte_order
 820 outfile_EOF
 821
 822 cat >>$outfile <<outfile_EOF
 823
 824 $g_enable_threads_def G_THREADS_ENABLED
 825
 826 /* definitions for the default mutex implementation */
 827 outfile_EOF
 828
 829   if test x$g_mutex_has_default = xyes; then
 830 cat >>$outfile <<outfile_EOF
 831
 832 typedef struct _GStaticMutex GStaticMutex;
 833 struct _GStaticMutex
 834 {
 835   $g_mutex_default_type default_mutex;
 836   struct _GMutex* runtime_mutex;
 837 };
 838 #define G_STATIC_MUTEX_INIT { $g_mutex_default_init, NULL }
 839 #define g_static_mutex_get_mutex(mutex) \
 840   ( g_thread_use_default_impl ? (GMutex*)&(mutex).default_mutex : \
 841     g_static_mutex_get_mutex_impl(&(mutex).runtime_mutex) )
 842 outfile_EOF
 843   else
 844 cat >>$outfile <<outfile_EOF
 845
 846 typedef struct _GMutex* GStaticMutex;
 847 #define G_STATIC_MUTEX_INIT NULL
 848 #define g_static_mutex_get_mutex(mutex) g_static_mutex_get_mutex_impl(&mutex)
 849 outfile_EOF
 850   fi
 851
 852   g_bit_sizes="16 32"
 853   if test -n "$gint64"; then
 854     g_bit_sizes="$g_bit_sizes 64"
 855   fi
 856
 857   for bits in $g_bit_sizes; do
 858     cat >>$outfile <<outfile_EOF
 859
 860 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
 861 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
 862 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
 863 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
 864 outfile_EOF
 865 done
 866
 867   cat >>$outfile <<outfile_EOF
 868
 869 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
 870 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
 871 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
 872 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
 873
 874 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
 875 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
 876 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
 877 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
 878 $glib_wc
 879
 880 #ifdef __cplusplus
 881 }
 882 #endif /* __cplusplus */
 883
 884 #endif /* GLIBCONFIG_H */
 885
 886 outfile_EOF
 887
 888   if cmp -s $outfile glibconfig.h; then
 889     echo glibconfig.h is unchanged
 890     rm -f $outfile
 891   else
 892     mv $outfile glibconfig.h
 893   fi ;;
 894 esac
 895 ],[
 896
 897 # Note that if two cases are the same, case goes with the first one.
 898 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
 899 # on variable expansion in case labels.  Look at the generated config.status
 900 # for a hint.
 901
 902 case xyes in
 903 x$ac_cv_header_float_h)
 904   glib_float_h=yes
 905   glib_mf=FLT_MIN glib_Mf=FLT_MAX
 906   glib_md=DBL_MIN glib_Md=DBL_MAX
 907   ;;
 908 x$ac_cv_header_values_h)
 909   glib_values_h=yes
 910   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
 911   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
 912   ;;
 913 esac
 914
 915 case xyes in
 916 x$ac_cv_header_limits_h)
 917   glib_limits_h=yes
 918   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX
 919   glib_mi=INT_MIN  glib_Mi=INT_MAX
 920   glib_ml=LONG_MIN glib_Ml=LONG_MAX
 921   ;;
 922 x$ac_cv_header_values_h)
 923   glib_values_h=yes
 924   glib_ms=MINSHORT glib_Ms=MAXSHORT
 925   glib_mi=MININT   glib_Mi=MAXINT
 926   glib_ml=MINLONG  glib_Ml=MAXLONG
 927   ;;
 928 esac
 929
 930 if test x$ac_cv_header_sys_poll_h = xyes ; then
 931   glib_sys_poll_h=yes
 932 fi
 933
 934 case 2 in
 935 $ac_cv_sizeof_short)            gint16=short;;
 936 $ac_cv_sizeof_int)              gint16=int;;
 937 esac
 938 case 4 in
 939 $ac_cv_sizeof_short)            gint32=short;;
 940 $ac_cv_sizeof_int)              gint32=int;;
 941 $ac_cv_sizeof_long)             gint32=long;;
 942 esac
 943 case 8 in
 944 $ac_cv_sizeof_int)
 945   gint64=int
 946   glib_extension=
 947   glib_warning_guard=
 948   gint64_constant='(val)'
 949   ;;
 950 $ac_cv_sizeof_long)
 951   gint64=long
 952   glib_extension=
 953   glib_warning_guard=
 954   gint64_constant='(val##L)'
 955   ;;
 956 $ac_cv_sizeof_long_long)
 957   gint64='long long'
 958   glib_extension='GLIB_WARNINGS_MAKE_PEOPLE_CRY '
 959   glib_warning_guard="
 960 #if defined (__GNUC__) && __GNUC__ >= 2 && __GNUC_MINOR__ >= 8
 961 #  define GLIB_WARNINGS_MAKE_PEOPLE_CRY __extension__
 962 #else
 963 #  define GLIB_WARNINGS_MAKE_PEOPLE_CRY
 964 #endif
 965
 966 "
 967   gint64_constant='(GLIB_WARNINGS_MAKE_PEOPLE_CRY (val##LL))'
 968   ;;
 969 esac
 970
 971 gintbits=`expr $ac_cv_sizeof_int \* 8`
 972 glongbits=`expr $ac_cv_sizeof_long \* 8`
 973
 974
 975 case $ac_cv_sizeof_void_p in
 976 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
 977 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
 978 *)                      glib_unknown_void_p=yes ;;
 979 esac
 980
 981
 982 case xyes in
 983 x$ac_cv_func_atexit)
 984   glib_atexit="
 985 #ifdef NeXT /* @#%@! NeXTStep */
 986 # define g_ATEXIT(proc) (!atexit (proc))
 987 #else
 988 # define g_ATEXIT(proc) (atexit (proc))
 989 #endif"
 990   ;;
 991 x$ac_cv_func_on_exit)
 992   glib_atexit="
 993 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
 994   ;;
 995 esac
 996
 997 case xyes in
 998 x$ac_cv_func_memmove)
 999   glib_memmove='
1000 #define g_memmove(d,s,n) G_STMT_START { memmove ((d), (s), (n)); } G_STMT_END'
1001   ;;
1002 *)
1003   glib_memmove="
1004 /* We make the assumption that if memmove isn't available, then
1005  * bcopy will do the job. This isn't safe everywhere. (bcopy can't
1006  * necessarily handle overlapping copies) */
1007 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
1008   ;;
1009 esac
1010
1011 glib_defines="
1012 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
1013 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
1014 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
1015 "
1016
1017 case xyes in
1018 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
1019 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
1020 *)                      glib_vacopy=''
1021 esac
1022
1023 if test x$glib_cv_va_val_copy = xno; then
1024   glib_vacopy="\$glib_vacopy
1025 #define G_VA_COPY_AS_ARRAY 1"
1026 fi
1027
1028 if test x$glib_cv_hasinline = xyes; then
1029     glib_inline='#define G_HAVE_INLINE 1'
1030 fi
1031 if test x$glib_cv_has__inline = xyes; then
1032     glib_inline="\$glib_inline
1033 #define G_HAVE___INLINE 1"
1034 fi
1035 if test x$glib_cv_has__inline__ = xyes; then
1036     glib_inline="\$glib_inline
1037 #define G_HAVE___INLINE__ 1"
1038 fi
1039
1040 case xyes in
1041 x$ac_cv_c_bigendian)
1042   g_byte_order=G_BIG_ENDIAN
1043   g_bs_native=BE
1044   g_bs_alien=LE
1045   ;;
1046 *)
1047   g_byte_order=G_LITTLE_ENDIAN
1048   g_bs_native=LE
1049   g_bs_alien=BE
1050   ;;
1051 esac
1052
1053 if test x$glib_wchar_h = xyes; then
1054   glib_wc='
1055 #define G_HAVE_WCHAR_H 1'
1056 fi
1057 if test x$glib_wctype_h = xyes; then
1058   glib_wc="\$glib_wc
1059 #define G_HAVE_WCTYPE_H 1"
1060 fi
1061 if test x$glib_working_wctype = xno; then
1062   glib_wc="\$glib_wc
1063 #define G_HAVE_BROKEN_WCTYPE 1"
1064 fi
1065
1066 case x$enable_threads in
1067 xyes)   g_enable_threads_def="#define";;
1068 *)      g_enable_threads_def="#undef ";;
1069 esac
1070
1071 case $have_threads in
1072         posix)
1073                 g_mutex_has_default=yes
1074                 g_mutex_default_type='pthread_mutex_t'
1075                 g_mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
1076                 g_mutex_header_file='pthread.h'
1077                 ;;
1078         solaris)
1079                 g_mutex_has_default=yes
1080                 g_mutex_default_type='mutex_t'
1081                 if test x$solaris_mutex_init_broken = xyes; then
1082                   g_mutex_default_init="{ { { 0, 0, 0, 0 }, USYNC_THREAD }, { { { 0, 0, 0, 0, 0, 0, 0, 0 } } }, 0}"
1083                 else
1084                   g_mutex_default_init="DEFAULTMUTEX"
1085                 fi
1086                 g_mutex_header_file='thread.h'
1087                 ;;
1088         nspr)
1089                 g_mutex_has_default=no
1090                 ;;
1091         *)
1092                 g_mutex_has_default=no
1093                 ;;
1094 esac
1095 ])
1096
1097 AC_OUTPUT([
1098 Makefile
1099 glib-config
1100 gmodule/gmoduleconf.h
1101 gmodule/Makefile
1102 gthread/Makefile
1103 docs/Makefile
1104 ],[case "$CONFIG_FILES" in
1105 *glib-config*)chmod +x glib-config;;
1106 esac])