configure.in

   1 Dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.10)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(features.h)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This will get text that should go into config.make.
   8 config_vars=
   9
  10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  11 AC_ARG_WITH(gmp, dnl
  12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  13             [dnl
  14 case "$with_gmp" in
  15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  16 ''|no) ;;
  17 *) config_vars="$config_vars
  18 gmp-srcdir = $withval" ;;
  19 esac
  20 ])
  21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  22 AC_ARG_WITH(gettext, dnl
  23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  24             [dnl
  25 case "$with_gettext" in
  26 yes)
  27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  28 ''|no) ;;
  29 *)
  30   config_vars="$config_vars
  31 gettext-srcdir = $withval" ;;
  32 esac
  33 ])
  34
  35 dnl Arguments to specify presence of other packages/features.
  36 AC_ARG_WITH(fp, dnl
  37   --with-fp               if using floating-point hardware,
  38             with_fp=$withval, with_fp=yes)
  39 AC_ARG_WITH(gnu-binutils, dnl
  40   --with-gnu-binutils     if using GNU binutils (as and ld),
  41             gnu_binutils=$withval, gnu_binutils=no)
  42 AC_ARG_WITH(gnu-ld, dnl
  43   --with-gnu-ld           if using GNU ld (in the binutils package),
  44             gnu_ld=$withval, gnu_ld=no)
  45 AC_ARG_WITH(gnu-as, dnl
  46   --with-gnu-as           if using GNU as (in the binutils package),
  47             gnu_as=$withval, gnu_as=no)
  48 test $gnu_binutils = yes && gnu_as=yes gnu_ld=yes
  49 AC_ARG_WITH(elf, dnl
  50   --with-elf              if using the ELF object format,
  51             elf=$withval, elf=no)
  52
  53 AC_ARG_ENABLE(libio, dnl
  54 [  --enable-libio          build in GNU libio instead of GNU stdio],
  55               [if test $enableval = yes; then
  56                  stdio=libio
  57                else
  58                  stdio=stdio
  59                fi],
  60               stdio=default)
  61
  62 dnl Arguments to enable or disable building the shared, profiled, and
  63 dnl -fomit-frame-pointer libraries.
  64 AC_ARG_ENABLE(shared, dnl
  65 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  66             shared=$enableval, shared=default)
  67 AC_ARG_ENABLE(profile, dnl
  68 [  --enable-profile        build profiled library [default=yes]],
  69             profile=$enableval, profile=yes)
  70 AC_ARG_ENABLE(omitfp, dnl
  71 [  --enable-omitfp       build undebuggable optimized library [default=no]],
  72             omitfp=$enableval, omitfp=no)
  73
  74 AC_CANONICAL_HOST
  75 # We keep the original values in `$config_*' and never modify them, so we
  76 # can write them unchanged into config.make.  Everything else uses
  77 # $machine, $vendor, and $os, and changes them whenever convenient.
  78 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
  79
  80 # Some configurations imply other options.
  81 case "$host_os" in
  82 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
  83   # These systems always use GNU tools.
  84   gnu_ld=yes gnu_as=yes ;;
  85 esac
  86 case "$host_os" in
  87 gnu* | linux* | sysv4* | solaris2*)
  88   # These systems always use the ELF format.
  89   elf=yes ;;
  90 esac
  91
  92 # Linux/Alpha does not use ELF yet.
  93 case "$host_cpu-$host_os" in
  94 alpha*-linux*)
  95   gnu_ld=no elf=no ;;
  96 esac
  97
  98 # Compute the list of sysdep directories for this configuration.
  99 sysdep_dir=$srcdir/sysdeps
 100 AC_CACHE_CHECK(sysdep dirs, libc_cv_sysdirs, [dnl
 101 machine=$config_machine
 102 vendor=$config_vendor
 103 os=$config_os
 104
 105 dnl We need to use [ and ] for other purposes for a while now.
 106 changequote(,)dnl
 107 # Expand the configuration machine name into a subdirectory by architecture
 108 # type and particular chip.
 109 case "$machine" in
 110 a29k | am29000) machine=a29k ;;
 111 alpha*)         machine=alpha/$machine ;;
 112 hppa*)          machine=hppa/$machine ;;
 113 i[345]86)       machine=i386/$machine ;;
 114 m680?0)         machine=m68k/$machine ;;
 115 m68k)           machine=m68k/m68020 ;;
 116 m88???)         machine=m88k/$machine ;;
 117 m88k)           machine=m88k/m88100 ;;
 118 mips*)          machine=mips/$machine ;;
 119 mips64*)        machine=mips/mips64/$machine ;;
 120 sparc[6789])    machine=sparc/$machine ;;
 121 supersparc)     machine=sparc/sparc8 ;;
 122 esac
 123
 124 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 125 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 126
 127 case "$os" in
 128 gnu*)
 129   base_os=mach/hurd ;;
 130 netbsd* | 386bsd* | freebsd* | bsdi*)
 131   base_os=unix/bsd/bsd4.4 ;;
 132 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 133   base_os=unix/bsd ;;
 134 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 135   base_os=unix/sysv ;;
 136 solaris[2-9]*)
 137   base_os=unix/sysv/sysv4 ;;
 138 none)
 139   base_os=standalone ;;
 140 *)
 141   base_os='' ;;
 142 esac
 143
 144 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 145 tail=$os
 146 ostry=$os
 147 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 148   ostry="$ostry /$o"
 149   tail=$o
 150 done
 151 o=`echo $tail | sed 's/[0-9]*$//'`
 152 if test $o != $tail; then
 153   ostry="$ostry /$o"
 154 fi
 155
 156 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 157 base=
 158 tail=$base_os
 159 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 160   set $b
 161   base="$base /$1"
 162   tail="$2"
 163 done
 164
 165 # For sparc/sparc9, try sparc/sparc9 and then sparc.
 166 mach=
 167 tail=$machine
 168 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 169   set $m
 170   # Prepend the machine's FPU directory unless --without-fp.
 171   if test "$with_fp" = yes; then
 172     mach="$mach /$1/fpu"
 173   fi
 174   mach="$mach /$1"
 175   tail="$2"
 176 done
 177
 178 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 179 changequote([,])dnl
 180
 181 # Find what sysdep directories exist.
 182 sysnames=
 183 for b in $base ''; do
 184   for m0 in $mach ''; do
 185     for v in /$vendor ''; do
 186       for o in /$ostry ''; do
 187         for m in $mach ''; do
 188           try="$m0$b$v$o$m"
 189           test -n "$enable_debug_configure" && echo "$0 [DEBUG]: try $try" >&2
 190           if test -d $sysdep_dir$try; then
 191             sysnames="$sysnames $try"
 192             { test -n "$o" || test -n "$b"; } && os_used=t
 193             { test -n "$m" || test -n "$m0"; } && machine_used=t
 194           fi
 195         done
 196       done
 197     done
 198   done
 199 done
 200
 201 if test -z "$os_used" && test "$os" != none; then
 202   AC_MSG_ERROR(Operating system $os is not supported.)
 203 fi
 204 if test -z "$machine_used" && test "$machine" != none; then
 205   AC_MSG_ERROR(The $machine is not supported.)
 206 fi
 207
 208 # We have now validated the configuration.
 209
 210
 211 # If using ELF, look for an `elf' subdirectory of each machine directory.
 212 # We prepend these rather than inserting them whereever the machine appears
 213 # because things specified by the machine's ELF ABI should override
 214 # OS-specific things, and should always be the same for any OS on the
 215 # machine (otherwise what's the point of an ABI?).
 216 if test "$elf" = yes; then
 217   elf_dirs=
 218   for m in $mach; do
 219     if test -d $sysdep_dir$m/elf; then
 220       elf_dirs="$elf_dirs $m/elf"
 221     fi
 222   done
 223   sysnames="`echo $elf_dirs | sed -e 's,^/,,' -e 's, /,,g'` $sysnames"
 224 fi
 225
 226
 227 # Remove the leading slashes.
 228 sysnames="`echo $sysnames | sed -e 's@^/@@' -e 's@ /@ @g'`"
 229
 230
 231 # Expand the list of system names into a full list of directories
 232 # from each element's parent name and Implies file (if present).
 233 set $sysnames
 234 while test $# -gt 0; do
 235   name=$1
 236   shift
 237
 238   if test -f $sysdep_dir/$name/Implies; then
 239     # Collect more names from the `Implies' file (removing comments).
 240     implied="`sed 's/#.*$//' < $sysdep_dir/$name/Implies`"
 241     for x in $implied; do
 242       test -d $sysdep_dir/$x || echo "Warning: $name implies nonexistent $x">&2
 243     done
 244   else
 245     implied=
 246   fi
 247
 248   # Add NAME to the list of names.
 249   names="$names $name"
 250
 251   # Find the parent of NAME, using the empty string if it has none.
 252 changequote(,)dnl
 253   parent="`echo $name | sed -n -e '/\//!q' -e 's=/[^/]*$==p'`"
 254 changequote([,])dnl
 255
 256   # Add the names implied by NAME, and NAME's parent (if it has one), to
 257   # the list of names to be processed (the argument list).  We prepend the
 258   # implied names to the list and append the parent.  We want implied
 259   # directories to come before further directories inferred from the
 260   # configuration components; this ensures that for sysv4, unix/common
 261   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 262   # after sysv4).
 263   sysnames="`echo $implied $* $parent`"
 264   test -n "$sysnames" && set $sysnames
 265 done
 266
 267 # Add the default directories.
 268 names="$names generic stub"
 269
 270 # Now uniquize the list.
 271 seen=
 272 sysnames=
 273 for name in $names; do
 274   if echo "$seen" | fgrep -x $name >/dev/null; then
 275     # Already in the list.
 276     true;
 277   else
 278     # A new one.
 279     if test -z "$seen"; then
 280       seen="$name" sysnames="$name"
 281     else
 282       seen="$seen
 283 $name"
 284       sysnames="$sysnames $name"
 285     fi
 286   fi
 287 done
 288 libc_cv_sysdirs="$sysnames"])
 289 AC_SUBST(sysnames) sysnames="$libc_cv_sysdirs"
 290
 291 AC_PROG_INSTALL
 292 if test "$INSTALL" = "${srcdir}/install-sh"; then
 293   # The makefiles need to use a different form to find it in $srcdir.
 294   INSTALL='$(..)./install-sh'
 295 fi
 296 AC_PROG_LN_S
 297 AC_CHECK_PROGS(MSGFMT, msgfmt gmsgfmt, :)
 298
 299 AC_CHECK_TOOL(CC, gcc)
 300 AC_CHECK_TOOL(AR, ar)
 301 AC_CHECK_TOOL(RANLIB, ranlib, :)
 302 AC_PROG_CPP
 303
 304 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 305 echo '#include <stddef.h>
 306 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 307 if eval "$ac_cpp conftest.c 2>/dev/null" \
 308 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 309   libc_cv_signed_size_t=no
 310 else
 311   libc_cv_signed_size_t=yes
 312 fi
 313 rm -f conftest*])
 314 if test $libc_cv_signed_size_t = yes; then
 315   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 316   cat >> confdefs.h <<\EOF
 317 #undef __SIZE_TYPE__
 318 #define __SIZE_TYPE__ unsigned
 319 EOF
 320 fi
 321
 322 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 323 AC_TRY_COMPILE(dnl
 324 [#define __need_size_t
 325 #define __need_wchar_t
 326 #include <stddef.h>
 327 #define __need_NULL
 328 #include <stddef.h>], [size_t size; wchar_t wchar;
 329 #ifdef offsetof
 330 #error stddef.h ignored __need_*
 331 #endif
 332 if (&size == NULL || &wchar == NULL) abort ();],
 333                libc_cv_friendly_stddef=yes,
 334                libc_cv_friendly_stddef=no)])
 335 if test $libc_cv_friendly_stddef = yes; then
 336   config_vars="$config_vars
 337 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 338 fi
 339
 340 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 341                libc_cv_need_minus_P, [dnl
 342 cat > conftest.S <<EOF
 343 #include "confdefs.h"
 344 /* Nothing whatsoever.  */
 345 EOF
 346 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 347   libc_cv_need_minus_P=no
 348 else
 349   libc_cv_need_minus_P=yes
 350 fi
 351 rm -f conftest*])
 352 if test $libc_cv_need_minus_P = yes; then
 353   config_vars="$config_vars
 354 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 355 fi
 356
 357 AC_CACHE_CHECK(for assembler global-symbol directive,
 358                libc_cv_asm_global_directive, [dnl
 359 libc_cv_asm_global_directive=UNKNOWN
 360 for ac_globl in .globl .global; do
 361   cat > conftest.s <<EOF
 362 .text
 363 ${ac_globl} foo
 364 foo: .long 0
 365 EOF
 366   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 367     libc_cv_asm_global_directive=${ac_globl}
 368   fi
 369   rm -f conftest*
 370   test $libc_cv_asm_global_directive != UNKNOWN && break
 371 done])
 372 if test $libc_cv_asm_global_directive = UNKNOWN; then
 373   AC_MSG_ERROR(cannot determine asm global directive)
 374 else
 375   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 376 fi
 377
 378 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 379 cat > conftest.s <<EOF
 380 .text
 381 foo: .long 0
 382 .set glibc_conftest_frobozz,foo
 383 $libc_cv_asm_global_directive glibc_conftest_frobozz
 384 EOF
 385 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 386 # (but it doesn't work), so we must do a linking check to be sure.
 387 cat > conftest1.c <<\EOF
 388 extern int glibc_conftest_frobozz;
 389 main () { printf ("%d\n", glibc_conftest_frobozz); }
 390 EOF
 391 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 392             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 393   libc_cv_asm_set_directive=yes
 394 else
 395   libc_cv_asm_set_directive=no
 396 fi
 397 rm -f conftest*])
 398 if test $libc_cv_asm_set_directive = yes; then
 399   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 400 fi
 401
 402 if test $elf != yes; then
 403   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 404                  [AC_TRY_COMPILE(, [asm (".section .init");
 405                                     asm (".section .fini");],
 406                                  libc_cv_have_initfini=yes,
 407                                  libc_cv_have_initfini=no)])
 408   AC_SUBST(libc_cv_have_initfini)dnl
 409   if test $libc_cv_have_initfini = yes; then
 410     AC_DEFINE(HAVE_INITFINI)
 411   fi
 412 fi
 413
 414 if test $elf = yes; then
 415   libc_cv_asm_underscores=no
 416 else
 417   AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 418                  [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 419                               libc_cv_asm_underscores=yes,
 420                               libc_cv_asm_underscores=no)])
 421 fi
 422 if test $libc_cv_asm_underscores = no; then
 423   AC_DEFINE(NO_UNDERSCORES)
 424 fi
 425
 426 if test $elf = yes; then
 427   libc_cv_weak_symbols=yes
 428   libc_cv_asm_weak_directive=yes
 429   libc_cv_asm_weakext_directive=no
 430 else
 431   AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 432                  [dnl
 433 cat > conftest.s <<EOF
 434 .text
 435 ${libc_cv_asm_global_directive} foo
 436 foo: .long 0
 437 .weak foo
 438 .weak bar; bar = foo
 439 EOF
 440   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 441     libc_cv_asm_weak_directive=yes
 442   else
 443     libc_cv_asm_weak_directive=no
 444   fi
 445   rm -f conftest*])
 446
 447 if test $libc_cv_asm_weak_directive = no; then
 448   AC_CACHE_CHECK(for assembler .weakext directive,
 449                  libc_cv_asm_weakext_directive,
 450                  [dnl
 451 cat > conftest.s <<EOF
 452 .text
 453 ${libc_cv_asm_global_directive} foo
 454 foo: .long 0
 455 .weakext foo
 456 .weakext bar, foo
 457 EOF
 458   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 459     libc_cv_asm_weakext_directive=yes
 460   else
 461     libc_cv_asm_weakext_directive=no
 462   fi
 463   rm -f conftest*])
 464
 465   fi # no .weak
 466 fi # not ELF
 467
 468 if test $libc_cv_asm_weak_directive = yes; then
 469   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 470 elif test $libc_cv_asm_weakext_directive = yes; then
 471   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 472 fi
 473
 474 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
 475 cat > conftest.c <<\EOF
 476 main () { exit (0); }
 477 EOF
 478 if ${CC-cc} $CFLAGS -Wl,--no-whole-archive \
 479             -o conftest conftest.c 2>/dev/null; then
 480   libc_cv_ld_no_whole_archive=yes
 481 else
 482   libc_cv_ld_no_whole_archive=no
 483 fi
 484 rm -f conftest*])
 485 AC_SUBST(libc_cv_ld_no_whole_archive)dnl
 486
 487 ### End of automated tests.
 488 ### Now run sysdeps configure fragments.
 489
 490 # sysdeps configure fragments may set these with files to be linked below.
 491 libc_link_dests=
 492 libc_link_sources=
 493
 494 # Iterate over all the sysdep directories we will use, running their
 495 # configure fragments, and looking for a uname implementation.
 496 uname=
 497 for dir in $sysnames; do
 498   if test -r $sysdep_dir/$dir/configure; then
 499     AC_MSG_RESULT(running configure fragment for $dir)
 500     . $sysdep_dir/$dir/configure
 501   fi
 502 [
 503   if test -z "$uname"; then
 504     if test -r $sysdep_dir/$dir/uname.c ||
 505        test -r $sysdep_dir/$dir/uname.S ||
 506        { test -r $sysdep_dir/$dir/syscalls.list &&
 507          grep '^uname[  ]' $sysdep_dir/$dir/syscalls.list >/dev/null; }; then
 508       uname=$dir
 509     fi
 510   fi
 511 ]dnl
 512 done
 513
 514 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
 515
 516 # If we will use the generic uname implementation, we must figure out what
 517 # it will say by examining the system, and write the results in config-name.h.
 518 if test "$uname" = generic; then
 519
 520 changequote(,)dnl
 521   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
 522 changequote([,])dnl
 523   if test $uname_sysname != $config_os; then
 524     config_release=`echo $config_os | sed s/$uname_sysname//`
 525   fi
 526 dnl
 527 AC_DEFUN(LIBC_KERNEL_ID, [dnl
 528     if test -r /vmunix; then
 529       kernel_id=`strings /vmunix | grep UNIX`
 530     elif test -r /dynix; then
 531       kernel_id=`strings /dynix | grep DYNIX`
 532     else
 533       kernel_id=
 534     fi
 535 ])dnl
 536
 537   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
 538 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 539 changequote(,)dnl
 540   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
 541 changequote([,])dnl
 542   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
 543          != x$config_release; then
 544     # The configuration release is a substring of the kernel release.
 545     libc_cv_uname_release=$kernel_release
 546   elif test x$config_release != x; then
 547     libc_cv_uname_release=$config_release
 548   elif test x$kernel_release != x; then
 549     libc_cv_uname_release=$kernel_release
 550   else
 551     libc_cv_uname_release=unknown
 552   fi])
 553   uname_release="$libc_cv_uname_release"
 554
 555   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
 556 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 557 changequote(,)dnl
 558   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
 559 changequote([,])dnl
 560   if test -n "$kernel_version"; then
 561     libc_cv_uname_version="$kernel_version"
 562   else
 563     libc_cv_uname_version=unknown
 564   fi])
 565   uname_version="$libc_cv_uname_version"
 566
 567 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
 568   config_uname=config-name.h:config-name.in
 569 else
 570   # For non-generic uname, we don't need to create config-name.h at all.
 571   config_uname=
 572 fi
 573
 574 AC_MSG_CHECKING(stdio selection)
 575 AC_SUBST(stdio)
 576 case $stdio in
 577 libio) AC_DEFINE(USE_IN_LIBIO) ;;
 578 default) stdio=stdio ;;
 579 esac
 580 AC_MSG_RESULT($stdio)
 581
 582 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
 583 if test $gnu_ld = yes; then
 584   AC_DEFINE(HAVE_GNU_LD)
 585 fi
 586 if test $gnu_as = yes; then
 587   AC_DEFINE(HAVE_GNU_AS)
 588 fi
 589 if test $elf = yes; then
 590   AC_DEFINE(HAVE_ELF)
 591 fi
 592
 593 AC_SUBST(shared)
 594 if test $shared = default; then
 595   if test $gnu_ld = yes; then
 596     shared=$elf
 597   fi
 598 fi
 599 AC_SUBST(profile)
 600 AC_SUBST(omitfp)
 601
 602 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
 603   config_makefile=
 604 else
 605   config_makefile=Makefile
 606 fi
 607
 608 AC_OUTPUT(config.make ${config_makefile} ${config_uname}, ,
 609           [echo '$config_vars' >> config.make])