configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.11)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(include/features.h)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This will get text that should go into config.make.
   8 config_vars=
   9
  10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  11 AC_ARG_WITH(gmp, dnl
  12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  13             [dnl
  14 case "$with_gmp" in
  15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  16 ''|no) ;;
  17 *) config_vars="$config_vars
  18 gmp-srcdir = $withval" ;;
  19 esac
  20 ])
  21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  22 AC_ARG_WITH(gettext, dnl
  23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  24             [dnl
  25 case "$with_gettext" in
  26 yes)
  27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  28 ''|no) ;;
  29 *)
  30   config_vars="$config_vars
  31 gettext-srcdir = $withval" ;;
  32 esac
  33 ])
  34
  35 dnl Arguments to specify presence of other packages/features.
  36 AC_ARG_WITH(fp, dnl
  37 [  --with-fp              if using floating-point hardware [default=yes]],
  38             with_fp=$withval, with_fp=yes)
  39 AC_ARG_WITH(binutils, dnl
  40   --with-binutils=PATH    specify location of binutils (as and ld),
  41             path_binutils=$withval, path_binutils='')
  42 AC_ARG_WITH(elf, dnl
  43   --with-elf              if using the ELF object format,
  44             elf=$withval, elf=no)
  45 AC_ARG_WITH(cvs, dnl
  46 [  --without-cvs          if CVS should not be used],
  47             with_cvs=$withval, with_cvs=yes)
  48 AC_SUBST(with_cvs)
  49
  50 AC_ARG_ENABLE(libio, dnl
  51 [  --enable-libio          build in GNU libio instead of GNU stdio],
  52               [if test $enableval = yes; then
  53                  stdio=libio
  54                else
  55                  stdio=stdio
  56                fi],
  57               stdio=default)
  58
  59 AC_ARG_ENABLE(sanity-checks, dnl
  60 [  --disable-sanity-checks really do not use threads (should not be used
  61                           except in special situations) [default=yes]],
  62               enable_sanity=$enableval, enable_sanity=yes)
  63
  64 dnl Arguments to enable or disable building the static, shared, profiled,
  65 dnl and -fomit-frame-pointer libraries.
  66 AC_ARG_ENABLE(static, dnl
  67 [  --enable-static         build static library [default=yes]],
  68               static=$enableval, static=yes)
  69 AC_ARG_ENABLE(shared, dnl
  70 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  71               shared=$enableval, shared=default)
  72 AC_ARG_ENABLE(profile, dnl
  73 [  --enable-profile        build profiled library [default=yes]],
  74               profile=$enableval, profile=yes)
  75 AC_ARG_ENABLE(omitfp, dnl
  76 [  --enable-omitfp         build undebuggable optimized library [default=no]],
  77               omitfp=$enableval, omitfp=no)
  78 AC_ARG_ENABLE(bounded, dnl
  79 [  --enable-bounded        build with runtime bounds checking [default=no]],
  80               bounded=$enableval, bounded=no)
  81 AC_ARG_ENABLE(versioning, dnl
  82 [  --disable-versioning    do not include versioning information in the
  83                           library objects [default=yes if supported]],
  84              enable_versioning=$enableval, enable_versioning=yes)
  85
  86 dnl Generic infrastructure for drop-in additions to libc.
  87 AC_ARG_ENABLE(add-ons, dnl
  88 [  --enable-add-ons[=DIR1,DIR2]... configure and build add-ons in DIR1,DIR2,...
  89                                   search for add-ons if no parameter given],
  90   [case "$enableval" in
  91     yes) if test "$srcdir" = "."; then
  92            add_ons=`echo */configure | sed -e 's!/configure!!g'`
  93          else
  94            add_ons=`echo $srcdir/*/configure | \
  95                     sed -e 's!/configure!!g' -e "s!$srcdir/!!g"`
  96          fi;;
  97     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
  98    esac],
  99   [add_ons=])
 100
 101 AC_CONFIG_SUBDIRS($add_ons)
 102 add_ons_pfx=
 103 if test x"$add_ons" != x; then
 104   for f in $add_ons; do
 105     # Test whether such a subdir really exists.
 106     if test -d $srcdir/$f; then
 107       add_ons_pfx="$add_ons_pfx $f/"
 108     else
 109       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
 110     fi
 111   done
 112 fi
 113
 114 dnl On some platforms we cannot use dynamic loading.  We must provide
 115 dnl static NSS modules.
 116 AC_ARG_ENABLE(static-nss, dnl
 117 [  --enable-static-nss     build static NSS modules [default=no]],
 118               static_nss=$enableval, static_nss=no)
 119 if test x"$static_nss" = xyes; then
 120   AC_DEFINE(DO_STATIC_NSS)
 121 fi
 122
 123 AC_CANONICAL_HOST
 124
 125 # The way shlib-versions is used to generate soversions.mk uses a
 126 # fairly simplistic model for name recognition that can't distinguish
 127 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 128 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 129 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 130 case "$host_os" in
 131 linux*)
 132   ;;
 133 gnu*)
 134   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 135   ;;
 136 esac
 137
 138 ###
 139 ### I put this here to prevent those annoying emails from people who cannot
 140 ### read and try to compile glibc on unsupported platforms.  --drepper
 141 ###
 142 ### By using the undocumented --enable-hacker-mode option for configure
 143 ### one can skip this test to make the configuration not fail for unsupported
 144 ### platforms.
 145 ###
 146 if test -z "$enable_hacker_mode"; then
 147   case "$machine-$host_os" in
 148   *-linux* | *-gnu* | arm*-none*)
 149     ;;
 150   *)
 151     echo "*** The GNU C library is currently not available for this platform."
 152     echo "*** So far nobody cared to port it and if there is no volunteer it"
 153     echo "*** might never happen.  So, if you have interest to see glibc on"
 154     echo "*** this platform visit"
 155     echo "***   http://www.gnu.org/software/libc/porting.html"
 156     echo "*** and join the group of porters"
 157     exit 1
 158     ;;
 159   esac
 160 fi
 161
 162 # We keep the original values in `$config_*' and never modify them, so we
 163 # can write them unchanged into config.make.  Everything else uses
 164 # $machine, $vendor, and $os, and changes them whenever convenient.
 165 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 166
 167 # Some configurations imply other options.
 168 case "$host_os" in
 169 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 170   # These systems always use GNU tools.
 171   gnu_ld=yes gnu_as=yes ;;
 172 esac
 173 case "$host_os" in
 174 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
 175 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
 176   ;;
 177 gnu* | linux* | sysv4* | solaris2* | irix6*)
 178   # These systems (almost) always use the ELF format.
 179   elf=yes
 180   ;;
 181 esac
 182
 183 machine=$config_machine
 184 vendor=$config_vendor
 185 os=$config_os
 186
 187 dnl We need to use [ and ] for other purposes for a while now.
 188 changequote(,)dnl
 189 # Expand the configuration machine name into a subdirectory by architecture
 190 # type and particular chip.
 191 case "$machine" in
 192 a29k | am29000) base_machine=a29k machine=a29k ;;
 193 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 194 arm*)           base_machine=arm machine=arm/$machine ;;
 195 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
 196 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
 197 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 198 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 199 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 200 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 201 m88???)         base_machine=m88k machine=m88k/$machine ;;
 202 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 203 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 204 mips*)          base_machine=mips
 205                 case "`uname -m`" in
 206                 IP22) machine=mips/mips3 ;;
 207                 *)    machine=mips/$machine ,,
 208                 esac ;;
 209 sparc | sparcv[67])
 210                 base_machine=sparc machine=sparc/sparc32 ;;
 211 sparcv8 | supersparc | hypersparc)
 212                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 213 sparc64 | ultrasparc)
 214                 base_machine=sparc machine=sparc/sparc64 ;;
 215 esac
 216 changequote([,])dnl
 217 AC_SUBST(base_machine)
 218
 219 if test "$base_machine" = "i386"; then
 220   AC_DEFINE(USE_REGPARMS)
 221 fi
 222
 223 # Compute the list of sysdep directories for this configuration.
 224 # This can take a while to compute.
 225 sysdep_dir=$srcdir/sysdeps
 226 AC_MSG_CHECKING(sysdep dirs)
 227 dnl We need to use [ and ] for other purposes for a while now.
 228 changequote(,)dnl
 229 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 230 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 231
 232 case "$os" in
 233 gnu*)
 234   base_os=mach/hurd ;;
 235 netbsd* | 386bsd* | freebsd* | bsdi*)
 236   base_os=unix/bsd/bsd4.4 ;;
 237 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 238   base_os=unix/bsd ;;
 239 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 240   base_os=unix/sysv ;;
 241 irix6*)
 242   base_os=unix/sysv/irix6/$os ;;
 243 solaris[2-9]*)
 244   base_os=unix/sysv/sysv4 ;;
 245 none)
 246   base_os=standalone ;;
 247 *)
 248   base_os='' ;;
 249 esac
 250
 251 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 252 tail=$os
 253 ostry=$os
 254 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 255   ostry="$ostry /$o"
 256   tail=$o
 257 done
 258 o=`echo $tail | sed 's/[0-9]*$//'`
 259 if test $o != $tail; then
 260   ostry="$ostry /$o"
 261 fi
 262 # For linux-gnu, try linux-gnu, then linux.
 263 o=`echo $tail | sed 's/-.*$//'`
 264 if test $o != $tail; then
 265   ostry="$ostry /$o"
 266 fi
 267
 268 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 269 base=
 270 tail=$base_os
 271 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 272   set $b
 273   base="$base /$1"
 274   tail="$2"
 275 done
 276
 277 # For sparc/sparc9, try sparc/sparc9 and then sparc.
 278 mach=
 279 tail=$machine
 280 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 281   set $m
 282   # Prepend the machine's FPU directory unless --without-fp.
 283   if test "$with_fp" = yes; then
 284     mach="$mach /$1/fpu"
 285   fi
 286   mach="$mach /$1"
 287   tail="$2"
 288 done
 289
 290 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 291 changequote([,])dnl
 292
 293 # Find what sysdep directories exist.
 294 sysnames=
 295 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 296 for d in $add_ons_pfx ''; do
 297   for b in $base ''; do
 298     for m0 in $mach ''; do
 299       for v in /$vendor ''; do
 300         test "$v" = / && continue
 301         for o in /$ostry ''; do
 302           test "$o" = / && continue
 303           for m in $mach ''; do
 304             if test "$m0$b$v$o$m"; then
 305               try="${d}sysdeps$m0$b$v$o$m"
 306               test -n "$enable_debug_configure" &&
 307               echo "$0 [DEBUG]: try $try" >&2
 308               case $try in
 309                 /*) dest=$try ;;
 310                 *)  dest=$srcdir/$try ;;
 311               esac
 312               if test -d $dest; then
 313                 sysnames="$sysnames $try"
 314                 { test -n "$o" || test -n "$b"; } && os_used=t
 315                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 316               fi
 317             fi
 318           done
 319         done
 320       done
 321     done
 322   done
 323 done
 324 IFS="$ac_save_ifs"
 325
 326 if test -z "$os_used" && test "$os" != none; then
 327   AC_MSG_ERROR(Operating system $os is not supported.)
 328 fi
 329 if test -z "$machine_used" && test "$machine" != none; then
 330   AC_MSG_ERROR(The $machine is not supported.)
 331 fi
 332
 333 # We have now validated the configuration.
 334
 335
 336 # If using ELF, look for an `elf' subdirectory of each machine directory.
 337 # We prepend these rather than inserting them whereever the machine appears
 338 # because things specified by the machine's ELF ABI should override
 339 # OS-specific things, and should always be the same for any OS on the
 340 # machine (otherwise what's the point of an ABI?).
 341 if test "$elf" = yes; then
 342   elf_dirs=
 343   for d in $add_ons_pfx ''; do
 344     case $d in
 345       /*) xsrcdir= ;;
 346       *)  xsrcdir=$srcdir/ ;;
 347     esac
 348     for m in $mach; do
 349       if test -d $xsrcdir${d}sysdeps$m/elf; then
 350         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 351       fi
 352     done
 353   done
 354   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 355 fi
 356
 357
 358 # Expand the list of system names into a full list of directories
 359 # from each element's parent name and Implies file (if present).
 360 set $sysnames
 361 names=
 362 while test $# -gt 0; do
 363   name=$1
 364   shift
 365
 366   case " $names " in *" $name "*)
 367     # Already in the list.
 368     continue
 369   esac
 370
 371   # Report each name as we discover it, so there is no long pause in output.
 372   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 373
 374   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 375
 376   case $name in
 377     /*) xsrcdir= ;;
 378     *)  xsrcdir=$srcdir/ ;;
 379   esac
 380   test -n "$enable_debug_configure" &&
 381   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 382
 383   if test -f $xsrcdir$name/Implies; then
 384     # Collect more names from the `Implies' file (removing comments).
 385     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 386     implied=
 387     for x in $implied_candidate; do
 388       if test -d $xsrcdir$name_base/$x; then
 389         implied="$implied $name_base/$x";
 390       else
 391         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 392       fi
 393     done
 394   else
 395     implied=
 396   fi
 397
 398   # Add NAME to the list of names.
 399   names="$names $name"
 400
 401   # Find the parent of NAME, using the empty string if it has none.
 402 changequote(,)dnl
 403   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 404 changequote([,])dnl
 405
 406   # Add the names implied by NAME, and NAME's parent (if it has one), to
 407   # the list of names to be processed (the argument list).  We prepend the
 408   # implied names to the list and append the parent.  We want implied
 409   # directories to come before further directories inferred from the
 410   # configuration components; this ensures that for sysv4, unix/common
 411   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 412   # after sysv4).
 413   sysnames="`echo $implied $* $parent`"
 414   test -n "$sysnames" && set $sysnames
 415 done
 416
 417 # Add the default directories.
 418 sysnames="$names sysdeps/generic"
 419 AC_SUBST(sysnames)
 420 # The other names were emitted during the scan.
 421 AC_MSG_RESULT(sysdeps/generic)
 422
 423
 424 ### Locate tools.
 425
 426 AC_PROG_INSTALL
 427 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
 428   # The makefiles need to use a different form to find it in $srcdir.
 429   INSTALL='\$(..)./install-sh -c'
 430 fi
 431 AC_PROG_LN_S
 432 AC_CHECK_PROGS(MSGFMT, msgfmt gmsgfmt, :)
 433 if test "$MSGFMT" != ":"; then
 434 changequote(,)dnl Need [] for regexps.
 435   if $MSGFMT --version 2>&1 | grep 'GNU gettext.*0\.[1-9][0-9]' >/dev/null 2>&1
 436 changequote([,])dnl
 437   then : # msgfmt from gettext 0.10 or greater, works.
 438   else
 439     AC_MSG_WARN([
 440 *** (g)msgfmt is too old or wrong version (need gettext 0.10 or better).])
 441     MSGFMT=":"
 442   fi
 443 fi
 444
 445 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo)
 446 if test "$MAKEINFO"; then
 447 changequote(,)dnl Need [] for regexps.
 448   if $MAKEINFO --version | grep 'texinfo 3\.[1-9][1-9]' >/dev/null 2>&1
 449 changequote([,])dnl
 450   then : # Makeinfo 3.11 or greater, works.
 451   else
 452     AC_MSG_WARN([
 453 *** makeinfo is too old (need version 3.11 or better).
 454 *** You should install the needed version and re-configure since otherwise
 455 *** you won't get the info pages installed.])
 456     MAKEINFO=
 457   fi
 458 fi
 459
 460 AC_PROG_CC_LOCAL
 461 AC_CANONICAL_BUILD
 462 if test $host != $build; then
 463   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 464 fi
 465 AC_SUBST(cross_compiling)
 466 AC_PROG_CPP
 467 LIBC_PROG_BINUTILS
 468 AC_CHECK_TOOL(AR, ar)
 469 AC_CHECK_TOOL(RANLIB, ranlib, :)
 470
 471 # check if ar takes S
 472 AC_CACHE_CHECK(for ar S, libc_cv_ar_S, [dnl
 473 tmpo=$$.o
 474 tmplib=lib$$.a
 475 rm -f $tmpo $tmplib
 476 touch $tmpo
 477 if AC_TRY_COMMAND([${AR-ar} rcuS $tmplib $tmpo > /dev/null 2>&1]); then
 478   libc_cv_ar_S=yes
 479 else
 480   libc_cv_ar_S=no
 481 fi
 482 rm -f $tmpo $tmplib])
 483 AC_SUBST(libc_cv_ar_S)dnl
 484
 485 # check for recent compiler
 486 AC_MSG_CHECKING(compiler version)
 487 changequote(,)dnl
 488 case `${CC-cc} -v 2>&1` in
 489   *egcs-2.91.* | *egcs-1.0.[2-9]* | *egcs-1.1* | *2.8.[1-9]* | *2.9.[0-9]*)
 490     cc_is_recent="ok"
 491     ;;
 492   *)
 493     cc_is_recent="too old"
 494     ;;
 495 esac
 496 changequote([,])dnl
 497 AC_MSG_RESULT($cc_is_recent)
 498 if test "$cc_is_recent" != "ok"; then
 499   AC_MSG_WARN([
 500 *** Your compiler is too old.
 501 *** You need at least egcs 1.0.2 or GNU CC 2.8.1 to compile glibc.
 502 ])
 503 fi
 504
 505 # Test if LD_LIBRARY_PATH contains the notation for the current directory
 506 # since this would lead to problems installing/building glibc.
 507 # LD_LIBRARY_PATH contains the current directory if one of the following
 508 # is true:
 509 # - one of the terminals (":" and ";") is the first or last sign
 510 # - two terminals occur directly after each other
 511 # - the path contains an element with a dot in it
 512 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
 513 changequote(,)dnl
 514 case ${LD_LIBRARY_PATH} in
 515   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
 516     ld_library_path_setting="contains current directory"
 517     ;;
 518   *)
 519     ld_library_path_setting="ok"
 520     ;;
 521 esac
 522 changequote([,])dnl
 523 AC_MSG_RESULT($ld_library_path_setting)
 524 if test "$ld_library_path_setting" != "ok"; then
 525 AC_MSG_ERROR(
 526 *** LD_LIBRARY_PATH shouldn't contain the current path when building glibc.
 527 *** Please change the environment variable and run configure again.)
 528 fi
 529
 530 AC_PATH_PROG(BASH, bash, no)
 531 if test "$BASH" != no &&
 532    $BASH -c 'test "$BASH_VERSINFO" \
 533              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 534   libc_cv_have_bash2=yes
 535 else
 536   libc_cv_have_bash2=no
 537 fi
 538 AC_SUBST(libc_cv_have_bash2)
 539
 540 dnl We need a ksh compatible shell for tzselect.
 541 if test "$BASH" = no; then
 542   AC_PATH_PROG(KSH, ksh, no)
 543   if test "$KSH" = no; then
 544     libc_cv_have_ksh=no
 545   else
 546     libc_cv_have_ksh=yes
 547   fi
 548 else
 549   KSH="$BASH"
 550   AC_SUBST(KSH)
 551   libc_cv_have_ksh=yes
 552 fi
 553 AC_SUBST(libc_cv_have_ksh)
 554
 555 AC_PATH_PROGS(PERL, perl, no)
 556 AC_SUBST(PERL)
 557
 558 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 559 echo '#include <stddef.h>
 560 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 561 if eval "$ac_cpp conftest.c 2>/dev/null" \
 562 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 563   libc_cv_signed_size_t=no
 564 else
 565   libc_cv_signed_size_t=yes
 566 fi
 567 rm -f conftest*])
 568 if test $libc_cv_signed_size_t = yes; then
 569   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 570   cat >> confdefs.h <<\EOF
 571 #undef __SIZE_TYPE__
 572 #define __SIZE_TYPE__ unsigned
 573 EOF
 574 fi
 575
 576 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 577 AC_TRY_COMPILE(dnl
 578 [#define __need_size_t
 579 #define __need_wchar_t
 580 #include <stddef.h>
 581 #define __need_NULL
 582 #include <stddef.h>], [size_t size; wchar_t wchar;
 583 #ifdef offsetof
 584 #error stddef.h ignored __need_*
 585 #endif
 586 if (&size == NULL || &wchar == NULL) abort ();],
 587                libc_cv_friendly_stddef=yes,
 588                libc_cv_friendly_stddef=no)])
 589 if test $libc_cv_friendly_stddef = yes; then
 590   config_vars="$config_vars
 591 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 592 fi
 593
 594 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 595                libc_cv_need_minus_P, [dnl
 596 cat > conftest.S <<EOF
 597 #include "confdefs.h"
 598 /* Nothing whatsoever.  */
 599 EOF
 600 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 601   libc_cv_need_minus_P=no
 602 else
 603   libc_cv_need_minus_P=yes
 604 fi
 605 rm -f conftest*])
 606 if test $libc_cv_need_minus_P = yes; then
 607   config_vars="$config_vars
 608 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 609 fi
 610
 611 # gcc 2.7.x has a bug where if -pipe is set, the assembler will always
 612 # be told to read stdin.  This causes the compiler to hang when fed an
 613 # .s file.
 614 if test $ac_cv_prog_gcc = yes; then
 615  case `${CC-cc} -v 2>&1` in
 616   *2.7*)
 617   # We must check this even if -pipe is not given here, because the user
 618   # might do `make CFLAGS=-pipe'.
 619   AC_CACHE_CHECK(for gcc 2.7.x -pipe bug, libc_cv_gcc_pipe_bug, [dnl
 620    cp /dev/null conftest.s
 621    cat >conftest1.s <<EOF
 622 .nosuchdirective
 623 EOF
 624    if ${CC-cc} -pipe -c conftest.s <conftest1.s 2>/dev/null; then
 625     libc_cv_gcc_pipe_bug=no
 626    else
 627     libc_cv_gcc_pipe_bug=yes
 628    fi
 629    rm -f conftest*])
 630   if test $libc_cv_gcc_pipe_bug = yes; then
 631    makeCC="${CC-cc} -B\$(common-objpfx)"
 632    makeCFLAGS=$CFLAGS
 633    CFLAGS=`echo $CFLAGS |sed 's/-pipe//'`
 634   fi;;
 635  *) libc_cv_gcc_pipe_bug=no;;
 636  esac
 637 else
 638  libc_cv_gcc_pipe_bug=no
 639 fi
 640
 641 AC_CACHE_CHECK(for assembler global-symbol directive,
 642                libc_cv_asm_global_directive, [dnl
 643 libc_cv_asm_global_directive=UNKNOWN
 644 for ac_globl in .globl .global; do
 645   cat > conftest.s <<EOF
 646 .text
 647 ${ac_globl} foo
 648 foo:
 649 EOF
 650   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 651     libc_cv_asm_global_directive=${ac_globl}
 652   fi
 653   rm -f conftest*
 654   test $libc_cv_asm_global_directive != UNKNOWN && break
 655 done])
 656 if test $libc_cv_asm_global_directive = UNKNOWN; then
 657   AC_MSG_ERROR(cannot determine asm global directive)
 658 else
 659   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 660 fi
 661
 662 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 663 cat > conftest.s <<EOF
 664 .text
 665 foo:
 666 .set glibc_conftest_frobozz,foo
 667 $libc_cv_asm_global_directive glibc_conftest_frobozz
 668 EOF
 669 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 670 # (but it doesn't work), so we must do a linking check to be sure.
 671 cat > conftest1.c <<\EOF
 672 extern int glibc_conftest_frobozz;
 673 main () { printf ("%d\n", glibc_conftest_frobozz); }
 674 EOF
 675 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 676             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 677   libc_cv_asm_set_directive=yes
 678 else
 679   libc_cv_asm_set_directive=no
 680 fi
 681 rm -f conftest*])
 682 if test $libc_cv_asm_set_directive = yes; then
 683   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 684 fi
 685
 686 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
 687 [cat > conftest.s <<EOF
 688 .text
 689 _sym:
 690 .symver _sym,sym@VERS
 691 EOF
 692 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 693   libc_cv_asm_symver_directive=yes
 694 else
 695   libc_cv_asm_symver_directive=no
 696 fi
 697 rm -f conftest*])
 698 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
 699 if test $libc_cv_asm_symver_directive = yes; then
 700   cat > conftest.s <<EOF
 701 .text
 702 _sym:
 703 .symver _sym,sym@VERS
 704 EOF
 705   cat > conftest.map <<EOF
 706 VERS_1 {
 707         global: sym;
 708 };
 709
 710 VERS_2 {
 711         global: sym;
 712 } VERS_1;
 713 EOF
 714   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 715     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
 716                                         -nostartfiles -nostdlib
 717                                         -Wl,--version-script,conftest.map
 718                        1>&AC_FD_CC]);
 719     then
 720       libc_cv_ld_version_script_option=yes
 721     else
 722       libc_cv_ld_version_script_option=no
 723     fi
 724   else
 725     libc_cv_ld_version_script_option=no
 726   fi
 727 else
 728   libc_cv_ld_version_script_option=no
 729 fi
 730 rm -f conftest*])
 731 if test $libc_cv_asm_symver_directive = yes &&
 732    test $libc_cv_ld_version_script_option = yes &&
 733    test $enable_versioning = yes; then
 734   VERSIONING=yes
 735   AC_DEFINE(DO_VERSIONING)
 736 else
 737   VERSIONING=no
 738 fi
 739 AC_SUBST(VERSIONING)
 740
 741 if test $VERSIONING = no; then
 742   echo "\
 743 *** WARNING: You should not compile GNU libc without versioning. Not using
 744 *** versioning will introduce incompatibilities so that old binaries
 745 *** will not run anymore.
 746 *** For versioning you need recent binutils (binutils-2.8.1.0.17 or newer)."
 747 fi
 748 if test $elf = yes; then
 749   AC_CACHE_CHECK(for .previous assembler directive,
 750                  libc_cv_asm_previous_directive, [dnl
 751   cat > conftest.s <<EOF
 752 .section foo_section
 753 .previous
 754 EOF
 755   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 756     libc_cv_asm_previous_directive=yes
 757   else
 758     libc_cv_asm_previous_directive=no
 759   fi
 760   rm -f conftest*])
 761   if test $libc_cv_asm_previous_directive = yes; then
 762     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
 763   else
 764     AC_CACHE_CHECK(for .popsection assembler directive,
 765                    libc_cv_asm_popsection_directive, [dnl
 766     cat > conftest.s <<EOF
 767 .pushsection foo_section
 768 .popsection
 769 EOF
 770     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 771       libc_cv_asm_popsection_directive=yes
 772     else
 773       libc_cv_asm_popsection_directive=no
 774     fi
 775     rm -f conftest*])
 776     if test $libc_cv_asm_popsection_directive = yes; then
 777       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
 778     fi
 779   fi
 780 fi
 781
 782 if test $elf != yes; then
 783   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 784                  [AC_TRY_COMPILE(, [asm (".section .init");
 785                                     asm (".section .fini");
 786                                     asm (".text");],
 787                                  libc_cv_have_initfini=yes,
 788                                  libc_cv_have_initfini=no)])
 789   AC_SUBST(libc_cv_have_initfini)dnl
 790   if test $libc_cv_have_initfini = yes; then
 791     AC_DEFINE(HAVE_INITFINI)
 792   fi
 793 fi
 794
 795 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
 796 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
 797 [cat > conftest.$ac_ext <<EOF
 798 dnl This sometimes fails to find confdefs.h, for some reason.
 799 dnl [#]line __oline__ "[$]0"
 800 [#]line __oline__ "configure"
 801 #include "confdefs.h"
 802 void underscore_test(void) {
 803 return; }
 804 EOF
 805 if AC_TRY_EVAL(ac_compile); then
 806   if grep _underscore_test conftest* >/dev/null; then
 807     ifelse([$1], , :, [rm -f conftest*
 808     $1])
 809   else
 810     ifelse([$2], , , [rm -f conftest*
 811     $2])
 812   fi
 813 else
 814   echo "configure: failed program was:" >&AC_FD_CC
 815   cat conftest.$ac_ext >&AC_FD_CC
 816   ifelse([$2], , , [rm -f conftest*
 817   $2])
 818 fi
 819 rm -f conftest*])
 820
 821 if test $elf = yes; then
 822   libc_cv_asm_underscores=no
 823 else
 824   if test $ac_cv_prog_cc_works = yes; then
 825     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 826                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 827                                 libc_cv_asm_underscores=yes,
 828                                 libc_cv_asm_underscores=no)])
 829   else
 830     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 831                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
 832                                             libc_cv_asm_underscores=no)])
 833   fi
 834 fi
 835 if test $libc_cv_asm_underscores = no; then
 836   AC_DEFINE(NO_UNDERSCORES)
 837 fi
 838
 839 if test $elf = yes; then
 840   libc_cv_weak_symbols=yes
 841 fi
 842
 843 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 844                  [dnl
 845 cat > conftest.s <<EOF
 846 .text
 847 ${libc_cv_asm_global_directive} foo
 848 foo:
 849 .weak foo
 850 .weak bar; bar = foo
 851 EOF
 852 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 853   libc_cv_asm_weak_directive=yes
 854 else
 855   libc_cv_asm_weak_directive=no
 856 fi
 857 rm -f conftest*])
 858
 859 if test $libc_cv_asm_weak_directive = no; then
 860   AC_CACHE_CHECK(for assembler .weakext directive,
 861                  libc_cv_asm_weakext_directive,
 862                  [dnl
 863 cat > conftest.s <<EOF
 864 .text
 865 ${libc_cv_asm_global_directive} foo
 866 foo:
 867 .weakext bar foo
 868 .weakext baz
 869 ${libc_cv_asm_global_directive} baz
 870 baz:
 871 EOF
 872   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 873     libc_cv_asm_weakext_directive=yes
 874   else
 875     libc_cv_asm_weakext_directive=no
 876   fi
 877   rm -f conftest*])
 878
 879 fi # no .weak
 880
 881 if test $libc_cv_asm_weak_directive = yes; then
 882   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 883 elif test $libc_cv_asm_weakext_directive = yes; then
 884   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 885 fi
 886
 887 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
 888 cat > conftest.c <<\EOF
 889 _start () {}
 890 int __eh_pc;
 891 __throw () {}
 892 EOF
 893 dnl No \ in command here because it ends up inside ''.
 894 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 895                             -nostdlib -nostartfiles -Wl,--no-whole-archive
 896                             -o conftest conftest.c 1>&AC_FD_CC]); then
 897   libc_cv_ld_no_whole_archive=yes
 898 else
 899   libc_cv_ld_no_whole_archive=no
 900 fi
 901 rm -f conftest*])
 902 AC_SUBST(libc_cv_ld_no_whole_archive)dnl
 903
 904 AC_CACHE_CHECK(for gcc -fno-exceptions, libc_cv_gcc_no_exceptions, [dnl
 905 cat > conftest.c <<\EOF
 906 _start () {}
 907 int __eh_pc;
 908 __throw () {}
 909 EOF
 910 dnl No \ in command here because it ends up inside ''.
 911 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 912                             -nostdlib -nostartfiles -fno-exceptions
 913                             -o conftest conftest.c 1>&AC_FD_CC]); then
 914   libc_cv_gcc_no_exceptions=yes
 915 else
 916   libc_cv_gcc_no_exceptions=no
 917 fi
 918 rm -f conftest*])
 919 AC_SUBST(libc_cv_gcc_no_exceptions)dnl
 920
 921 if test "$base_machine" = alpha ; then
 922 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
 923 cat > conftest.c <<\EOF
 924 foo () { }
 925 EOF
 926 dnl
 927 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
 928 then
 929   libc_cv_gcc_alpha_ng_prefix=yes
 930 else
 931   libc_cv_gcc_alpha_ng_prefix=no
 932 fi
 933 rm -f conftest* ])
 934 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
 935   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
 936 else
 937   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
 938 fi
 939 fi
 940
 941 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
 942 [cat > conftest.c <<EOF
 943 #line __oline__ "configure"
 944 static char __EH_FRAME_BEGIN__[];
 945 _start ()
 946 {
 947 #ifdef CHECK__register_frame
 948   __register_frame (__EH_FRAME_BEGIN__);
 949   __deregister_frame (__EH_FRAME_BEGIN__);
 950 #endif
 951 #ifdef CHECK__register_frame_info
 952   __register_frame_info (__EH_FRAME_BEGIN__);
 953   __deregister_frame_info (__EH_FRAME_BEGIN__);
 954 #endif
 955 }
 956 int __eh_pc;
 957 __throw () {}
 958 /* FIXME: this is fragile.  */
 959 malloc () {}
 960 strcmp () {}
 961 strlen () {}
 962 memcpy () {}
 963 memset () {}
 964 free () {}
 965 abort () {}
 966 __bzero () {}
 967 EOF
 968 dnl No \ in command here because it ends up inside ''.
 969 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
 970                             -nostdlib -nostartfiles
 971                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
 972   libc_cv_gcc_dwarf2_unwind_info=static
 973 else
 974   libc_cv_gcc_dwarf2_unwind_info=no
 975 fi
 976 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
 977   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
 978                               -nostdlib -nostartfiles
 979                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
 980     libc_cv_gcc_dwarf2_unwind_info=yes
 981   else
 982     libc_cv_gcc_dwarf2_unwind_info=no
 983   fi
 984 fi
 985 rm -f conftest*])
 986 case $libc_cv_gcc_dwarf2_unwind_info in
 987 yes)
 988   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
 989   ;;
 990 static)
 991   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
 992   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
 993   ;;
 994 esac
 995
 996 ### End of automated tests.
 997 ### Now run sysdeps configure fragments.
 998
 999 # sysdeps configure fragments may set these with files to be linked below.
1000 libc_link_dests=
1001 libc_link_sources=
1002
1003 # They also can set these variables.
1004 ldd_rewrite_script=no
1005
1006 # Iterate over all the sysdep directories we will use, running their
1007 # configure fragments, and looking for a uname implementation.
1008 uname=
1009 for dir in $sysnames; do
1010   case $dir in
1011     /*) dest=$dir ;;
1012     *)  dest=$srcdir/$dir ;;
1013   esac
1014   if test -r $dest/configure; then
1015     AC_MSG_RESULT(running configure fragment for $dest)
1016     . $dest/configure
1017   fi
1018 [
1019   if test -z "$uname"; then
1020     if test -r $dest/uname.c ||
1021        test -r $dest/uname.S ||
1022        { test -r $dest/syscalls.list &&
1023          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
1024       uname=$dir
1025     fi
1026   fi
1027 ]dnl
1028 done
1029
1030 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
1031
1032 # If we will use the generic uname implementation, we must figure out what
1033 # it will say by examining the system, and write the results in config-name.h.
1034 if test "$uname" = "sysdeps/generic"; then
1035
1036 changequote(,)dnl
1037   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
1038 changequote([,])dnl
1039   if test $uname_sysname != $config_os; then
1040     config_release=`echo $config_os | sed s/$uname_sysname//`
1041   fi
1042 dnl
1043 AC_DEFUN(LIBC_KERNEL_ID, [dnl
1044     if test -r /vmunix; then
1045       kernel_id=`strings /vmunix | grep UNIX`
1046     elif test -r /dynix; then
1047       kernel_id=`strings /dynix | grep DYNIX`
1048     else
1049       kernel_id=
1050     fi
1051 ])dnl
1052
1053   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
1054 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1055 changequote(,)dnl
1056   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
1057 changequote([,])dnl
1058   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
1059          != x$config_release; then
1060     # The configuration release is a substring of the kernel release.
1061     libc_cv_uname_release=$kernel_release
1062   elif test x$config_release != x; then
1063     libc_cv_uname_release=$config_release
1064   elif test x$kernel_release != x; then
1065     libc_cv_uname_release=$kernel_release
1066   else
1067     libc_cv_uname_release=unknown
1068   fi])
1069   uname_release="$libc_cv_uname_release"
1070
1071   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
1072 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1073 changequote(,)dnl
1074   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
1075 changequote([,])dnl
1076   if test -n "$kernel_version"; then
1077     libc_cv_uname_version="$kernel_version"
1078   else
1079     libc_cv_uname_version=unknown
1080   fi])
1081   uname_version="$libc_cv_uname_version"
1082
1083 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1084   config_uname=config-name.h:config-name.in
1085 else
1086   # For non-generic uname, we don't need to create config-name.h at all.
1087   config_uname=
1088 fi
1089
1090 AC_MSG_CHECKING(stdio selection)
1091 AC_SUBST(stdio)
1092 case $stdio in
1093 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1094 default) stdio=stdio ;;
1095 esac
1096 AC_MSG_RESULT($stdio)
1097
1098 AC_MSG_CHECKING(ldap selection)
1099 AC_SUBST(LDAP)
1100 case $add_ons in
1101 *ldap*)
1102    ldap=yes
1103    LDAP=ldap ;;
1104 *) ldap=no
1105    LDAP= ;;
1106 esac
1107 AC_MSG_RESULT($ldap)
1108
1109 AC_SUBST(libc_cv_slibdir)
1110 AC_SUBST(libc_cv_sysconfdir)
1111 AC_SUBST(libc_cv_rootsbindir)
1112
1113 AC_SUBST(has_ldconfig)
1114 AC_SUBST(ldd_rewrite_script)
1115
1116 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1117 if test $gnu_ld = yes; then
1118   AC_DEFINE(HAVE_GNU_LD)
1119 fi
1120 if test $gnu_as = yes; then
1121   AC_DEFINE(HAVE_GNU_AS)
1122 fi
1123 if test $elf = yes; then
1124   AC_DEFINE(HAVE_ELF)
1125 fi
1126
1127 AC_SUBST(static)
1128 AC_SUBST(shared)
1129 if test $shared = default; then
1130   if test $gnu_ld = yes; then
1131     shared=$elf
1132   else
1133     # For now we do not assume shared libs are available.  In future more
1134     # tests might become available.
1135     shared=no
1136   fi
1137 fi
1138
1139 dnl We must not allow compilation without static library on some platforms.
1140 if test $static = no && test $shared = yes; then
1141   case "$host_os" in
1142   linux* | gnu*)
1143     AC_MSG_ERROR([
1144 *** You must compile with support for the static library since the shared
1145 *** library uses it.  Restart configure without \`--disable-static'.])
1146     ;;
1147   *)
1148     ;;
1149   esac
1150 fi
1151
1152 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1153 [pic_default=yes
1154 cat > conftest.c <<EOF
1155 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1156 # error PIC is default.
1157 #endif
1158 EOF
1159 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1160   pic_default=no
1161 fi
1162 rm -f conftest.*])
1163 AC_SUBST(pic_default)
1164
1165 AC_SUBST(profile)
1166 AC_SUBST(omitfp)
1167 AC_SUBST(bounded)
1168 AC_SUBST(static_nss)
1169 AC_SUBST(nopic_initfini)
1170
1171 AC_SUBST(DEFINES)
1172
1173 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1174   config_makefile=
1175 else
1176   config_makefile=Makefile
1177 fi
1178
1179 VERSION=`sed -e 's/^#define VERSION "\([^"]*\)"/\1/p' -e d < $srcdir/version.h`
1180 AC_SUBST(VERSION)
1181
1182 if test $libc_cv_gcc_pipe_bug = yes; then
1183  realCC=$CC
1184  CC=$makeCC
1185  CFLAGS=$makeCFLAGS
1186 fi
1187 AC_OUTPUT_COMMANDS([
1188 if test "$realCC"; then
1189  sed -e 's/%{pipe:-}/%|/g' `$realCC -print-file-name=specs` >specsT
1190  mv specsT specs
1191 fi], [realCC=$realCC])
1192
1193 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, ,
1194           [echo '$config_vars' >> config.make; test -d bits || mkdir bits])