configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 # require autoconf 2.54
   3 AC_PREREQ(2.54)
   4
   5 dnl ***********************************
   6 dnl *** include special GLib macros ***
   7 dnl ***********************************
   8
   9 m4_define(glib_configure_in)
  10 m4_include(acglib.m4)dnl
  11 m4_include(glib/libcharset/codeset.m4)dnl
  12 m4_include(glib/libcharset/glibc21.m4)dnl
  13 m4_include(m4macros/glib-gettext.m4)dnl
  14
  15 #
  16 # The following version number definitions apply to GLib, GModule, GObject
  17 # and GThread as a whole, so if changes occoured in any of them, they are all
  18 # treated with the same interface and binary age.
  19 #
  20 # Making releases:
  21 #   glib_micro_version += 1;
  22 #   glib_interface_age += 1;
  23 #   glib_binary_age += 1;
  24 # if any functions have been added, set glib_interface_age to 0.
  25 # if backwards compatibility has been broken,
  26 # set glib_binary_age _and_ glib_interface_age to 0.
  27 #
  28 m4_define([glib_major_version], [2])
  29 m4_define([glib_minor_version], [3])
  30 m4_define([glib_micro_version], [1])
  31 m4_define([glib_interface_age], [0])
  32 m4_define([glib_binary_age],
  33           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  34 m4_define([glib_version],
  35           [glib_major_version.glib_minor_version.glib_micro_version])
  36
  37 # libtool version related macros
  38 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  39 m4_define([glib_lt_current],
  40           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  41 m4_define([glib_lt_revision], [glib_interface_age])
  42 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  43 m4_define([glib_lt_current_minus_age],
  44           [m4_eval(glib_lt_current - glib_lt_age)])
  45
  46 # if the minor version number is odd, then we want debugging.  Otherwise
  47 # we only want minimal debugging support.
  48 m4_define([glib_debug_default],
  49           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  50
  51
  52 AC_INIT(glib, [glib_version],
  53         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  54
  55 AC_CONFIG_SRCDIR([glib/glib.h])
  56
  57 # Save this value here, since automake will set cflags later
  58 cflags_set=${CFLAGS+set}
  59
  60 AM_INIT_AUTOMAKE([no-define])
  61
  62 # Specify a configuration file
  63 AM_CONFIG_HEADER([config.h])
  64
  65
  66 GLIB_MAJOR_VERSION=glib_major_version
  67 GLIB_MINOR_VERSION=glib_minor_version
  68 GLIB_MICRO_VERSION=glib_micro_version
  69 GLIB_INTERFACE_AGE=glib_interface_age
  70 GLIB_BINARY_AGE=glib_binary_age
  71 GLIB_VERSION=glib_version
  72
  73 AC_SUBST(GLIB_MAJOR_VERSION)
  74 AC_SUBST(GLIB_MINOR_VERSION)
  75 AC_SUBST(GLIB_MICRO_VERSION)
  76 AC_SUBST(GLIB_VERSION)
  77 AC_SUBST(GLIB_INTERFACE_AGE)
  78 AC_SUBST(GLIB_BINARY_AGE)
  79
  80 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  81           [Define to the GLIB major version])
  82 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  83           [Define to the GLIB minor version])
  84 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  85           [Define to the GLIB micro version])
  86 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  87           [Define to the GLIB interface age])
  88 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  89           [Define to the GLIB binary age])
  90
  91 # libtool versioning
  92 LT_RELEASE=glib_lt_release
  93 LT_CURRENT=glib_lt_current
  94 LT_REVISION=glib_lt_revision
  95 LT_AGE=glib_lt_age
  96 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
  97 AC_SUBST(LT_RELEASE)
  98 AC_SUBST(LT_CURRENT)
  99 AC_SUBST(LT_REVISION)
 100 AC_SUBST(LT_AGE)
 101 AC_SUBST(LT_CURRENT_MINUS_AGE)
 102
 103 dnl Initialize maintainer mode
 104 AM_MAINTAINER_MODE
 105
 106 AC_CANONICAL_HOST
 107
 108 AC_MSG_CHECKING([for the BeOS])
 109 case $host in
 110   *-*-beos*)
 111     glib_native_beos="yes"
 112     ;;
 113   *)
 114     glib_native_beos="no"
 115     ;;
 116 esac
 117 AC_MSG_RESULT([$glib_native_beos])
 118
 119 dnl
 120
 121 AC_MSG_CHECKING([for Win32])
 122 case "$host" in
 123   *-*-mingw*)
 124     glib_native_win32=yes
 125     G_LIB_WIN32_RESOURCE=glib-win32res.lo
 126     G_MODULE_WIN32_RESOURCE=gmodule-win32res.lo
 127     G_OBJECT_WIN32_RESOURCE=gobject-win32res.lo
 128     G_THREAD_WIN32_RESOURCE=gthread-win32res.lo
 129     GLIB_DEF=glib.def
 130     GMODULE_DEF=gmodule.def
 131     GOBJECT_DEF=gobject.def
 132     GTHREAD_DEF=gthread.def
 133     TESTGMODULE_EXP=testgmodule.exp
 134     ;;
 135   *)
 136     glib_native_win32=no
 137     G_LIB_WIN32_RESOURCE=
 138     G_MODULE_WIN32_RESOURCE=
 139     G_OBJECT_WIN32_RESOURCE=
 140     G_THREAD_WIN32_RESOURCE=
 141     GLIB_DEF=
 142     GMODULE_DEF=
 143     GOBJECT_DEF=
 144     GTHREAD_DEF=
 145     TESTGMODULE_EXP=
 146     ;;
 147 esac
 148 AC_MSG_RESULT([$glib_native_win32])
 149 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 150 AC_SUBST(G_LIB_WIN32_RESOURCE)
 151 AC_SUBST(G_MODULE_WIN32_RESOURCE)
 152 AC_SUBST(G_OBJECT_WIN32_RESOURCE)
 153 AC_SUBST(G_THREAD_WIN32_RESOURCE)
 154 AC_SUBST(GLIB_DEF)
 155 AC_SUBST(GMODULE_DEF)
 156 AC_SUBST(GOBJECT_DEF)
 157 AC_SUBST(GTHREAD_DEF)
 158 AC_SUBST(TESTGMODULE_EXP)
 159
 160 if test "$glib_native_win32" = "yes"; then
 161   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 162 fi
 163 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 164
 165 dnl declare --enable-* args and collect ac_help strings
 166 AC_ARG_ENABLE(debug,
 167               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 168                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 169               enable_debug=glib_debug_default)
 170
 171 AC_ARG_ENABLE(gc_friendly,
 172               [AC_HELP_STRING([--enable-gc-friendly],
 173                               [turn on garbage collector friendliness [default=no]])],,
 174               [enable_gc_friendly=no])
 175 AC_ARG_ENABLE(mem_pools,
 176               [AC_HELP_STRING([--disable-mem-pools],
 177                               [disable all glib memory pools])],,
 178               [disable_mem_pools=no])
 179 AC_ARG_ENABLE(ansi,
 180               [AC_HELP_STRING([--enable-ansi],
 181                               [turn on strict ansi [default=no]])],,
 182               [enable_ansi=no])
 183 AC_ARG_ENABLE(threads,
 184               [AC_HELP_STRING([--enable-threads],
 185                               [turn on basic thread support [default=yes]
 186 ([=no] will override --with-threads)])],,
 187               [enable_threads=yes])
 188 AC_ARG_ENABLE(rebuilds,
 189               [AC_HELP_STRING([--disable-rebuilds],
 190                               [disable all source autogeneration rules])],,
 191               [enable_rebuilds=yes])
 192
 193 if test "x$enable_threads" != "xyes"; then
 194   enable_threads=no
 195 fi
 196
 197 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, ["${enable_debug}"],
 198         [Whether glib was compiled with debugging enabled])
 199
 200 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 201 if test "x$enable_gc_friendly" = "xyes"; then
 202   AC_DEFINE(ENABLE_GC_FRIENDLY, 1, [Whether to enable GC friendliness])
 203   AC_SUBST(ENABLE_GC_FRIENDLY)
 204   AC_MSG_RESULT([yes])
 205 else
 206   AC_MSG_RESULT([no])
 207 fi
 208
 209 AC_MSG_CHECKING([whether to disable memory pools])
 210 if test "x$disable_mem_pools" = "xno"; then
 211   AC_MSG_RESULT([no])
 212 else
 213   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 214   AC_SUBST(DISABLE_MEM_POOLS)
 215   AC_MSG_RESULT([yes])
 216 fi
 217
 218 if test "$glib_native_win32" = "yes"; then
 219   if test x$enable_static = xyes -o x$enable_static = x; then
 220     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 221     enable_static=no
 222   fi
 223   if test x$enable_shared = xno; then
 224     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 225   fi
 226   enable_shared=yes
 227 fi
 228
 229 dnl Checks for programs.
 230 AC_PROG_CC
 231
 232 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 233 AC_CHECK_PROGS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 234 AC_LANG_SAVE
 235 AC_LANG_CPLUSPLUS
 236 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 237 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 238 AC_LANG_RESTORE
 239
 240 AM_PROG_CC_STDC
 241 AC_PROG_INSTALL
 242
 243 AC_SYS_LARGEFILE
 244
 245 #
 246 # Find pkg-config
 247 #
 248 AC_PATH_PROG(PKG_CONFIG, [pkg-config], [no])
 249 if test x$PKG_CONFIG = xno ; then
 250   AC_MSG_ERROR([*** pkg-config not found. See http://www.freedesktop.org/software/pkgconfig/])
 251 fi
 252
 253 if $PKG_CONFIG --atleast-pkgconfig-version 0.14 ; then
 254   :
 255 else
 256   AC_MSG_ERROR([*** pkg-config too old; version 0.14 or better required.])
 257 fi
 258
 259 if test "x$enable_debug" = "xyes"; then
 260   if test x$cflags_set != xset ; then
 261       case " $CFLAGS " in
 262       *[[\ \    ]]-g[[\ \       ]]*) ;;
 263       *) CFLAGS="$CFLAGS -g" ;;
 264       esac
 265   fi
 266
 267   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 268 else
 269   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 270
 271   if test "x$enable_debug" = "xno"; then
 272     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 273   fi
 274 fi
 275
 276 # Ensure MSVC-compatible struct packing convention is used when
 277 # compiling for Win32 with gcc.
 278 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 279 # gcc2 uses "-fnative-struct".
 280 if test x"$glib_native_win32" = xyes; then
 281   if test x"$GCC" = xyes; then
 282     msnative_struct=''
 283     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 284     if test -z "$ac_cv_prog_CC"; then
 285       our_gcc="$CC"
 286     else
 287       our_gcc="$ac_cv_prog_CC"
 288     fi
 289     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 290       2.)
 291         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 292           msnative_struct='-fnative-struct'
 293         fi
 294         ;;
 295       *)
 296         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 297           msnative_struct='-mms-bitfields'
 298         fi
 299         ;;
 300     esac
 301     if test x"$msnative_struct" = x ; then
 302       AC_MSG_RESULT([no way])
 303       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 304     else
 305       CFLAGS="$CFLAGS $msnative_struct"
 306       AC_MSG_RESULT([${msnative_struct}])
 307     fi
 308   fi
 309 fi
 310
 311 AC_CYGWIN
 312 AC_EXEEXT
 313
 314 # define a MAINT-like variable REBUILD which is set if Perl
 315 # and awk are found, so autogenerated sources can be rebuilt
 316 AC_PROG_AWK
 317 AC_CHECK_PROGS(PERL, [perl5 perl])
 318 # We would like indent, but don't require it.
 319 AC_CHECK_PROG(INDENT, indent, indent)
 320 REBUILD=\#
 321 if test "x$enable_rebuilds" = "xyes" && \
 322      test -n "$PERL" && \
 323      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 324      test -n "$AWK" ; then
 325   REBUILD=
 326 fi
 327 AC_SUBST(REBUILD)
 328
 329 # Need full path to Perl for glib-mkenums
 330 #
 331 if test "x$PERL" != x ; then
 332   AC_PATH_PROG(PERL_PATH, [$PERL])
 333 else
 334   PERL_PATH="/usr/bin/env perl"
 335 fi
 336 AC_SUBST(PERL_PATH)
 337
 338 dnl ***********************
 339 dnl *** Tests for iconv ***
 340 dnl ***********************
 341 dnl
 342 dnl We do this before the gettext checks, to avoid distortion
 343
 344 AC_ARG_WITH(libiconv,
 345             [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 346                             [use the libiconv library])],,
 347             [with_libiconv=maybe])
 348
 349 found_iconv=no
 350 case $with_libiconv in
 351   maybe)
 352     # Check in the C library first
 353     AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 354     # Check if we have GNU libiconv
 355     if test $found_iconv = "no"; then
 356       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 357     fi
 358     # Check if we have a iconv in -liconv, possibly from vendor
 359     if test $found_iconv = "no"; then
 360       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 361     fi
 362     ;;
 363   no)
 364     AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 365     ;;
 366   gnu|yes)
 367     AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 368     ;;
 369   native)
 370     AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 371     ;;
 372 esac
 373
 374 if test "x$found_iconv" = "xno" ; then
 375    AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 376 fi
 377
 378 dnl
 379 dnl gettext support
 380 dnl
 381
 382 ALL_LINGUAS="am ar az be bg bn ca cs cy da de el eo es et eu fa fi fr gl he hi id is it ja ko lt lv mk mn ms nl nn no pl pt pt_BR ro ru sk sl sq sr sr@Latn sv ta tr uk vi yi zh_CN zh_TW"
 383 GLIB_GNU_GETTEXT
 384
 385 if test "$gt_cv_have_gettext" != "yes" ; then
 386   AC_MSG_ERROR([
 387 *** You must have either have gettext support in your C library, or use the
 388 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 389 ])
 390 fi
 391
 392 LIBS="$INTLLIBS $LIBS"
 393
 394 GETTEXT_PACKAGE=glib20
 395 AC_SUBST(GETTEXT_PACKAGE)
 396 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 397   [Define the gettext package to be used])
 398
 399 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 400
 401 dnl
 402 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 403 dnl
 404
 405 if test x$with_libiconv != xno ; then
 406   case " $INTLLIBS " in
 407   *[[\ \        ]]-liconv[[\ \  ]]*) ;;
 408   *) ICONV_LIBS="-liconv" ;;
 409   esac
 410 fi
 411 AC_SUBST(ICONV_LIBS)
 412
 413 case $with_libiconv in
 414   gnu)
 415     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 416     ;;
 417   native)
 418     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 419     ;;
 420 esac
 421
 422 dnl Initialize libtool
 423 AM_DISABLE_STATIC
 424 AM_PROG_LIBTOOL
 425
 426 if test "x$GCC" = "xyes"; then
 427   case " $CFLAGS " in
 428   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 429   *) CFLAGS="$CFLAGS -Wall" ;;
 430   esac
 431
 432   if test "x$enable_ansi" = "xyes"; then
 433     case " $CFLAGS " in
 434     *[[\ \      ]]-ansi[[\ \    ]]*) ;;
 435     *) CFLAGS="$CFLAGS -ansi" ;;
 436     esac
 437
 438     case " $CFLAGS " in
 439     *[[\ \      ]]-pedantic[[\ \        ]]*) ;;
 440     *) CFLAGS="$CFLAGS -pedantic" ;;
 441     esac
 442   fi
 443 fi
 444
 445 dnl
 446 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 447 dnl
 448 if test $cross_compiling != yes ; then
 449     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 450     glib_save_LIBS=$LIBS
 451     LIBS="$LIBS -lm"
 452     AC_TRY_RUN([#include <math.h>
 453                  int main (void) { return (log(1) != log(1.)); }],
 454          AC_MSG_RESULT(none needed),
 455          glib_save_CFLAGS=$CFLAGS
 456          CFLAGS="$CFLAGS -std1"
 457          AC_TRY_RUN([#include <math.h>
 458                      int main (void) { return (log(1) != log(1.)); }],
 459              AC_MSG_RESULT(-std1),
 460              AC_MSG_RESULT()
 461              CFLAGS=$glib_save_CFLAGS
 462              AC_MSG_WARN(
 463                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 464          )
 465     )
 466     LIBS=$glib_save_LIBS
 467 fi
 468
 469 dnl NeXTStep cc seems to need this
 470 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 471 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 472   AC_MSG_RESULT(none needed),
 473   glib_save_CFLAGS=$CFLAGS
 474   CFLAGS="$CFLAGS -posix"
 475   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 476     AC_MSG_RESULT(-posix),
 477     AC_MSG_RESULT()
 478     CFLAGS=$glib_save_CFLAGS
 479     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 480
 481 # Checks for header files.
 482 AC_HEADER_STDC
 483
 484 # Checks for library functions.
 485 AC_FUNC_VPRINTF
 486
 487 AC_FUNC_ALLOCA
 488
 489 AC_CHECK_FUNCS(atexit on_exit)
 490
 491 AC_CHECK_SIZEOF(char)
 492 AC_CHECK_SIZEOF(short)
 493 AC_CHECK_SIZEOF(long)
 494 AC_CHECK_SIZEOF(int)
 495 AC_CHECK_SIZEOF(void *)
 496 AC_CHECK_SIZEOF(long long)
 497 AC_CHECK_SIZEOF(__int64)
 498
 499 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 500   :
 501 else
 502   AC_MSG_ERROR([
 503 *** GLib requires a 64 bit type. You might want to consider
 504 *** using the GNU C compiler.
 505 ])
 506 fi
 507
 508 if test x$ac_cv_sizeof_long_long = x8; then
 509         # long long is a 64 bit integer.
 510         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 511         AC_CACHE_VAL(glib_cv_long_long_format,[
 512                 for format in ll q I64; do
 513                   AC_TRY_RUN([#include <stdio.h>
 514                         int main()
 515                         {
 516                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 517                           char buffer[1000];
 518                           sprintf (buffer, "%${format}u", a);
 519                           sscanf (buffer, "%${format}u", &b);
 520                           exit (b!=a);
 521                         }
 522                         ],
 523                         [glib_cv_long_long_format=${format}
 524                         break],
 525                         [],[:])
 526                 done])
 527         if test -n "$glib_cv_long_long_format"; then
 528           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 529           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 530         else
 531           AC_MSG_RESULT(none)
 532         fi
 533 elif test x$ac_cv_sizeof___int64 = x8; then
 534         # __int64 is a 64 bit integer.
 535         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 536         # We know this is MSVC, and what the formats are
 537         glib_cv_long_long_format=I64
 538         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 539         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 540         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing __int64 with format I64])
 541 fi
 542
 543 dnl long doubles were not used, and a portability problem
 544 dnl AC_C_LONG_DOUBLE
 545 AC_C_CONST
 546
 547 dnl ok, here we try to check whether the systems prototypes for
 548 dnl malloc and friends actually match the prototypes provided
 549 dnl by gmem.h (keep in sync). i currently only know how to check
 550 dnl this reliably with gcc (-Werror), improvements for other
 551 dnl compilers are apprechiated.
 552 SANE_MALLOC_PROTOS=no
 553 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 554 glib_save_CFLAGS=$CFLAGS
 555 if test "x$GCC" = "xyes"; then
 556   CFLAGS="$CFLAGS -Werror"
 557   AC_TRY_COMPILE([#include <stdlib.h>], [
 558     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 559     void* (*my_malloc_p)  (size_t)         = malloc;
 560     void  (*my_free_p)    (void*)          = free;
 561     void* (*my_realloc_p) (void*, size_t)  = realloc;
 562     my_calloc_p = 0;
 563     my_malloc_p = 0;
 564     my_free_p = 0;
 565     my_realloc_p = 0;
 566   ],
 567     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 568       [Define if you have correct malloc prototypes])
 569     SANE_MALLOC_PROTOS=yes)
 570 fi
 571 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 572 CFLAGS=$glib_save_CFLAGS
 573
 574 dnl
 575 dnl check in which direction the stack grows
 576 dnl
 577 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 578         AC_TRY_RUN([
 579         volatile int *a = 0, *b = 0;
 580         void foo (void);
 581         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 582         void foo (void) { volatile int x = 5; b = &x; }
 583         ],
 584         glib_cv_stack_grows=no
 585         ,
 586         glib_cv_stack_grows=yes
 587         ,)
 588 ])
 589
 590 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 591 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 592 dnl actually supported.
 593 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 594         AC_COMPILE_IFELSE([
 595         __inline int foo () { return 0; }
 596         int main () { return foo (); }
 597         ],
 598         glib_cv_has__inline=yes
 599         ,
 600         glib_cv_has__inline=no
 601         ,)
 602 ])
 603 case x$glib_cv_has__inline in
 604 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 605 esac
 606 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 607         AC_COMPILE_IFELSE([
 608         __inline__ int foo () { return 0; }
 609         int main () { return foo (); }
 610         ],
 611         glib_cv_has__inline__=yes
 612         ,
 613         glib_cv_has__inline__=no
 614         ,)
 615 ])
 616 case x$glib_cv_has__inline__ in
 617 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 618 esac
 619 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 620         AC_COMPILE_IFELSE([
 621         #undef inline
 622         inline int foo () { return 0; }
 623         int main () { return foo (); }
 624         ],
 625         glib_cv_hasinline=yes
 626         ,
 627         glib_cv_hasinline=no
 628         ,)
 629 ])
 630 case x$glib_cv_hasinline in
 631 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 632 esac
 633
 634 # check for flavours of varargs macros
 635 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 636 AC_TRY_COMPILE([],[
 637 int a(int p1, int p2, int p3);
 638 #define call_a(...) a(1,__VA_ARGS__)
 639 call_a(2,3);
 640 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 641 AC_MSG_RESULT($g_have_iso_c_varargs)
 642
 643 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 644 if test "$CXX" = ""; then
 645 dnl No C++ compiler
 646   g_have_iso_cxx_varargs=no
 647 else
 648   AC_LANG_CPLUSPLUS
 649   AC_TRY_COMPILE([],[
 650 int a(int p1, int p2, int p3);
 651 #define call_a(...) a(1,__VA_ARGS__)
 652 call_a(2,3);
 653 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 654   AC_LANG_C
 655 fi
 656 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 657
 658 AC_MSG_CHECKING(for GNUC varargs macros)
 659 AC_TRY_COMPILE([],[
 660 int a(int p1, int p2, int p3);
 661 #define call_a(params...) a(1,params)
 662 call_a(2,3);
 663 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 664 AC_MSG_RESULT($g_have_gnuc_varargs)
 665
 666 # check for bytesex stuff
 667 AC_C_BIGENDIAN
 668
 669 # check for header files
 670 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h sys/param.h sys/poll.h sys/select.h sys/types.h])
 671 AC_CHECK_HEADERS([sys/time.h sys/times.h unistd.h values.h stdint.h sched.h])
 672
 673 # Checks for libcharset
 674 jm_LANGINFO_CODESET
 675 jm_GLIBC21
 676 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 677 AC_CHECK_FUNCS(setlocale)
 678
 679 AC_MSG_CHECKING(whether make is GNU Make)
 680 STRIP_BEGIN=
 681 STRIP_END=
 682 if $ac_make --version 2>/dev/null | grep '^GNU Make ' >/dev/null ; then
 683         STRIP_BEGIN='$(strip $(STRIP_DUMMY)'
 684         STRIP_END=')'
 685         AC_MSG_RESULT(yes)
 686 else
 687         AC_MSG_RESULT(no)
 688 fi
 689 STRIP_DUMMY=
 690 AC_SUBST(STRIP_DUMMY)
 691 AC_SUBST(STRIP_BEGIN)
 692 AC_SUBST(STRIP_END)
 693
 694 # check additional type sizes
 695 AC_CHECK_SIZEOF(size_t)
 696
 697 dnl Try to figure out whether gsize, gssize should be long or int
 698 AC_MSG_CHECKING([for the appropriate definition for size_t])
 699
 700 case $ac_cv_sizeof_size_t in
 701   $ac_cv_sizeof_short)
 702       glib_size_type=short
 703       ;;
 704   $ac_cv_sizeof_int)
 705       glib_size_type=int
 706       ;;
 707   $ac_cv_sizeof_long)
 708       glib_size_type=long
 709       ;;
 710   *)  AC_MSG_ERROR([No type matching size_t in size])
 711       ;;
 712 esac
 713
 714 dnl If int/long are the same size, we see which one produces
 715 dnl warnings when used in the location as size_t. (This matters
 716 dnl on AIX with xlc)
 717 dnl
 718 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 719    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 720   GLIB_CHECK_COMPILE_WARNINGS([
 721 #include <stddef.h>
 722 int main ()
 723 {
 724   size_t s = 1;
 725   unsigned int *size_int = &s;
 726   return (int)*size_int;
 727 }
 728     ],glib_size_type=int,
 729       [GLIB_CHECK_COMPILE_WARNINGS([
 730 #include <stddef.h>
 731 int main ()
 732 {
 733    size_t s = 1;
 734    unsigned long *size_long = &s;
 735    return (int)*size_long;
 736 }
 737         ],glib_size_type=long)])
 738 fi
 739
 740 AC_MSG_RESULT(unsigned $glib_size_type)
 741
 742 # Check for some functions
 743 AC_CHECK_FUNCS(lstat strerror strsignal memmove mkstemp vsnprintf stpcpy strcasecmp strncasecmp poll getcwd nanosleep vasprintf setenv unsetenv getc_unlocked readlink symlink)
 744
 745 AC_FUNC_VSNPRINTF_C99
 746 AC_FUNC_PRINTF_UNIX98
 747
 748 #
 749 # Check whether to use an included printf
 750 #
 751
 752 AC_ARG_ENABLE(included-printf,
 753               [AC_HELP_STRING([--enable-included-printf],
 754                               [use included printf [default=auto]])],
 755               enable_included_printf="$enableval")
 756
 757 need_included_printf=no
 758 if test "x$enable_included_printf" = "xyes" ; then
 759   need_included_printf=yes
 760 fi
 761 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
 762   need_included_printf=yes
 763 fi
 764 if test "$ac_cv_func_printf_unix98" != "yes" ; then
 765   need_included_printf=yes
 766 fi
 767 if test "x$ac_cv_sizeof_long_long" = "x8" &&
 768    test -z "$glib_cv_long_long_format" ; then
 769   need_included_printf=yes
 770 fi
 771
 772 if test "x$enable_included_printf" = "xno" &&
 773    test "x$need_included_printf" = "xyes" ; then
 774   AC_MSG_ERROR([
 775 *** Your C library's printf doesn't appear to have the features that
 776 *** GLib needs, but you specified --enable-included-printf=no.])
 777 fi
 778
 779 enable_included_printf=$need_included_printf
 780
 781 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
 782 if test "$enable_included_printf" != "yes" ; then
 783   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
 784 else
 785   if test -z "$glib_cv_long_long_format" ; then
 786     glib_cv_long_long_format="ll"
 787   fi
 788   AC_DEFINE(HAVE_VASPRINTF,1)
 789 fi
 790
 791 # Checks needed for gnulib vasnprintf
 792 bh_C_SIGNED
 793 jm_AC_TYPE_LONG_LONG
 794 gt_TYPE_LONGDOUBLE
 795 gt_TYPE_WCHAR_T
 796 gt_TYPE_WINT_T
 797 AC_TYPE_SIZE_T
 798 AC_CHECK_TYPES(ptrdiff_t)
 799 jm_AC_TYPE_INTMAX_T
 800 AC_CHECK_FUNCS(snprintf)
 801 AC_FUNC_SNPRINTF_C99
 802
 803 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
 804 # The check is borrowed from the PERL Configure script.
 805 if test "$ac_cv_func_memmove" != "yes"; then
 806   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
 807     glib_cv_working_bcopy,[AC_TRY_RUN([
 808       int main() {
 809         char buf[128], abc[128], *b;
 810         int len, off, align;
 811         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
 812         for (align = 7; align >= 0; align--) {
 813           for (len = 36; len; len--) {
 814             b = buf+align; bcopy(abc, b, len);
 815             for (off = 1; off <= len; off++) {
 816               bcopy(b, b+off, len); bcopy(b+off, b, len);
 817                 if (bcmp(b, abc, len)) return(1);
 818             }
 819           }
 820         }
 821         return(0);
 822       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
 823
 824   GLIB_ASSERT_SET(glib_cv_working_bcopy)
 825   if test "$glib_cv_working_bcopy" = "yes"; then
 826     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
 827   fi
 828 fi
 829
 830 # Check for sys_errlist
 831 AC_MSG_CHECKING(for sys_errlist)
 832 AC_TRY_LINK(, [
 833 extern char *sys_errlist[];
 834 extern int sys_nerr;
 835 sys_errlist[sys_nerr-1][0] = 0;
 836 ], glib_ok=yes, glib_ok=no)
 837 AC_MSG_RESULT($glib_ok)
 838 if test "$glib_ok" = "no"; then
 839     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
 840 fi
 841
 842 # Check for sys_siglist
 843 AC_MSG_CHECKING(for sys_siglist)
 844 AC_TRY_LINK(, [
 845 extern char *sys_siglist[];
 846 exit (sys_siglist[0]);
 847 ], glib_ok=yes, glib_ok=no)
 848 AC_MSG_RESULT($glib_ok)
 849 if test "$glib_ok" = "no"; then
 850     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
 851 fi
 852
 853 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
 854 AC_MSG_CHECKING(for sys_siglist declaration)
 855 AC_TRY_COMPILE([#include <signal.h>], [
 856 strlen (sys_siglist[0]);
 857 ], glib_ok=yes, glib_ok=no)
 858 AC_MSG_RESULT($glib_ok)
 859 if test "$glib_ok" = "no"; then
 860     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
 861 fi
 862
 863 # Check if <sys/select.h> needs to be included for fd_set
 864 AC_MSG_CHECKING([for fd_set])
 865 AC_TRY_COMPILE([#include <sys/types.h>],
 866         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 867 if test "$gtk_ok" = "yes"; then
 868     AC_MSG_RESULT([yes, found in sys/types.h])
 869 else
 870     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
 871     if test "$gtk_ok" = "yes"; then
 872         # *** FIXME: give it a different name
 873         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
 874         AC_MSG_RESULT([yes, found in sys/select.h])
 875     else
 876         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
 877         AC_MSG_RESULT(no)
 878     fi
 879 fi
 880
 881 dnl *** check for sane realloc() ***
 882 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
 883         AC_TRY_RUN([#include <stdlib.h>
 884         int main() {
 885           return realloc (0, sizeof (int)) == 0;
 886         }],
 887         [glib_cv_sane_realloc=yes],
 888         [glib_cv_sane_realloc=no],
 889         [glib_cv_sane_realloc=yes])
 890 ])
 891 if test x$glib_cv_sane_realloc = xyes; then
 892   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
 893 fi
 894
 895 dnl Check for nl_langinfo and CODESET
 896
 897 AC_MSG_CHECKING([for nl_langinfo (CODESET)])
 898 AC_TRY_COMPILE([#include <langinfo.h>],
 899         [char *codeset = nl_langinfo (CODESET);],
 900    AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
 901    have_codeset=yes,
 902    have_codeset=no)
 903 AC_MSG_RESULT($have_codeset)
 904
 905
 906 dnl ****************************************
 907 dnl *** strlcpy/strlcat                  ***
 908 dnl ****************************************
 909 # Check for strlcpy
 910 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
 911 AC_TRY_RUN([#include <stdlib.h>
 912 #include <string.h>
 913 int main() {
 914   char p[10];
 915   (void) strlcpy (p, "hi", 10);
 916   if (strlcat (p, "bye", 0) != 3)
 917     return 1;
 918   return 0;
 919 }], glib_cv_have_strlcpy=yes,
 920     glib_cv_have_strlcpy=no,
 921     glib_cv_have_strlcpy=no)])
 922 if test "$glib_cv_have_strlcpy" = "yes"; then
 923     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
 924 fi
 925
 926
 927 dnl **********************
 928 dnl *** va_copy checks ***
 929 dnl **********************
 930 dnl we currently check for all three va_copy possibilities, so we get
 931 dnl all results in config.log for bug reports.
 932 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
 933         AC_LINK_IFELSE([#include <stdarg.h>
 934         void f (int i, ...) {
 935         va_list args1, args2;
 936         va_start (args1, i);
 937         va_copy (args2, args1);
 938         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 939           exit (1);
 940         va_end (args1); va_end (args2);
 941         }
 942         int main() {
 943           f (0, 42);
 944           return 0;
 945         }],
 946         [glib_cv_va_copy=yes],
 947         [glib_cv_va_copy=no])
 948 ])
 949 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
 950         AC_LINK_IFELSE([#include <stdarg.h>
 951         void f (int i, ...) {
 952         va_list args1, args2;
 953         va_start (args1, i);
 954         __va_copy (args2, args1);
 955         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 956           exit (1);
 957         va_end (args1); va_end (args2);
 958         }
 959         int main() {
 960           f (0, 42);
 961           return 0;
 962         }],
 963         [glib_cv___va_copy=yes],
 964         [glib_cv___va_copy=no])
 965 ])
 966
 967 if test "x$glib_cv_va_copy" = "xyes"; then
 968   g_va_copy_func=va_copy
 969 else if test "x$glib_cv___va_copy" = "xyes"; then
 970   g_va_copy_func=__va_copy
 971 fi
 972 fi
 973
 974 if test -n "$g_va_copy_func"; then
 975   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
 976 fi
 977
 978 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
 979         AC_TRY_RUN([#include <stdarg.h>
 980         void f (int i, ...) {
 981         va_list args1, args2;
 982         va_start (args1, i);
 983         args2 = args1;
 984         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 985           exit (1);
 986         va_end (args1); va_end (args2);
 987         }
 988         int main() {
 989           f (0, 42);
 990           return 0;
 991         }],
 992         [glib_cv_va_val_copy=yes],
 993         [glib_cv_va_val_copy=no],
 994         [glib_cv_va_val_copy=yes])
 995 ])
 996
 997 if test "x$glib_cv_va_val_copy" = "xno"; then
 998   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 999 fi
1000
1001 dnl ***********************
1002 dnl *** g_module checks ***
1003 dnl ***********************
1004 G_MODULE_LIBS=
1005 G_MODULE_LIBS_EXTRA=
1006 G_MODULE_PLUGIN_LIBS=
1007 if test x"$glib_native_win32" = xyes; then
1008   dnl No use for this on Win32
1009   G_MODULE_LDFLAGS=
1010 else
1011   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1012 fi
1013 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1014 G_MODULE_NEED_USCORE=0
1015 G_MODULE_BROKEN_RTLD_GLOBAL=0
1016 G_MODULE_HAVE_DLERROR=0
1017 dnl *** force native WIN32 shared lib loader
1018 if test -z "$G_MODULE_IMPL"; then
1019   case "$host" in
1020   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1021   esac
1022 fi
1023 dnl *** dlopen() and dlsym() in system libraries
1024 if test -z "$G_MODULE_IMPL"; then
1025         AC_CHECK_FUNC(dlopen,
1026                       [AC_CHECK_FUNC(dlsym,
1027                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1028                       [])
1029 fi
1030 dnl *** load_image (BeOS)
1031 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1032   AC_CHECK_LIB(root, load_image,
1033       [G_MODULE_LIBS="-lbe -lroot -lglib"
1034       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1035       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1036       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1037       [])
1038 fi
1039 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1040 if test -z "$G_MODULE_IMPL"; then
1041         AC_CHECK_FUNC(NSLinkModule,
1042                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1043                        G_MODULE_NEED_USCORE=1],
1044                       [])
1045 fi
1046 dnl *** dlopen() and dlsym() in libdl
1047 if test -z "$G_MODULE_IMPL"; then
1048         AC_CHECK_LIB(dl, dlopen,
1049                      [AC_CHECK_LIB(dl, dlsym,
1050                                    [G_MODULE_LIBS=-ldl
1051                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1052                      [])
1053 fi
1054 dnl *** shl_load() in libdld (HP-UX)
1055 if test -z "$G_MODULE_IMPL"; then
1056         AC_CHECK_LIB(dld, shl_load,
1057                 [G_MODULE_LIBS=-ldld
1058                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1059                 [])
1060 fi
1061 dnl *** additional checks for G_MODULE_IMPL_DL
1062 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1063         LIBS_orig="$LIBS"
1064         LDFLAGS_orig="$LDFLAGS"
1065         LIBS="$G_MODULE_LIBS $LIBS"
1066         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1067 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1068         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1069                 glib_cv_rtldglobal_broken,[
1070                 AC_TRY_RUN([
1071 #include <dlfcn.h>
1072 #ifndef RTLD_GLOBAL
1073 #  define RTLD_GLOBAL 0
1074 #endif
1075 #ifndef RTLD_LAZY
1076 #  define RTLD_LAZY 0
1077 #endif
1078 int pthread_create;
1079 int main () {
1080     void *handle, *global, *local;
1081     global = &pthread_create;
1082     handle = dlopen ("libpthread.so", RTLD_GLOBAL | RTLD_LAZY);
1083     if (!handle) return 0;
1084     local = dlsym (handle, "pthread_create");
1085     return global == local;
1086 }                       ],
1087                         [glib_cv_rtldglobal_broken=no],
1088                         [glib_cv_rtldglobal_broken=yes],
1089                         [glib_cv_rtldglobal_broken=no])
1090                 rm -f plugin.c plugin.o plugin.lo
1091         ])
1092         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1093                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1094         else
1095                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1096         fi
1097 dnl *** check whether we need preceeding underscores
1098         AC_CACHE_CHECK([for preceeding underscore in symbols],
1099                 glib_cv_uscore,[
1100                 AC_TRY_RUN([#include <dlfcn.h>
1101                 int glib_underscore_test (void) { return 42; }
1102                 int main() {
1103                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1104                   handle = dlopen ((void*)0, 0);
1105                   if (handle) {
1106                     f1 = dlsym (handle, "glib_underscore_test");
1107                     f2 = dlsym (handle, "_glib_underscore_test");
1108                   } return (!f2 || f1);
1109                 }],
1110                         [glib_cv_uscore=yes],
1111                         [glib_cv_uscore=no],
1112                         [])
1113                 rm -f plugin.c plugin.$ac_objext plugin.lo
1114         ])
1115         GLIB_ASSERT_SET(glib_cv_uscore)
1116         if test "x$glib_cv_uscore" = "xyes"; then
1117                 G_MODULE_NEED_USCORE=1
1118         else
1119                 G_MODULE_NEED_USCORE=0
1120         fi
1121
1122         LDFLAGS="$LDFLAGS_orig"
1123 dnl *** check for having dlerror()
1124         AC_CHECK_FUNC(dlerror,
1125                 [G_MODULE_HAVE_DLERROR=1],
1126                 [G_MODULE_HAVE_DLERROR=0])
1127         LIBS="$LIBS_orig"
1128 fi
1129 dnl *** done, have we got an implementation?
1130 if test -z "$G_MODULE_IMPL"; then
1131         G_MODULE_IMPL=0
1132         G_MODULE_SUPPORTED=false
1133 else
1134         G_MODULE_SUPPORTED=true
1135 fi
1136
1137 AC_MSG_CHECKING(for the suffix of shared libraries)
1138 case "$host_os" in
1139   hpux9* | hpux10* | hpux11*)  # taken from ltconfig
1140     glib_gmodule_suffix='sl'
1141     ;;
1142   cygwin* | mingw*)
1143     glib_gmodule_suffix='dll'
1144     ;;
1145   *)
1146     glib_gmodule_suffix='so'
1147     ;;
1148 esac
1149 AC_MSG_RESULT(.$glib_gmodule_suffix)
1150
1151 AC_SUBST(G_MODULE_SUPPORTED)
1152 AC_SUBST(G_MODULE_IMPL)
1153 AC_SUBST(G_MODULE_LIBS)
1154 AC_SUBST(G_MODULE_LIBS_EXTRA)
1155 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1156 AC_SUBST(G_MODULE_LDFLAGS)
1157 AC_SUBST(G_MODULE_HAVE_DLERROR)
1158 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1159 AC_SUBST(G_MODULE_NEED_USCORE)
1160 AC_SUBST(GLIB_DEBUG_FLAGS)
1161
1162 dnl **********************
1163 dnl *** g_spawn checks ***
1164 dnl **********************
1165
1166 AC_MSG_CHECKING(for gspawn implementation)
1167 case "$host" in
1168   *-*-mingw*)
1169     GSPAWN=gspawn-win32.lo
1170     ;;
1171   *)
1172     GSPAWN=gspawn.lo
1173     ;;
1174 esac
1175 AC_MSG_RESULT($GSPAWN)
1176 AC_SUBST(GSPAWN)
1177
1178 dnl *************************
1179 dnl *** GIOChannel checks ***
1180 dnl *************************
1181
1182 AC_MSG_CHECKING(for GIOChannel implementation)
1183 case "$host" in
1184   *-*-mingw*)
1185     GIO=giowin32.lo
1186     ;;
1187   *)
1188     GIO=giounix.lo
1189     ;;
1190 esac
1191 AC_MSG_RESULT($GIO)
1192 AC_SUBST(GIO)
1193
1194 dnl check for cpu to enable double checked locking when possible
1195 dnl ************************************************************
1196
1197 if test x"$have_threads" != xno; then
1198         AC_MSG_CHECKING(whether double checked locking is safe)
1199         # According to glibc/linuxthreads the following platforms do
1200         # not have the notion of a read or write memory barrier and
1201         # therefore the double checked locking should be safe. Have a
1202         # look at pthread_once in glibc/linuxthreads/mutex.c to see,
1203         # what this means.
1204         case $host_cpu in
1205                 arm|hppa|i386|i686|ia64|m68k|sh|cris|x86_64)
1206                         g_use_double_checked_locking=yes
1207                 ;;
1208                 *)
1209                         g_use_double_checked_locking=no
1210                 ;;
1211         esac
1212         AC_MSG_RESULT($g_use_double_checked_locking)
1213 fi
1214
1215 dnl ****************************************
1216 dnl *** platform dependent source checks ***
1217 dnl ****************************************
1218
1219 AC_MSG_CHECKING(for platform-dependent source)
1220 case "$host" in
1221   *-*-cygwin*|*-*-mingw*)
1222     PLATFORMDEP=gwin32.lo
1223     ;;
1224   *)
1225     PLATFORMDEP=
1226     ;;
1227 esac
1228 AC_MSG_RESULT($PLATFORMDEP)
1229 AC_SUBST(PLATFORMDEP)
1230
1231 AC_MSG_CHECKING([whether to compile timeloop])
1232 case "$host" in
1233   *-*-cygwin*|*-*-mingw*)
1234     enable_timeloop=no
1235     ;;
1236   *)
1237     enable_timeloop=yes
1238     ;;
1239 esac
1240 AC_MSG_RESULT($enable_timeloop)
1241 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1242
1243 AC_MSG_CHECKING([if building for some Win32 platform])
1244 case "$host" in
1245   *-*-mingw*|*-*-cygwin*)
1246     platform_win32=yes
1247     ;;
1248   *)
1249     platform_win32=no
1250     ;;
1251 esac
1252 AC_MSG_RESULT($platform_win32)
1253 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1254
1255 dnl ***********************
1256 dnl *** g_thread checks ***
1257 dnl ***********************
1258
1259 AC_ARG_WITH(threads,
1260            [AC_HELP_STRING([--with-threads=@<:@none/posix/dce/solaris/win32@:>@],
1261                            [specify a thread implementation to use])],
1262            [if test "x$with_threads" = x; then
1263                 want_threads=yes
1264             else
1265                 want_threads=$with_threads
1266             fi],
1267            [want_threads=yes])
1268 if test "x$enable_threads" = "xno"; then
1269         want_threads=no
1270 fi
1271
1272 dnl error and warning message
1273 dnl *************************
1274
1275 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1276                 computer. GLib will not have a default thread implementation."
1277
1278 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1279                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1280                 compilation now, but then your programs might not work.
1281                 Please provide information on how it is done on your system."
1282
1283 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1284                 "
1285
1286 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1287                 provide information on your thread implementation.
1288                 You can also run 'configure --disable-threads'
1289                 to compile without thread support."
1290
1291 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1292                 functions will not be MT-safe during their first call because
1293                 there is no working 'getpwuid_r' on your system."
1294
1295 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1296                 because there is no 'localtime_r' on your system."
1297
1298 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1299                 crude surrogate will be used. If you happen to know a
1300                 yield function for your system, please inform the GLib
1301                 developers."
1302
1303 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1304                 threads on your system. Thus threads can only have the default
1305                 priority. If you happen to know these main/max
1306                 priorities, please inform the GLib developers."
1307
1308 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1309                 linking threaded applications. As GLib cannot do that
1310                 automatically, you will get an linkg error everytime you are
1311                 not using the right compiler. In that case you have to relink
1312                 with the right compiler. Ususally just '_r' is appended
1313                 to the compiler name."
1314
1315 dnl determination of thread implementation
1316 dnl ***************************************
1317
1318 # have_threads=no   means no thread support
1319 # have_threads=none means no default thread implementation
1320
1321 have_threads=no
1322 if test "x$want_threads" = xyes || test "x$want_threads" = xsolaris; then
1323         case $host in
1324                 *-*-solaris*)
1325                 AC_CHECK_LIB(thread, cond_init, have_threads=solaris)
1326                 ;;
1327         esac
1328 fi
1329 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1330                                 || test "x$want_threads" = xdce; then
1331         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1332         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1333         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1334         glib_save_CPPFLAGS="$CPPFLAGS"
1335         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1336         if test "x$have_threads" = xno; then
1337                 AC_TRY_COMPILE([#include <pthread.h>],
1338                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1339                         have_threads=posix)
1340         fi
1341         if test "x$have_threads" = xno; then
1342                 AC_TRY_COMPILE([#include <pthread.h>],
1343                         [pthread_mutex_t m;
1344                          pthread_mutex_init (&m, pthread_mutexattr_default);],
1345                         have_threads=dce)
1346         fi
1347         # Tru64Unix requires -pthread to find pthread.h. See #103020
1348         CPPFLAGS="$CPPFLAGS -pthread"
1349         if test "x$have_threads" = xno; then
1350         AC_TRY_COMPILE([#include <pthread.h>],
1351                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1352                        have_threads=posix)
1353         fi
1354         CPPFLAGS="$glib_save_CPPFLAGS"
1355 fi
1356 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1357         case $host in
1358                 *-*-mingw*)
1359                 have_threads=win32
1360                 ;;
1361         esac
1362 fi
1363 if test "x$want_threads" = xnone; then
1364         have_threads=none
1365 fi
1366
1367 AC_MSG_CHECKING(for thread implementation)
1368
1369 if test "x$have_threads" = xno && test "x$want_threads" != xno; then
1370         AC_MSG_RESULT(none available)
1371         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
1372 else
1373         AC_MSG_RESULT($have_threads)
1374 fi
1375
1376
1377 dnl determination of G_THREAD_CFLAGS
1378 dnl ********************************
1379
1380 G_THREAD_LIBS=
1381 G_THREAD_LIBS_EXTRA=
1382 G_THREAD_CFLAGS=
1383
1384 dnl
1385 dnl Test program for basic POSIX threads functionality
1386 dnl
1387 m4_define([glib_thread_test],[
1388 #include <pthread.h>
1389 int check_me = 0;
1390 void* func(void* data) {check_me = 42; return &check_me;}
1391 int main()
1392  { pthread_t t;
1393    void *ret;
1394    pthread_create (&t, $1, func, 0);
1395    pthread_join (t, &ret);
1396    exit (check_me != 42 || ret != &check_me);
1397 }])
1398
1399 dnl
1400 dnl Test program for sched_get_priority_min()
1401 dnl
1402 m4_define([glib_sched_priority_test],[
1403 #include <sched.h>
1404 #include <errno.h>
1405 int main() {
1406     errno = 0;
1407     return sched_get_priority_min(SCHED_OTHER)==-1
1408            && errno != 0;
1409 }])
1410
1411 if test x"$have_threads" != xno; then
1412
1413   if test x"$have_threads" = xposix; then
1414     # First we test for posix, whether -pthread or -pthreads do the trick as
1415     # both CPPFLAG and LIBS.
1416     # One of them does for most gcc versions and some other platforms/compilers
1417     # too and could be considered as the canonical way to go.
1418     for flag in pthread pthreads; do
1419       glib_save_CFLAGS="$CFLAGS"
1420       CFLAGS="$CFLAGS -$flag"
1421       AC_TRY_RUN(glib_thread_test(0),
1422                  glib_flag_works=yes,
1423                  glib_flag_works=no,
1424                  [AC_LINK_IFELSE(glib_thread_test(0),
1425                                  glib_flag_works=yes,
1426                                  glib_flag_works=no)])
1427       CFLAGS="$glib_save_CFLAGS"
1428       if test $glib_flag_works = yes ; then
1429          G_THREAD_CFLAGS=-$flag
1430          G_THREAD_LIBS=-$flag
1431       fi
1432     done
1433   fi
1434
1435   if test x"$G_THREAD_CFLAGS" = x; then
1436
1437     # The canonical -pthread[s] does not work. Try something different.
1438
1439     case $host in
1440         *-aix*)
1441                 if test x"$GCC" = xyes; then
1442                         # GCC 3.0 and above needs -pthread.
1443                         # Should be coverd by the case above.
1444                         # GCC 2.x and below needs -mthreads
1445                         G_THREAD_CFLAGS="-mthreads"
1446                         G_THREAD_LIBS=$G_THREAD_CFLAGS
1447                 else
1448                         # We are probably using the aix compiler. Normaly a
1449                         # program would have to be compiled with the _r variant
1450                         # of the corresponding compiler, but we as GLib cannot
1451                         # do that: but the good news is that for compiling the
1452                         # only difference is the added -D_THREAD_SAFE compile
1453                         # option. This is according to the "C for AIX User's
1454                         # Guide".
1455                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
1456                 fi
1457                 ;;
1458         *-dg-dgux*)  # DG/UX
1459                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
1460                 ;;
1461         *-osf*)
1462                 # So we are using dce threads. posix threads are already
1463                 # catched above.
1464                 G_THREAD_CFLAGS="-threads"
1465                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1466                 ;;
1467         *-solaris*)
1468                 if test x"$GCC" = xyes; then
1469                    # We are using solaris threads. posix threads are
1470                    # already catched above.
1471                         G_THREAD_CFLAGS="-threads"
1472                 else
1473                         G_THREAD_CFLAGS="-mt"
1474                 fi
1475                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1476                 ;;
1477         *-sysv5uw7*) # UnixWare 7
1478                 # We are not using gcc with -pthread. Catched above.
1479                 G_THREAD_CFLAGS="-Kthread"
1480                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1481                 ;;
1482         *-mingw*)
1483                 # No flag needed when using MSVCRT.DLL
1484                 G_THREAD_CFLAGS=""
1485                 ;;
1486         *)
1487                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
1488                 ;;
1489     esac
1490
1491   fi
1492
1493     # if we are not finding the localtime_r function, then we probably are
1494     # not using the proper multithread flag
1495
1496     glib_save_CPPFLAGS="$CPPFLAGS"
1497     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1498
1499     # First we test, whether localtime_r is declared in time.h
1500     # directly. Then we test whether a macro localtime_r exists, in
1501     # which case localtime_r in the test program is replaced and thus
1502     # if we still find localtime_r in the output, it is not defined as
1503     # a macro.
1504
1505     AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
1506       [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
1507                                                            localtime_r(a,b)],
1508                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
1509
1510     CPPFLAGS="$glib_save_CPPFLAGS"
1511
1512     AC_MSG_CHECKING(thread related cflags)
1513     AC_MSG_RESULT($G_THREAD_CFLAGS)
1514     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1515 fi
1516
1517 dnl determination of G_THREAD_LIBS
1518 dnl ******************************
1519
1520 mutex_has_default=no
1521 case $have_threads in
1522         posix|dce)
1523           glib_save_CPPFLAGS="$CPPFLAGS"
1524           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1525           if test x"$G_THREAD_LIBS" = x; then
1526             case $host in
1527               *-aix*)
1528                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
1529                 # probably using the aix compiler.
1530                 AC_MSG_WARN($AIX_COMPILE_INFO)
1531                 ;;
1532               *)
1533                 G_THREAD_LIBS=error
1534                 glib_save_LIBS="$LIBS"
1535                 for thread_lib in "" pthread pthread32 pthreads thread dce; do
1536                         if test x"$thread_lib" = x; then
1537                                 add_thread_lib=""
1538                                 IN=""
1539                         else
1540                                 add_thread_lib="-l$thread_lib"
1541                                 IN=" in -l$thread_lib"
1542                         fi
1543                         if test x"$have_threads" = xposix; then
1544                                 defattr=0
1545                         else
1546                                 defattr=pthread_attr_default
1547                         fi
1548
1549                         LIBS="$add_thread_lib $glib_save_LIBS"
1550
1551                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
1552                         AC_TRY_RUN(glib_thread_test($defattr),
1553                                    glib_result=yes,
1554                                    glib_result=no,
1555                                    [AC_LINK_IFELSE(glib_thread_test($defattr),
1556                                                    glib_result=yes,
1557                                                    glib_result=no)])
1558                         AC_MSG_RESULT($glib_result)
1559
1560                         if test "$glib_result" = "yes" ; then
1561                           G_THREAD_LIBS="$add_thread_lib"
1562                           break
1563                         fi
1564                 done
1565                 if test "x$G_THREAD_LIBS" = xerror; then
1566                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1567                 fi
1568                 LIBS="$glib_save_LIBS"
1569                 ;;
1570             esac
1571           fi
1572
1573           glib_save_LIBS="$LIBS"
1574           for thread_lib in "" rt rte; do
1575             if test x"$thread_lib" = x; then
1576               add_thread_lib=""
1577               IN=""
1578             else
1579               add_thread_lib="-l$thread_lib"
1580               IN=" in -l$thread_lib"
1581             fi
1582             LIBS="$add_thread_lib $glib_save_LIBS"
1583
1584             AC_MSG_CHECKING(for sched_get_priority_min$IN)
1585             AC_TRY_RUN(glib_sched_priority_test,
1586                        glib_result=yes,
1587                        glib_result=no,
1588                        [AC_LINK_IFELSE(glib_sched_priority_test,
1589                                        glib_result=yes,
1590                                        glib_result=no)])
1591             AC_MSG_RESULT($glib_result)
1592
1593             if test "$glib_result" = "yes" ; then
1594                G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
1595                posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
1596                posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
1597                break
1598             fi
1599           done
1600           LIBS="$glib_save_LIBS"
1601           mutex_has_default=yes
1602           mutex_default_type='pthread_mutex_t'
1603           mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
1604           mutex_header_file='pthread.h'
1605           if test "x$have_threads" = "xposix"; then
1606             g_threads_impl="POSIX"
1607           else
1608             g_threads_impl="DCE"
1609             have_threads="posix"
1610           fi
1611           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
1612           CPPFLAGS="$glib_save_CPPFLAGS"
1613           ;;
1614         solaris)
1615            mutex_has_default=yes
1616            mutex_default_type='mutex_t'
1617            mutex_default_init="DEFAULTMUTEX"
1618            mutex_header_file='thread.h'
1619            g_threads_impl="SOLARIS"
1620            ;;
1621         win32)
1622            g_threads_impl="WIN32"
1623            ;;
1624         none|no)
1625            g_threads_impl="NONE"
1626            ;;
1627         *)
1628            g_threads_impl="NONE"
1629            G_THREAD_LIBS=error
1630            ;;
1631 esac
1632
1633 if test "x$G_THREAD_LIBS" = xerror; then
1634         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1635 fi
1636
1637 case $host in
1638   *-*-beos*)
1639     G_THREAD_LIBS="-lbe -lroot -lglib "
1640     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1641     ;;
1642   *)
1643     ;;
1644 esac
1645
1646 AC_MSG_CHECKING(thread related libraries)
1647 AC_MSG_RESULT($G_THREAD_LIBS)
1648
1649 dnl check for mt safe function variants and some posix functions
1650 dnl ************************************************************
1651
1652 if test x"$have_threads" != xno; then
1653         glib_save_LIBS="$LIBS"
1654         # we are not doing the following for now, as this might require glib
1655         # to always be linked with the thread libs on some platforms.
1656         # LIBS="$LIBS $G_THREAD_LIBS"
1657         AC_CHECK_FUNCS(localtime_r)
1658         if test "$ac_cv_header_pwd_h" = "yes"; then
1659                 AC_CACHE_CHECK([for posix getpwuid_r],
1660                         ac_cv_func_posix_getpwuid_r,
1661                         [AC_TRY_RUN([
1662 #include <errno.h>
1663 #include <pwd.h>
1664 int main () {
1665     char buffer[10000];
1666     struct passwd pwd, *pwptr = &pwd;
1667     int error;
1668     errno = 0;
1669     error = getpwuid_r (0, &pwd, buffer,
1670                         sizeof (buffer), &pwptr);
1671    return (error < 0 && errno == ENOSYS)
1672            || error == ENOSYS;
1673 }                               ],
1674                                 [ac_cv_func_posix_getpwuid_r=yes],
1675                                 [ac_cv_func_posix_getpwuid_r=no])])
1676                 GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
1677                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
1678                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
1679                                 [Have POSIX function getpwuid_r])
1680                 else
1681                         AC_CACHE_CHECK([for nonposix getpwuid_r],
1682                                 ac_cv_func_nonposix_getpwuid_r,
1683                                 [AC_TRY_LINK([#include <pwd.h>],
1684                                         [char buffer[10000];
1685                                         struct passwd pwd;
1686                                         getpwuid_r (0, &pwd, buffer,
1687                                                         sizeof (buffer));],
1688                                         [ac_cv_func_nonposix_getpwuid_r=yes],
1689                                         [ac_cv_func_nonposix_getpwuid_r=no])])
1690                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
1691                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
1692                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
1693                                         [Have non-POSIX function getpwuid_r])
1694                         fi
1695                 fi
1696         fi
1697         LIBS="$G_THREAD_LIBS $LIBS"
1698         if test x"$have_threads" = xposix; then
1699                 glib_save_CPPFLAGS="$CPPFLAGS"
1700                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1701                 dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
1702                 GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
1703                 # This is not AC_CHECK_FUNC to also work with function
1704                 # name mangling in header files.
1705                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
1706                 AC_TRY_LINK([#include <pthread.h>],
1707                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
1708                         [AC_MSG_RESULT(yes)
1709                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
1710                                   [Have function pthread_attr_setstacksize])],
1711                         [AC_MSG_RESULT(no)])
1712                 AC_MSG_CHECKING(for minimal/maximal thread priority)
1713                 if test x"$posix_priority_min" = x; then
1714                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
1715                                 PX_PRIO_MIN],,[
1716                                 posix_priority_min=PX_PRIO_MIN
1717                                 posix_priority_max=PX_PRIO_MAX])
1718                 fi
1719                 if test x"$posix_priority_min" = x; then
1720                         # AIX
1721                         AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
1722                                 PTHREAD_PRIO_MIN],,[
1723                                 posix_priority_min=PTHREAD_PRIO_MIN
1724                                 posix_priority_max=PTHREAD_PRIO_MAX])
1725                 fi
1726                 if test x"$posix_priority_min" = x; then
1727                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
1728                                 PRI_OTHER_MIN],,[
1729                                 posix_priority_min=PRI_OTHER_MIN
1730                                 posix_priority_max=PRI_OTHER_MAX])
1731                 fi
1732                 if test x"$posix_priority_min" = x; then
1733                         AC_MSG_RESULT(none found)
1734                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
1735                         posix_priority_min=-1
1736                         posix_priority_max=-1
1737                 else
1738                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
1739                         AC_MSG_CHECKING(for pthread_setschedparam)
1740                         AC_TRY_LINK([#include <pthread.h>],
1741                           [pthread_t t; pthread_setschedparam(t, 0, NULL)],
1742                           [AC_MSG_RESULT(yes)
1743                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
1744                            AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
1745                           [AC_MSG_RESULT(no)
1746                            AC_MSG_WARN($POSIX_NO_PRIORITIES)])
1747                 fi
1748                 posix_yield_func=none
1749                 AC_MSG_CHECKING(for posix yield function)
1750                 for yield_func in sched_yield pthread_yield_np pthread_yield \
1751                                                         thr_yield; do
1752                         AC_TRY_LINK([#include <pthread.h>],
1753                                 [$yield_func()],
1754                                 [posix_yield_func="$yield_func"
1755                                 break])
1756                 done
1757                 if test x"$posix_yield_func" = xnone; then
1758                         AC_MSG_RESULT(none found)
1759                         AC_MSG_WARN($POSIX_NO_YIELD)
1760                         posix_yield_func="g_usleep(1000)"
1761                 else
1762                         AC_MSG_RESULT($posix_yield_func)
1763                         posix_yield_func="$posix_yield_func()"
1764                 fi
1765                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
1766                 CPPFLAGS="$glib_save_CPPFLAGS"
1767
1768                 AC_CACHE_CHECK([whether to use the PID niceness surrogate for thread priorities],
1769                                glib_cv_use_pid_surrogate,
1770                  [AC_TRY_RUN([
1771 #include <pthread.h>
1772 #include <sys/types.h>
1773 #include <unistd.h>
1774 pid_t other_pid = 0;
1775
1776 void* func(void* data) {other_pid = getpid();}
1777 main()
1778 { pthread_t t;
1779   void *ret;
1780   pthread_create (&t, 0, func, NULL);
1781   pthread_join (t, &ret);
1782   exit (getpid()==other_pid ||
1783         $posix_priority_min != $posix_priority_max);
1784 }               ],
1785                 [glib_cv_use_pid_surrogate=yes],
1786                 [glib_cv_use_pid_surrogate=no],
1787                 [])])
1788           GLIB_ASSERT_SET(glib_cv_use_pid_surrogate)
1789           if test "$glib_cv_use_pid_surrogate" = "yes" ; then
1790             AC_DEFINE(G_THREAD_USE_PID_SURROGATE, 1,
1791                       [whether to use the PID niceness surrogate for thread priorities])
1792           fi
1793
1794         elif test x"$have_threads" = xwin32; then
1795                 # It's a pointer to a private struct
1796                 GLIB_SIZEOF(,struct _GThreadData *, system_thread)
1797         elif test x"$have_threads" = xsolaris; then
1798                 GLIB_SIZEOF([#include <thread.h>], thread_t, system_thread)
1799         fi
1800
1801         LIBS="$glib_save_LIBS"
1802
1803         # now spit out all the warnings.
1804         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
1805            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
1806                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
1807         fi
1808         if test "$ac_cv_func_localtime_r" != "yes"; then
1809                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
1810         fi
1811 fi
1812
1813 if test x"$glib_cv_sizeof_system_thread" = x; then
1814    # use a pointer as a fallback.
1815    GLIB_SIZEOF(,void *, system_thread)
1816 fi
1817
1818 #
1819 # Hack to deal with:
1820 #
1821 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
1822 #     building shared libraries with linux.
1823 #  b) libtool doesn't recognize -pthread as a library dependency.
1824 #
1825 case $host in
1826   *-*-linux*)
1827     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
1828     ;;
1829   *)
1830     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-Wc,-pthread/`"
1831     ;;
1832 esac
1833
1834 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
1835                    [Source file containing theread implementation])
1836 AC_SUBST(G_THREAD_CFLAGS)
1837 AC_SUBST(G_THREAD_LIBS)
1838 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
1839 AC_SUBST(G_THREAD_LIBS_EXTRA)
1840
1841 dnl **********************************************
1842 dnl *** GDefaultMutex setup and initialization ***
1843 dnl **********************************************
1844 dnl
1845 dnl if mutex_has_default = yes, we also got
1846 dnl mutex_default_type, mutex_default_init and mutex_header_file
1847 if test $mutex_has_default = yes ; then
1848         glib_save_CPPFLAGS="$CPPFLAGS"
1849         glib_save_LIBS="$LIBS"
1850         LIBS="$G_THREAD_LIBS $LIBS"
1851         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1852         GLIB_SIZEOF([#include <$mutex_header_file>],
1853                     $mutex_default_type,
1854                     gmutex)
1855         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
1856                            $mutex_default_type,
1857                            gmutex,
1858                            $glib_cv_sizeof_gmutex,
1859                            $mutex_default_init)
1860         if test x"$glib_cv_byte_contents_gmutex" = xno; then
1861                 mutex_has_default=no
1862         fi
1863         CPPFLAGS="$glib_save_CPPFLAGS"
1864         LIBS="$glib_save_LIBS"
1865 fi
1866
1867 dnl ****************************************
1868 dnl *** GLib POLL* compatibility defines ***
1869 dnl ****************************************
1870
1871 glib_poll_includes=["
1872 #include <sys/types.h>
1873 #include <sys/poll.h>
1874 "]
1875
1876 if test $ac_cv_header_sys_types_h = yes &&
1877    test $ac_cv_header_sys_poll_h = yes ; then
1878   glib_failed=false
1879   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
1880   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
1881   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
1882   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
1883   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
1884   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
1885   if $glib_failed ; then
1886     AC_MSG_ERROR([Could not determine values for POLL* constants])
1887   fi
1888 else
1889   glib_cv_value_POLLIN=1
1890   glib_cv_value_POLLOUT=4
1891   glib_cv_value_POLLPRI=2
1892   glib_cv_value_POLLERR=8
1893   glib_cv_value_POLLHUP=16
1894   glib_cv_value_POLLNVAL=32
1895 fi
1896
1897 dnl **********************
1898 dnl *** Win32 API libs ***
1899 dnl **********************
1900
1901 case $host in
1902   *-*-cygwin*)
1903         G_LIBS_EXTRA="-luser32 -lkernel32"
1904     ;;
1905   *-*-mingw*)
1906         G_LIBS_EXTRA="-lwsock32"
1907     ;;
1908   *)
1909         G_LIBS_EXTRA=""
1910     ;;
1911 esac
1912 AC_SUBST(G_LIBS_EXTRA)
1913
1914 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
1915 dnl since we need it for g_iconv()
1916
1917 AC_MSG_CHECKING([for EILSEQ])
1918 AC_TRY_COMPILE([
1919 #include <errno.h>
1920 ],
1921 [
1922 int error = EILSEQ;
1923 ], have_eilseq=yes, have_eilseq=no);
1924 AC_MSG_RESULT($have_eilseq)
1925
1926 dnl ******************************************************************
1927 dnl *** Look for glib-genmarshal in PATH if we are cross-compiling ***
1928 dnl ******************************************************************
1929
1930 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
1931
1932 if test $cross_compiling = yes; then
1933   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
1934   if test x$GLIB_GENMARSHAL = xno; then
1935     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
1936   fi
1937 fi
1938
1939 dnl **************************
1940 dnl *** Checks for gtk-doc ***
1941 dnl **************************
1942
1943 GTK_DOC_CHECK([1.0])
1944
1945 AC_ARG_ENABLE(man,
1946               [AC_HELP_STRING([--enable-man],
1947                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
1948               enable_man=no)
1949 dnl
1950 dnl Check for xsltproc
1951 dnl
1952 AC_PATH_PROG([XSLTPROC], [xsltproc])
1953 if test -z "$XSLTPROC"; then
1954   enable_man=no
1955 fi
1956
1957 dnl check for DocBook DTD and stylesheets in the local catalog.
1958 JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1959    [DocBook XML DTD V4.1.2],,enable_man=no)
1960 JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1961    [DocBook XSL Stylesheets],,enable_man=no)
1962 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1963
1964 dnl ******************************
1965 dnl *** output the whole stuff ***
1966 dnl ******************************
1967
1968 dnl this section will only be run if config.status is invoked with no
1969 dnl arguments, or with "glibconfig.h" as an argument.
1970 AC_CONFIG_COMMANDS([glibconfig.h],
1971 [
1972         outfile=glibconfig.h-tmp
1973         cat > $outfile <<\_______EOF
1974 /* glibconfig.h
1975  *
1976  * This is a generated file.  Please modify 'configure.in'
1977  */
1978
1979 #ifndef __G_LIBCONFIG_H__
1980 #define __G_LIBCONFIG_H__
1981
1982 #include <glib/gmacros.h>
1983
1984 _______EOF
1985
1986         if test x$glib_limits_h = xyes; then
1987           echo '#include <limits.h>' >> $outfile
1988         fi
1989         if test x$glib_float_h = xyes; then
1990           echo '#include <float.h>' >> $outfile
1991         fi
1992         if test x$glib_values_h = xyes; then
1993           echo '#include <values.h>' >> $outfile
1994         fi
1995         if test "$glib_header_alloca_h" = "yes"; then
1996           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
1997         fi
1998         if test x$glib_sys_poll_h = xyes; then
1999           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2000         fi
2001
2002         cat >> $outfile <<_______EOF
2003
2004 G_BEGIN_DECLS
2005
2006 #define G_MINFLOAT      $glib_mf
2007 #define G_MAXFLOAT      $glib_Mf
2008 #define G_MINDOUBLE     $glib_md
2009 #define G_MAXDOUBLE     $glib_Md
2010 #define G_MINSHORT      $glib_ms
2011 #define G_MAXSHORT      $glib_Ms
2012 #define G_MAXUSHORT     $glib_Mus
2013 #define G_MININT        $glib_mi
2014 #define G_MAXINT        $glib_Mi
2015 #define G_MAXUINT       $glib_Mui
2016 #define G_MINLONG       $glib_ml
2017 #define G_MAXLONG       $glib_Ml
2018 #define G_MAXULONG      $glib_Mul
2019
2020 #define G_MININT64      G_GINT64_CONSTANT(0x8000000000000000)
2021 #define G_MAXINT64      G_GINT64_CONSTANT(0x7fffffffffffffff)
2022 #define G_MAXUINT64     G_GINT64_CONSTANT(0xffffffffffffffffU)
2023
2024 _______EOF
2025
2026
2027         ### this should always be true in a modern C/C++ compiler
2028         cat >>$outfile <<_______EOF
2029 typedef signed char gint8;
2030 typedef unsigned char guint8;
2031 _______EOF
2032
2033
2034         if test -n "$gint16"; then
2035           cat >>$outfile <<_______EOF
2036 typedef signed $gint16 gint16;
2037 typedef unsigned $gint16 guint16;
2038 #define G_GINT16_MODIFIER $gint16_modifier
2039 #define G_GINT16_FORMAT $gint16_format
2040 #define G_GUINT16_FORMAT $guint16_format
2041 _______EOF
2042         fi
2043
2044
2045         if test -n "$gint32"; then
2046           cat >>$outfile <<_______EOF
2047 typedef signed $gint32 gint32;
2048 typedef unsigned $gint32 guint32;
2049 #define G_GINT32_MODIFIER $gint32_modifier
2050 #define G_GINT32_FORMAT $gint32_format
2051 #define G_GUINT32_FORMAT $guint32_format
2052 _______EOF
2053         fi
2054
2055         cat >>$outfile <<_______EOF
2056 #define G_HAVE_GINT64 1          /* deprecated, always true */
2057
2058 ${glib_extension}typedef signed $gint64 gint64;
2059 ${glib_extension}typedef unsigned $gint64 guint64;
2060
2061 #define G_GINT64_CONSTANT(val)  $gint64_constant
2062 _______EOF
2063
2064         if test x$gint64_format != x ; then
2065           cat >>$outfile <<_______EOF
2066 #define G_GINT64_MODIFIER $gint64_modifier
2067 #define G_GINT64_FORMAT $gint64_format
2068 #define G_GUINT64_FORMAT $guint64_format
2069 _______EOF
2070         else
2071           cat >>$outfile <<_______EOF
2072 #undef G_GINT64_MODIFIER
2073 #undef G_GINT64_FORMAT
2074 #undef G_GUINT64_FORMAT
2075 _______EOF
2076         fi
2077
2078         cat >>$outfile <<_______EOF
2079
2080 #define GLIB_SIZEOF_VOID_P $glib_void_p
2081 #define GLIB_SIZEOF_LONG   $glib_long
2082 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2083
2084 _______EOF
2085
2086         cat >>$outfile <<_______EOF
2087 typedef signed $glib_size_type_define gssize;
2088 typedef unsigned $glib_size_type_define gsize;
2089 #define G_GSIZE_MODIFIER $gsize_modifier
2090 #define G_GSSIZE_FORMAT $gssize_format
2091 #define G_GSIZE_FORMAT $gsize_format
2092 _______EOF
2093
2094         if test -z "$glib_unknown_void_p"; then
2095           cat >>$outfile <<_______EOF
2096
2097 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2098 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2099
2100 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2101 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2102 _______EOF
2103         else
2104           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2105         fi
2106
2107
2108
2109         cat >>$outfile <<_______EOF
2110 $glib_atexit
2111 $glib_memmove
2112 $glib_defines
2113 $glib_os
2114
2115 $glib_vacopy
2116
2117 #ifdef  __cplusplus
2118 #define G_HAVE_INLINE   1
2119 #else   /* !__cplusplus */
2120 $glib_inline
2121 #endif  /* !__cplusplus */
2122
2123 _______EOF
2124
2125         if test x$g_have_iso_c_varargs = xyes ; then
2126                 cat >>$outfile <<_______EOF
2127 #ifndef __cplusplus
2128 # define G_HAVE_ISO_VARARGS 1
2129 #endif
2130 _______EOF
2131         fi
2132         if test x$g_have_iso_cxx_varargs = xyes ; then
2133                 cat >>$outfile <<_______EOF
2134 #ifdef __cplusplus
2135 # define G_HAVE_ISO_VARARGS 1
2136 #endif
2137 _______EOF
2138         fi
2139         if test x$g_have_gnuc_varargs = xyes ; then
2140                 cat >>$outfile <<_______EOF
2141
2142 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2143  * is passed ISO vararg support is turned off, and there is no work
2144  * around to turn it on, so we unconditionally turn it off.
2145  */
2146 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2147 #  undef G_HAVE_ISO_VARARGS
2148 #endif
2149
2150 #define G_HAVE_GNUC_VARARGS 1
2151 _______EOF
2152         fi
2153
2154         case x$g_stack_grows in
2155         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2156         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2157         esac
2158
2159
2160         echo >>$outfile
2161         if test x$g_have_eilseq = xno; then
2162                 cat >>$outfile <<_______EOF
2163 #ifndef EILSEQ
2164 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
2165  * The correspondence between this and the corresponding definition
2166  * in libiconv is essential.
2167  */
2168 #  define EILSEQ ENOENT
2169 #endif
2170 _______EOF
2171
2172         fi
2173
2174         echo >>$outfile
2175         if test x$g_mutex_has_default = xyes; then
2176                 cat >>$outfile <<_______EOF
2177 $g_enable_threads_def G_THREADS_ENABLED
2178 #define G_THREADS_IMPL_$g_threads_impl_def
2179 typedef struct _GStaticMutex GStaticMutex;
2180 struct _GStaticMutex
2181 {
2182   struct _GMutex *runtime_mutex;
2183   union {
2184     char   pad[[$g_mutex_sizeof]];
2185     double dummy_double;
2186     void  *dummy_pointer;
2187     long   dummy_long;
2188   } static_mutex;
2189 };
2190 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
2191 #define g_static_mutex_get_mutex(mutex) \\
2192   (g_thread_use_default_impl ? ((GMutex*) &((mutex)->static_mutex)) : \\
2193    g_static_mutex_get_mutex_impl_shortcut (&((mutex)->runtime_mutex)))
2194 _______EOF
2195         else
2196                 cat >>$outfile <<_______EOF
2197 $g_enable_threads_def G_THREADS_ENABLED
2198 #define G_THREADS_IMPL_$g_threads_impl_def
2199 typedef struct _GMutex* GStaticMutex;
2200 #define G_STATIC_MUTEX_INIT NULL
2201 #define g_static_mutex_get_mutex(mutex) \\
2202   (g_static_mutex_get_mutex_impl_shortcut (mutex))
2203 _______EOF
2204         fi
2205
2206         if test x$g_use_double_checked_locking = xyes; then
2207                 cat >>$outfile <<_______EOF
2208 /* double checked locking can be used on this platform */
2209 #define g_once(once, func, arg) \\
2210   ((once)->status == G_ONCE_STATUS_READY ? (once)->retval : \\
2211    g_once_impl (once, func, arg))
2212 #define g_static_mutex_get_mutex_impl_shortcut(mutex) \\
2213   (*(mutex) ? *(mutex) : g_static_mutex_get_mutex_impl (mutex))
2214 _______EOF
2215         else
2216                 cat >>$outfile <<_______EOF
2217 /* double checked locking is unsafe to use on this platform, do full locking */
2218 #define g_once(once, func, arg) (g_once_impl(once, func, arg))
2219 #define g_static_mutex_get_mutex_impl_shortcut(mutex) \\
2220   (g_static_mutex_get_mutex_impl (mutex))
2221 _______EOF
2222 fi
2223
2224         cat >>$outfile <<_______EOF
2225 /* This represents a system thread as used by the implementation. An
2226  * alien implementaion, as loaded by g_thread_init can only count on
2227  * "sizeof (gpointer)" bytes to store their info. We however need more
2228  * for some of our native implementations. */
2229 typedef union _GSystemThread GSystemThread;
2230 union _GSystemThread
2231 {
2232   char   data[[$g_system_thread_sizeof]];
2233   double dummy_double;
2234   void  *dummy_pointer;
2235   long   dummy_long;
2236 };
2237 _______EOF
2238
2239         echo >>$outfile
2240         g_bit_sizes="16 32 64"
2241         for bits in $g_bit_sizes; do
2242           cat >>$outfile <<_______EOF
2243 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
2244 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
2245 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
2246 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
2247 _______EOF
2248         done
2249
2250         cat >>$outfile <<_______EOF
2251 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
2252 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
2253 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
2254 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
2255 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
2256 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
2257 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
2258 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
2259 #define G_BYTE_ORDER $g_byte_order
2260
2261 #define GLIB_SYSDEF_POLLIN =$g_pollin
2262 #define GLIB_SYSDEF_POLLOUT =$g_pollout
2263 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
2264 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
2265 #define GLIB_SYSDEF_POLLERR =$g_pollerr
2266 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
2267
2268 #define G_MODULE_SUFFIX "$g_module_suffix"
2269
2270 G_END_DECLS
2271
2272 #endif /* GLIBCONFIG_H */
2273 _______EOF
2274
2275
2276         if cmp -s $outfile glibconfig.h; then
2277           AC_MSG_NOTICE([glibconfig.h is unchanged])
2278           rm -f $outfile
2279         else
2280           mv $outfile glibconfig.h
2281         fi
2282 ],[
2283
2284 # Note that if two cases are the same, case goes with the first one.
2285 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
2286 # on variable expansion in case labels.  Look at the generated config.status
2287 # for a hint.
2288
2289 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
2290   glib_header_alloca_h="$ac_cv_working_alloca_h"
2291 else
2292   glib_header_alloca_h="$ac_cv_header_alloca_h"
2293 fi
2294
2295 case xyes in
2296 x$ac_cv_header_float_h)
2297   glib_float_h=yes
2298   glib_mf=FLT_MIN glib_Mf=FLT_MAX
2299   glib_md=DBL_MIN glib_Md=DBL_MAX
2300   ;;
2301 x$ac_cv_header_values_h)
2302   glib_values_h=yes
2303   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
2304   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
2305   ;;
2306 esac
2307
2308 case xyes in
2309 x$ac_cv_header_limits_h)
2310   glib_limits_h=yes
2311   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
2312   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
2313   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
2314   ;;
2315 x$ac_cv_header_values_h)
2316   glib_values_h=yes
2317   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
2318   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
2319   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
2320   ;;
2321 esac
2322
2323 if test x$ac_cv_header_sys_poll_h = xyes ; then
2324   glib_sys_poll_h=yes
2325 fi
2326
2327 case 2 in
2328 $ac_cv_sizeof_short)
2329   gint16=short
2330   gint16_modifier='"h"'
2331   gint16_format='"hi"'
2332   guint16_format='"hu"'
2333   ;;
2334 $ac_cv_sizeof_int)
2335   gint16=int
2336   gint16_modifier='""'
2337   gint16_format='"i"'
2338   guint16_format='"u"'
2339   ;;
2340 esac
2341 case 4 in
2342 $ac_cv_sizeof_short)
2343   gint32=short
2344   gint32_modifier='"h"'
2345   gint32_format='"hi"'
2346   guint32_format='"hu"'
2347   ;;
2348 $ac_cv_sizeof_int)
2349   gint32=int
2350   gint32_modifier='""'
2351   gint32_format='"i"'
2352   guint32_format='"u"'
2353   ;;
2354 $ac_cv_sizeof_long)
2355   gint32=long
2356   gint32_modifier='"l"'
2357   gint32_format='"li"'
2358   guint32_format='"lu"'
2359   ;;
2360 esac
2361 case 8 in
2362 $ac_cv_sizeof_int)
2363   gint64=int
2364   gint64_modifier='""'
2365   gint64_format='"i"'
2366   guint64_format='"u"'
2367   glib_extension=
2368   gint64_constant='(val)'
2369   ;;
2370 $ac_cv_sizeof_long)
2371   gint64=long
2372   gint64_modifier='"l"'
2373   gint64_format='"li"'
2374   guint64_format='"lu"'
2375   glib_extension=
2376   gint64_constant='(val##L)'
2377   ;;
2378 $ac_cv_sizeof_long_long)
2379   gint64='long long'
2380   if test -n "$glib_cv_long_long_format"; then
2381     gint64_modifier='"'$glib_cv_long_long_format'"'
2382     gint64_format='"'$glib_cv_long_long_format'i"'
2383     guint64_format='"'$glib_cv_long_long_format'u"'
2384   fi
2385   glib_extension='G_GNUC_EXTENSION '
2386   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
2387   ;;
2388 $ac_cv_sizeof___int64)
2389   gint64='__int64'
2390   if test -n "$glib_cv_long_long_format"; then
2391     gint64_modifier='"'$glib_cv_long_long_format'"'
2392     gint64_format='"'$glib_cv_long_long_format'i"'
2393     guint64_format='"'$glib_cv_long_long_format'u"'
2394   fi
2395   glib_extension=
2396   gint64_constant='(val##i64)'
2397   ;;
2398 esac
2399 glib_size_t=$ac_cv_sizeof_size_t
2400 glib_size_type_define=$glib_size_type
2401 glib_void_p=$ac_cv_sizeof_long
2402 glib_long=$ac_cv_sizeof_void_p
2403
2404 case $glib_size_type in
2405 short)
2406   gsize_modifier='"h"'
2407   gsize_format='"hu"'
2408   gssize_format='"hi"'
2409   ;;
2410 int)
2411   gsize_modifier='""'
2412   gsize_format='"u"'
2413   gssize_format='"i"'
2414   ;;
2415 long)
2416   gsize_modifier='"l"'
2417   gsize_format='"lu"'
2418   gssize_format='"li"'
2419   ;;
2420 esac
2421
2422 gintbits=`expr $ac_cv_sizeof_int \* 8`
2423 glongbits=`expr $ac_cv_sizeof_long \* 8`
2424
2425
2426 case $ac_cv_sizeof_void_p in
2427 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
2428 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
2429 *)                      glib_unknown_void_p=yes ;;
2430 esac
2431
2432
2433 case xyes in
2434 x$ac_cv_func_atexit)
2435   glib_atexit="
2436 #ifdef NeXT /* @#%@! NeXTStep */
2437 # define g_ATEXIT(proc) (!atexit (proc))
2438 #else
2439 # define g_ATEXIT(proc) (atexit (proc))
2440 #endif"
2441   ;;
2442 x$ac_cv_func_on_exit)
2443   glib_atexit="
2444 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
2445   ;;
2446 esac
2447
2448 case xyes in
2449 x$ac_cv_func_memmove)
2450   glib_memmove='
2451 #define g_memmove(d,s,n) G_STMT_START { memmove ((d), (s), (n)); } G_STMT_END'
2452   ;;
2453 x$glib_cv_working_bcopy)
2454   glib_memmove="
2455 /* memmove isn't available, but bcopy can copy overlapping memory regions */
2456 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
2457   ;;
2458 *)
2459   glib_memmove="
2460 /* memmove isn't found and bcopy can't copy overlapping memory regions,
2461  * so we have to roll our own copy routine. */
2462 void g_memmove (void* dest, const void * src, unsigned long len);"
2463   ;;
2464 esac
2465
2466 glib_defines="
2467 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
2468 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
2469 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
2470 "
2471
2472 case xyes in
2473 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
2474 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
2475 *)                      glib_vacopy=''
2476 esac
2477
2478 if test x$glib_cv_va_val_copy = xno; then
2479   glib_vacopy="\$glib_vacopy
2480 #define G_VA_COPY_AS_ARRAY 1"
2481 fi
2482
2483 if test x$glib_cv_hasinline = xyes; then
2484     glib_inline='#define G_HAVE_INLINE 1'
2485 fi
2486 if test x$glib_cv_has__inline = xyes; then
2487     glib_inline="\$glib_inline
2488 #define G_HAVE___INLINE 1"
2489 fi
2490 if test x$glib_cv_has__inline__ = xyes; then
2491     glib_inline="\$glib_inline
2492 #define G_HAVE___INLINE__ 1"
2493 fi
2494
2495 g_have_gnuc_varargs=$g_have_gnuc_varargs
2496 g_have_iso_c_varargs=$g_have_iso_c_varargs
2497 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
2498
2499 case xyes in
2500 x$ac_cv_c_bigendian)
2501   g_byte_order=G_BIG_ENDIAN
2502   g_bs_native=BE
2503   g_bs_alien=LE
2504   ;;
2505 *)
2506   g_byte_order=G_LITTLE_ENDIAN
2507   g_bs_native=LE
2508   g_bs_alien=BE
2509   ;;
2510 esac
2511
2512 g_pollin=$glib_cv_value_POLLIN
2513 g_pollout=$glib_cv_value_POLLOUT
2514 g_pollpri=$glib_cv_value_POLLPRI
2515 g_pollhup=$glib_cv_value_POLLHUP
2516 g_pollerr=$glib_cv_value_POLLERR
2517 g_pollnval=$glib_cv_value_POLLNVAL
2518
2519 g_stack_grows=$glib_cv_stack_grows
2520
2521 g_have_eilseq=$have_eilseq
2522
2523 case x$have_threads in
2524 xno)    g_enable_threads_def="#undef";;
2525 *)      g_enable_threads_def="#define";;
2526 esac
2527
2528 g_threads_impl_def=$g_threads_impl
2529 g_use_double_checked_locking=$g_use_double_checked_locking
2530
2531 g_mutex_has_default="$mutex_has_default"
2532 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
2533 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
2534 g_mutex_contents="$glib_cv_byte_contents_gmutex"
2535
2536 g_module_suffix="$glib_gmodule_suffix"
2537
2538 case $host in
2539   *-*-beos*)
2540     glib_os="#define G_OS_BEOS"
2541     ;;
2542   *-*-cygwin*)
2543     glib_os="#define G_OS_UNIX
2544 #define G_PLATFORM_WIN32
2545 #define G_WITH_CYGWIN"
2546     ;;
2547   *-*-mingw*)
2548     glib_os="#define G_OS_WIN32
2549 #define G_PLATFORM_WIN32"
2550     ;;
2551   *)
2552     glib_os="#define G_OS_UNIX"
2553     ;;
2554 esac
2555 ])
2556
2557 AC_CONFIG_FILES([
2558 glib-2.0.pc
2559 glib-2.0-uninstalled.pc
2560 gmodule-2.0.pc
2561 gmodule-2.0-uninstalled.pc
2562 gthread-2.0.pc
2563 gthread-2.0-uninstalled.pc
2564 gobject-2.0.pc
2565 gobject-2.0-uninstalled.pc
2566 glib-zip
2567 glib-gettextize
2568 Makefile
2569 build/Makefile
2570 build/win32/Makefile
2571 build/win32/dirent/Makefile
2572 glib/Makefile
2573 glib/libcharset/Makefile
2574 glib/gnulib/Makefile
2575 gmodule/Makefile
2576 gmodule/gmoduleconf.h
2577 gobject/Makefile
2578 gobject/glib-mkenums
2579 gthread/Makefile
2580 po/Makefile.in
2581 docs/Makefile
2582 docs/reference/Makefile
2583 docs/reference/glib/Makefile
2584 docs/reference/glib/version.xml
2585 docs/reference/gobject/Makefile
2586 docs/reference/gobject/version.xml
2587 tests/Makefile
2588 tests/gobject/Makefile
2589 m4macros/Makefile
2590 ])
2591
2592 AC_CONFIG_COMMANDS([chmod-scripts],
2593 [chmod 0755 glib-zip
2594 chmod 0755 glib-gettextize
2595 chmod 0755 gobject/glib-mkenums])
2596
2597 # we want to invoke this macro solely so that the config.status script
2598 # and automake generated makefiles know about these generated files.
2599 # They are only needed to distcheck the package
2600 if false; then
2601   AC_CONFIG_FILES([
2602     INSTALL
2603     README
2604     config.h.win32
2605     glibconfig.h.win32
2606     glib/makefile.mingw
2607     glib/makefile.msc
2608     glib/glib.rc
2609     gmodule/makefile.mingw
2610     gmodule/makefile.msc
2611     gmodule/gmodule.rc
2612     gobject/makefile.mingw
2613     gobject/makefile.msc
2614     gobject/gobject.rc
2615     gthread/makefile.mingw
2616     gthread/makefile.msc
2617     gthread/gthread.rc
2618     tests/makefile.mingw
2619     tests/makefile.msc
2620   ])
2621 fi
2622
2623 AC_OUTPUT