configure.in

   1 dnl ***********************************
   2 dnl *** include special GLib macros ***
   3 dnl ***********************************
   4 builtin(include, acglib.m4)dnl
   5
   6 # require autoconf 2.13
   7 AC_PREREQ(2.13)
   8
   9 # Process this file with autoconf to produce a configure script.
  10 AC_INIT(glist.c)
  11
  12 # Save this value here, since automake will set cflags later
  13 cflags_set=${CFLAGS+set}
  14
  15 # we rewrite this file
  16 rm -f glibconfig-sysdefs.h
  17
  18 GLIB_AC_DIVERT_BEFORE_HELP([
  19 #
  20 # The following version number definitions apply to GLib, GModule, GObject
  21 # and GThread as a whole, so if changes occoured in any of them, they are all
  22 # treated with the same interface and binary age.
  23 #
  24 # Making releases:
  25 #   GLIB_MICRO_VERSION += 1;
  26 #   GLIB_INTERFACE_AGE += 1;
  27 #   GLIB_BINARY_AGE += 1;
  28 # if any functions have been added, set GLIB_INTERFACE_AGE to 0.
  29 # if backwards compatibility has been broken,
  30 # set GLIB_BINARY_AGE _and_ GLIB_INTERFACE_AGE to 0.
  31 #
  32 GLIB_MAJOR_VERSION=1
  33 GLIB_MINOR_VERSION=3
  34 GLIB_MICRO_VERSION=2
  35 GLIB_INTERFACE_AGE=0
  36 GLIB_BINARY_AGE=0
  37 GLIB_VERSION=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION.$GLIB_MICRO_VERSION
  38 ])dnl
  39
  40 AC_SUBST(GLIB_MAJOR_VERSION)
  41 AC_SUBST(GLIB_MINOR_VERSION)
  42 AC_SUBST(GLIB_MICRO_VERSION)
  43 AC_SUBST(GLIB_VERSION)
  44 AC_SUBST(GLIB_INTERFACE_AGE)
  45 AC_SUBST(GLIB_BINARY_AGE)
  46
  47 # libtool versioning
  48 LT_RELEASE=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION
  49 LT_CURRENT=`expr $GLIB_MICRO_VERSION - $GLIB_INTERFACE_AGE`
  50 LT_REVISION=$GLIB_INTERFACE_AGE
  51 LT_AGE=`expr $GLIB_BINARY_AGE - $GLIB_INTERFACE_AGE`
  52 AC_SUBST(LT_RELEASE)
  53 AC_SUBST(LT_CURRENT)
  54 AC_SUBST(LT_REVISION)
  55 AC_SUBST(LT_AGE)
  56
  57 VERSION=$GLIB_VERSION
  58 PACKAGE=glib
  59
  60 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  61
  62 # Specify a configuration file
  63 AM_CONFIG_HEADER(config.h)
  64
  65 AC_DEFINE_UNQUOTED(GLIB_MAJOR_VERSION, $GLIB_MAJOR_VERSION,
  66                    [Define to the GLIB major version])
  67 AC_DEFINE_UNQUOTED(GLIB_MINOR_VERSION, $GLIB_MINOR_VERSION,
  68                    [Define to the GLIB minor version])
  69 AC_DEFINE_UNQUOTED(GLIB_MICRO_VERSION, $GLIB_MICRO_VERSION,
  70                    [Define to the GLIB micro version])
  71 AC_DEFINE_UNQUOTED(GLIB_INTERFACE_AGE, $GLIB_INTERFACE_AGE,
  72                    [Define to the GLIB interface age])
  73 AC_DEFINE_UNQUOTED(GLIB_BINARY_AGE, $GLIB_BINARY_AGE,
  74                    [Define to the GLIB binary age])
  75
  76 dnl Initialize maintainer mode
  77 AM_MAINTAINER_MODE
  78
  79 AC_CANONICAL_HOST
  80
  81 AC_MSG_CHECKING(for the BeOS)
  82 case $host in
  83   *-*-beos*)
  84     glib_native_beos="yes"
  85     ;;
  86   *)
  87     glib_native_beos="no"
  88     ;;
  89 esac
  90 AC_MSG_RESULT([$glib_native_beos])
  91
  92 dnl
  93
  94 GLIB_AC_DIVERT_BEFORE_HELP([
  95 # figure debugging default, prior to $ac_help setup
  96 case $GLIB_MINOR_VERSION in
  97 *[[13579]]) debug_default=yes ;;
  98 *)          debug_default=minimum ;;
  99 esac[]dnl
 100 ])
 101
 102 dnl declare --enable-* args and collect ac_help strings
 103 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=$debug_default]],,enable_debug=$debug_default)
 104 AC_ARG_ENABLE(msg-prefix, [  --enable-msg-prefix     turn on program name and PID prefixing of messages and warnings],,enable_msg_prefix=no)
 105 AC_ARG_ENABLE(mem_check, [  --enable-mem-check      turn on malloc/free sanity checking [default=no]],,enable_mem_check=no)
 106 AC_ARG_ENABLE(mem_profile, [  --enable-mem-profile    turn on malloc profiling atexit [default=no]],,enable_mem_profile=no)
 107 AC_ARG_ENABLE(gc_friendly, [  --enable-gc-friendly    turn on garbage collector friendliness [default=no]],,enable_gc_friendly=no)
 108 AC_ARG_ENABLE(mem_pools, [  --disable-mem-pools     disable all glib memory pools],,disable_mem_pools=no)
 109 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
 110                     , enable_ansi=no)
 111 AC_ARG_ENABLE(threads, [  --enable-threads        turn on basic thread support [default=yes]
 112                           ([=no] will override --with-threads)],,enable_threads=yes)
 113 AC_ARG_ENABLE(rebuilds, [  --disable-rebuilds      disable all source autogeneration rules],,enable_rebuilds=yes)
 114
 115 if test "x$enable_threads" != "xyes"; then
 116   enable_threads=no
 117 fi
 118
 119 AC_MSG_CHECKING(whether to enable memory checking)
 120 if test "x$enable_mem_check" = "xyes"; then
 121   AC_DEFINE(ENABLE_MEM_CHECK, 1, [Whether to enable memory checking])
 122   AC_SUBST(ENABLE_MEM_CHECK)
 123   AC_MSG_RESULT(yes)
 124 else
 125   AC_MSG_RESULT(no)
 126 fi
 127
 128 AC_MSG_CHECKING(whether to enable memory profiling)
 129 if test "x$enable_mem_profile" = "xyes"; then
 130   AC_DEFINE(ENABLE_MEM_PROFILE, 1, [Whether to enable memory profiling])
 131   AC_SUBST(ENABLE_MEM_PROFILE)
 132   AC_MSG_RESULT(yes)
 133 else
 134   AC_MSG_RESULT(no)
 135 fi
 136
 137 AC_MSG_CHECKING(whether to enable garbage collector friendliness)
 138 if test "x$enable_gc_friendly" = "xyes"; then
 139   AC_DEFINE(ENABLE_GC_FRIENDLY, 1, [Whether to enable GC friendliness])
 140   AC_SUBST(ENABLE_GC_FRIENDLY)
 141   AC_MSG_RESULT(yes)
 142 else
 143   AC_MSG_RESULT(no)
 144 fi
 145
 146 AC_MSG_CHECKING(whether to disable memory pools)
 147 if test "x$disable_mem_pools" = "xno"; then
 148   AC_MSG_RESULT(no)
 149 else
 150   AC_DEFINE(DISABLE_MEM_POOLS, 1, [Whether to disable memory pools])
 151   AC_SUBST(DISABLE_MEM_POOLS)
 152   AC_MSG_RESULT(yes)
 153 fi
 154
 155
 156 if test "x$enable_debug" = "xyes"; then
 157   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 158   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 159 else
 160   if test "x$enable_debug" = "xno"; then
 161     GLIB_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 162   fi
 163 fi
 164
 165 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 166         [Whether glib was compiled with debugging enabled])
 167
 168 if test "x$enable_msg_prefix" = "xyes"; then
 169   AC_DEFINE_UNQUOTED(G_ENABLE_MSG_PREFIX, 1,
 170                      [Enable prefixing of error messages with program names])
 171 fi
 172
 173 # Checks for programs.
 174 AC_PROG_CC
 175 AM_PROG_CC_STDC
 176 AC_PROG_INSTALL
 177
 178 # define a MAINT-like variable REBUILD which is set if Perl
 179 # and awk are found, so autogenerated sources can be rebuilt
 180 AC_PROG_AWK
 181 AC_CHECK_PROGS(PERL, perl5 perl)
 182 # We would like indent, but don't require it.
 183 AC_CHECK_PROG(INDENT, indent, indent)
 184 REBUILD=\#
 185 if test "x$enable_rebuilds" = "xyes" && \
 186      test -n "$PERL" && \
 187      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 188      test -n "$AWK" ; then
 189   REBUILD=
 190 fi
 191 AC_SUBST(REBUILD)
 192
 193 dnl Initialize libtool
 194 AM_PROG_LIBTOOL
 195
 196 if test "x$GCC" = "xyes"; then
 197   case " $CFLAGS " in
 198   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 199   *) CFLAGS="$CFLAGS -Wall" ;;
 200   esac
 201
 202   if test "x$enable_ansi" = "xyes"; then
 203     case " $CFLAGS " in
 204     *[[\ \      ]]-ansi[[\ \    ]]*) ;;
 205     *) CFLAGS="$CFLAGS -ansi" ;;
 206     esac
 207
 208     case " $CFLAGS " in
 209     *[[\ \      ]]-pedantic[[\ \        ]]*) ;;
 210     *) CFLAGS="$CFLAGS -pedantic" ;;
 211     esac
 212   fi
 213 fi
 214
 215 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 216 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 217 glib_save_LIBS=$LIBS
 218 LIBS="$LIBS -lm"
 219 AC_TRY_RUN([#include <math.h>
 220              int main (void) { return (log(1) != log(1.)); }],
 221      AC_MSG_RESULT(none needed),
 222      glib_save_CFLAGS=$CFLAGS
 223      CFLAGS="$CFLAGS -std1"
 224      AC_TRY_RUN([#include <math.h>
 225                  int main (void) { return (log(1) != log(1.)); }],
 226          AC_MSG_RESULT(-std1),
 227          AC_MSG_RESULT()
 228          CFLAGS=$glib_save_CFLAGS
 229          AC_MSG_WARN(
 230                 [No ANSI prototypes found in library. (-std1 didn't work.)])
 231      )
 232 )
 233 LIBS=$glib_save_LIBS
 234
 235 dnl NeXTStep cc seems to need this
 236 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 237 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 238   AC_MSG_RESULT(none needed),
 239   glib_save_CFLAGS=$CFLAGS
 240   CFLAGS="$CFLAGS -posix"
 241   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 242     AC_MSG_RESULT(-posix),
 243     AC_MSG_RESULT()
 244     CFLAGS=$glib_save_CFLAGS
 245     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 246
 247 # Checks for header files.
 248 AC_HEADER_STDC
 249
 250 # Checks for library functions.
 251 AC_FUNC_VPRINTF
 252
 253 AC_FUNC_ALLOCA
 254
 255 AC_CHECK_FUNCS(atexit on_exit)
 256
 257 AC_CHECK_SIZEOF(char)
 258 AC_CHECK_SIZEOF(short)
 259 AC_CHECK_SIZEOF(long)
 260 AC_CHECK_SIZEOF(int)
 261 AC_CHECK_SIZEOF(void *)
 262 AC_CHECK_SIZEOF(long long)
 263
 264 if test x$ac_cv_sizeof_long_long = x8; then
 265         # long long is a 64 bit integer.
 266         AC_MSG_CHECKING(for format to printf and scanf a gint64)
 267         AC_CACHE_VAL(glib_cv_long_long_format,[
 268                 for format in ll q; do
 269                   AC_TRY_RUN([#include <stdio.h>
 270                         int main()
 271                         {
 272                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 273                           char buffer[1000];
 274                           sprintf (buffer, "%${format}u", a);
 275                           sscanf (buffer, "%${format}u", &b);
 276                           exit (b!=a);
 277                         }
 278                         ],
 279                         glib_cv_long_long_format=${format}
 280                         break)
 281                 done])
 282         if test -n "$glib_cv_long_long_format"; then
 283           AC_MSG_RESULT(%${glib_cv_long_long_format}i)
 284         else
 285           AC_MSG_RESULT(none)
 286         fi
 287 fi
 288
 289 dnl long doubles were not used, and a portability problem
 290 dnl AC_C_LONG_DOUBLE
 291 AC_C_CONST
 292
 293 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 294 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 295 dnl actually supported.
 296 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 297         AC_TRY_RUN([
 298         __inline int foo () { return 0; }
 299         int main () { return foo (); }
 300         ],
 301         glib_cv_has__inline=yes
 302         ,
 303         glib_cv_has__inline=no
 304         ,)
 305 ])
 306 case x$glib_cv_has__inline in
 307 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 308 esac
 309 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 310         AC_TRY_RUN([
 311         __inline__ int foo () { return 0; }
 312         int main () { return foo (); }
 313         ],
 314         glib_cv_has__inline__=yes
 315         ,
 316         glib_cv_has__inline__=no
 317         ,)
 318 ])
 319 case x$glib_cv_has__inline__ in
 320 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 321 esac
 322 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 323         AC_TRY_RUN([
 324         inline int foo () { return 0; }
 325         int main () { return foo (); }
 326         ],
 327         glib_cv_hasinline=yes
 328         ,
 329         glib_cv_hasinline=no
 330         ,)
 331 ])
 332 case x$glib_cv_hasinline in
 333 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 334 esac
 335
 336 # check for bytesex stuff
 337 AC_C_BIGENDIAN
 338
 339 # check for header files
 340 AC_CHECK_HEADERS([float.h limits.h pwd.h sys/param.h sys/poll.h sys/select.h])
 341 AC_CHECK_HEADERS([sys/time.h sys/times.h unistd.h values.h stdint.h sched.h])
 342
 343 AC_MSG_CHECKING(whether make is GNU Make)
 344 STRIP_BEGIN=
 345 STRIP_END=
 346 if $ac_make --version 2>/dev/null | grep '^GNU Make ' >/dev/null ; then
 347         STRIP_BEGIN='$(strip $(STRIP_DUMMY)'
 348         STRIP_END=')'
 349         AC_MSG_RESULT(yes)
 350 else
 351         AC_MSG_RESULT(no)
 352 fi
 353 STRIP_DUMMY=
 354 AC_SUBST(STRIP_DUMMY)
 355 AC_SUBST(STRIP_BEGIN)
 356 AC_SUBST(STRIP_END)
 357
 358 # check additional type sizes
 359 size_includes=["
 360 #include <stdarg.h>
 361 #include <stdio.h>
 362 #include <ctype.h>
 363 #include <string.h>
 364 "]
 365 if test "x$ac_cv_header_stdint_h" = "xyes"; then
 366   size_includes=["$size_includes
 367 #include <stdint.h>
 368 "]
 369 fi
 370 if test "x$ac_cv_header_unistd_h" = "xyes"; then
 371   size_includes=["$size_includes
 372 #include <unistd.h>
 373 "]
 374 fi
 375 GLIB_SIZEOF([$size_includes], size_t, size_t)
 376 GLIB_SIZEOF([$size_includes], ptrdiff_t, ptrdiff_t)
 377 GLIB_SIZEOF([$size_includes], intmax_t, intmax_t)
 378
 379 # Check for some functions
 380 AC_CHECK_FUNCS(lstat strerror strsignal memmove mkstemp vsnprintf strcasecmp strncasecmp poll getcwd)
 381
 382 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
 383 # The check is borrowed from the PERL Configure script.
 384 if test "$ac_cv_func_memmove" != "yes"; then
 385   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
 386     glib_cv_working_bcopy,[AC_TRY_RUN([
 387       int main() {
 388         char buf[128], abc[128], *b;
 389         int len, off, align;
 390         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
 391         for (align = 7; align >= 0; align--) {
 392           for (len = 36; len; len--) {
 393             b = buf+align; bcopy(abc, b, len);
 394             for (off = 1; off <= len; off++) {
 395               bcopy(b, b+off, len); bcopy(b+off, b, len);
 396                 if (bcmp(b, abc, len)) return(1);
 397             }
 398           }
 399         }
 400         return(0);
 401       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
 402   if test "$glib_cv_working_bcopy" = "yes"; then
 403     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
 404   fi
 405 fi
 406
 407 # Check for sys_errlist
 408 AC_MSG_CHECKING(for sys_errlist)
 409 AC_TRY_LINK(, [
 410 extern char *sys_errlist[];
 411 extern int sys_nerr;
 412 sys_errlist[sys_nerr-1][0] = 0;
 413 ], glib_ok=yes, glib_ok=no)
 414 AC_MSG_RESULT($glib_ok)
 415 if test $glib_ok = no; then
 416     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
 417 fi
 418
 419 # Check for sys_siglist
 420 AC_MSG_CHECKING(for sys_siglist)
 421 AC_TRY_LINK(, [
 422 extern char *sys_siglist[];
 423 exit (sys_siglist[0]);
 424 ], glib_ok=yes, glib_ok=no)
 425 AC_MSG_RESULT($glib_ok)
 426 if test $glib_ok = no; then
 427     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
 428 fi
 429
 430 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
 431 AC_MSG_CHECKING(for sys_siglist declaration)
 432 AC_TRY_COMPILE([#include <signal.h>], [
 433 strlen (sys_siglist[0]);
 434 ], glib_ok=yes, glib_ok=no)
 435 AC_MSG_RESULT($glib_ok)
 436 if test $glib_ok = no; then
 437     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
 438 fi
 439
 440 # Check if <sys/select.h> needs to be included for fd_set
 441 AC_MSG_CHECKING([for fd_set])
 442 AC_TRY_COMPILE([#include <sys/types.h>],
 443         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 444 if test $gtk_ok = yes; then
 445     AC_MSG_RESULT([yes, found in sys/types.h])
 446 else
 447     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
 448     if test $gtk_ok = yes; then
 449         # *** FIXME: give it a different name
 450         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
 451         AC_MSG_RESULT([yes, found in sys/select.h])
 452     else
 453         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
 454         AC_MSG_RESULT(no)
 455     fi
 456 fi
 457
 458 dnl *** check for sane realloc() ***
 459 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
 460         AC_TRY_RUN([
 461         #include <stdlib.h>
 462         int main() {
 463           return realloc (0, sizeof (int)) == 0;
 464         }],
 465         [glib_cv_sane_realloc=yes],
 466         [glib_cv_sane_realloc=no],
 467         [])
 468 ])
 469 if test x$glib_cv_sane_realloc = xyes; then
 470   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
 471 fi
 472
 473 dnl Check for nl_langinfo and CODESET
 474
 475 AC_MSG_CHECKING([for nl_langinfo (CODESET)])
 476 AC_TRY_COMPILE([#include <langinfo.h>],
 477         [char *codeset = nl_langinfo (CODESET);],
 478    AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
 479    have_codeset=yes,
 480    have_codeset=no)
 481 AC_MSG_RESULT($have_codeset)
 482
 483
 484 dnl ****************************************
 485 dnl *** strlcpy/strlcat                  ***
 486 dnl ****************************************
 487 # Check for strlcpy
 488 AC_MSG_CHECKING(for strlcpy/strlcat)
 489 AC_TRY_LINK([#include <stdlib.h>
 490 #include <string.h>], [
 491 char *p = malloc(10);
 492 (void) strlcpy(p, "hi", 10);
 493 (void) strlcat(p, "bye", 10);
 494 ], glib_ok=yes, glib_ok=no)
 495 AC_MSG_RESULT($glib_ok)
 496 if test $glib_ok = yes; then
 497     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
 498 fi
 499
 500
 501 dnl **********************
 502 dnl *** va_copy checks ***
 503 dnl **********************
 504 dnl we currently check for all three va_copy possibilities, so we get
 505 dnl all results in config.log for bug reports.
 506 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
 507         AC_TRY_RUN([
 508         #include <stdarg.h>
 509         void f (int i, ...) {
 510         va_list args1, args2;
 511         va_start (args1, i);
 512         va_copy (args2, args1);
 513         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 514           exit (1);
 515         va_end (args1); va_end (args2);
 516         }
 517         int main() {
 518           f (0, 42);
 519           return 0;
 520         }],
 521         [glib_cv_va_copy=yes],
 522         [glib_cv_va_copy=no],
 523         [])
 524 ])
 525 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
 526         AC_TRY_RUN([
 527         #include <stdarg.h>
 528         void f (int i, ...) {
 529         va_list args1, args2;
 530         va_start (args1, i);
 531         __va_copy (args2, args1);
 532         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 533           exit (1);
 534         va_end (args1); va_end (args2);
 535         }
 536         int main() {
 537           f (0, 42);
 538           return 0;
 539         }],
 540         [glib_cv___va_copy=yes],
 541         [glib_cv___va_copy=no],
 542         [])
 543 ])
 544
 545 if test "x$glib_cv_va_copy" = "xyes"; then
 546   g_va_copy_func=va_copy
 547 else if test "x$glib_cv___va_copy" = "xyes"; then
 548   g_va_copy_func=__va_copy
 549 fi
 550 fi
 551
 552 if test -n "$g_va_copy_func"; then
 553   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
 554 fi
 555
 556 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
 557         AC_TRY_RUN([
 558         #include <stdarg.h>
 559         void f (int i, ...) {
 560         va_list args1, args2;
 561         va_start (args1, i);
 562         args2 = args1;
 563         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 564           exit (1);
 565         va_end (args1); va_end (args2);
 566         }
 567         int main() {
 568           f (0, 42);
 569           return 0;
 570         }],
 571         [glib_cv_va_val_copy=yes],
 572         [glib_cv_va_val_copy=no],
 573         [])
 574 ])
 575
 576 if test "x$glib_cv_va_val_copy" = "xno"; then
 577   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 578 fi
 579
 580 dnl ***********************
 581 dnl *** g_module checks ***
 582 dnl ***********************
 583 G_MODULE_LIBS=
 584 G_MODULE_LIBS_EXTRA=
 585 G_MODULE_PLUGIN_LIBS=
 586 G_MODULE_LDFLAGS=
 587 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
 588 G_MODULE_NEED_USCORE=0
 589 G_MODULE_HAVE_DLERROR=0
 590 dnl *** dlopen() and dlsym() in system libraries
 591 if test -z "$G_MODULE_IMPL"; then
 592         AC_CHECK_FUNC(dlopen,
 593                       [AC_CHECK_FUNC(dlsym,
 594                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
 595                       [])
 596 fi
 597 dnl *** load_image (BeOS)
 598 if test -z "$G_MODULE_IMPL" -a "x$glib_native_beos" = "xyes"; then
 599   AC_CHECK_LIB(root, load_image,
 600       [G_MODULE_LIBS="-lbe -lroot -lglib"
 601       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
 602       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
 603       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
 604       [])
 605 fi
 606 # *** dlopen() and dlsym() in libdl
 607 if test -z "$G_MODULE_IMPL"; then
 608         AC_CHECK_LIB(dl, dlopen,
 609                      [AC_CHECK_LIB(dl, dlsym,
 610                                    [G_MODULE_LIBS=-ldl
 611                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
 612                      [])
 613 fi
 614 dnl *** shl_load() in libdld (HP-UX)
 615 if test -z "$G_MODULE_IMPL"; then
 616         AC_MSG_CHECKING(how to export all symbols)
 617         SAVED_LDFLAGS=$LDFLAGS
 618         LDFLAGS="$LDFLAGS -Wl,-E"
 619         AC_TRY_LINK(,[ return 0; ],
 620                 [ G_MODULE_LDFLAGS="-Wl,-E" ],[
 621                 LDFLAGS="$SAVED_LDFLAGS -bexpall"
 622                 AC_TRY_LINK(,[ return 0; ],
 623                         [G_MODULE_LDFLAGS="-bexpall"],
 624                         [G_MODULE_LDFLAGS="none"])
 625         ])
 626         LDFLAGS=$SAVED_LDFLAGS
 627         AC_MSG_RESULT($G_MODULE_LDFLAGS)
 628         if test "x$G_MODULE_LDFLAGS" = "xnone"; then
 629                 G_MODULE_LDFLAGS=
 630         fi
 631         AC_CHECK_LIB(dld, shl_load,
 632                 [G_MODULE_LIBS=-ldld
 633                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
 634                 [])
 635 fi
 636 dnl *** additional checks for G_MODULE_IMPL_DL
 637 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
 638         case "$host_os" in
 639           linux*)
 640             G_MODULE_LDFLAGS='-rdynamic'
 641             ;;
 642         esac
 643         LIBS_orig="$LIBS"
 644         LDFLAGS_orig="$LDFLAGS"
 645         LIBS="$LIBS $G_MODULE_LIBS"
 646         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
 647 dnl *** check whether we need preceeding underscores
 648         AC_CACHE_CHECK([for preceeding underscore in symbols],
 649                 glib_cv_uscore,[
 650                 AC_TRY_RUN([
 651                 #include <dlfcn.h>
 652                 int glib_underscore_test (void) { return 42; }
 653                 int main() {
 654                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
 655                   handle = dlopen ((void*)0, 0);
 656                   if (handle) {
 657                     f1 = dlsym (handle, "glib_underscore_test");
 658                     f2 = dlsym (handle, "_glib_underscore_test");
 659                   } return (!f2 || f1);
 660                 }],
 661                         [glib_cv_uscore=yes],
 662                         [glib_cv_uscore=no],
 663                         [])
 664                 rm -f plugin.c plugin.o plugin.lo
 665         ])
 666         if test "x$glib_cv_uscore" = "xyes"; then
 667                 G_MODULE_NEED_USCORE=1
 668         else
 669                 G_MODULE_NEED_USCORE=0
 670         fi
 671
 672         LDFLAGS="$LDFLAGS_orig"
 673 dnl *** check for having dlerror()
 674         AC_CHECK_FUNC(dlerror,
 675                 [G_MODULE_HAVE_DLERROR=1],
 676                 [G_MODULE_HAVE_DLERROR=0])
 677         LIBS="$LIBS_orig"
 678 fi
 679 dnl *** done, have e got an implementation?
 680 if test -z "$G_MODULE_IMPL"; then
 681         G_MODULE_IMPL=0
 682 fi
 683 AC_SUBST(G_MODULE_IMPL)
 684 AC_SUBST(G_MODULE_LIBS)
 685 AC_SUBST(G_MODULE_LIBS_EXTRA)
 686 AC_SUBST(G_MODULE_PLUGIN_LIBS)
 687 AC_SUBST(G_MODULE_LDFLAGS)
 688 AC_SUBST(G_MODULE_HAVE_DLERROR)
 689 AC_SUBST(G_MODULE_NEED_USCORE)
 690 AC_SUBST(GLIB_DEBUG_FLAGS)
 691
 692
 693 dnl ***********************
 694 dnl *** g_thread checks ***
 695 dnl ***********************
 696
 697 AC_ARG_WITH(threads, [  --with-threads=[none/posix/dce/solaris] specify a thread implementation to use],
 698         if test "x$with_threads" = x; then
 699                 want_threads=yes
 700         else
 701                 want_threads=$with_threads
 702         fi,
 703         want_threads=yes)
 704 if test "x$enable_threads" = "xno"; then
 705         want_threads=no
 706 fi
 707 if test "x$want_threads" = "xnone"; then
 708         want_threads=no
 709 fi
 710
 711 dnl error and warning message
 712 dnl *************************
 713
 714 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
 715                 computer. GLib will not have a default thread implementation."
 716
 717 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
 718                 platform (normaly it's "_REENTRANT"). I'll not use any flag on
 719                 compilation now, but then your programs might not work.
 720                 Please provide information on how it is done on your system."
 721
 722 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
 723                 "
 724
 725 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
 726                 provide information on your thread implementation.
 727                 You can also run 'configure --disable-threads'
 728                 to compile without thread support."
 729
 730 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
 731                 functions will not be MT-safe during their first call because
 732                 there is no working 'getpwuid_r' on your system."
 733
 734 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
 735                 because there is no 'localtime_r' on your system."
 736
 737 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
 738                 crude surrogate will be used. If you happen to know a
 739                 yield function for your system, please inform the GLib
 740                 developers."
 741
 742 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
 743                 threads on your system. Thus threads can only have the default
 744                 priority. If you happen to know these main/max
 745                 priorities, please inform the GLib developers."
 746
 747
 748 dnl determination of thread implementation
 749 dnl ***************************************
 750
 751 have_threads=none
 752 if test "x$want_threads" = xyes || test "x$want_threads" = xsolaris; then
 753         case $host in
 754                 *-*-solaris*)
 755                 AC_CHECK_LIB(thread, cond_init, have_threads=solaris)
 756                 ;;
 757         esac
 758 fi
 759 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
 760                                 || test "x$want_threads" = xdce; then
 761         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
 762         # -U_OSF_SOURCE is for Digital UNIX 4.0d
 763         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
 764         glib_save_CPPFLAGS="$CPPFLAGS"
 765         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
 766         if test "x$have_threads" = xnone; then
 767                 AC_TRY_COMPILE([#include <pthread.h>],
 768                         [pthread_attr_t attr; pthread_attr_init(&attr);],
 769                         have_threads=posix)
 770         fi
 771         if test "x$have_threads" = xnone; then
 772                 AC_TRY_COMPILE([#include <pthread.h>],
 773                         [pthread_attr_t attr; pthread_attr_create(&attr);],
 774                         have_threads=posix)
 775         fi
 776         CPPFLAGS="$glib_save_CPPFLAGS"
 777 fi
 778
 779 AC_MSG_CHECKING(for thread implementation)
 780
 781 if test "x$have_threads" = xnone && test "x$want_threads" != xno; then
 782         AC_MSG_RESULT(none available)
 783         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
 784 else
 785         AC_MSG_RESULT($have_threads)
 786 fi
 787
 788
 789 dnl determination of G_THREAD_CFLAGS
 790 dnl ********************************
 791
 792 G_THREAD_LIBS=
 793 G_THREAD_LIBS_EXTRA=
 794 G_THREAD_CFLAGS=
 795
 796 if test x"$have_threads" != xnone; then
 797
 798     G_THREAD_CFLAGS="-D_REENTRANT" # good default guess
 799
 800     case $host in
 801         *-aix*)
 802                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 803                 if test x"$GCC" = xyes; then
 804                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -mthreads"
 805                 fi
 806                 ;;
 807         *-freebsd2.2*)
 808                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 809
 810                 # FreeBSD 2.2.x shiped with gcc 2.7.2.x, which doesn't support
 811                 # -mthreads flag.
 812                 ;;
 813         *-sysv5uw7*)  # UnixWare 7
 814                 if test "$GCC" != "yes"; then
 815                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -Kthread"
 816                 else
 817                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -pthread"
 818                 fi
 819                 ;;
 820         *-dg-dgux*)  # DG/UX
 821                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_POSIX4A_DRAFT10_SOURCE"
 822     esac
 823
 824     # if we are not finding the ctime_r function, then we probably are
 825     # not using the proper multithread flag
 826
 827     glib_save_CPPFLAGS="$CPPFLAGS"
 828     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
 829
 830     AC_TRY_COMPILE([#include <time.h>],
 831         [time_t t; char b[30]; ctime_r (&t, b);], ,
 832             [AC_TRY_COMPILE([#include <time.h>],
 833                 [time_t t; char b[30]; ctime_r (&t, b, 30);], ,
 834                         AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
 835
 836     CPPFLAGS="$glib_save_CPPFLAGS"
 837
 838     AC_MSG_CHECKING(thread related cflags)
 839     AC_MSG_RESULT($G_THREAD_CFLAGS)
 840     CFLAGS="$CFLAGS $G_THREAD_CFLAGS"
 841 fi
 842
 843 dnl determination of G_THREAD_LIBS
 844 dnl ******************************
 845
 846 mutex_has_default=no
 847 case $have_threads in
 848         posix|dce)
 849            glib_save_CPPFLAGS="$CPPFLAGS"
 850            CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
 851            G_THREAD_LIBS=error
 852            glib_save_LIBS="$LIBS"
 853            case $host in
 854              *-sysv5uw7*) # UnixWare 7
 855                 if test "$GCC" != "yes"; then
 856                         G_THREAD_LIBS="-Kthread"
 857                 else
 858                         G_THREAD_LIBS="-pthread"
 859                 fi
 860                 ;;
 861              *)
 862                 for thread_lib in "" pthread pthreads c_r thread dce; do
 863                         if test x"$thread_lib" = x; then
 864                                 add_thread_lib=""
 865                                 IN=""
 866                         else
 867                                 add_thread_lib="-l$thread_lib"
 868                                 IN=" in -l$thread_lib"
 869                         fi
 870                         if test x"$have_threads" = xposix; then
 871                                 defattr=0
 872                         else
 873                                 defattr=pthread_attr_default
 874                         fi
 875
 876                         LIBS="$glib_save_LIBS $add_thread_lib"
 877
 878                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
 879                         AC_TRY_RUN([#include <pthread.h>
 880                                 int check_me = 0;
 881                                 void* func(void* data) {check_me = 42;}
 882                                 main()
 883                                 { pthread_t t;
 884                                   void *ret;
 885                                   pthread_create (&t, $defattr, func, 0);
 886                                   pthread_join (t, &ret);
 887                                   exit (check_me != 42);
 888                                 }],
 889                                 [AC_MSG_RESULT(yes)
 890                                 G_THREAD_LIBS="$add_thread_lib"
 891                                 break],
 892                                 [AC_MSG_RESULT(no)])
 893                 done
 894                 if test "x$G_THREAD_LIBS" = xerror; then
 895                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
 896                 fi
 897                 for thread_lib in "" rt rte; do
 898                         if test x"$thread_lib" = x; then
 899                                 add_thread_lib=""
 900                                 IN=""
 901                         else
 902                                 add_thread_lib="-l$thread_lib"
 903                                 IN=" in -l$thread_lib"
 904                         fi
 905                         LIBS="$glib_save_LIBS $add_thread_lib"
 906
 907                         AC_MSG_CHECKING(for sched_get_priority_min$IN)
 908                         AC_TRY_RUN([#include <sched.h>
 909                                 #include <errno.h>
 910                                 int main() {
 911                                 errno = 0;
 912                                 return sched_get_priority_min(SCHED_OTHER)==-1
 913                                         && errno != 0;
 914                                 }],
 915                                 [AC_MSG_RESULT(yes)
 916                                 G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
 917                                 posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
 918                                 posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
 919                                 break],
 920                                 [AC_MSG_RESULT(no)])
 921                 done
 922                 LIBS="$glib_save_LIBS"
 923                 ;;
 924            esac
 925            mutex_has_default=yes
 926            mutex_default_type='pthread_mutex_t'
 927            mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
 928            mutex_header_file='pthread.h'
 929            if test "x$have_threads" = "xposix"; then
 930              g_threads_impl="POSIX"
 931            else
 932              g_threads_impl="DCE"
 933              have_threads="posix"
 934            fi
 935            AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
 936            CPPFLAGS="$glib_save_CPPFLAGS"
 937            ;;
 938         solaris)
 939            G_THREAD_LIBS=error
 940            AC_CHECK_LIB(thread, cond_init, G_THREAD_LIBS="-lthread")
 941            mutex_has_default=yes
 942            mutex_default_type='mutex_t'
 943            mutex_default_init="DEFAULTMUTEX"
 944            mutex_header_file='thread.h'
 945            g_threads_impl="SOLARIS"
 946            ;;
 947         none)
 948            g_threads_impl="NONE"
 949            ;;
 950         *)
 951            g_threads_impl="NONE"
 952            G_THREAD_LIBS=error
 953            ;;
 954 esac
 955
 956 if test "x$G_THREAD_LIBS" = xerror; then
 957         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
 958 fi
 959
 960 case $host in
 961   *-*-beos*)
 962     G_THREAD_LIBS="-lbe -lroot -lglib "
 963     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
 964     ;;
 965   *)
 966     ;;
 967 esac
 968
 969 AC_MSG_CHECKING(thread related libraries)
 970 AC_MSG_RESULT($G_THREAD_LIBS)
 971
 972 dnl check for mt safe function variants and some posix functions
 973 dnl ************************************************************
 974
 975 if test x"$have_threads" != xnone; then
 976         glib_save_LIBS="$LIBS"
 977         # we are not doing the following for now, as this might require glib
 978         # to always be linked with the thread libs on some platforms.
 979         # LIBS="$LIBS $G_THREAD_LIBS"
 980         AC_CHECK_FUNCS(localtime_r)
 981         if test "$ac_cv_header_pwd_h" = "yes"; then
 982                 AC_CACHE_CHECK([for posix getpwuid_r],
 983                         ac_cv_func_posix_getpwuid_r,
 984                         [AC_TRY_RUN([#include <errno.h>
 985                                 #include <pwd.h>
 986                                 int main () { char buffer[10000];
 987                                 struct passwd pwd, *pwptr = &pwd;
 988                                 int error;
 989                                 errno = 0;
 990                                 error = getpwuid_r (0, &pwd, buffer,
 991                                         sizeof (buffer), &pwptr);
 992                                 return (error < 0 && errno == ENOSYS)
 993                                         || error == ENOSYS; }],
 994                                 [ac_cv_func_posix_getpwuid_r=yes],
 995                                 [ac_cv_func_posix_getpwuid_r=no])])
 996                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
 997                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
 998                                 [Have POSIX function getpwuid_r])
 999                 else
1000                         AC_CACHE_CHECK([for nonposix getpwuid_r],
1001                                 ac_cv_func_nonposix_getpwuid_r,
1002                                 [AC_TRY_COMPILE([#include <pwd.h>],
1003                                         [char buffer[10000];
1004                                         struct passwd pwd;
1005                                         getpwuid_r (0, &pwd, buffer,
1006                                                         sizeof (buffer));],
1007                                         [ac_cv_func_nonposix_getpwuid_r=yes],
1008                                         [ac_cv_func_nonposix_getpwuid_r=no])])
1009                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
1010                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
1011                                         [Have non-POSIX function getpwuid_r])
1012                         fi
1013                 fi
1014         fi
1015         LIBS="$LIBS $G_THREAD_LIBS"
1016         if test x"$have_threads" = xposix; then
1017                 glib_save_CPPFLAGS="$CPPFLAGS"
1018                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1019                 GLIB_SIZEOF([#include <pthread.h>],
1020                         pthread_t,
1021                         system_thread)
1022                 # This is not AC_CHECK_FUNC to also work with function
1023                 # name mangling in header files.
1024                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
1025                 AC_TRY_LINK([#include <pthread.h>],
1026                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
1027                         [AC_MSG_RESULT(yes)
1028                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
1029                                   [Have function pthread_attr_setstacksize])],
1030                         [AC_MSG_RESULT(no)])
1031                 AC_MSG_CHECKING(for minimal/maximal thread priority)
1032                 if test x"$posix_priority_min" = xnone; then
1033                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
1034                                 PX_PRIO_MIN],,[
1035                                 posix_priority_min=PX_PRIO_MIN
1036                                 posix_priority_max=PX_PRIO_MAX])
1037                 fi
1038                 if test x"$posix_priority_min" = xnone; then
1039                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
1040                                 PRI_OTHER_MIN],,[
1041                                 posix_priority_min=PRI_OTHER_MIN
1042                                 posix_priority_max=PRI_OTHER_MAX])
1043                 fi
1044                 if test x"$posix_priority_min" = x; then
1045                         AC_MSG_RESULT(none found)
1046                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
1047                         posix_priority_min=-1
1048                         posix_priority_max=-1
1049                 else
1050                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
1051                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
1052                         AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])
1053                 fi
1054                 posix_yield_func=none
1055                 AC_MSG_CHECKING(for posix yield function)
1056                 for yield_func in sched_yield pthread_yield_np pthread_yield \
1057                                                         thr_yield; do
1058                         AC_TRY_LINK([#include <pthread.h>],
1059                                 [$yield_func()],
1060                                 [posix_yield_func="$yield_func"
1061                                 break])
1062                 done
1063                 if test x"$posix_yield_func" = xnone; then
1064                         AC_MSG_RESULT(none found)
1065                         AC_MSG_WARN($POSIX_NO_YIELD)
1066                         posix_yield_func="g_usleep(1000)"
1067                 else
1068                         AC_MSG_RESULT($posix_yield_func)
1069                         posix_yield_func="$posix_yield_func()"
1070                 fi
1071                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
1072                 CPPFLAGS="$glib_save_CPPFLAGS"
1073
1074                 AC_MSG_CHECKING(whether to use the PID niceness surrogate for thread priorities)
1075                 AC_TRY_RUN([#include <pthread.h>
1076                         #include <sys/types.h>
1077                         #include <unistd.h>
1078                         pid_t other_pid = 0;
1079
1080                         void* func(void* data) {other_pid = getpid();}
1081                         main()
1082                         { pthread_t t;
1083                           void *ret;
1084                           pthread_create (&t, $defattr, func, NULL);
1085                           pthread_join (t, &ret);
1086                           exit (getpid()==other_pid ||
1087                                 $posix_priority_min != $posix_priority_max);
1088                         }],
1089                         [AC_MSG_RESULT(yes),
1090                          AC_DEFINE(G_THREAD_USE_PID_SURROGATE, 1,
1091                                 [whether to use the PID niceness surrogate for thread priorities])
1092
1093                          glib_cv_sizeof_system_thread=`expr $glib_cv_sizeof_system_thread + $ac_cv_sizeof_long`],
1094                         [AC_MSG_RESULT(no)])
1095
1096         else # solaris threads
1097                 GLIB_SIZEOF([#include <thread.h>],
1098                         thread_t,
1099                         system_thread)
1100         fi
1101
1102         LIBS="$glib_save_LIBS"
1103
1104         # now spit out all the warnings.
1105         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
1106            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
1107                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
1108         fi
1109         if test "$ac_cv_func_localtime_r" != "yes"; then
1110                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
1111         fi
1112 else
1113         # If no thread implementation exists, we will provide enough
1114         # space for a pointer
1115         GLIB_SIZEOF(, void*, system_thread)
1116 fi
1117
1118 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
1119                    [Source file containing theread implementation])
1120 AC_SUBST(G_THREAD_CFLAGS)
1121 AC_SUBST(G_THREAD_LIBS)
1122 AC_SUBST(G_THREAD_LIBS_EXTRA)
1123
1124 dnl **********************************************
1125 dnl *** GDefaultMutex setup and initialization ***
1126 dnl **********************************************
1127 dnl
1128 dnl if mutex_has_default = yes, we also got
1129 dnl mutex_default_type, mutex_default_init and mutex_header_file
1130 GLIB_IF_VAR_EQ(mutex_has_default, yes,
1131         glib_save_CPPFLAGS="$CPPFLAGS"
1132         glib_save_LIBS="$LIBS"
1133         LIBS="$LIBS $G_THREAD_LIBS"
1134         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1135         GLIB_SIZEOF([#include <$mutex_header_file>],
1136                     $mutex_default_type,
1137                     gmutex,
1138                     )
1139         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
1140                            $mutex_default_type,
1141                            gmutex,
1142                            $glib_cv_sizeof_gmutex,
1143                            $mutex_default_init)
1144         if test x"$glib_cv_byte_contents_gmutex" = xno; then
1145                 mutex_has_default=no
1146         fi
1147         CPPFLAGS="$glib_save_CPPFLAGS"
1148         LIBS="$glib_save_LIBS"
1149         ,
1150 )
1151
1152
1153 dnl ****************************************
1154 dnl *** GLib POLL* compatibility defines ***
1155 dnl ****************************************
1156 GLIB_SYSDEFS(
1157 [#include <sys/types.h>
1158 #include <sys/poll.h>],
1159         POLLIN:1 POLLOUT:4 POLLPRI:2 POLLERR:8 POLLHUP:16 POLLNVAL:32,
1160         glibconfig-sysdefs.h,
1161         =)
1162
1163 dnl ***********************
1164 dnl *** Tests for iconv ***
1165 dnl ***********************
1166
1167 AC_ARG_WITH(libiconv, [ --with-libiconv     Use the libiconv library ],,with_libiconv=maybe)
1168
1169 found_iconv=no
1170
1171 if test "x$with_libiconv" != "xyes" ; then
1172    #
1173    # Check in the C library
1174    #
1175    AC_CHECK_FUNC(iconv_open, with_libiconv=no; found_iconv=yes)
1176 fi
1177
1178 if test "x$with_libiconv" != "xno" ; then
1179    #
1180    # Check for libiconv
1181    #
1182    AC_CHECK_LIB(iconv, libiconv_open, with_libiconv=yes; found_iconv=yes)
1183 fi
1184
1185 if test "x$found_iconv" = "xno" ; then
1186    AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
1187 fi
1188
1189 if test "x$with_libiconv" = "xyes" ; then
1190   ICONV_LIBS="-liconv"
1191   AC_DEFINE(USE_LIBICONV)
1192 fi
1193 AC_SUBST(ICONV_LIBS)
1194
1195 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
1196 dnl since we need it for g_iconv()
1197
1198 AC_MSG_CHECKING([for EILSEQ])
1199 AC_TRY_COMPILE([
1200 #include <errno.h>
1201 ],
1202 [
1203 int error = EILSEQ;
1204 ], have_eilseq=yes, have_eilseq=no);
1205 AC_MSG_RESULT($have_eilseq)
1206
1207 dnl **************************
1208 dnl *** Checks for gtk-doc ***
1209 dnl **************************
1210
1211 AC_ARG_WITH(html-dir, [  --with-html-dir=PATH path to installed docs ])
1212
1213 if test "x$with_html_dir" = "x" ; then
1214   HTML_DIR='${datadir}/gtk-doc/html'
1215 else
1216   HTML_DIR=$with_html_dir
1217 fi
1218
1219 AC_SUBST(HTML_DIR)
1220
1221
1222 AC_CHECK_PROG(GTKDOC, gtkdoc-mkdb, true, false)
1223 AM_CONDITIONAL(HAVE_GTK_DOC, $GTKDOC)
1224 AC_SUBST(HAVE_GTK_DOC)
1225
1226 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1227 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1228
1229 dnl Let people disable the gtk-doc stuff.
1230 AC_ARG_ENABLE(gtk-doc, [  --enable-gtk-doc  Use gtk-doc to build documentation [default=auto]], enable_gtk_doc="$enableval", enable_gtk_doc=auto)
1231
1232 if test x$enable_gtk_doc = xauto ; then
1233   if test x$GTKDOC = xtrue ; then
1234     enable_gtk_doc=yes
1235   else
1236     enable_gtk_doc=no
1237   fi
1238 fi
1239
1240 dnl NOTE: We need to use a separate automake conditional for this
1241 dnl       to make this work with the tarballs.
1242 AM_CONDITIONAL(ENABLE_GTK_DOC, test x$enable_gtk_doc = xyes)
1243
1244 dnl ******************************
1245 dnl *** output the whole stuff ***
1246 dnl ******************************
1247
1248 AC_OUTPUT_COMMANDS([
1249
1250 ## Generate `glibconfig.h' in two cases
1251 ## 1. `config.status' is run either explicitly, or via configure.
1252 ##     Esp. not when it is run in `Makefile' to generate makefiles and
1253 ##     config.h
1254 ## 2. CONFIG_OTHER is set explicitly
1255 ##
1256 ## Case 1 is difficult.  We know that `automake' sets one of
1257 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
1258 ## only when AM_CONFIG_HEADER is set, however.
1259
1260 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
1261   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
1262   CONFIG_OTHER=${CONFIG_OTHER:-glibconfig.h}
1263 fi
1264 case "$CONFIG_OTHER" in
1265 *glibconfig.h*)
1266         echo creating glibconfig.h
1267         outfile=glibconfig.h-tmp
1268         cat > $outfile <<\_______EOF
1269 /* glibconfig.h
1270  *
1271  * This is a generated file.  Please modify 'configure.in'
1272  */
1273
1274 #ifndef __G_LIBCONFIG_H__
1275 #define __G_LIBCONFIG_H__
1276
1277 #include <gmacros.h>
1278
1279 _______EOF
1280
1281         if test x$glib_limits_h = xyes; then
1282           echo '#include <limits.h>' >> $outfile
1283         fi
1284         if test x$glib_float_h = xyes; then
1285           echo '#include <float.h>' >> $outfile
1286         fi
1287         if test x$glib_values_h = xyes; then
1288           echo '#include <values.h>' >> $outfile
1289         fi
1290         if test "$glib_header_alloca_h" = "yes"; then
1291           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
1292         fi
1293         if test x$glib_sys_poll_h = xyes; then
1294           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
1295         fi
1296
1297         cat >> $outfile <<_______EOF
1298
1299 G_BEGIN_DECLS
1300
1301 #define G_MINFLOAT      $glib_mf
1302 #define G_MAXFLOAT      $glib_Mf
1303 #define G_MINDOUBLE     $glib_md
1304 #define G_MAXDOUBLE     $glib_Md
1305 #define G_MINSHORT      $glib_ms
1306 #define G_MAXSHORT      $glib_Ms
1307 #define G_MAXUSHORT     $glib_Mus
1308 #define G_MININT        $glib_mi
1309 #define G_MAXINT        $glib_Mi
1310 #define G_MAXUINT       $glib_Mui
1311 #define G_MINLONG       $glib_ml
1312 #define G_MAXLONG       $glib_Ml
1313 #define G_MAXULONG      $glib_Mul
1314
1315 _______EOF
1316
1317
1318         ### this should always be true in a modern C/C++ compiler
1319         cat >>$outfile <<_______EOF
1320 typedef signed char gint8;
1321 typedef unsigned char guint8;
1322 _______EOF
1323
1324
1325         if test -n "$gint16"; then
1326           cat >>$outfile <<_______EOF
1327 typedef signed $gint16 gint16;
1328 typedef unsigned $gint16 guint16;
1329 #define G_GINT16_FORMAT $gint16_format
1330 #define G_GUINT16_FORMAT $guint16_format
1331 _______EOF
1332         fi
1333
1334
1335         if test -n "$gint32"; then
1336           cat >>$outfile <<_______EOF
1337 typedef signed $gint32 gint32;
1338 typedef unsigned $gint32 guint32;
1339 #define G_GINT32_FORMAT $gint32_format
1340 #define G_GUINT32_FORMAT $guint32_format
1341 _______EOF
1342         fi
1343
1344
1345         if test -n "$gint64"; then
1346           cat >>$outfile <<_______EOF
1347 #define G_HAVE_GINT64 1
1348
1349 ${glib_extension}typedef signed $gint64 gint64;
1350 ${glib_extension}typedef unsigned $gint64 guint64;
1351
1352 #define G_GINT64_CONSTANT(val)  $gint64_constant
1353 _______EOF
1354                 if test -n "$gint64_format"; then
1355           cat >>$outfile <<_______EOF
1356 #define G_GINT64_FORMAT $gint64_format
1357 #define G_GUINT64_FORMAT $guint64_format
1358 _______EOF
1359                 fi
1360         fi
1361
1362         case x$glib_size_t in
1363         x2) echo "typedef gint16  gssize;" >> $outfile
1364             echo "typedef guint16 gsize;"  >> $outfile
1365             ;;
1366         x4) echo "typedef gint32  gssize;" >> $outfile
1367             echo "typedef guint32 gsize;"  >> $outfile
1368             ;;
1369         x8) echo "typedef gint64  gssize;" >> $outfile
1370             echo "typedef guint64 gsize;"  >> $outfile
1371             ;;
1372         *)  echo "#error size of size_t is unknown" >> $outfile
1373             ;;
1374         esac
1375
1376         if test -z "$glib_unknown_void_p"; then
1377           cat >>$outfile <<_______EOF
1378
1379 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
1380 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
1381
1382 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
1383 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
1384 _______EOF
1385         else
1386           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
1387         fi
1388
1389
1390
1391         cat >>$outfile <<_______EOF
1392 $glib_atexit
1393 $glib_memmove
1394 $glib_defines
1395 $glib_os
1396
1397 $glib_vacopy
1398
1399 #ifdef  __cplusplus
1400 #define G_HAVE_INLINE   1
1401 #else   /* !__cplusplus */
1402 $glib_inline
1403 #endif  /* !__cplusplus */
1404 _______EOF
1405
1406         echo >>$outfile
1407         if test x$g_have_eilseq = xno; then
1408                 cat >>$outfile <<_______EOF
1409 #ifndef EILSEQ
1410 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
1411  * The correspondence between this and the corresponding definition
1412  * in libiconv is essential.
1413  */
1414 #  define EILSEQ ENOENT
1415 #endif
1416 _______EOF
1417
1418         fi
1419
1420         echo >>$outfile
1421         if test x$g_mutex_has_default = xyes; then
1422                 cat >>$outfile <<_______EOF
1423 $g_enable_threads_def G_THREADS_ENABLED
1424 #define G_THREADS_IMPL_$g_threads_impl_def
1425 typedef struct _GStaticMutex GStaticMutex;
1426 struct _GStaticMutex
1427 {
1428   struct _GMutex *runtime_mutex;
1429   struct {
1430     union {
1431       char   pad[$g_mutex_sizeof];
1432       double dummy_double;
1433       void  *dummy_pointer;
1434       long   dummy_long;
1435     } mutex;
1436     void *debug_info;
1437   } static_mutex;
1438 };
1439 #define G_STATIC_MUTEX_INIT     { NULL, { { { $g_mutex_contents} }, NULL } }
1440 #define g_static_mutex_get_mutex(mutex) \
1441   (g_thread_use_default_impl ? ((GMutex*) &((mutex)->static_mutex)) : \
1442    g_static_mutex_get_mutex_impl (&((mutex)->runtime_mutex)))
1443 _______EOF
1444         else
1445                 cat >>$outfile <<_______EOF
1446 $g_enable_threads_def G_THREADS_ENABLED
1447 #define G_THREADS_IMPL_$g_threads_impl_def
1448 typedef struct _GMutex* GStaticMutex;
1449 #define G_STATIC_MUTEX_INIT NULL
1450 #define g_static_mutex_get_mutex(mutex) (g_static_mutex_get_mutex_impl (mutex))
1451 _______EOF
1452         fi
1453
1454         cat >>$outfile <<_______EOF
1455 /* This represents a system thread as used by the implementation. An
1456  * alien implementaion, as loaded by g_thread_init can only count on
1457  * "sizeof (gpointer)" bytes to store their info. We however need more
1458  * for some of our native implementations. */
1459 typedef union _GSystemThread GSystemThread;
1460 union _GSystemThread
1461 {
1462   char   data[$g_system_thread_sizeof];
1463   double dummy_double;
1464   void  *dummy_pointer;
1465   long   dummy_long;
1466 };
1467 _______EOF
1468
1469         echo >>$outfile
1470         g_bit_sizes="16 32"
1471         if test -n "$gint64"; then
1472           g_bit_sizes="$g_bit_sizes 64"
1473         fi
1474         for bits in $g_bit_sizes; do
1475           cat >>$outfile <<_______EOF
1476 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
1477 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
1478 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
1479 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
1480 _______EOF
1481         done
1482
1483         cat >>$outfile <<_______EOF
1484 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
1485 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
1486 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
1487 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
1488 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
1489 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
1490 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
1491 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
1492 #define G_BYTE_ORDER $g_byte_order
1493
1494 _______EOF
1495
1496         if test -r glibconfig-sysdefs.h; then
1497           cat glibconfig-sysdefs.h >>$outfile
1498         fi
1499
1500         cat >>$outfile <<_______EOF
1501
1502 G_END_DECLS
1503
1504 #endif /* GLIBCONFIG_H */
1505 _______EOF
1506
1507
1508         if cmp -s $outfile glibconfig.h; then
1509           echo glibconfig.h is unchanged
1510           rm -f $outfile
1511         else
1512           mv $outfile glibconfig.h
1513         fi ;;
1514 esac
1515 ],[
1516
1517 # Note that if two cases are the same, case goes with the first one.
1518 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
1519 # on variable expansion in case labels.  Look at the generated config.status
1520 # for a hint.
1521
1522 glib_header_alloca_h="$ac_cv_header_alloca_h"
1523
1524 case xyes in
1525 x$ac_cv_header_float_h)
1526   glib_float_h=yes
1527   glib_mf=FLT_MIN glib_Mf=FLT_MAX
1528   glib_md=DBL_MIN glib_Md=DBL_MAX
1529   ;;
1530 x$ac_cv_header_values_h)
1531   glib_values_h=yes
1532   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
1533   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
1534   ;;
1535 esac
1536
1537 case xyes in
1538 x$ac_cv_header_limits_h)
1539   glib_limits_h=yes
1540   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
1541   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
1542   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
1543   ;;
1544 x$ac_cv_header_values_h)
1545   glib_values_h=yes
1546   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
1547   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
1548   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
1549   ;;
1550 esac
1551
1552 if test x$ac_cv_header_sys_poll_h = xyes ; then
1553   glib_sys_poll_h=yes
1554 fi
1555
1556 case 2 in
1557 $ac_cv_sizeof_short)
1558   gint16=short
1559   gint16_format='"hi"'
1560   guint16_format='"hu"'
1561   ;;
1562 $ac_cv_sizeof_int)
1563   gint16=int
1564   gint16_format='"i"'
1565   guint16_format='"u"'
1566   ;;
1567 esac
1568 case 4 in
1569 $ac_cv_sizeof_short)
1570   gint32=short
1571   gint32_format='"hi"'
1572   guint32_format='"hu"'
1573   ;;
1574 $ac_cv_sizeof_int)
1575   gint32=int
1576   gint32_format='"i"'
1577   guint32_format='"u"'
1578   ;;
1579 $ac_cv_sizeof_long)
1580   gint32=long
1581   gint32_format='"li"'
1582   guint32_format='"lu"'
1583   ;;
1584 esac
1585 case 8 in
1586 $ac_cv_sizeof_int)
1587   gint64=int
1588   gint64_format='"i"'
1589   guint64_format='"u"'
1590   glib_extension=
1591   gint64_constant='(val)'
1592   ;;
1593 $ac_cv_sizeof_long)
1594   gint64=long
1595   gint64_format='"li"'
1596   guint64_format='"lu"'
1597   glib_extension=
1598   gint64_constant='(val##L)'
1599   ;;
1600 $ac_cv_sizeof_long_long)
1601   gint64='long long'
1602   if test -n "$glib_cv_long_long_format"; then
1603     gint64_format='"'$glib_cv_long_long_format'i"'
1604     guint64_format='"'$glib_cv_long_long_format'u"'
1605   fi
1606   glib_extension='G_GNUC_EXTENSION '
1607   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
1608   ;;
1609 esac
1610 glib_size_t=$glib_cv_sizeof_size_t
1611
1612 gintbits=`expr $ac_cv_sizeof_int \* 8`
1613 glongbits=`expr $ac_cv_sizeof_long \* 8`
1614
1615
1616 case $ac_cv_sizeof_void_p in
1617 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
1618 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
1619 *)                      glib_unknown_void_p=yes ;;
1620 esac
1621
1622
1623 case xyes in
1624 x$ac_cv_func_atexit)
1625   glib_atexit="
1626 #ifdef NeXT /* @#%@! NeXTStep */
1627 # define g_ATEXIT(proc) (!atexit (proc))
1628 #else
1629 # define g_ATEXIT(proc) (atexit (proc))
1630 #endif"
1631   ;;
1632 x$ac_cv_func_on_exit)
1633   glib_atexit="
1634 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
1635   ;;
1636 esac
1637
1638 case xyes in
1639 x$ac_cv_func_memmove)
1640   glib_memmove='
1641 #define g_memmove(d,s,n) G_STMT_START { memmove ((d), (s), (n)); } G_STMT_END'
1642   ;;
1643 x$glib_cv_working_bcopy)
1644   glib_memmove="
1645 /* memmove isn't available, but bcopy can copy overlapping memory regions */
1646 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
1647   ;;
1648 *)
1649   glib_memmove="
1650 /* memmove isn't found and bcopy can't copy overlapping memory regions,
1651  * so we have to roll our own copy routine. */
1652 void g_memmove (void* dest, const void * src, unsigned long len);"
1653   ;;
1654 esac
1655
1656 glib_defines="
1657 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
1658 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
1659 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
1660 "
1661
1662 case xyes in
1663 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
1664 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
1665 *)                      glib_vacopy=''
1666 esac
1667
1668 if test x$glib_cv_va_val_copy = xno; then
1669   glib_vacopy="\$glib_vacopy
1670 #define G_VA_COPY_AS_ARRAY 1"
1671 fi
1672
1673 if test x$glib_cv_hasinline = xyes; then
1674     glib_inline='#define G_HAVE_INLINE 1'
1675 fi
1676 if test x$glib_cv_has__inline = xyes; then
1677     glib_inline="\$glib_inline
1678 #define G_HAVE___INLINE 1"
1679 fi
1680 if test x$glib_cv_has__inline__ = xyes; then
1681     glib_inline="\$glib_inline
1682 #define G_HAVE___INLINE__ 1"
1683 fi
1684
1685 case xyes in
1686 x$ac_cv_c_bigendian)
1687   g_byte_order=G_BIG_ENDIAN
1688   g_bs_native=BE
1689   g_bs_alien=LE
1690   ;;
1691 *)
1692   g_byte_order=G_LITTLE_ENDIAN
1693   g_bs_native=LE
1694   g_bs_alien=BE
1695   ;;
1696 esac
1697
1698 g_have_eilseq=$have_eilseq
1699
1700 case x$have_threads in
1701 xnone)  g_enable_threads_def="#undef";;
1702 *)      g_enable_threads_def="#define";;
1703 esac
1704
1705 g_threads_impl_def=$g_threads_impl
1706
1707 g_mutex_has_default="$mutex_has_default"
1708 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
1709 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
1710 g_mutex_contents="$glib_cv_byte_contents_gmutex"
1711
1712 case $host in
1713   *-*-beos*)
1714     glib_os="#define G_OS_BEOS"
1715     ;;
1716   *-*-cygwin*)
1717     glib_os="#define G_OS_UNIX
1718 #define G_WITH_CYGWIN"
1719 v    ;;
1720   *)
1721     glib_os="#define G_OS_UNIX"
1722     ;;
1723 esac
1724 ])
1725
1726 AC_OUTPUT([
1727 glib-2.0.pc
1728 gmodule-2.0.pc
1729 gthread-2.0.pc
1730 gobject-2.0.pc
1731 glib.spec
1732 Makefile
1733 glib-config-2.0
1734 build/Makefile
1735 build/win32/Makefile
1736 gmodule/gmoduleconf.h
1737 gmodule/Makefile
1738 gobject/Makefile
1739 gthread/Makefile
1740 docs/Makefile
1741 docs/glib-config.1
1742 docs/reference/Makefile
1743 docs/reference/glib/Makefile
1744 docs/reference/gobject/Makefile
1745 tests/Makefile
1746 ],[case "$CONFIG_FILES" in
1747 *glib-config-2.0*)chmod +x glib-config-2.0;;
1748 esac
1749 echo ""
1750 echo " *** IMPORTANT *** "
1751 echo ""
1752 echo "This is a development version of GLib.  You should be using a stable"
1753 echo "version, which is available at ftp://ftp.gtk.org/pub/gtk/v1.2/.  The"
1754 echo "version you just configured is meant for developers of GLib only:"
1755 echo ""
1756 echo "  * You should not base stable software on this version of GLib."
1757 echo "  * GNOME developers should use a stable version of GLib."
1758 echo ""
1759 echo "If you install this version of GLib, we strongly recommend that you"
1760 echo "install it in a different prefix than GLib 1.2.  Use --prefix as an"
1761 echo "argument to configure to do this.  Otherwise, you will not be able to"
1762 echo "do development with GLib 1.2 any longer."
1763 echo ""
1764 echo " *** You should be using GLib 1.2 instead. ***"
1765 ])