configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.54)
   4
   5 dnl ==========================================================================
   6 dnl                              Versioning
   7 dnl ==========================================================================
   8
   9 dnl Making releases:
  10 dnl   ATK_MICRO_VERSION += 1;
  11 dnl   ATK_INTERFACE_AGE += 1;
  12 dnl   ATK_BINARY_AGE += 1;
  13 dnl if any functions have been added, set ATK_INTERFACE_AGE to 0.
  14 dnl if backwards compatibility has been broken,
  15 dnl set ATK_BINARY_AGE _and_ ATK_INTERFACE_AGE to 0.
  16
  17 dnl The triplet
  18 m4_define([atk_major_version], [1])
  19 m4_define([atk_minor_version], [10])
  20 m4_define([atk_micro_version], [1])
  21 m4_define([atk_version],
  22           [atk_major_version.atk_minor_version.atk_micro_version])
  23
  24 dnl The X.Y in -latk-X.Y line. This is expected to stay 1.0 until Atk 2.
  25 m4_define([atk_api_version], [1.0])
  26
  27 dnl Number of releases since we've added interfaces
  28 m4_define([atk_interface_age], [0])
  29
  30 m4_define([atk_binary_age],
  31           [m4_eval(100 * atk_minor_version + 10 + atk_micro_version)])
  32
  33 m4_define([lt_current],
  34           [m4_eval(100 * atk_minor_version + 10 + atk_micro_version - atk_interface_age)])`
  35 m4_define([lt_revision], [atk_interface_age])
  36 m4_define([lt_age], [m4_eval(atk_binary_age - atk_interface_age)])
  37 m4_define([lt_version_info], [lt_current:lt_revision:lt_age])
  38 m4_define([lt_current_minus_age], [m4_eval(lt_current - lt_age)])
  39
  40
  41 AC_INIT(atk, [atk_version],
  42         [http://bugzilla.gnome.org/enter_bug.cgi?product=atk])
  43 AC_CONFIG_SRCDIR([ChangeLog])
  44
  45 AM_CONFIG_HEADER(config.h)
  46
  47 AM_INIT_AUTOMAKE
  48
  49 dnl ==========================================================================
  50 dnl
  51 dnl If you add a version number here, you *must* add an AC_SUBST line for
  52 dnl it too, or it will never make it into the spec file!
  53 dnl
  54 dnl ==========================================================================
  55
  56 ATK_MAJOR_VERSION=atk_major_version
  57 ATK_MINOR_VERSION=atk_minor_version
  58 ATK_MICRO_VERSION=atk_micro_version
  59 ATK_VERSION=atk_version
  60 ATK_API_VERSION=atk_api_version
  61 ATK_INTERFACE_AGE=atk_interface_age
  62 ATK_BINARY_AGE=atk_binary_age
  63
  64 AC_SUBST(ATK_MAJOR_VERSION)
  65 AC_SUBST(ATK_MINOR_VERSION)
  66 AC_SUBST(ATK_VERSION)
  67 AC_SUBST(ATK_API_VERSION)
  68 AC_SUBST(ATK_MICRO_VERSION)
  69 AC_SUBST(ATK_INTERFACE_AGE)
  70 AC_SUBST(ATK_BINARY_AGE)
  71
  72 dnl libtool versioning
  73 LT_VERSION_INFO=lt_version_info
  74 LT_CURRENT_MINUS_AGE=lt_current_minus_age
  75 AC_SUBST(LT_VERSION_INFO)
  76 AC_SUBST(LT_CURRENT_MINUS_AGE)
  77
  78 dnl ==========================================================================
  79
  80 GETTEXT_PACKAGE=atk10
  81 AC_SUBST(GETTEXT_PACKAGE)
  82 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
  83   [Define the gettext package to be used])
  84
  85 AC_PROG_CC
  86 AM_DISABLE_STATIC
  87 AC_LIBTOOL_WIN32_DLL
  88 AM_PROG_LIBTOOL
  89
  90 AC_MSG_CHECKING([for some Win32 platform])
  91 case "$host" in
  92   *-*-mingw*|*-*-cygwin*)
  93     platform_win32=yes
  94     ;;
  95   *)
  96     platform_win32=no
  97     ;;
  98 esac
  99 AC_MSG_RESULT([$platform_win32])
 100 AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")
 101
 102 AC_MSG_CHECKING([for native Win32 platform])
 103 case "$host" in
 104   *-*-mingw*)
 105     atk_native_win32=yes
 106     ;;
 107   *)
 108     atk_native_win32=no
 109     ;;
 110 esac
 111 AC_MSG_RESULT([$atk_native_win32])
 112 AM_CONDITIONAL(OS_WIN32, test "$atk_native_win32" = "yes")
 113
 114 if test "$atk_native_win32" = "yes"; then
 115   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 116 fi
 117 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 118
 119 dnl Cache $ACLOCAL_FLAGS
 120 AC_CACHE_CHECK([for aclocal flags], ac_cv_atk_aclocal_flags,[
 121    ac_cv_atk_aclocal_flags="$ACLOCAL_FLAGS"
 122 ])
 123 ACLOCAL="$ACLOCAL $ac_cv_atk_aclocal_flags"
 124
 125 AC_ARG_ENABLE(rebuilds,
 126               [AC_HELP_STRING([--disable-rebuilds],
 127                               [disable all source autogeneration rules])],,
 128               [enable_rebuilds=yes])
 129
 130 changequote(,)dnl
 131 if test "x$GCC" = "xyes"; then
 132   case " $CFLAGS " in
 133   *[\ \ ]-Wall[\ \      ]*) ;;
 134   *) CFLAGS="$CFLAGS -Wall" ;;
 135   esac
 136 fi
 137 changequote([,])dnl
 138
 139 AM_PATH_GLIB_2_0(2.5.7,have_no_export=true,have_no_export=false)
 140 if test "x$have_no_export" = "xtrue"; then
 141    GLIB_REQUIRED_VERSION=2.5.7
 142    glib_no_export_package="gmodule-no-export-2.0"
 143 else
 144    GLIB_REQUIRED_VERSION=2.0.0
 145    glib_no_export_package=
 146 fi
 147 GLIB_PACKAGES="gobject-2.0 $glib_no_export_package"
 148 AC_SUBST(GLIB_PACKAGES)
 149 AC_SUBST(GLIB_REQUIRED_VERSION)
 150
 151 dnl This PATH_GLIB is somewhat redundant, but does a sanity compile and
 152 dnl importantly defines the GLIB_GENMARSHAL variable for subst into the
 153 dnl Makefile
 154 AM_PATH_GLIB_2_0($GLIB_REQUIRED_VERSION, :,
 155   AC_MSG_ERROR([
 156 *** GLIB $GLIB_REQUIRED_VERSION or better is required. The latest version of
 157 *** GLIB is always available from ftp://ftp.gtk.org/. If GLIB is installed
 158 *** but not in the same location as pkg-config add the location of the file
 159 *** glib-2.0.pc to the environment variable PKG_CONFIG_PATH.]),
 160   gobject gmodule-no-export)
 161
 162 PKG_CHECK_MODULES(DEP, glib-2.0 >= $GLIB_REQUIRED_VERSION $GLIB_PACKAGES, ,
 163   AC_MSG_ERROR([
 164         *** GLib not found. You can find it on ftp://ftp.gtk.org
 165         *** Errors follow:
 166             $DEP_PKG_ERRORS]))
 167
 168 # Rerun PKG_CONFIG to add gthread-2.0 cflags, but not libs
 169 DEP_CFLAGS=`$PKG_CONFIG --cflags $GLIB_PACKAGES gthread-2.0`
 170
 171 ALL_LINGUAS="af am ar as az be bg bn bs ca cs cy da de el en_CA en_GB eo es et eu fa fi fr ga gl gu he hi hr hu id is it ja kn ko li lt lv mk ml mn mr ms nb ne nl nn no pa pl pt pt_BR ro ru rw sk sl sq sr sr@Latn sr@ije sv ta th tk tr uk vi wa xh yi zh_CN zh_TW"
 172 AM_GLIB_GNU_GETTEXT
 173
 174 AM_GLIB_DEFINE_LOCALEDIR(ATK_LOCALEDIR)
 175
 176 AC_CHECK_FUNCS(bind_textdomain_codeset)
 177
 178 GTK_DOC_CHECK([1.0])
 179
 180 # define a MAINT-like variable REBUILD which is set if Perl
 181 # and awk are found, so autogenerated sources can be rebuilt
 182
 183 AC_PROG_AWK
 184 AC_CHECK_PROGS(PERL, perl5 perl)
 185
 186 REBUILD=\#
 187 if test "x$enable_rebuilds" = "xyes" && \
 188         test -n "$PERL" && \
 189         $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 190      test -n "$AWK" ; then
 191   REBUILD=
 192 fi
 193 AC_SUBST(REBUILD)
 194
 195 AC_CONFIG_FILES([
 196 Makefile
 197 po/Makefile.in
 198 atk.pc
 199 atk-uninstalled.pc
 200 atk/Makefile
 201 atk/atk.rc
 202 tests/Makefile
 203 docs/Makefile
 204 docs/version.xml
 205 atk.spec
 206 atk-zip.sh
 207 ])
 208
 209 AC_OUTPUT