configure.in

   1 dnl ***********************************
   2 dnl *** include special GLib macros ***
   3 dnl ***********************************
   4 builtin(include, acglib.m4)dnl
   5
   6 # require autoconf 2.13
   7 AC_PREREQ(2.13)
   8
   9 # Process this file with autoconf to produce a configure script.
  10 AC_INIT(glist.c)
  11
  12 # Save this value here, since automake will set cflags later
  13 cflags_set=${CFLAGS+set}
  14
  15 # we rewrite this file
  16 rm -f glibconfig-sysdefs.h
  17
  18 GLIB_AC_DIVERT_BEFORE_HELP([
  19 #
  20 # The following version number definitions apply to GLib, GModule, GObject
  21 # and GThread as a whole, so if changes occoured in any of them, they are all
  22 # treated with the same interface and binary age.
  23 #
  24 # Making releases:
  25 #   GLIB_MICRO_VERSION += 1;
  26 #   GLIB_INTERFACE_AGE += 1;
  27 #   GLIB_BINARY_AGE += 1;
  28 # if any functions have been added, set GLIB_INTERFACE_AGE to 0.
  29 # if backwards compatibility has been broken,
  30 # set GLIB_BINARY_AGE _and_ GLIB_INTERFACE_AGE to 0.
  31 #
  32 GLIB_MAJOR_VERSION=1
  33 GLIB_MINOR_VERSION=3
  34 GLIB_MICRO_VERSION=2
  35 GLIB_INTERFACE_AGE=0
  36 GLIB_BINARY_AGE=0
  37 GLIB_VERSION=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION.$GLIB_MICRO_VERSION
  38 ])dnl
  39
  40 AC_SUBST(GLIB_MAJOR_VERSION)
  41 AC_SUBST(GLIB_MINOR_VERSION)
  42 AC_SUBST(GLIB_MICRO_VERSION)
  43 AC_SUBST(GLIB_VERSION)
  44 AC_SUBST(GLIB_INTERFACE_AGE)
  45 AC_SUBST(GLIB_BINARY_AGE)
  46
  47 # libtool versioning
  48 LT_RELEASE=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION
  49 LT_CURRENT=`expr $GLIB_MICRO_VERSION - $GLIB_INTERFACE_AGE`
  50 LT_REVISION=$GLIB_INTERFACE_AGE
  51 LT_AGE=`expr $GLIB_BINARY_AGE - $GLIB_INTERFACE_AGE`
  52 AC_SUBST(LT_RELEASE)
  53 AC_SUBST(LT_CURRENT)
  54 AC_SUBST(LT_REVISION)
  55 AC_SUBST(LT_AGE)
  56
  57 VERSION=$GLIB_VERSION
  58 PACKAGE=glib
  59
  60 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  61
  62 # Specify a configuration file
  63 AM_CONFIG_HEADER(config.h)
  64
  65 AC_DEFINE_UNQUOTED(GLIB_MAJOR_VERSION, $GLIB_MAJOR_VERSION,
  66                    [Define to the GLIB major version])
  67 AC_DEFINE_UNQUOTED(GLIB_MINOR_VERSION, $GLIB_MINOR_VERSION,
  68                    [Define to the GLIB minor version])
  69 AC_DEFINE_UNQUOTED(GLIB_MICRO_VERSION, $GLIB_MICRO_VERSION,
  70                    [Define to the GLIB micro version])
  71 AC_DEFINE_UNQUOTED(GLIB_INTERFACE_AGE, $GLIB_INTERFACE_AGE,
  72                    [Define to the GLIB interface age])
  73 AC_DEFINE_UNQUOTED(GLIB_BINARY_AGE, $GLIB_BINARY_AGE,
  74                    [Define to the GLIB binary age])
  75
  76 dnl Initialize maintainer mode
  77 AM_MAINTAINER_MODE
  78
  79 AC_CANONICAL_HOST
  80
  81 AC_MSG_CHECKING(for the BeOS)
  82 case $host in
  83   *-*-beos*)
  84     glib_native_beos="yes"
  85     ;;
  86   *)
  87     glib_native_beos="no"
  88     ;;
  89 esac
  90 AC_MSG_RESULT([$glib_native_beos])
  91
  92 dnl
  93
  94 GLIB_AC_DIVERT_BEFORE_HELP([
  95 # figure debugging default, prior to $ac_help setup
  96 case $GLIB_MINOR_VERSION in
  97 *[[13579]]) debug_default=yes ;;
  98 *)          debug_default=minimum ;;
  99 esac[]dnl
 100 ])
 101
 102 dnl declare --enable-* args and collect ac_help strings
 103 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=$debug_default]],,enable_debug=$debug_default)
 104 AC_ARG_ENABLE(msg-prefix, [  --enable-msg-prefix     turn on program name and PID prefixing of messages and warnings],,enable_msg_prefix=no)
 105 AC_ARG_ENABLE(gc_friendly, [  --enable-gc-friendly    turn on garbage collector friendliness [default=no]],,enable_gc_friendly=no)
 106 AC_ARG_ENABLE(mem_pools, [  --disable-mem-pools     disable all glib memory pools],,disable_mem_pools=no)
 107 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
 108                     , enable_ansi=no)
 109 AC_ARG_ENABLE(threads, [  --enable-threads        turn on basic thread support [default=yes]
 110                           ([=no] will override --with-threads)],,enable_threads=yes)
 111 AC_ARG_ENABLE(rebuilds, [  --disable-rebuilds      disable all source autogeneration rules],,enable_rebuilds=yes)
 112
 113 if test "x$enable_threads" != "xyes"; then
 114   enable_threads=no
 115 fi
 116
 117 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 118         [Whether glib was compiled with debugging enabled])
 119
 120 AC_MSG_CHECKING(whether to enable garbage collector friendliness)
 121 if test "x$enable_gc_friendly" = "xyes"; then
 122   AC_DEFINE(ENABLE_GC_FRIENDLY, 1, [Whether to enable GC friendliness])
 123   AC_SUBST(ENABLE_GC_FRIENDLY)
 124   AC_MSG_RESULT(yes)
 125 else
 126   AC_MSG_RESULT(no)
 127 fi
 128
 129 AC_MSG_CHECKING(whether to disable memory pools)
 130 if test "x$disable_mem_pools" = "xno"; then
 131   AC_MSG_RESULT(no)
 132 else
 133   AC_DEFINE(DISABLE_MEM_POOLS, 1, [Whether to disable memory pools])
 134   AC_SUBST(DISABLE_MEM_POOLS)
 135   AC_MSG_RESULT(yes)
 136 fi
 137
 138 if test "x$enable_msg_prefix" = "xyes"; then
 139   AC_DEFINE_UNQUOTED(G_ENABLE_MSG_PREFIX, 1,
 140                      [Enable prefixing of error messages with program names])
 141 fi
 142
 143 dnl Checks for programs.
 144 AC_PROG_CC
 145
 146 AM_PROG_CC_STDC
 147 AC_PROG_INSTALL
 148
 149 if test "x$enable_debug" = "xyes"; then
 150   if test x$cflags_set != xset ; then
 151       case " $CFLAGS " in
 152       *[[\ \    ]]-g[[\ \       ]]*) ;;
 153       *) CFLAGS="$CFLAGS -g" ;;
 154       esac
 155   fi
 156
 157   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 158 else
 159   if test "x$enable_debug" = "xno"; then
 160     GLIB_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 161   fi
 162 fi
 163
 164 # define a MAINT-like variable REBUILD which is set if Perl
 165 # and awk are found, so autogenerated sources can be rebuilt
 166 AC_PROG_AWK
 167 AC_CHECK_PROGS(PERL, perl5 perl)
 168 # We would like indent, but don't require it.
 169 AC_CHECK_PROG(INDENT, indent, indent)
 170 REBUILD=\#
 171 if test "x$enable_rebuilds" = "xyes" && \
 172      test -n "$PERL" && \
 173      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 174      test -n "$AWK" ; then
 175   REBUILD=
 176 fi
 177 AC_SUBST(REBUILD)
 178
 179
 180 dnl
 181 dnl gettext support
 182 dnl
 183
 184 ALL_LINGUAS="no tr uk"
 185 AM_GLIB_GNU_GETTEXT
 186 LIBS="$LIBS $INTLLIBS"
 187
 188 GETTEXT_PACKAGE=glib20
 189 AC_SUBST(GETTEXT_PACKAGE)
 190 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE")
 191
 192 # AM_GLIB_GNU_GETTEXT above substs $DATADIRNAME
 193 # this is the directory where the *.{mo,gmo} files are installed
 194 GLIB_LOCALE_DIR="${prefix}/${DATADIRNAME}/locale"
 195 AC_DEFINE_UNQUOTED(GLIB_LOCALE_DIR,"$GLIB_LOCALE_DIR")
 196
 197
 198 dnl Initialize libtool
 199 AM_PROG_LIBTOOL
 200
 201 if test "x$GCC" = "xyes"; then
 202   case " $CFLAGS " in
 203   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 204   *) CFLAGS="$CFLAGS -Wall" ;;
 205   esac
 206
 207   if test "x$enable_ansi" = "xyes"; then
 208     case " $CFLAGS " in
 209     *[[\ \      ]]-ansi[[\ \    ]]*) ;;
 210     *) CFLAGS="$CFLAGS -ansi" ;;
 211     esac
 212
 213     case " $CFLAGS " in
 214     *[[\ \      ]]-pedantic[[\ \        ]]*) ;;
 215     *) CFLAGS="$CFLAGS -pedantic" ;;
 216     esac
 217   fi
 218 fi
 219
 220 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 221 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 222 glib_save_LIBS=$LIBS
 223 LIBS="$LIBS -lm"
 224 AC_TRY_RUN([#include <math.h>
 225              int main (void) { return (log(1) != log(1.)); }],
 226      AC_MSG_RESULT(none needed),
 227      glib_save_CFLAGS=$CFLAGS
 228      CFLAGS="$CFLAGS -std1"
 229      AC_TRY_RUN([#include <math.h>
 230                  int main (void) { return (log(1) != log(1.)); }],
 231          AC_MSG_RESULT(-std1),
 232          AC_MSG_RESULT()
 233          CFLAGS=$glib_save_CFLAGS
 234          AC_MSG_WARN(
 235                 [No ANSI prototypes found in library. (-std1 didn't work.)])
 236      )
 237 )
 238 LIBS=$glib_save_LIBS
 239
 240 dnl NeXTStep cc seems to need this
 241 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 242 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 243   AC_MSG_RESULT(none needed),
 244   glib_save_CFLAGS=$CFLAGS
 245   CFLAGS="$CFLAGS -posix"
 246   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 247     AC_MSG_RESULT(-posix),
 248     AC_MSG_RESULT()
 249     CFLAGS=$glib_save_CFLAGS
 250     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 251
 252 # Checks for header files.
 253 AC_HEADER_STDC
 254
 255 # Checks for library functions.
 256 AC_FUNC_VPRINTF
 257
 258 AC_FUNC_ALLOCA
 259
 260 AC_CHECK_FUNCS(atexit on_exit)
 261
 262 AC_CHECK_SIZEOF(char)
 263 AC_CHECK_SIZEOF(short)
 264 AC_CHECK_SIZEOF(long)
 265 AC_CHECK_SIZEOF(int)
 266 AC_CHECK_SIZEOF(void *)
 267 AC_CHECK_SIZEOF(long long)
 268
 269 if test x$ac_cv_sizeof_long_long = x8; then
 270         # long long is a 64 bit integer.
 271         AC_MSG_CHECKING(for format to printf and scanf a gint64)
 272         AC_CACHE_VAL(glib_cv_long_long_format,[
 273                 for format in ll q; do
 274                   AC_TRY_RUN([#include <stdio.h>
 275                         int main()
 276                         {
 277                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 278                           char buffer[1000];
 279                           sprintf (buffer, "%${format}u", a);
 280                           sscanf (buffer, "%${format}u", &b);
 281                           exit (b!=a);
 282                         }
 283                         ],
 284                         glib_cv_long_long_format=${format}
 285                         break)
 286                 done])
 287         if test -n "$glib_cv_long_long_format"; then
 288           AC_MSG_RESULT(%${glib_cv_long_long_format}i)
 289         else
 290           AC_MSG_RESULT(none)
 291         fi
 292 fi
 293
 294 dnl long doubles were not used, and a portability problem
 295 dnl AC_C_LONG_DOUBLE
 296 AC_C_CONST
 297
 298 dnl ok, here we try to check whether the systems prototypes for
 299 dnl malloc and friends actually match the prototypes provided
 300 dnl by gmem.h (keep in sync). i currently only know how to check
 301 dnl this reliably with gcc (-Werror), improvements for other
 302 dnl compilers are apprechiated.
 303 SANE_MALLOC_PROTOS=no
 304 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 305 glib_save_CFLAGS=$CFLAGS
 306 if test "x$GCC" = "xyes"; then
 307   CFLAGS="$CFLAGS -Werror"
 308   AC_TRY_COMPILE([#include <stdlib.h>], [
 309     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 310     void* (*my_malloc_p)  (size_t)         = malloc;
 311     void  (*my_free_p)    (void*)          = free;
 312     void* (*my_realloc_p) (void*, size_t)  = realloc;
 313     my_calloc_p = 0;
 314     my_malloc_p = 0;
 315     my_free_p = 0;
 316     my_realloc_p = 0;
 317   ],
 318     AC_DEFINE(SANE_MALLOC_PROTOS)
 319     SANE_MALLOC_PROTOS=yes)
 320 fi
 321 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 322 CFLAGS=$glib_save_CFLAGS
 323
 324
 325 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 326 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 327 dnl actually supported.
 328 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 329         AC_TRY_RUN([
 330         __inline int foo () { return 0; }
 331         int main () { return foo (); }
 332         ],
 333         glib_cv_has__inline=yes
 334         ,
 335         glib_cv_has__inline=no
 336         ,)
 337 ])
 338 case x$glib_cv_has__inline in
 339 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 340 esac
 341 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 342         AC_TRY_RUN([
 343         __inline__ int foo () { return 0; }
 344         int main () { return foo (); }
 345         ],
 346         glib_cv_has__inline__=yes
 347         ,
 348         glib_cv_has__inline__=no
 349         ,)
 350 ])
 351 case x$glib_cv_has__inline__ in
 352 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 353 esac
 354 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 355         AC_TRY_RUN([
 356         inline int foo () { return 0; }
 357         int main () { return foo (); }
 358         ],
 359         glib_cv_hasinline=yes
 360         ,
 361         glib_cv_hasinline=no
 362         ,)
 363 ])
 364 case x$glib_cv_hasinline in
 365 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 366 esac
 367
 368 # check for bytesex stuff
 369 AC_C_BIGENDIAN
 370
 371 # check for header files
 372 AC_CHECK_HEADERS([float.h limits.h pwd.h sys/param.h sys/poll.h sys/select.h])
 373 AC_CHECK_HEADERS([sys/time.h sys/times.h unistd.h values.h stdint.h sched.h])
 374
 375 AC_MSG_CHECKING(whether make is GNU Make)
 376 STRIP_BEGIN=
 377 STRIP_END=
 378 if $ac_make --version 2>/dev/null | grep '^GNU Make ' >/dev/null ; then
 379         STRIP_BEGIN='$(strip $(STRIP_DUMMY)'
 380         STRIP_END=')'
 381         AC_MSG_RESULT(yes)
 382 else
 383         AC_MSG_RESULT(no)
 384 fi
 385 STRIP_DUMMY=
 386 AC_SUBST(STRIP_DUMMY)
 387 AC_SUBST(STRIP_BEGIN)
 388 AC_SUBST(STRIP_END)
 389
 390 # check additional type sizes
 391 size_includes=["
 392 #include <stdarg.h>
 393 #include <stdio.h>
 394 #include <ctype.h>
 395 #include <string.h>
 396 "]
 397 if test "x$ac_cv_header_stdint_h" = "xyes"; then
 398   size_includes=["$size_includes
 399 #include <stdint.h>
 400 "]
 401 fi
 402 if test "x$ac_cv_header_unistd_h" = "xyes"; then
 403   size_includes=["$size_includes
 404 #include <unistd.h>
 405 "]
 406 fi
 407 GLIB_SIZEOF([$size_includes], size_t, size_t)
 408 GLIB_SIZEOF([$size_includes], ptrdiff_t, ptrdiff_t)
 409 GLIB_SIZEOF([$size_includes], intmax_t, intmax_t)
 410
 411 # Check for some functions
 412 AC_CHECK_FUNCS(lstat strerror strsignal memmove mkstemp vsnprintf strcasecmp strncasecmp poll getcwd)
 413
 414 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
 415 # The check is borrowed from the PERL Configure script.
 416 if test "$ac_cv_func_memmove" != "yes"; then
 417   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
 418     glib_cv_working_bcopy,[AC_TRY_RUN([
 419       int main() {
 420         char buf[128], abc[128], *b;
 421         int len, off, align;
 422         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
 423         for (align = 7; align >= 0; align--) {
 424           for (len = 36; len; len--) {
 425             b = buf+align; bcopy(abc, b, len);
 426             for (off = 1; off <= len; off++) {
 427               bcopy(b, b+off, len); bcopy(b+off, b, len);
 428                 if (bcmp(b, abc, len)) return(1);
 429             }
 430           }
 431         }
 432         return(0);
 433       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
 434   if test "$glib_cv_working_bcopy" = "yes"; then
 435     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
 436   fi
 437 fi
 438
 439 # Check for sys_errlist
 440 AC_MSG_CHECKING(for sys_errlist)
 441 AC_TRY_LINK(, [
 442 extern char *sys_errlist[];
 443 extern int sys_nerr;
 444 sys_errlist[sys_nerr-1][0] = 0;
 445 ], glib_ok=yes, glib_ok=no)
 446 AC_MSG_RESULT($glib_ok)
 447 if test $glib_ok = no; then
 448     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
 449 fi
 450
 451 # Check for sys_siglist
 452 AC_MSG_CHECKING(for sys_siglist)
 453 AC_TRY_LINK(, [
 454 extern char *sys_siglist[];
 455 exit (sys_siglist[0]);
 456 ], glib_ok=yes, glib_ok=no)
 457 AC_MSG_RESULT($glib_ok)
 458 if test $glib_ok = no; then
 459     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
 460 fi
 461
 462 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
 463 AC_MSG_CHECKING(for sys_siglist declaration)
 464 AC_TRY_COMPILE([#include <signal.h>], [
 465 strlen (sys_siglist[0]);
 466 ], glib_ok=yes, glib_ok=no)
 467 AC_MSG_RESULT($glib_ok)
 468 if test $glib_ok = no; then
 469     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
 470 fi
 471
 472 # Check if <sys/select.h> needs to be included for fd_set
 473 AC_MSG_CHECKING([for fd_set])
 474 AC_TRY_COMPILE([#include <sys/types.h>],
 475         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 476 if test $gtk_ok = yes; then
 477     AC_MSG_RESULT([yes, found in sys/types.h])
 478 else
 479     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
 480     if test $gtk_ok = yes; then
 481         # *** FIXME: give it a different name
 482         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
 483         AC_MSG_RESULT([yes, found in sys/select.h])
 484     else
 485         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
 486         AC_MSG_RESULT(no)
 487     fi
 488 fi
 489
 490 dnl *** check for sane realloc() ***
 491 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
 492         AC_TRY_RUN([
 493         #include <stdlib.h>
 494         int main() {
 495           return realloc (0, sizeof (int)) == 0;
 496         }],
 497         [glib_cv_sane_realloc=yes],
 498         [glib_cv_sane_realloc=no],
 499         [])
 500 ])
 501 if test x$glib_cv_sane_realloc = xyes; then
 502   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
 503 fi
 504
 505 dnl Check for nl_langinfo and CODESET
 506
 507 AC_MSG_CHECKING([for nl_langinfo (CODESET)])
 508 AC_TRY_COMPILE([#include <langinfo.h>],
 509         [char *codeset = nl_langinfo (CODESET);],
 510    AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
 511    have_codeset=yes,
 512    have_codeset=no)
 513 AC_MSG_RESULT($have_codeset)
 514
 515
 516 dnl ****************************************
 517 dnl *** strlcpy/strlcat                  ***
 518 dnl ****************************************
 519 # Check for strlcpy
 520 AC_MSG_CHECKING(for strlcpy/strlcat)
 521 AC_TRY_LINK([#include <stdlib.h>
 522 #include <string.h>], [
 523 char *p = malloc(10);
 524 (void) strlcpy(p, "hi", 10);
 525 (void) strlcat(p, "bye", 10);
 526 ], glib_ok=yes, glib_ok=no)
 527 AC_MSG_RESULT($glib_ok)
 528 if test $glib_ok = yes; then
 529     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
 530 fi
 531
 532
 533 dnl **********************
 534 dnl *** va_copy checks ***
 535 dnl **********************
 536 dnl we currently check for all three va_copy possibilities, so we get
 537 dnl all results in config.log for bug reports.
 538 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
 539         AC_TRY_RUN([
 540         #include <stdarg.h>
 541         void f (int i, ...) {
 542         va_list args1, args2;
 543         va_start (args1, i);
 544         va_copy (args2, args1);
 545         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 546           exit (1);
 547         va_end (args1); va_end (args2);
 548         }
 549         int main() {
 550           f (0, 42);
 551           return 0;
 552         }],
 553         [glib_cv_va_copy=yes],
 554         [glib_cv_va_copy=no],
 555         [])
 556 ])
 557 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
 558         AC_TRY_RUN([
 559         #include <stdarg.h>
 560         void f (int i, ...) {
 561         va_list args1, args2;
 562         va_start (args1, i);
 563         __va_copy (args2, args1);
 564         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 565           exit (1);
 566         va_end (args1); va_end (args2);
 567         }
 568         int main() {
 569           f (0, 42);
 570           return 0;
 571         }],
 572         [glib_cv___va_copy=yes],
 573         [glib_cv___va_copy=no],
 574         [])
 575 ])
 576
 577 if test "x$glib_cv_va_copy" = "xyes"; then
 578   g_va_copy_func=va_copy
 579 else if test "x$glib_cv___va_copy" = "xyes"; then
 580   g_va_copy_func=__va_copy
 581 fi
 582 fi
 583
 584 if test -n "$g_va_copy_func"; then
 585   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
 586 fi
 587
 588 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
 589         AC_TRY_RUN([
 590         #include <stdarg.h>
 591         void f (int i, ...) {
 592         va_list args1, args2;
 593         va_start (args1, i);
 594         args2 = args1;
 595         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 596           exit (1);
 597         va_end (args1); va_end (args2);
 598         }
 599         int main() {
 600           f (0, 42);
 601           return 0;
 602         }],
 603         [glib_cv_va_val_copy=yes],
 604         [glib_cv_va_val_copy=no],
 605         [])
 606 ])
 607
 608 if test "x$glib_cv_va_val_copy" = "xno"; then
 609   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 610 fi
 611
 612 dnl ***********************
 613 dnl *** g_module checks ***
 614 dnl ***********************
 615 G_MODULE_LIBS=
 616 G_MODULE_LIBS_EXTRA=
 617 G_MODULE_PLUGIN_LIBS=
 618 G_MODULE_LDFLAGS=
 619 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
 620 G_MODULE_NEED_USCORE=0
 621 G_MODULE_HAVE_DLERROR=0
 622 dnl *** dlopen() and dlsym() in system libraries
 623 if test -z "$G_MODULE_IMPL"; then
 624         AC_CHECK_FUNC(dlopen,
 625                       [AC_CHECK_FUNC(dlsym,
 626                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
 627                       [])
 628 fi
 629 dnl *** load_image (BeOS)
 630 if test -z "$G_MODULE_IMPL" -a "x$glib_native_beos" = "xyes"; then
 631   AC_CHECK_LIB(root, load_image,
 632       [G_MODULE_LIBS="-lbe -lroot -lglib"
 633       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
 634       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
 635       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
 636       [])
 637 fi
 638 # *** dlopen() and dlsym() in libdl
 639 if test -z "$G_MODULE_IMPL"; then
 640         AC_CHECK_LIB(dl, dlopen,
 641                      [AC_CHECK_LIB(dl, dlsym,
 642                                    [G_MODULE_LIBS=-ldl
 643                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
 644                      [])
 645 fi
 646 dnl *** shl_load() in libdld (HP-UX)
 647 if test -z "$G_MODULE_IMPL"; then
 648         AC_MSG_CHECKING(how to export all symbols)
 649         SAVED_LDFLAGS=$LDFLAGS
 650         LDFLAGS="$LDFLAGS -Wl,-E"
 651         AC_TRY_LINK(,[ return 0; ],
 652                 [ G_MODULE_LDFLAGS="-Wl,-E" ],[
 653                 LDFLAGS="$SAVED_LDFLAGS -bexpall"
 654                 AC_TRY_LINK(,[ return 0; ],
 655                         [G_MODULE_LDFLAGS="-bexpall"],
 656                         [G_MODULE_LDFLAGS="none"])
 657         ])
 658         LDFLAGS=$SAVED_LDFLAGS
 659         AC_MSG_RESULT($G_MODULE_LDFLAGS)
 660         if test "x$G_MODULE_LDFLAGS" = "xnone"; then
 661                 G_MODULE_LDFLAGS=
 662         fi
 663         AC_CHECK_LIB(dld, shl_load,
 664                 [G_MODULE_LIBS=-ldld
 665                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
 666                 [])
 667 fi
 668 dnl *** additional checks for G_MODULE_IMPL_DL
 669 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
 670         case "$host_os" in
 671           linux*)
 672             G_MODULE_LDFLAGS='-rdynamic'
 673             ;;
 674         esac
 675         LIBS_orig="$LIBS"
 676         LDFLAGS_orig="$LDFLAGS"
 677         LIBS="$LIBS $G_MODULE_LIBS"
 678         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
 679 dnl *** check whether we need preceeding underscores
 680         AC_CACHE_CHECK([for preceeding underscore in symbols],
 681                 glib_cv_uscore,[
 682                 AC_TRY_RUN([
 683                 #include <dlfcn.h>
 684                 int glib_underscore_test (void) { return 42; }
 685                 int main() {
 686                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
 687                   handle = dlopen ((void*)0, 0);
 688                   if (handle) {
 689                     f1 = dlsym (handle, "glib_underscore_test");
 690                     f2 = dlsym (handle, "_glib_underscore_test");
 691                   } return (!f2 || f1);
 692                 }],
 693                         [glib_cv_uscore=yes],
 694                         [glib_cv_uscore=no],
 695                         [])
 696                 rm -f plugin.c plugin.o plugin.lo
 697         ])
 698         if test "x$glib_cv_uscore" = "xyes"; then
 699                 G_MODULE_NEED_USCORE=1
 700         else
 701                 G_MODULE_NEED_USCORE=0
 702         fi
 703
 704         LDFLAGS="$LDFLAGS_orig"
 705 dnl *** check for having dlerror()
 706         AC_CHECK_FUNC(dlerror,
 707                 [G_MODULE_HAVE_DLERROR=1],
 708                 [G_MODULE_HAVE_DLERROR=0])
 709         LIBS="$LIBS_orig"
 710 fi
 711 dnl *** done, have e got an implementation?
 712 if test -z "$G_MODULE_IMPL"; then
 713         G_MODULE_IMPL=0
 714 fi
 715
 716 AC_MSG_CHECKING(for the suffix of shared libraries)
 717 case "$host_os" in
 718   hpux9* | hpux10* | hpux11*)  # taken from ltconfig
 719     glib_gmodule_suffix='sl'
 720     ;;
 721   cygwin* | mingw*)
 722     glib_gmodule_suffix='dll'
 723     ;;
 724   *)
 725     glib_gmodule_suffix='so'
 726     ;;
 727 esac
 728 AC_MSG_RESULT(.$glib_gmodule_suffix)
 729
 730 AC_SUBST(G_MODULE_IMPL)
 731 AC_SUBST(G_MODULE_LIBS)
 732 AC_SUBST(G_MODULE_LIBS_EXTRA)
 733 AC_SUBST(G_MODULE_PLUGIN_LIBS)
 734 AC_SUBST(G_MODULE_LDFLAGS)
 735 AC_SUBST(G_MODULE_HAVE_DLERROR)
 736 AC_SUBST(G_MODULE_NEED_USCORE)
 737 AC_SUBST(GLIB_DEBUG_FLAGS)
 738
 739
 740 dnl ***********************
 741 dnl *** g_thread checks ***
 742 dnl ***********************
 743
 744 AC_ARG_WITH(threads, [  --with-threads=[none/posix/dce/solaris] specify a thread implementation to use],
 745         if test "x$with_threads" = x; then
 746                 want_threads=yes
 747         else
 748                 want_threads=$with_threads
 749         fi,
 750         want_threads=yes)
 751 if test "x$enable_threads" = "xno"; then
 752         want_threads=no
 753 fi
 754 if test "x$want_threads" = "xnone"; then
 755         want_threads=no
 756 fi
 757
 758 dnl error and warning message
 759 dnl *************************
 760
 761 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
 762                 computer. GLib will not have a default thread implementation."
 763
 764 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
 765                 platform (normaly it's "_REENTRANT"). I'll not use any flag on
 766                 compilation now, but then your programs might not work.
 767                 Please provide information on how it is done on your system."
 768
 769 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
 770                 "
 771
 772 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
 773                 provide information on your thread implementation.
 774                 You can also run 'configure --disable-threads'
 775                 to compile without thread support."
 776
 777 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
 778                 functions will not be MT-safe during their first call because
 779                 there is no working 'getpwuid_r' on your system."
 780
 781 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
 782                 because there is no 'localtime_r' on your system."
 783
 784 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
 785                 crude surrogate will be used. If you happen to know a
 786                 yield function for your system, please inform the GLib
 787                 developers."
 788
 789 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
 790                 threads on your system. Thus threads can only have the default
 791                 priority. If you happen to know these main/max
 792                 priorities, please inform the GLib developers."
 793
 794
 795 dnl determination of thread implementation
 796 dnl ***************************************
 797
 798 have_threads=none
 799 if test "x$want_threads" = xyes || test "x$want_threads" = xsolaris; then
 800         case $host in
 801                 *-*-solaris*)
 802                 AC_CHECK_LIB(thread, cond_init, have_threads=solaris)
 803                 ;;
 804         esac
 805 fi
 806 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
 807                                 || test "x$want_threads" = xdce; then
 808         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
 809         # -U_OSF_SOURCE is for Digital UNIX 4.0d
 810         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
 811         glib_save_CPPFLAGS="$CPPFLAGS"
 812         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
 813         if test "x$have_threads" = xnone; then
 814                 AC_TRY_COMPILE([#include <pthread.h>],
 815                         [pthread_attr_t attr; pthread_attr_init(&attr);],
 816                         have_threads=posix)
 817         fi
 818         if test "x$have_threads" = xnone; then
 819                 AC_TRY_COMPILE([#include <pthread.h>],
 820                         [pthread_attr_t attr; pthread_attr_create(&attr);],
 821                         have_threads=posix)
 822         fi
 823         CPPFLAGS="$glib_save_CPPFLAGS"
 824 fi
 825
 826 AC_MSG_CHECKING(for thread implementation)
 827
 828 if test "x$have_threads" = xnone && test "x$want_threads" != xno; then
 829         AC_MSG_RESULT(none available)
 830         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
 831 else
 832         AC_MSG_RESULT($have_threads)
 833 fi
 834
 835
 836 dnl determination of G_THREAD_CFLAGS
 837 dnl ********************************
 838
 839 G_THREAD_LIBS=
 840 G_THREAD_LIBS_EXTRA=
 841 G_THREAD_CFLAGS=
 842
 843 if test x"$have_threads" != xnone; then
 844
 845     G_THREAD_CFLAGS="-D_REENTRANT" # good default guess
 846
 847     case $host in
 848         *-aix*)
 849                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 850                 if test x"$GCC" = xyes; then
 851                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -mthreads"
 852                 fi
 853                 ;;
 854         *-freebsd2.2*)
 855                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 856
 857                 # FreeBSD 2.2.x shiped with gcc 2.7.2.x, which doesn't support
 858                 # -mthreads flag.
 859                 ;;
 860         *-sysv5uw7*)  # UnixWare 7
 861                 if test "$GCC" != "yes"; then
 862                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -Kthread"
 863                 else
 864                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -pthread"
 865                 fi
 866                 ;;
 867         *-dg-dgux*)  # DG/UX
 868                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_POSIX4A_DRAFT10_SOURCE"
 869     esac
 870
 871     # if we are not finding the ctime_r function, then we probably are
 872     # not using the proper multithread flag
 873
 874     glib_save_CPPFLAGS="$CPPFLAGS"
 875     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
 876
 877     AC_TRY_COMPILE([#include <time.h>],
 878         [time_t t; char b[30]; ctime_r (&t, b);], ,
 879             [AC_TRY_COMPILE([#include <time.h>],
 880                 [time_t t; char b[30]; ctime_r (&t, b, 30);], ,
 881                         AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
 882
 883     CPPFLAGS="$glib_save_CPPFLAGS"
 884
 885     AC_MSG_CHECKING(thread related cflags)
 886     AC_MSG_RESULT($G_THREAD_CFLAGS)
 887     CFLAGS="$CFLAGS $G_THREAD_CFLAGS"
 888 fi
 889
 890 dnl determination of G_THREAD_LIBS
 891 dnl ******************************
 892
 893 mutex_has_default=no
 894 case $have_threads in
 895         posix|dce)
 896            glib_save_CPPFLAGS="$CPPFLAGS"
 897            CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
 898            G_THREAD_LIBS=error
 899            glib_save_LIBS="$LIBS"
 900            case $host in
 901              *-sysv5uw7*) # UnixWare 7
 902                 if test "$GCC" != "yes"; then
 903                         G_THREAD_LIBS="-Kthread"
 904                 else
 905                         G_THREAD_LIBS="-pthread"
 906                 fi
 907                 ;;
 908              *)
 909                 for thread_lib in "" pthread pthreads c_r thread dce; do
 910                         if test x"$thread_lib" = x; then
 911                                 add_thread_lib=""
 912                                 IN=""
 913                         else
 914                                 add_thread_lib="-l$thread_lib"
 915                                 IN=" in -l$thread_lib"
 916                         fi
 917                         if test x"$have_threads" = xposix; then
 918                                 defattr=0
 919                         else
 920                                 defattr=pthread_attr_default
 921                         fi
 922
 923                         LIBS="$glib_save_LIBS $add_thread_lib"
 924
 925                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
 926                         AC_TRY_RUN([#include <pthread.h>
 927                                 int check_me = 0;
 928                                 void* func(void* data) {check_me = 42;}
 929                                 main()
 930                                 { pthread_t t;
 931                                   void *ret;
 932                                   pthread_create (&t, $defattr, func, 0);
 933                                   pthread_join (t, &ret);
 934                                   exit (check_me != 42);
 935                                 }],
 936                                 [AC_MSG_RESULT(yes)
 937                                 G_THREAD_LIBS="$add_thread_lib"
 938                                 break],
 939                                 [AC_MSG_RESULT(no)])
 940                 done
 941                 if test "x$G_THREAD_LIBS" = xerror; then
 942                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
 943                 fi
 944                 for thread_lib in "" rt rte; do
 945                         if test x"$thread_lib" = x; then
 946                                 add_thread_lib=""
 947                                 IN=""
 948                         else
 949                                 add_thread_lib="-l$thread_lib"
 950                                 IN=" in -l$thread_lib"
 951                         fi
 952                         LIBS="$glib_save_LIBS $add_thread_lib"
 953
 954                         AC_MSG_CHECKING(for sched_get_priority_min$IN)
 955                         AC_TRY_RUN([#include <sched.h>
 956                                 #include <errno.h>
 957                                 int main() {
 958                                 errno = 0;
 959                                 return sched_get_priority_min(SCHED_OTHER)==-1
 960                                         && errno != 0;
 961                                 }],
 962                                 [AC_MSG_RESULT(yes)
 963                                 G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
 964                                 posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
 965                                 posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
 966                                 break],
 967                                 [AC_MSG_RESULT(no)])
 968                 done
 969                 LIBS="$glib_save_LIBS"
 970                 ;;
 971            esac
 972            mutex_has_default=yes
 973            mutex_default_type='pthread_mutex_t'
 974            mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
 975            mutex_header_file='pthread.h'
 976            if test "x$have_threads" = "xposix"; then
 977              g_threads_impl="POSIX"
 978            else
 979              g_threads_impl="DCE"
 980              have_threads="posix"
 981            fi
 982            AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
 983            CPPFLAGS="$glib_save_CPPFLAGS"
 984            ;;
 985         solaris)
 986            G_THREAD_LIBS=error
 987            AC_CHECK_LIB(thread, cond_init, G_THREAD_LIBS="-lthread")
 988            mutex_has_default=yes
 989            mutex_default_type='mutex_t'
 990            mutex_default_init="DEFAULTMUTEX"
 991            mutex_header_file='thread.h'
 992            g_threads_impl="SOLARIS"
 993            ;;
 994         none)
 995            g_threads_impl="NONE"
 996            ;;
 997         *)
 998            g_threads_impl="NONE"
 999            G_THREAD_LIBS=error
1000            ;;
1001 esac
1002
1003 if test "x$G_THREAD_LIBS" = xerror; then
1004         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1005 fi
1006
1007 case $host in
1008   *-*-beos*)
1009     G_THREAD_LIBS="-lbe -lroot -lglib "
1010     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1011     ;;
1012   *)
1013     ;;
1014 esac
1015
1016 AC_MSG_CHECKING(thread related libraries)
1017 AC_MSG_RESULT($G_THREAD_LIBS)
1018
1019 dnl check for mt safe function variants and some posix functions
1020 dnl ************************************************************
1021
1022 if test x"$have_threads" != xnone; then
1023         glib_save_LIBS="$LIBS"
1024         # we are not doing the following for now, as this might require glib
1025         # to always be linked with the thread libs on some platforms.
1026         # LIBS="$LIBS $G_THREAD_LIBS"
1027         AC_CHECK_FUNCS(localtime_r)
1028         if test "$ac_cv_header_pwd_h" = "yes"; then
1029                 AC_CACHE_CHECK([for posix getpwuid_r],
1030                         ac_cv_func_posix_getpwuid_r,
1031                         [AC_TRY_RUN([#include <errno.h>
1032                                 #include <pwd.h>
1033                                 int main () { char buffer[10000];
1034                                 struct passwd pwd, *pwptr = &pwd;
1035                                 int error;
1036                                 errno = 0;
1037                                 error = getpwuid_r (0, &pwd, buffer,
1038                                         sizeof (buffer), &pwptr);
1039                                 return (error < 0 && errno == ENOSYS)
1040                                         || error == ENOSYS; }],
1041                                 [ac_cv_func_posix_getpwuid_r=yes],
1042                                 [ac_cv_func_posix_getpwuid_r=no])])
1043                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
1044                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
1045                                 [Have POSIX function getpwuid_r])
1046                 else
1047                         AC_CACHE_CHECK([for nonposix getpwuid_r],
1048                                 ac_cv_func_nonposix_getpwuid_r,
1049                                 [AC_TRY_COMPILE([#include <pwd.h>],
1050                                         [char buffer[10000];
1051                                         struct passwd pwd;
1052                                         getpwuid_r (0, &pwd, buffer,
1053                                                         sizeof (buffer));],
1054                                         [ac_cv_func_nonposix_getpwuid_r=yes],
1055                                         [ac_cv_func_nonposix_getpwuid_r=no])])
1056                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
1057                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
1058                                         [Have non-POSIX function getpwuid_r])
1059                         fi
1060                 fi
1061         fi
1062         LIBS="$LIBS $G_THREAD_LIBS"
1063         if test x"$have_threads" = xposix; then
1064                 glib_save_CPPFLAGS="$CPPFLAGS"
1065                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1066                 dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
1067                 GLIB_SIZEOF([#include <pthread.h>], pthread_t, core_system_thread)
1068                 # This is not AC_CHECK_FUNC to also work with function
1069                 # name mangling in header files.
1070                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
1071                 AC_TRY_LINK([#include <pthread.h>],
1072                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
1073                         [AC_MSG_RESULT(yes)
1074                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
1075                                   [Have function pthread_attr_setstacksize])],
1076                         [AC_MSG_RESULT(no)])
1077                 AC_MSG_CHECKING(for minimal/maximal thread priority)
1078                 if test x"$posix_priority_min" = xnone; then
1079                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
1080                                 PX_PRIO_MIN],,[
1081                                 posix_priority_min=PX_PRIO_MIN
1082                                 posix_priority_max=PX_PRIO_MAX])
1083                 fi
1084                 if test x"$posix_priority_min" = xnone; then
1085                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
1086                                 PRI_OTHER_MIN],,[
1087                                 posix_priority_min=PRI_OTHER_MIN
1088                                 posix_priority_max=PRI_OTHER_MAX])
1089                 fi
1090                 if test x"$posix_priority_min" = x; then
1091                         AC_MSG_RESULT(none found)
1092                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
1093                         posix_priority_min=-1
1094                         posix_priority_max=-1
1095                 else
1096                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
1097                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
1098                         AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])
1099                 fi
1100                 posix_yield_func=none
1101                 AC_MSG_CHECKING(for posix yield function)
1102                 for yield_func in sched_yield pthread_yield_np pthread_yield \
1103                                                         thr_yield; do
1104                         AC_TRY_LINK([#include <pthread.h>],
1105                                 [$yield_func()],
1106                                 [posix_yield_func="$yield_func"
1107                                 break])
1108                 done
1109                 if test x"$posix_yield_func" = xnone; then
1110                         AC_MSG_RESULT(none found)
1111                         AC_MSG_WARN($POSIX_NO_YIELD)
1112                         posix_yield_func="g_usleep(1000)"
1113                 else
1114                         AC_MSG_RESULT($posix_yield_func)
1115                         posix_yield_func="$posix_yield_func()"
1116                 fi
1117                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
1118                 CPPFLAGS="$glib_save_CPPFLAGS"
1119
1120                 AC_MSG_CHECKING(whether to use the PID niceness surrogate for thread priorities)
1121                 glib_system_thread_size_growth=0
1122                 AC_TRY_RUN([#include <pthread.h>
1123                         #include <sys/types.h>
1124                         #include <unistd.h>
1125                         pid_t other_pid = 0;
1126
1127                         void* func(void* data) {other_pid = getpid();}
1128                         main()
1129                         { pthread_t t;
1130                           void *ret;
1131                           pthread_create (&t, $defattr, func, NULL);
1132                           pthread_join (t, &ret);
1133                           exit (getpid()==other_pid ||
1134                                 $posix_priority_min != $posix_priority_max);
1135                         }],
1136                         [AC_MSG_RESULT(yes),
1137                           AC_DEFINE(G_THREAD_USE_PID_SURROGATE, 1, [whether to use the PID niceness surrogate for thread priorities])
1138                           glib_system_thread_size_growth=$ac_cv_sizeof_long
1139                         ],
1140                         [AC_MSG_RESULT(no)])
1141                 dnl make sure both glib_cv_sizeof_system_thread and GLIB_SIZEOF_SYSTEM_THREAD are setup
1142                 glib_cv_sizeof_system_thread=`expr $glib_cv_sizeof_core_system_thread + $glib_system_thread_size_growth`
1143                 AC_DEFINE_UNQUOTED(GLIB_SIZEOF_SYSTEM_THREAD, $glib_cv_sizeof_system_thread)
1144         else # solaris threads
1145                 GLIB_SIZEOF([#include <thread.h>], thread_t, system_thread)
1146         fi
1147
1148         LIBS="$glib_save_LIBS"
1149
1150         # now spit out all the warnings.
1151         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
1152            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
1153                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
1154         fi
1155         if test "$ac_cv_func_localtime_r" != "yes"; then
1156                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
1157         fi
1158 else
1159         # If no thread implementation exists, we will provide enough
1160         # space for a pointer
1161         GLIB_SIZEOF(, void*, system_thread)
1162 fi
1163
1164 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
1165                    [Source file containing theread implementation])
1166 AC_SUBST(G_THREAD_CFLAGS)
1167 AC_SUBST(G_THREAD_LIBS)
1168 AC_SUBST(G_THREAD_LIBS_EXTRA)
1169
1170 dnl **********************************************
1171 dnl *** GDefaultMutex setup and initialization ***
1172 dnl **********************************************
1173 dnl
1174 dnl if mutex_has_default = yes, we also got
1175 dnl mutex_default_type, mutex_default_init and mutex_header_file
1176 GLIB_IF_VAR_EQ(mutex_has_default, yes,
1177         glib_save_CPPFLAGS="$CPPFLAGS"
1178         glib_save_LIBS="$LIBS"
1179         LIBS="$LIBS $G_THREAD_LIBS"
1180         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1181         GLIB_SIZEOF([#include <$mutex_header_file>],
1182                     $mutex_default_type,
1183                     gmutex,
1184                     )
1185         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
1186                            $mutex_default_type,
1187                            gmutex,
1188                            $glib_cv_sizeof_gmutex,
1189                            $mutex_default_init)
1190         if test x"$glib_cv_byte_contents_gmutex" = xno; then
1191                 mutex_has_default=no
1192         fi
1193         CPPFLAGS="$glib_save_CPPFLAGS"
1194         LIBS="$glib_save_LIBS"
1195         ,
1196 )
1197
1198
1199 dnl ****************************************
1200 dnl *** GLib POLL* compatibility defines ***
1201 dnl ****************************************
1202 GLIB_SYSDEFS(
1203 [#include <sys/types.h>
1204 #include <sys/poll.h>],
1205         POLLIN:1 POLLOUT:4 POLLPRI:2 POLLERR:8 POLLHUP:16 POLLNVAL:32,
1206         glibconfig-sysdefs.h,
1207         =)
1208
1209 dnl ***********************
1210 dnl *** Tests for iconv ***
1211 dnl ***********************
1212
1213 AC_ARG_WITH(libiconv, [ --with-libiconv     Use the libiconv library ],,with_libiconv=maybe)
1214
1215 found_iconv=no
1216
1217 if test "x$with_libiconv" != "xyes" ; then
1218    #
1219    # Check in the C library
1220    #
1221    AC_CHECK_FUNC(iconv_open, with_libiconv=no; found_iconv=yes)
1222 fi
1223
1224 if test "x$with_libiconv" != "xno" ; then
1225    #
1226    # Check for libiconv
1227    #
1228    AC_CHECK_LIB(iconv, libiconv_open, with_libiconv=yes; found_iconv=yes)
1229 fi
1230
1231 if test "x$found_iconv" = "xno" ; then
1232    AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
1233 fi
1234
1235 if test "x$with_libiconv" = "xyes" ; then
1236   ICONV_LIBS="-liconv"
1237   AC_DEFINE(USE_LIBICONV)
1238 fi
1239 AC_SUBST(ICONV_LIBS)
1240
1241 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
1242 dnl since we need it for g_iconv()
1243
1244 AC_MSG_CHECKING([for EILSEQ])
1245 AC_TRY_COMPILE([
1246 #include <errno.h>
1247 ],
1248 [
1249 int error = EILSEQ;
1250 ], have_eilseq=yes, have_eilseq=no);
1251 AC_MSG_RESULT($have_eilseq)
1252
1253 dnl **************************
1254 dnl *** Checks for gtk-doc ***
1255 dnl **************************
1256
1257 AC_ARG_WITH(html-dir, [  --with-html-dir=PATH path to installed docs ])
1258
1259 if test "x$with_html_dir" = "x" ; then
1260   HTML_DIR='${datadir}/gtk-doc/html'
1261 else
1262   HTML_DIR=$with_html_dir
1263 fi
1264
1265 AC_SUBST(HTML_DIR)
1266
1267 AC_CHECK_PROG(GTKDOC, gtkdoc-mkdb, true, false)
1268
1269 gtk_doc_min_version=0.6
1270 if $GTKDOC ; then
1271     gtk_doc_version=`gtkdoc-mkdb --version`
1272     AC_MSG_CHECKING([gtk-doc version ($gtk_doc_version) >= $gtk_doc_min_version])
1273     if perl <<EOF ; then
1274       exit (("$gtk_doc_version" =~ /^[[0-9]]+\.[[0-9]]+$/) &&
1275             ("$gtk_doc_version" >= "$gtk_doc_min_version") ? 0 : 1);
1276 EOF
1277       AC_MSG_RESULT(yes)
1278    else
1279       AC_MSG_RESULT(no)
1280       GTKDOC=false
1281    fi
1282 fi
1283
1284 AM_CONDITIONAL(HAVE_GTK_DOC, $GTKDOC)
1285 AC_SUBST(HAVE_GTK_DOC)
1286
1287 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1288 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1289
1290 dnl Let people disable the gtk-doc stuff.
1291 AC_ARG_ENABLE(gtk-doc, [  --enable-gtk-doc  Use gtk-doc to build documentation [default=auto]], enable_gtk_doc="$enableval", enable_gtk_doc=auto)
1292
1293 if test x$enable_gtk_doc = xauto ; then
1294   if test x$GTKDOC = xtrue ; then
1295     enable_gtk_doc=yes
1296   else
1297     enable_gtk_doc=no
1298   fi
1299 fi
1300
1301 dnl NOTE: We need to use a separate automake conditional for this
1302 dnl       to make this work with the tarballs.
1303 AM_CONDITIONAL(ENABLE_GTK_DOC, test x$enable_gtk_doc = xyes)
1304
1305 dnl ******************************
1306 dnl *** output the whole stuff ***
1307 dnl ******************************
1308
1309 AC_OUTPUT_COMMANDS([
1310
1311 ## Generate `glibconfig.h' in two cases
1312 ## 1. `config.status' is run either explicitly, or via configure.
1313 ##     Esp. not when it is run in `Makefile' to generate makefiles and
1314 ##     config.h
1315 ## 2. CONFIG_OTHER is set explicitly
1316 ##
1317 ## Case 1 is difficult.  We know that `automake' sets one of
1318 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
1319 ## only when AM_CONFIG_HEADER is set, however.
1320
1321 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
1322   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
1323   CONFIG_OTHER=${CONFIG_OTHER:-glibconfig.h}
1324 fi
1325 case "$CONFIG_OTHER" in
1326 *glibconfig.h*)
1327         echo creating glibconfig.h
1328         outfile=glibconfig.h-tmp
1329         cat > $outfile <<\_______EOF
1330 /* glibconfig.h
1331  *
1332  * This is a generated file.  Please modify 'configure.in'
1333  */
1334
1335 #ifndef __G_LIBCONFIG_H__
1336 #define __G_LIBCONFIG_H__
1337
1338 #include <gmacros.h>
1339
1340 _______EOF
1341
1342         if test x$glib_limits_h = xyes; then
1343           echo '#include <limits.h>' >> $outfile
1344         fi
1345         if test x$glib_float_h = xyes; then
1346           echo '#include <float.h>' >> $outfile
1347         fi
1348         if test x$glib_values_h = xyes; then
1349           echo '#include <values.h>' >> $outfile
1350         fi
1351         if test "$glib_header_alloca_h" = "yes"; then
1352           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
1353         fi
1354         if test x$glib_sys_poll_h = xyes; then
1355           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
1356         fi
1357
1358         cat >> $outfile <<_______EOF
1359
1360 G_BEGIN_DECLS
1361
1362 #define G_MINFLOAT      $glib_mf
1363 #define G_MAXFLOAT      $glib_Mf
1364 #define G_MINDOUBLE     $glib_md
1365 #define G_MAXDOUBLE     $glib_Md
1366 #define G_MINSHORT      $glib_ms
1367 #define G_MAXSHORT      $glib_Ms
1368 #define G_MAXUSHORT     $glib_Mus
1369 #define G_MININT        $glib_mi
1370 #define G_MAXINT        $glib_Mi
1371 #define G_MAXUINT       $glib_Mui
1372 #define G_MINLONG       $glib_ml
1373 #define G_MAXLONG       $glib_Ml
1374 #define G_MAXULONG      $glib_Mul
1375
1376 _______EOF
1377
1378
1379         ### this should always be true in a modern C/C++ compiler
1380         cat >>$outfile <<_______EOF
1381 typedef signed char gint8;
1382 typedef unsigned char guint8;
1383 _______EOF
1384
1385
1386         if test -n "$gint16"; then
1387           cat >>$outfile <<_______EOF
1388 typedef signed $gint16 gint16;
1389 typedef unsigned $gint16 guint16;
1390 #define G_GINT16_FORMAT $gint16_format
1391 #define G_GUINT16_FORMAT $guint16_format
1392 _______EOF
1393         fi
1394
1395
1396         if test -n "$gint32"; then
1397           cat >>$outfile <<_______EOF
1398 typedef signed $gint32 gint32;
1399 typedef unsigned $gint32 guint32;
1400 #define G_GINT32_FORMAT $gint32_format
1401 #define G_GUINT32_FORMAT $guint32_format
1402 _______EOF
1403         fi
1404
1405
1406         if test -n "$gint64"; then
1407           cat >>$outfile <<_______EOF
1408 #define G_HAVE_GINT64 1
1409
1410 ${glib_extension}typedef signed $gint64 gint64;
1411 ${glib_extension}typedef unsigned $gint64 guint64;
1412
1413 #define G_GINT64_CONSTANT(val)  $gint64_constant
1414 _______EOF
1415                 if test -n "$gint64_format"; then
1416           cat >>$outfile <<_______EOF
1417 #define G_GINT64_FORMAT $gint64_format
1418 #define G_GUINT64_FORMAT $guint64_format
1419 _______EOF
1420                 fi
1421         fi
1422
1423         cat >>$outfile <<_______EOF
1424
1425 #define GLIB_SIZEOF_VOID_P $glib_void_p
1426 #define GLIB_SIZEOF_LONG   $glib_long
1427
1428 _______EOF
1429
1430         case x$glib_size_t in
1431         x2) echo "typedef gint16  gssize;" >> $outfile
1432             echo "typedef guint16 gsize;"  >> $outfile
1433             ;;
1434         x4) echo "typedef gint32  gssize;" >> $outfile
1435             echo "typedef guint32 gsize;"  >> $outfile
1436             ;;
1437         x8) echo "typedef gint64  gssize;" >> $outfile
1438             echo "typedef guint64 gsize;"  >> $outfile
1439             ;;
1440         *)  echo "#error size of size_t is unknown" >> $outfile
1441             ;;
1442         esac
1443
1444         if test -z "$glib_unknown_void_p"; then
1445           cat >>$outfile <<_______EOF
1446
1447 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
1448 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
1449
1450 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
1451 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
1452 _______EOF
1453         else
1454           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
1455         fi
1456
1457
1458
1459         cat >>$outfile <<_______EOF
1460 $glib_atexit
1461 $glib_memmove
1462 $glib_defines
1463 $glib_os
1464
1465 $glib_vacopy
1466
1467 #ifdef  __cplusplus
1468 #define G_HAVE_INLINE   1
1469 #else   /* !__cplusplus */
1470 $glib_inline
1471 #endif  /* !__cplusplus */
1472 _______EOF
1473
1474         echo >>$outfile
1475         if test x$g_have_eilseq = xno; then
1476                 cat >>$outfile <<_______EOF
1477 #ifndef EILSEQ
1478 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
1479  * The correspondence between this and the corresponding definition
1480  * in libiconv is essential.
1481  */
1482 #  define EILSEQ ENOENT
1483 #endif
1484 _______EOF
1485
1486         fi
1487
1488         echo >>$outfile
1489         if test x$g_mutex_has_default = xyes; then
1490                 cat >>$outfile <<_______EOF
1491 $g_enable_threads_def G_THREADS_ENABLED
1492 #define G_THREADS_IMPL_$g_threads_impl_def
1493 typedef struct _GStaticMutex GStaticMutex;
1494 struct _GStaticMutex
1495 {
1496   struct _GMutex *runtime_mutex;
1497   union {
1498     char   pad[$g_mutex_sizeof];
1499     double dummy_double;
1500     void  *dummy_pointer;
1501     long   dummy_long;
1502   } static_mutex;
1503 };
1504 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
1505 #define g_static_mutex_get_mutex(mutex) \
1506   (g_thread_use_default_impl ? ((GMutex*) &((mutex)->static_mutex)) : \
1507    g_static_mutex_get_mutex_impl (&((mutex)->runtime_mutex)))
1508 _______EOF
1509         else
1510                 cat >>$outfile <<_______EOF
1511 $g_enable_threads_def G_THREADS_ENABLED
1512 #define G_THREADS_IMPL_$g_threads_impl_def
1513 typedef struct _GMutex* GStaticMutex;
1514 #define G_STATIC_MUTEX_INIT NULL
1515 #define g_static_mutex_get_mutex(mutex) (g_static_mutex_get_mutex_impl (mutex))
1516 _______EOF
1517         fi
1518
1519         cat >>$outfile <<_______EOF
1520 /* This represents a system thread as used by the implementation. An
1521  * alien implementaion, as loaded by g_thread_init can only count on
1522  * "sizeof (gpointer)" bytes to store their info. We however need more
1523  * for some of our native implementations. */
1524 typedef union _GSystemThread GSystemThread;
1525 union _GSystemThread
1526 {
1527   char   data[$g_system_thread_sizeof];
1528   double dummy_double;
1529   void  *dummy_pointer;
1530   long   dummy_long;
1531 };
1532 _______EOF
1533
1534         echo >>$outfile
1535         g_bit_sizes="16 32"
1536         if test -n "$gint64"; then
1537           g_bit_sizes="$g_bit_sizes 64"
1538         fi
1539         for bits in $g_bit_sizes; do
1540           cat >>$outfile <<_______EOF
1541 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
1542 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
1543 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
1544 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
1545 _______EOF
1546         done
1547
1548         cat >>$outfile <<_______EOF
1549 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
1550 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
1551 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
1552 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
1553 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
1554 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
1555 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
1556 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
1557 #define G_BYTE_ORDER $g_byte_order
1558
1559 _______EOF
1560
1561         if test -r glibconfig-sysdefs.h; then
1562           cat glibconfig-sysdefs.h >>$outfile
1563         fi
1564
1565         cat >>$outfile <<_______EOF
1566
1567 #define G_MODULE_SUFFIX "$g_module_suffix"
1568
1569 G_END_DECLS
1570
1571 #endif /* GLIBCONFIG_H */
1572 _______EOF
1573
1574
1575         if cmp -s $outfile glibconfig.h; then
1576           echo glibconfig.h is unchanged
1577           rm -f $outfile
1578         else
1579           mv $outfile glibconfig.h
1580         fi ;;
1581 esac
1582 ],[
1583
1584 # Note that if two cases are the same, case goes with the first one.
1585 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
1586 # on variable expansion in case labels.  Look at the generated config.status
1587 # for a hint.
1588
1589 glib_header_alloca_h="$ac_cv_header_alloca_h"
1590
1591 case xyes in
1592 x$ac_cv_header_float_h)
1593   glib_float_h=yes
1594   glib_mf=FLT_MIN glib_Mf=FLT_MAX
1595   glib_md=DBL_MIN glib_Md=DBL_MAX
1596   ;;
1597 x$ac_cv_header_values_h)
1598   glib_values_h=yes
1599   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
1600   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
1601   ;;
1602 esac
1603
1604 case xyes in
1605 x$ac_cv_header_limits_h)
1606   glib_limits_h=yes
1607   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
1608   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
1609   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
1610   ;;
1611 x$ac_cv_header_values_h)
1612   glib_values_h=yes
1613   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
1614   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
1615   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
1616   ;;
1617 esac
1618
1619 if test x$ac_cv_header_sys_poll_h = xyes ; then
1620   glib_sys_poll_h=yes
1621 fi
1622
1623 case 2 in
1624 $ac_cv_sizeof_short)
1625   gint16=short
1626   gint16_format='"hi"'
1627   guint16_format='"hu"'
1628   ;;
1629 $ac_cv_sizeof_int)
1630   gint16=int
1631   gint16_format='"i"'
1632   guint16_format='"u"'
1633   ;;
1634 esac
1635 case 4 in
1636 $ac_cv_sizeof_short)
1637   gint32=short
1638   gint32_format='"hi"'
1639   guint32_format='"hu"'
1640   ;;
1641 $ac_cv_sizeof_int)
1642   gint32=int
1643   gint32_format='"i"'
1644   guint32_format='"u"'
1645   ;;
1646 $ac_cv_sizeof_long)
1647   gint32=long
1648   gint32_format='"li"'
1649   guint32_format='"lu"'
1650   ;;
1651 esac
1652 case 8 in
1653 $ac_cv_sizeof_int)
1654   gint64=int
1655   gint64_format='"i"'
1656   guint64_format='"u"'
1657   glib_extension=
1658   gint64_constant='(val)'
1659   ;;
1660 $ac_cv_sizeof_long)
1661   gint64=long
1662   gint64_format='"li"'
1663   guint64_format='"lu"'
1664   glib_extension=
1665   gint64_constant='(val##L)'
1666   ;;
1667 $ac_cv_sizeof_long_long)
1668   gint64='long long'
1669   if test -n "$glib_cv_long_long_format"; then
1670     gint64_format='"'$glib_cv_long_long_format'i"'
1671     guint64_format='"'$glib_cv_long_long_format'u"'
1672   fi
1673   glib_extension='G_GNUC_EXTENSION '
1674   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
1675   ;;
1676 esac
1677 glib_size_t=$glib_cv_sizeof_size_t
1678 glib_void_p=$ac_cv_sizeof_long
1679 glib_long=$ac_cv_sizeof_void_p
1680
1681 gintbits=`expr $ac_cv_sizeof_int \* 8`
1682 glongbits=`expr $ac_cv_sizeof_long \* 8`
1683
1684
1685 case $ac_cv_sizeof_void_p in
1686 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
1687 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
1688 *)                      glib_unknown_void_p=yes ;;
1689 esac
1690
1691
1692 case xyes in
1693 x$ac_cv_func_atexit)
1694   glib_atexit="
1695 #ifdef NeXT /* @#%@! NeXTStep */
1696 # define g_ATEXIT(proc) (!atexit (proc))
1697 #else
1698 # define g_ATEXIT(proc) (atexit (proc))
1699 #endif"
1700   ;;
1701 x$ac_cv_func_on_exit)
1702   glib_atexit="
1703 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
1704   ;;
1705 esac
1706
1707 case xyes in
1708 x$ac_cv_func_memmove)
1709   glib_memmove='
1710 #define g_memmove(d,s,n) G_STMT_START { memmove ((d), (s), (n)); } G_STMT_END'
1711   ;;
1712 x$glib_cv_working_bcopy)
1713   glib_memmove="
1714 /* memmove isn't available, but bcopy can copy overlapping memory regions */
1715 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
1716   ;;
1717 *)
1718   glib_memmove="
1719 /* memmove isn't found and bcopy can't copy overlapping memory regions,
1720  * so we have to roll our own copy routine. */
1721 void g_memmove (void* dest, const void * src, unsigned long len);"
1722   ;;
1723 esac
1724
1725 glib_defines="
1726 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
1727 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
1728 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
1729 "
1730
1731 case xyes in
1732 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
1733 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
1734 *)                      glib_vacopy=''
1735 esac
1736
1737 if test x$glib_cv_va_val_copy = xno; then
1738   glib_vacopy="\$glib_vacopy
1739 #define G_VA_COPY_AS_ARRAY 1"
1740 fi
1741
1742 if test x$glib_cv_hasinline = xyes; then
1743     glib_inline='#define G_HAVE_INLINE 1'
1744 fi
1745 if test x$glib_cv_has__inline = xyes; then
1746     glib_inline="\$glib_inline
1747 #define G_HAVE___INLINE 1"
1748 fi
1749 if test x$glib_cv_has__inline__ = xyes; then
1750     glib_inline="\$glib_inline
1751 #define G_HAVE___INLINE__ 1"
1752 fi
1753
1754 case xyes in
1755 x$ac_cv_c_bigendian)
1756   g_byte_order=G_BIG_ENDIAN
1757   g_bs_native=BE
1758   g_bs_alien=LE
1759   ;;
1760 *)
1761   g_byte_order=G_LITTLE_ENDIAN
1762   g_bs_native=LE
1763   g_bs_alien=BE
1764   ;;
1765 esac
1766
1767 g_have_eilseq=$have_eilseq
1768
1769 case x$have_threads in
1770 xnone)  g_enable_threads_def="#undef";;
1771 *)      g_enable_threads_def="#define";;
1772 esac
1773
1774 g_threads_impl_def=$g_threads_impl
1775
1776 g_mutex_has_default="$mutex_has_default"
1777 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
1778 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
1779 g_mutex_contents="$glib_cv_byte_contents_gmutex"
1780
1781 g_module_suffix="$glib_gmodule_suffix"
1782
1783 case $host in
1784   *-*-beos*)
1785     glib_os="#define G_OS_BEOS"
1786     ;;
1787   *-*-cygwin*)
1788     glib_os="#define G_OS_UNIX
1789 #define G_WITH_CYGWIN"
1790     ;;
1791   *-*-mingw*)
1792     glib_os="#define G_OS_WIN32"
1793     ;;
1794   *)
1795     glib_os="#define G_OS_UNIX"
1796     ;;
1797 esac
1798 ])
1799
1800 AC_OUTPUT([
1801 glib-2.0.pc
1802 gmodule-2.0.pc
1803 gthread-2.0.pc
1804 gobject-2.0.pc
1805 glib.spec
1806 Makefile
1807 build/Makefile
1808 build/win32/Makefile
1809 gmodule/gmoduleconf.h
1810 gmodule/Makefile
1811 gobject/Makefile
1812 gthread/Makefile
1813 po/Makefile.in
1814 docs/Makefile
1815 docs/glib-config.1
1816 docs/reference/Makefile
1817 docs/reference/glib/Makefile
1818 docs/reference/gobject/Makefile
1819 tests/Makefile
1820 ],[case "$CONFIG_FILES" in
1821 *glib-config-2.0*)chmod +x glib-config-2.0;;
1822 esac
1823 echo ""
1824 echo " *** IMPORTANT *** "
1825 echo ""
1826 echo "This is a development version of GLib.  You should be using a stable"
1827 echo "version, which is available at ftp://ftp.gtk.org/pub/gtk/v1.2/.  The"
1828 echo "version you just configured is meant for developers of GLib only:"
1829 echo ""
1830 echo "  * You should not base stable software on this version of GLib."
1831 echo "  * GNOME developers should use a stable version of GLib."
1832 echo ""
1833 echo "If you install this version of GLib, we strongly recommend that you"
1834 echo "install it in a different prefix than GLib 1.2.  Use --prefix as an"
1835 echo "argument to configure to do this.  Otherwise, you will not be able to"
1836 echo "do development with GLib 1.2 any longer."
1837 echo ""
1838 echo " *** You should be using GLib 1.2 instead. ***"
1839 ])