configure.in

   1 dnl -*- mode: m4 -*-
   2 AC_PREREQ(2.52)
   3
   4 AC_INIT(dbus/dbus.h)
   5
   6 AM_INIT_AUTOMAKE(dbus, 0.10)
   7
   8 AM_CONFIG_HEADER(config.h)
   9
  10 # Honor aclocal flags
  11 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
  12
  13 GETTEXT_PACKAGE=dbus-1
  14 AC_SUBST(GETTEXT_PACKAGE)
  15 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[The name of the gettext domain])
  16
  17  ## must come before we use the $USE_MAINTAINER_MODE variable later
  18 AM_MAINTAINER_MODE
  19
  20 AC_PROG_CC
  21 AC_PROG_CXX
  22 AC_ISC_POSIX
  23 AC_HEADER_STDC
  24 AM_PROG_LIBTOOL
  25
  26 AC_ARG_ENABLE(qt,      [  --enable-qt      enable Qt-friendly client library],enable_qt=$enableval,enable_qt=auto)
  27 AC_ARG_ENABLE(glib,    [  --enable-glib    enable GLib-friendly client library],enable_glib=$enableval,enable_glib=auto)
  28 AC_ARG_ENABLE(tests,   [  --enable-tests   enable unit test code],enable_tests=$enableval,enable_tests=$USE_MAINTAINER_MODE)
  29 AC_ARG_ENABLE(ansi,    [  --enable-ansi    enable -ansi -pedantic gcc flags],enable_ansi=$enableval,enable_ansi=no)
  30 AC_ARG_ENABLE(verbose-mode, [  --enable-verbose-mode support verbose debug mode],enable_verbose_mode=$enableval,enable_verbose_mode=$USE_MAINTAINER_MODE)
  31 AC_ARG_ENABLE(asserts, [  --enable-asserts include assertion checks],enable_asserts=$enableval,enable_asserts=$USE_MAINTAINER_MODE)
  32 AC_ARG_ENABLE(checks,  [  --enable-checks  include sanity checks on public API],enable_checks=$enableval,enable_checks=yes)
  33 AC_ARG_ENABLE(docs,    [  --enable-docs    build documentation (requires Doxygen and jade)],enable_docs=$enableval,enable_docs=auto)
  34 AC_ARG_ENABLE(gcov,    [  --enable-gcov compile with coverage profiling instrumentation (gcc only)],enable_gcov=$enableval,enable_gcov=no)
  35
  36 AC_ARG_WITH(xml,                [  --with-xml=[libxml/expat] XML library to use])
  37 AC_ARG_WITH(init-scripts,       [  --with-init-scripts=[redhat] Style of init scripts to install])
  38 AC_ARG_WITH(session-socket-dir, [  --with-session-socket-dir=[dirname] Where to put sockets for the per-login-session message bus])
  39 AC_ARG_WITH(test-socket-dir,    [  --with-test-socket-dir=[dirname] Where to put sockets for make check])
  40 AC_ARG_WITH(system-pid-file,    [  --with-system-pid-file=[pidfile] PID file for systemwide daemon])
  41 AC_ARG_WITH(system-socket,      [  --with-system-socket=[filename] UNIX domain socket for systemwide daemon])
  42
  43 dnl DBUS_BUILD_TESTS controls unit tests built in to .c files
  44 dnl and also some stuff in the test/ subdir
  45 AM_CONDITIONAL(DBUS_BUILD_TESTS, test x$enable_tests = xyes)
  46 if test x$enable_tests = xyes; then
  47     AC_DEFINE(DBUS_BUILD_TESTS,1,[Build test code])
  48 fi
  49
  50 if test x$enable_verbose_mode = xyes; then
  51     AC_DEFINE(DBUS_ENABLE_VERBOSE_MODE,1,[Support a verbose mode])
  52 fi
  53 if test x$enable_asserts = xno; then
  54     AC_DEFINE(DBUS_DISABLE_ASSERT,1,[Disable assertion checking])
  55 fi
  56 if test x$enable_checks = xno; then
  57     AC_DEFINE(DBUS_DISABLE_CHECKS,1,[Disable public API sanity checking])
  58 fi
  59
  60 #### gcc warning flags
  61
  62 if test "x$GCC" = "xyes"; then
  63   changequote(,)dnl
  64   case " $CFLAGS " in
  65   *[\ \ ]-Wall[\ \      ]*) ;;
  66   *) CFLAGS="$CFLAGS -Wall" ;;
  67   esac
  68
  69   case " $CFLAGS " in
  70   *[\ \ ]-Wchar-subscripts[\ \  ]*) ;;
  71   *) CFLAGS="$CFLAGS -Wchar-subscripts" ;;
  72   esac
  73
  74   case " $CFLAGS " in
  75   *[\ \ ]-Wmissing-declarations[\ \     ]*) ;;
  76   *) CFLAGS="$CFLAGS -Wmissing-declarations" ;;
  77   esac
  78
  79   case " $CFLAGS " in
  80   *[\ \ ]-Wmissing-prototypes[\ \       ]*) ;;
  81   *) CFLAGS="$CFLAGS -Wmissing-prototypes" ;;
  82   esac
  83
  84   case " $CFLAGS " in
  85   *[\ \ ]-Wnested-externs[\ \   ]*) ;;
  86   *) CFLAGS="$CFLAGS -Wnested-externs" ;;
  87   esac
  88
  89   case " $CFLAGS " in
  90   *[\ \ ]-Wpointer-arith[\ \    ]*) ;;
  91   *) CFLAGS="$CFLAGS -Wpointer-arith" ;;
  92   esac
  93
  94   case " $CFLAGS " in
  95   *[\ \ ]-Wcast-align[\ \       ]*) ;;
  96   *) CFLAGS="$CFLAGS -Wcast-align" ;;
  97   esac
  98
  99   case " $CFLAGS " in
 100   *[\ \ ]-Wsign-compare[\ \     ]*) ;;
 101   *) CFLAGS="$CFLAGS -Wsign-compare" ;;
 102   esac
 103
 104   if test "x$enable_ansi" = "xyes"; then
 105     case " $CFLAGS " in
 106     *[\ \       ]-ansi[\ \      ]*) ;;
 107     *) CFLAGS="$CFLAGS -ansi" ;;
 108     esac
 109
 110     case " $CFLAGS " in
 111     *[\ \       ]-pedantic[\ \  ]*) ;;
 112     *) CFLAGS="$CFLAGS -pedantic" ;;
 113     esac
 114   fi
 115   if test x$enable_gcov = xyes; then
 116     case " $CFLAGS " in
 117     *[\ \       ]-fprofile-arcs[\ \     ]*) ;;
 118     *) CFLAGS="$CFLAGS -fprofile-arcs" ;;
 119     esac
 120     case " $CFLAGS " in
 121     *[\ \       ]-ftest-coverage[\ \    ]*) ;;
 122     *) CFLAGS="$CFLAGS -ftest-coverage" ;;
 123     esac
 124
 125     ## remove optimization
 126     CFLAGS=`echo "$CFLAGS" | sed -e 's/-O[0-9]*//g'`
 127   fi
 128   changequote([,])dnl
 129 else
 130   if test x$enable_gcov = xyes; then
 131     AC_MSG_ERROR([--enable-gcov can only be used with gcc])
 132   fi
 133 fi
 134
 135 # compress spaces in cflags
 136 CFLAGS=`echo "$CFLAGS" | sed -e 's/ +/ /g'`
 137
 138 if test x$enable_gcov = xyes; then
 139      ## so that config.h changes when you toggle gcov support
 140      AC_DEFINE_UNQUOTED(DBUS_GCOV_ENABLED, 1, [Defined if gcov is enabled to force a rebuild due to config.h changing])
 141 fi
 142 AM_CONDITIONAL(DBUS_GCOV_ENABLED, test x$enable_gcov = xyes)
 143
 144 #### Integer sizes
 145
 146 AC_CHECK_SIZEOF(char)
 147 AC_CHECK_SIZEOF(short)
 148 AC_CHECK_SIZEOF(long)
 149 AC_CHECK_SIZEOF(int)
 150 AC_CHECK_SIZEOF(void *)
 151 AC_CHECK_SIZEOF(long long)
 152 AC_CHECK_SIZEOF(__int64)
 153
 154 ### See what our 64 bit type is called
 155 AC_MSG_CHECKING([64-bit integer type])
 156
 157 case 8 in
 158 $ac_cv_sizeof_int)
 159   dbusint64=int
 160   dbusint64_constant='(val)'
 161   dbusuint64_constant='(val)'
 162   ;;
 163 $ac_cv_sizeof_long)
 164   dbusint64=long
 165   dbusint64_constant='(val##L)'
 166   dbusuint64_constant='(val##UL)'
 167   ;;
 168 $ac_cv_sizeof_long_long)
 169   dbusint64='long long'
 170   dbusint64_constant='(val##LL)'
 171   dbusuint64_constant='(val##ULL)'
 172   ;;
 173 $ac_cv_sizeof___int64)
 174   dbusint64=__int64
 175   dbusint64_constant='(val##i64)'
 176   dbusuint64_constant='(val##ui64)'
 177   ;;
 178 esac
 179
 180 if test -z "$dbusint64" ; then
 181         DBUS_INT64_TYPE="no_int64_type_detected"
 182         DBUS_HAVE_INT64=0
 183         DBUS_INT64_CONSTANT=
 184         DBUS_UINT64_CONSTANT=
 185         AC_MSG_RESULT([none found])
 186 else
 187         DBUS_INT64_TYPE="$dbusint64"
 188         DBUS_HAVE_INT64=1
 189         DBUS_INT64_CONSTANT="$dbusint64_constant"
 190         DBUS_UINT64_CONSTANT="$dbusuint64_constant"
 191         AC_MSG_RESULT($DBUS_INT64_TYPE)
 192 fi
 193
 194 AC_SUBST(DBUS_INT64_TYPE)
 195 AC_SUBST(DBUS_INT64_CONSTANT)
 196 AC_SUBST(DBUS_UINT64_CONSTANT)
 197 AC_SUBST(DBUS_HAVE_INT64)
 198
 199 ## byte order
 200 AC_C_BIGENDIAN
 201
 202 #### Various functions
 203 AC_CHECK_LIB(socket,socket)
 204 AC_CHECK_LIB(nsl,gethostbyname)
 205
 206 AC_CHECK_FUNCS(vsnprintf vasprintf nanosleep usleep poll setenv unsetenv socketpair getgrouplist)
 207
 208 AC_CHECK_HEADERS(execinfo.h, [AC_CHECK_FUNCS(backtrace)])
 209
 210 AC_CACHE_CHECK([for posix getpwnam_r],
 211                 ac_cv_func_posix_getpwnam_r,
 212                 [AC_TRY_RUN([
 213 #include <errno.h>
 214 #include <pwd.h>
 215 int main () {
 216     char buffer[10000];
 217     struct passwd pwd, *pwptr = &pwd;
 218     int error;
 219     errno = 0;
 220     error = getpwnam_r ("", &pwd, buffer,
 221                         sizeof (buffer), &pwptr);
 222    return (error < 0 && errno == ENOSYS)
 223            || error == ENOSYS;
 224 }               ],
 225         [ac_cv_func_posix_getpwnam_r=yes],
 226         [ac_cv_func_posix_getpwnam_r=no])])
 227 if test "$ac_cv_func_posix_getpwnam_r" = yes; then
 228         AC_DEFINE(HAVE_POSIX_GETPWNAM_R,1,
 229                 [Have POSIX function getpwnam_r])
 230 else
 231         AC_CACHE_CHECK([for nonposix getpwnam_r],
 232                 ac_cv_func_nonposix_getpwnam_r,
 233                 [AC_TRY_LINK([#include <pwd.h>],
 234                         [char buffer[10000];
 235                         struct passwd pwd;
 236                         getpwnam_r ("", &pwd, buffer,
 237                                         sizeof (buffer));],
 238                         [ac_cv_func_nonposix_getpwnam_r=yes],
 239                         [ac_cv_func_nonposix_getpwnam_r=no])])
 240                 if test "$ac_cv_func_nonposix_getpwnam_r" = yes; then
 241                 AC_DEFINE(HAVE_NONPOSIX_GETPWNAM_R,1,
 242                         [Have non-POSIX function getpwnam_r])
 243         fi
 244 fi
 245
 246 dnl check for writev header and writev function so we're
 247 dnl good to go if HAVE_WRITEV gets defined.
 248 AC_CHECK_HEADERS(sys/uio.h, [AC_CHECK_FUNCS(writev)])
 249
 250 dnl check for flavours of varargs macros (test from GLib)
 251 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 252 AC_TRY_COMPILE([],[
 253 int a(int p1, int p2, int p3);
 254 #define call_a(...) a(1,__VA_ARGS__)
 255 call_a(2,3);
 256 ],dbus_have_iso_c_varargs=yes,dbus_have_iso_c_varargs=no)
 257 AC_MSG_RESULT($dbus_have_iso_c_varargs)
 258
 259 AC_MSG_CHECKING(for GNUC varargs macros)
 260 AC_TRY_COMPILE([],[
 261 int a(int p1, int p2, int p3);
 262 #define call_a(params...) a(1,params)
 263 call_a(2,3);
 264 ],dbus_have_gnuc_varargs=yes,dbus_have_gnuc_varargs=no)
 265 AC_MSG_RESULT($dbus_have_gnuc_varargs)
 266
 267 dnl Output varargs tests
 268 if test x$dbus_have_iso_c_varargs = xyes; then
 269     AC_DEFINE(HAVE_ISO_VARARGS,1,[Have ISO C99 varargs macros])
 270 fi
 271 if test x$dbus_have_gnuc_varargs = xyes; then
 272     AC_DEFINE(HAVE_GNUC_VARARGS,1,[Have GNU-style varargs macros])
 273 fi
 274
 275 dnl Check for various credentials.
 276 AC_MSG_CHECKING(for struct cmsgcred)
 277 AC_TRY_COMPILE([
 278 #include <sys/types.h>
 279 #include <sys/socket.h>
 280 ],[
 281 struct cmsgcred cred;
 282
 283 cred.cmcred_pid = 0;
 284 ],dbus_have_struct_cmsgcred=yes,dbus_have_struct_cmsgcred=no)
 285 AC_MSG_RESULT($dbus_have_struct_cmsgcred)
 286
 287 if test x$dbus_have_struct_cmsgcred = xyes; then
 288     AC_DEFINE(HAVE_CMSGCRED,1,[Have cmsgcred structure])
 289 fi
 290
 291
 292 #### Sort out XML library
 293
 294 # see what we have
 295 AC_CHECK_LIB(expat, XML_ParserCreate_MM,
 296              [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ],
 297              have_expat=false)
 298
 299 PKG_CHECK_MODULES(LIBXML, libxml-2.0, have_libxml=true, have_libxml=false)
 300
 301 # see what we want to use
 302 dbus_use_libxml=false
 303 dbus_use_expat=false
 304 if test x$with_xml = xexpat; then
 305         dbus_use_expat=true
 306         if ! $have_expat ; then
 307            AC_MSG_ERROR([Explicitly requested expat but expat not found])
 308         fi
 309 elif test x$with_xml = xlibxml; then
 310         dbus_use_libxml=true
 311         if ! $have_libxml ; then
 312            AC_MSG_ERROR([Explicitly requested libxml but libxml not found])
 313         fi
 314 else
 315         ### expat is the default because libxml can't currently survive
 316         ### our brutal OOM-handling unit test setup.
 317         ### http://bugzilla.gnome.org/show_bug.cgi?id=109368
 318         if $have_expat ; then
 319                 with_xml=expat
 320                 dbus_use_expat=true
 321         elif $have_libxml ; then
 322                 with_xml=libxml
 323                 dbus_use_libxml=true
 324         else
 325                 AC_MSG_ERROR([No XML library found, check config.log for failed attempts])
 326         fi
 327 fi
 328
 329 AM_CONDITIONAL(DBUS_USE_EXPAT, $dbus_use_expat)
 330 AM_CONDITIONAL(DBUS_USE_LIBXML, $dbus_use_libxml)
 331
 332 if $dbus_use_expat; then
 333    XML_LIBS=-lexpat
 334    XML_CFLAGS=
 335 fi
 336 if $dbus_use_libxml; then
 337    XML_LIBS=$LIBXML_LIBS
 338    XML_CFLAGS=$LIBXML_CFLAGS
 339 fi
 340
 341 #### Set up final flags
 342 DBUS_CLIENT_CFLAGS=
 343 DBUS_CLIENT_LIBS=
 344 AC_SUBST(DBUS_CLIENT_CFLAGS)
 345 AC_SUBST(DBUS_CLIENT_LIBS)
 346
 347 DBUS_BUS_CFLAGS=$XML_CFLAGS
 348 DBUS_BUS_LIBS=$XML_LIBS
 349 AC_SUBST(DBUS_BUS_CFLAGS)
 350 AC_SUBST(DBUS_BUS_LIBS)
 351
 352 DBUS_TEST_CFLAGS=
 353 DBUS_TEST_LIBS=
 354 AC_SUBST(DBUS_TEST_CFLAGS)
 355 AC_SUBST(DBUS_TEST_LIBS)
 356
 357 # Glib detection
 358 PKG_CHECK_MODULES(DBUS_GLIB, glib-2.0, have_glib=yes, have_glib=no)
 359 PKG_CHECK_MODULES(DBUS_GLIB_THREADS, glib-2.0 gthread-2.0, have_glib_threads=yes, have_glib_threads=no)
 360
 361 if test x$have_glib = xno ; then
 362     AC_MSG_WARN([GLib development libraries not found])
 363 fi
 364
 365 if test x$enable_glib = xyes; then
 366     if test x$have_glib = xno; then
 367         AC_MSG_ERROR([GLib explicitly required, and GLib development libraries not found])
 368     fi
 369 fi
 370
 371 if test x$enable_glib = xno; then
 372    have_glib=no;
 373 fi
 374
 375 AM_CONDITIONAL(HAVE_GLIB, test x$have_glib = xyes)
 376 AM_CONDITIONAL(HAVE_GLIB_THREADS, test x$have_glib_threads = xyes)
 377
 378 dnl GLib flags
 379 AC_SUBST(DBUS_GLIB_CFLAGS)
 380 AC_SUBST(DBUS_GLIB_LIBS)
 381 AC_SUBST(DBUS_GLIB_THREADS_LIBS)
 382
 383 # Qt detection
 384 have_qt=no
 385 AC_MSG_CHECKING([for qglobal.h])
 386 if test -n "$QTDIR" -a -f "$QTDIR/include/qglobal.h"; then
 387     have_qt=yes
 388     DBUS_QT_CXXFLAGS="-I$QTDIR/include"
 389 else
 390     for dir in "${prefix}/include/qt" "/usr/include/qt-3.1" "/usr/include/qt3" "/usr/include/qt" "/usr/lib/qt/include"; do
 391         if test -f "$dir/qglobal.h"; then
 392             have_qt=yes
 393             DBUS_QT_CXXFLAGS="-I$dir"
 394        fi
 395     done
 396 fi
 397 if test x"$have_qt" = x"yes"; then
 398    AC_MSG_RESULT([found])
 399 else
 400    AC_MSG_RESULT([not found])
 401 fi
 402
 403 dnl linking to kdecore will give us a bit of help from libtool
 404 if (! kde-config >& /dev/null); then
 405     have_qt=no
 406 else
 407     kdelibs=`kde-config --install lib --expandvars 2>/dev/null`
 408     if test -z $kdelibs -o ! -f $kdelibs/libkdecore.la; then
 409         have_qt=no
 410     else
 411         DBUS_QT_LIBS="$kdelibs/libkdecore.la"
 412     fi
 413 fi
 414
 415 if test x$have_qt = xno ; then
 416     AC_MSG_WARN([Qt development libraries not found])
 417 fi
 418
 419 if test x$enable_qt = xyes; then
 420     if test x$have_qt = xno; then
 421         AC_MSG_ERROR([Qt integration explicitly required, and Qt libraries not found])
 422     fi
 423 fi
 424
 425 if test x$enable_qt = xno; then
 426    have_qt=no;
 427 fi
 428
 429 AM_CONDITIONAL(HAVE_QT, test x$have_qt = xyes)
 430
 431 dnl Qt flags
 432 AC_SUBST(DBUS_QT_CXXFLAGS)
 433 AC_SUBST(DBUS_QT_LIBS)
 434
 435 ### Documentation
 436
 437 AC_PATH_PROG(DOXYGEN, doxygen, no)
 438 AC_PATH_PROG(DB2HTML, db2html, no)
 439
 440 AC_MSG_CHECKING([whether to build documentation])
 441
 442 if test x$DOXYGEN = xno -o x$DB2HTML = xno ; then
 443     have_docs_tools=no
 444 else
 445     have_docs_tools=yes
 446 fi
 447
 448 if test x$enable_docs = xauto ; then
 449     if test x$have_docs_tools = xno ; then
 450         enable_docs=no
 451     else
 452         enable_docs=yes
 453     fi
 454 fi
 455
 456 if test x$enable_docs = xyes; then
 457     if test x$have_docs_tools = xno; then
 458         AC_MSG_ERROR([Building docs explicitly required, but Doxygen or db2html not found])
 459     fi
 460 fi
 461
 462 AM_CONDITIONAL(DBUS_DOCS_ENABLED, test x$enable_docs = xyes)
 463 AC_MSG_RESULT(yes)
 464
 465 #### find the actual value for $prefix that we'll end up with
 466 ##   (I know this is broken and should be done in the Makefile, but
 467 ##    that's a major pain and almost nobody actually seems to care)
 468 REAL_PREFIX=
 469 if test "x$prefix" = "xNONE"; then
 470   REAL_PREFIX=$ac_default_prefix
 471 else
 472   REAL_PREFIX=$prefix
 473 fi
 474
 475 #### Have to go $localstatedir->$prefix/var->/usr/local/var
 476 #### someone please fix this a better way...
 477 LOCALSTATEDIR_TMP="$localstatedir"
 478 old_prefix=$prefix
 479 prefix=$REAL_PREFIX
 480 EXPANDED_LOCALSTATEDIR=`eval echo $LOCALSTATEDIR_TMP`
 481 prefix=$old_prefix
 482 AC_SUBST(EXPANDED_LOCALSTATEDIR)
 483
 484 SYSCONFDIR_TMP="$sysconfdir"
 485 old_prefix=$prefix
 486 prefix=$REAL_PREFIX
 487 EXPANDED_SYSCONFDIR=`eval echo $SYSCONFDIR_TMP`
 488 prefix=$old_prefix
 489 AC_SUBST(EXPANDED_SYSCONFDIR)
 490
 491 BINDIR_TMP="$bindir"
 492 old_prefix=$prefix
 493 prefix=$REAL_PREFIX
 494 EXPANDED_BINDIR=`eval echo $BINDIR_TMP`
 495 prefix=$old_prefix
 496 AC_SUBST(EXPANDED_BINDIR)
 497
 498 #### Check our operating system
 499 operating_system=unknown
 500 if test -f /etc/redhat-release || test -f $EXPANDED_SYSCONFDIR/redhat-release ; then
 501    operating_system=redhat
 502 fi
 503
 504 #### Sort out init scripts
 505
 506 if test x$with_init_scripts = x; then
 507     if test xredhat = x$operating_system ; then
 508         with_init_scripts=redhat
 509     else
 510         with_init_scripts=none
 511     fi
 512 fi
 513
 514 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_RED_HAT, test x$with_init_scripts = xredhat)
 515
 516
 517 ##### Set up location for system bus socket
 518 if ! test -z "$with_system_socket"; then
 519    DBUS_SYSTEM_SOCKET=$with_system_socket
 520 else
 521    DBUS_SYSTEM_SOCKET=${EXPANDED_LOCALSTATEDIR}/run/dbus/system_bus_socket
 522 fi
 523
 524 AC_SUBST(DBUS_SYSTEM_SOCKET)
 525
 526 #### Set up the pid file
 527 if ! test -z "$with_system_pid_file"; then
 528    DBUS_SYSTEM_PID_FILE=$with_system_pid_file
 529 elif test x$operating_system = xredhat ; then
 530    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/messagebus.pid
 531 else
 532    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/dbus/pid
 533 fi
 534
 535 AC_SUBST(DBUS_SYSTEM_PID_FILE)
 536
 537 #### Tell tests where to find certain stuff in builddir
 538 ABSOLUTE_TOP_BUILDDIR=`cd ${ac_top_builddir}. && pwd`
 539
 540 AC_DEFUN(TEST_PATH, [
 541 TEST_$1=${ABSOLUTE_TOP_BUILDDIR}/test/$2
 542 AC_DEFINE_UNQUOTED(TEST_$1, "$TEST_$1",
 543                    [Full path to test file test/$2 in builddir])
 544 AC_SUBST(TEST_$1)
 545 ])
 546
 547 TEST_PATH(SERVICE_DIR, data/valid-service-files)
 548 TEST_PATH(SERVICE_BINARY, test-service)
 549 TEST_PATH(EXIT_BINARY, test-exit)
 550 TEST_PATH(SEGFAULT_BINARY, test-segfault)
 551 TEST_PATH(SLEEP_FOREVER_BINARY, test-sleep-forever)
 552
 553 #### Find socket directories
 554 if ! test -z "$TMPDIR" ; then
 555    DEFAULT_SOCKET_DIR=$TMPDIR
 556 elif ! test -z "$TEMP" ; then
 557    DEFAULT_SOCKET_DIR=$TEMP
 558 elif ! test -z "$TMP" ; then
 559    DEFAULT_SOCKET_DIR=$TMP
 560 else
 561    DEFAULT_SOCKET_DIR=/tmp
 562 fi
 563
 564 if ! test -z "$with_test_socket_dir" ; then
 565    TEST_SOCKET_DIR="$with_test_socket_dir"
 566 else
 567    TEST_SOCKET_DIR=$DEFAULT_SOCKET_DIR
 568 fi
 569 AC_SUBST(TEST_SOCKET_DIR)
 570
 571 if ! test -z "$with_session_socket_dir" ; then
 572    DBUS_SESSION_SOCKET_DIR="$with_session_socket_dir"
 573 else
 574    DBUS_SESSION_SOCKET_DIR=$DEFAULT_SOCKET_DIR
 575 fi
 576 AC_SUBST(DBUS_SESSION_SOCKET_DIR)
 577
 578
 579 AC_OUTPUT([
 580 Doxyfile
 581 bus/system.conf
 582 bus/session.conf
 583 bus/messagebus
 584 Makefile
 585 dbus/Makefile
 586 dbus/dbus-arch-deps.h
 587 glib/Makefile
 588 qt/Makefile
 589 bus/Makefile
 590 tools/Makefile
 591 test/Makefile
 592 doc/Makefile
 593 dbus-1.0.pc
 594 dbus-glib-1.0.pc
 595 test/data/valid-config-files/debug-allow-all.conf
 596 test/data/valid-config-files/debug-allow-all-sha1.conf
 597 test/data/valid-service-files/debug-echo.service
 598 test/data/valid-service-files/debug-segfault.service
 599 ])
 600
 601 dnl ==========================================================================
 602 echo "
 603                     D-BUS $VERSION
 604                   ==============
 605
 606         prefix:                   ${prefix}
 607         source code location:     ${srcdir}
 608         compiler:                 ${CC}
 609         cflags:                   ${CFLAGS}
 610         Doxygen:                  ${DOXYGEN}
 611         db2html:                  ${DB2HTML}
 612
 613         Maintainer mode:          ${USE_MAINTAINER_MODE}
 614         gcc coverage profiling:   ${enable_gcov}
 615         Building unit tests:      ${enable_tests}
 616         Building verbose mode:    ${enable_verbose_mode}
 617         Building assertions:      ${enable_asserts}
 618         Building checks:          ${enable_checks}
 619         Building Qt bindings:     ${have_qt}
 620         Building GLib bindings:   ${have_glib}
 621         Building documentation:   ${enable_docs}
 622         Using XML parser:         ${with_xml}
 623         Init scripts style:       ${with_init_scripts}
 624         System bus socket:        ${DBUS_SYSTEM_SOCKET}
 625         System bus PID file:      ${DBUS_SYSTEM_PID_FILE}
 626         Session bus socket dir:   ${DBUS_SESSION_SOCKET_DIR}
 627         'make check' socket dir:  ${TEST_SOCKET_DIR}
 628 "
 629
 630 if test x$enable_tests = xyes; then
 631         echo "NOTE: building with unit tests increases the size of the installed library and renders it insecure."
 632 fi
 633 if test x$enable_gcov = xyes; then
 634         echo "NOTE: building with coverage profiling is definitely for developers only."
 635 fi
 636 if test x$enable_verbose_mode = xyes; then
 637         echo "NOTE: building with verbose mode increases library size, may slightly increase security risk, and decreases performance."
 638 fi
 639 if test x$enable_asserts = xyes; then
 640         echo "NOTE: building with assertions increases library size and decreases performance."
 641 fi
 642 if test x$enable_checks = xno; then
 643         echo "NOTE: building without checks for arguments passed to public API makes it harder to debug apps using D-BUS, but will slightly decrease D-BUS library size and _very_ slightly improve performance."
 644 fi