configure.in

   1 dnl ***********************************
   2 dnl *** include special GLib macros ***
   3 dnl ***********************************
   4 builtin(include, acglib.m4)dnl
   5
   6 # require autoconf 2.13
   7 AC_PREREQ(2.13)
   8
   9 # Process this file with autoconf to produce a configure script.
  10 AC_INIT(glist.c)
  11
  12 # Save this value here, since automake will set cflags later
  13 cflags_set=${CFLAGS+set}
  14
  15 # we rewrite this file
  16 rm -f glibconfig-sysdefs.h
  17
  18 GLIB_DIVERT_BEFORE_HELP([
  19 #
  20 # The following version number definitions apply to GLib, GModule, GObject and GThread
  21 # as a whole, so if changes occoured in any of them, they are all
  22 # treated with the same interface and binary age.
  23 #
  24 # Making releases:
  25 #   GLIB_MICRO_VERSION += 1;
  26 #   GLIB_INTERFACE_AGE += 1;
  27 #   GLIB_BINARY_AGE += 1;
  28 # if any functions have been added, set GLIB_INTERFACE_AGE to 0.
  29 # if backwards compatibility has been broken,
  30 # set GLIB_BINARY_AGE _and_ GLIB_INTERFACE_AGE to 0.
  31 #
  32 GLIB_MAJOR_VERSION=1
  33 GLIB_MINOR_VERSION=3
  34 GLIB_MICRO_VERSION=2
  35 GLIB_INTERFACE_AGE=0
  36 GLIB_BINARY_AGE=0
  37 GLIB_VERSION=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION.$GLIB_MICRO_VERSION
  38 ])dnl
  39
  40 AC_SUBST(GLIB_MAJOR_VERSION)
  41 AC_SUBST(GLIB_MINOR_VERSION)
  42 AC_SUBST(GLIB_MICRO_VERSION)
  43 AC_SUBST(GLIB_VERSION)
  44 AC_SUBST(GLIB_INTERFACE_AGE)
  45 AC_SUBST(GLIB_BINARY_AGE)
  46
  47 # libtool versioning
  48 LT_RELEASE=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION
  49 LT_CURRENT=`expr $GLIB_MICRO_VERSION - $GLIB_INTERFACE_AGE`
  50 LT_REVISION=$GLIB_INTERFACE_AGE
  51 LT_AGE=`expr $GLIB_BINARY_AGE - $GLIB_INTERFACE_AGE`
  52 AC_SUBST(LT_RELEASE)
  53 AC_SUBST(LT_CURRENT)
  54 AC_SUBST(LT_REVISION)
  55 AC_SUBST(LT_AGE)
  56
  57 VERSION=$GLIB_VERSION
  58 PACKAGE=glib
  59
  60 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  61
  62 # Specify a configuration file
  63 AM_CONFIG_HEADER(config.h)
  64
  65 AC_DEFINE_UNQUOTED(GLIB_MAJOR_VERSION, $GLIB_MAJOR_VERSION,
  66                    [Define to the GLIB major version])
  67 AC_DEFINE_UNQUOTED(GLIB_MINOR_VERSION, $GLIB_MINOR_VERSION,
  68                    [Define to the GLIB minor version])
  69 AC_DEFINE_UNQUOTED(GLIB_MICRO_VERSION, $GLIB_MICRO_VERSION,
  70                    [Define to the GLIB micro version])
  71 AC_DEFINE_UNQUOTED(GLIB_INTERFACE_AGE, $GLIB_INTERFACE_AGE,
  72                    [Define to the GLIB interface age])
  73 AC_DEFINE_UNQUOTED(GLIB_BINARY_AGE, $GLIB_BINARY_AGE,
  74                    [Define to the GLIB binary age])
  75
  76 dnl Initialize maintainer mode
  77 AM_MAINTAINER_MODE
  78
  79 AC_CANONICAL_HOST
  80
  81 AC_MSG_CHECKING(for the BeOS)
  82 case $host in
  83   *-*-beos*)
  84     glib_native_beos="yes"
  85     ;;
  86   *)
  87     glib_native_beos="no"
  88     ;;
  89 esac
  90 AC_MSG_RESULT([$glib_native_beos])
  91
  92 dnl
  93
  94 GLIB_DIVERT_BEFORE_HELP([
  95 # figure debugging default, prior to $ac_help setup
  96 if test `expr $GLIB_MINOR_VERSION \% 2` = 1 ; then
  97   debug_default=yes
  98 else
  99   debug_default=minimum
 100 fi[]dnl
 101 ])
 102
 103 dnl declare --enable-* args and collect ac_help strings
 104 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=$debug_default]],,enable_debug=$debug_default)
 105 AC_ARG_ENABLE(msg-prefix, [  --enable-msg-prefix     turn on program name and PID prefixing of messages and warnings],,enable_msg_prefix=no)
 106 AC_ARG_ENABLE(mem_check, [  --enable-mem-check      turn on malloc/free sanity checking [default=no]],,enable_mem_check=no)
 107 AC_ARG_ENABLE(mem_profile, [  --enable-mem-profile    turn on malloc profiling atexit [default=no]],,enable_mem_profile=no)
 108 AC_ARG_ENABLE(gc_friendly, [  --enable-gc-friendly    turn on garbage collector friendliness [default=no]],,enable_gc_friendly=no)
 109 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
 110                     , enable_ansi=no)
 111 AC_ARG_ENABLE(threads, [  --enable-threads        turn on basic thread support [default=yes]
 112                           ([=no] will override --with-threads)],,enable_threads=yes)
 113
 114 if test "x$enable_threads" != "xyes"; then
 115   enable_threads=no
 116 fi
 117
 118 AC_MSG_CHECKING(whether to enable memory checking)
 119 if test "x$enable_mem_check" = "xyes"; then
 120   AC_DEFINE(ENABLE_MEM_CHECK, 1, [Whether to enable memory checking])
 121   AC_SUBST(ENABLE_MEM_CHECK)
 122   AC_MSG_RESULT(yes)
 123 else
 124   AC_MSG_RESULT(no)
 125 fi
 126
 127 AC_MSG_CHECKING(whether to enable memory profiling)
 128 if test "x$enable_mem_profile" = "xyes"; then
 129   AC_DEFINE(ENABLE_MEM_PROFILE, 1, [Whether to enable memory profiling])
 130   AC_SUBST(ENABLE_MEM_PROFILE)
 131   AC_MSG_RESULT(yes)
 132 else
 133   AC_MSG_RESULT(no)
 134 fi
 135
 136 AC_MSG_CHECKING(whether to enable garbage collector friendliness)
 137 if test "x$enable_gc_friendly" = "xyes"; then
 138   AC_DEFINE(ENABLE_GC_FRIENDLY, 1, [Whether to enable GC friendliness])
 139   AC_SUBST(ENABLE_GC_FRIENDLY)
 140   AC_MSG_RESULT(yes)
 141 else
 142   AC_MSG_RESULT(no)
 143 fi
 144
 145 if test "x$enable_debug" = "xyes"; then
 146   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 147   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 148 else
 149   if test "x$enable_debug" = "xno"; then
 150     GLIB_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 151   fi
 152 fi
 153
 154 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 155         [Whether glib was compiled with debugging enabled])
 156
 157 if test "x$enable_msg_prefix" = "xyes"; then
 158   AC_DEFINE_UNQUOTED(G_ENABLE_MSG_PREFIX, 1,
 159                      [Enable prefixing of error messages with program names])
 160 fi
 161
 162 # Checks for programs.
 163 AC_PROG_CC
 164 AM_PROG_CC_STDC
 165 AC_PROG_INSTALL
 166
 167 dnl Initialize libtool
 168 AM_PROG_LIBTOOL
 169
 170 if test "x$GCC" = "xyes"; then
 171   case " $CFLAGS " in
 172   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 173   *) CFLAGS="$CFLAGS -Wall" ;;
 174   esac
 175
 176   if test "x$enable_ansi" = "xyes"; then
 177     case " $CFLAGS " in
 178     *[[\ \      ]]-ansi[[\ \    ]]*) ;;
 179     *) CFLAGS="$CFLAGS -ansi" ;;
 180     esac
 181
 182     case " $CFLAGS " in
 183     *[[\ \      ]]-pedantic[[\ \        ]]*) ;;
 184     *) CFLAGS="$CFLAGS -pedantic" ;;
 185     esac
 186   fi
 187 fi
 188
 189 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 190 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 191 glib_save_LIBS=$LIBS
 192 LIBS="$LIBS -lm"
 193 AC_TRY_RUN([#include <math.h>
 194              int main (void) { return (log(1) != log(1.)); }],
 195      AC_MSG_RESULT(none needed),
 196      glib_save_CFLAGS=$CFLAGS
 197      CFLAGS="$CFLAGS -std1"
 198      AC_TRY_RUN([#include <math.h>
 199                  int main (void) { return (log(1) != log(1.)); }],
 200          AC_MSG_RESULT(-std1),
 201          AC_MSG_RESULT()
 202          CFLAGS=$glib_save_CFLAGS
 203          AC_MSG_WARN(
 204                 [No ANSI prototypes found in library. (-std1 didn't work.)])
 205      )
 206 )
 207 LIBS=$glib_save_LIBS
 208
 209 dnl NeXTStep cc seems to need this
 210 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 211 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 212   AC_MSG_RESULT(none needed),
 213   glib_save_CFLAGS=$CFLAGS
 214   CFLAGS="$CFLAGS -posix"
 215   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 216     AC_MSG_RESULT(-posix),
 217     AC_MSG_RESULT()
 218     CFLAGS=$glib_save_CFLAGS
 219     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 220
 221 # Checks for header files.
 222 AC_HEADER_STDC
 223
 224 # Checks for library functions.
 225 AC_FUNC_VPRINTF
 226
 227 AC_FUNC_ALLOCA
 228
 229 AC_CHECK_FUNCS(atexit on_exit)
 230
 231 AC_CHECK_SIZEOF(char)
 232 AC_CHECK_SIZEOF(short)
 233 AC_CHECK_SIZEOF(long)
 234 AC_CHECK_SIZEOF(int)
 235 AC_CHECK_SIZEOF(void *)
 236 AC_CHECK_SIZEOF(long long)
 237
 238 if test x$ac_cv_sizeof_long_long = x8; then
 239         # long long is a 64 bit integer.
 240         AC_MSG_CHECKING(for format to printf and scanf a gint64)
 241         AC_CACHE_VAL(glib_cv_long_long_format,[
 242                 for format in ll q; do
 243                   AC_TRY_RUN([#include <stdio.h>
 244                         int main()
 245                         {
 246                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 247                           char buffer[1000];
 248                           sprintf (buffer, "%${format}u", a);
 249                           sscanf (buffer, "%${format}u", &b);
 250                           exit (b!=a);
 251                         }
 252                         ],
 253                         glib_cv_long_long_format=${format}
 254                         break)
 255                 done])
 256         if test -n "$glib_cv_long_long_format"; then
 257           AC_MSG_RESULT(%${glib_cv_long_long_format}i)
 258         else
 259           AC_MSG_RESULT(none)
 260         fi
 261 fi
 262
 263 dnl long doubles were not used, and a portability problem
 264 dnl AC_C_LONG_DOUBLE
 265 AC_C_CONST
 266
 267 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 268 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 269 dnl actually supported.
 270 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 271         AC_TRY_RUN([
 272         __inline int foo () { return 0; }
 273         int main () { return foo (); }
 274         ],
 275         glib_cv_has__inline=yes
 276         ,
 277         glib_cv_has__inline=no
 278         ,)
 279 ])
 280 case x$glib_cv_has__inline in
 281 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 282 esac
 283 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 284         AC_TRY_RUN([
 285         __inline__ int foo () { return 0; }
 286         int main () { return foo (); }
 287         ],
 288         glib_cv_has__inline__=yes
 289         ,
 290         glib_cv_has__inline__=no
 291         ,)
 292 ])
 293 case x$glib_cv_has__inline__ in
 294 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 295 esac
 296 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 297         AC_TRY_RUN([
 298         inline int foo () { return 0; }
 299         int main () { return foo (); }
 300         ],
 301         glib_cv_hasinline=yes
 302         ,
 303         glib_cv_hasinline=no
 304         ,)
 305 ])
 306 case x$glib_cv_hasinline in
 307 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 308 esac
 309
 310 # check for bytesex stuff
 311 AC_C_BIGENDIAN
 312
 313 # check for header files
 314 AC_CHECK_HEADERS([float.h limits.h pwd.h sys/param.h sys/poll.h sys/select.h])
 315 AC_CHECK_HEADERS([sys/time.h sys/times.h unistd.h values.h stdint.h])
 316
 317 AC_MSG_CHECKING(whether make is GNU Make)
 318 STRIP_BEGIN=
 319 STRIP_END=
 320 if $ac_make --version 2>/dev/null | grep '^GNU Make ' >/dev/null ; then
 321         STRIP_BEGIN='$(strip $(STRIP_DUMMY)'
 322         STRIP_END=')'
 323         AC_MSG_RESULT(yes)
 324 else
 325         AC_MSG_RESULT(no)
 326 fi
 327 STRIP_DUMMY=
 328 AC_SUBST(STRIP_DUMMY)
 329 AC_SUBST(STRIP_BEGIN)
 330 AC_SUBST(STRIP_END)
 331
 332 # check additional type sizes
 333 size_includes=["
 334 #include <stdarg.h>
 335 #include <stdio.h>
 336 #include <ctype.h>
 337 #include <string.h>
 338 "]
 339 if test "x$ac_cv_header_stdint_h" = "xyes"; then
 340   size_includes=["$size_includes
 341 #include <stdint.h>
 342 "]
 343 fi
 344 if test "x$ac_cv_header_unistd_h" = "xyes"; then
 345   size_includes=["$size_includes
 346 #include <unistd.h>
 347 "]
 348 fi
 349 GLIB_SIZEOF([$size_includes], size_t, size_t)
 350 GLIB_SIZEOF([$size_includes], ptrdiff_t, ptrdiff_t)
 351 GLIB_SIZEOF([$size_includes], intmax_t, intmax_t)
 352
 353 # Check for some functions
 354 AC_CHECK_FUNCS(lstat strerror strsignal memmove mkstemp vsnprintf strcasecmp strncasecmp poll getcwd)
 355
 356 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
 357 # The check is borrowed from the PERL Configure script.
 358 if test "$ac_cv_func_memmove" != "yes"; then
 359   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
 360     glib_cv_working_bcopy,[AC_TRY_RUN([
 361       int main() {
 362         char buf[128], abc[128], *b;
 363         int len, off, align;
 364         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
 365         for (align = 7; align >= 0; align--) {
 366           for (len = 36; len; len--) {
 367             b = buf+align; bcopy(abc, b, len);
 368             for (off = 1; off <= len; off++) {
 369               bcopy(b, b+off, len); bcopy(b+off, b, len);
 370                 if (bcmp(b, abc, len)) return(1);
 371             }
 372           }
 373         }
 374         return(0);
 375       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
 376   if test "$glib_cv_working_bcopy" = "yes"; then
 377     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
 378   fi
 379 fi
 380
 381 # Check for sys_errlist
 382 AC_MSG_CHECKING(for sys_errlist)
 383 AC_TRY_LINK(, [
 384 extern char *sys_errlist[];
 385 extern int sys_nerr;
 386 sys_errlist[sys_nerr-1][0] = 0;
 387 ], glib_ok=yes, glib_ok=no)
 388 AC_MSG_RESULT($glib_ok)
 389 if test $glib_ok = no; then
 390     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
 391 fi
 392
 393 # Check for sys_siglist
 394 AC_MSG_CHECKING(for sys_siglist)
 395 AC_TRY_LINK(, [
 396 extern char *sys_siglist[];
 397 exit (sys_siglist[0]);
 398 ], glib_ok=yes, glib_ok=no)
 399 AC_MSG_RESULT($glib_ok)
 400 if test $glib_ok = no; then
 401     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
 402 fi
 403
 404 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
 405 AC_MSG_CHECKING(for sys_siglist declaration)
 406 AC_TRY_COMPILE([#include <signal.h>], [
 407 strlen (sys_siglist[0]);
 408 ], glib_ok=yes, glib_ok=no)
 409 AC_MSG_RESULT($glib_ok)
 410 if test $glib_ok = no; then
 411     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
 412 fi
 413
 414 # Check if <sys/select.h> needs to be included for fd_set
 415 AC_MSG_CHECKING([for fd_set])
 416 AC_TRY_COMPILE([#include <sys/types.h>],
 417         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 418 if test $gtk_ok = yes; then
 419     AC_MSG_RESULT([yes, found in sys/types.h])
 420 else
 421     AC_HEADER_EGREP(fd_set, sys/select.h, gtk_ok=yes)
 422     if test $gtk_ok = yes; then
 423         # *** FIXME: give it a different name
 424         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
 425         AC_MSG_RESULT([yes, found in sys/select.h])
 426     else
 427         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
 428         AC_MSG_RESULT(no)
 429     fi
 430 fi
 431
 432 dnl *** check for sane realloc() ***
 433 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
 434         AC_TRY_RUN([
 435         #include <stdlib.h>
 436         int main() {
 437           return realloc (0, sizeof (int)) == 0;
 438         }],
 439         [glib_cv_sane_realloc=yes],
 440         [glib_cv_sane_realloc=no],
 441         [])
 442 ])
 443 if test x$glib_cv_sane_realloc = xyes; then
 444   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
 445 fi
 446
 447 dnl Check for nl_langinfo and CODESET
 448
 449 AC_MSG_CHECKING([for nl_langinfo (CODESET)])
 450 AC_TRY_COMPILE([#include <langinfo.h>],
 451         [char *codeset = nl_langinfo (CODESET);],
 452    AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
 453    have_codeset=yes,
 454    have_codeset=no)
 455 AC_MSG_RESULT($have_codeset)
 456
 457
 458 dnl ****************************************
 459 dnl *** strlcpy/strlcat                  ***
 460 dnl ****************************************
 461 # Check for strlcpy
 462 AC_MSG_CHECKING(for strlcpy/strlcat)
 463 AC_TRY_LINK([#include <stdlib.h>
 464 #include <string.h>], [
 465 char *p = malloc(10);
 466 (void) strlcpy(p, "hi", 10);
 467 (void) strlcat(p, "bye", 10);
 468 ], glib_ok=yes, glib_ok=no)
 469 AC_MSG_RESULT($glib_ok)
 470 if test $glib_ok = yes; then
 471     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
 472 fi
 473
 474
 475 dnl **********************
 476 dnl *** va_copy checks ***
 477 dnl **********************
 478 dnl we currently check for all three va_copy possibilities, so we get
 479 dnl all results in config.log for bug reports.
 480 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
 481         AC_TRY_RUN([
 482         #include <stdarg.h>
 483         void f (int i, ...) {
 484         va_list args1, args2;
 485         va_start (args1, i);
 486         va_copy (args2, args1);
 487         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 488           exit (1);
 489         va_end (args1); va_end (args2);
 490         }
 491         int main() {
 492           f (0, 42);
 493           return 0;
 494         }],
 495         [glib_cv_va_copy=yes],
 496         [glib_cv_va_copy=no],
 497         [])
 498 ])
 499 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
 500         AC_TRY_RUN([
 501         #include <stdarg.h>
 502         void f (int i, ...) {
 503         va_list args1, args2;
 504         va_start (args1, i);
 505         __va_copy (args2, args1);
 506         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 507           exit (1);
 508         va_end (args1); va_end (args2);
 509         }
 510         int main() {
 511           f (0, 42);
 512           return 0;
 513         }],
 514         [glib_cv___va_copy=yes],
 515         [glib_cv___va_copy=no],
 516         [])
 517 ])
 518
 519 if test "x$glib_cv_va_copy" = "xyes"; then
 520   g_va_copy_func=va_copy
 521 else if test "x$glib_cv___va_copy" = "xyes"; then
 522   g_va_copy_func=__va_copy
 523 fi
 524 fi
 525
 526 if test -n "$g_va_copy_func"; then
 527   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
 528 fi
 529
 530 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
 531         AC_TRY_RUN([
 532         #include <stdarg.h>
 533         void f (int i, ...) {
 534         va_list args1, args2;
 535         va_start (args1, i);
 536         args2 = args1;
 537         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 538           exit (1);
 539         va_end (args1); va_end (args2);
 540         }
 541         int main() {
 542           f (0, 42);
 543           return 0;
 544         }],
 545         [glib_cv_va_val_copy=yes],
 546         [glib_cv_va_val_copy=no],
 547         [])
 548 ])
 549
 550 if test "x$glib_cv_va_val_copy" = "xno"; then
 551   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 552 fi
 553
 554 dnl ***********************
 555 dnl *** g_module checks ***
 556 dnl ***********************
 557 G_MODULE_LIBS=
 558 G_MODULE_LIBS_EXTRA=
 559 G_MODULE_PLUGIN_LIBS=
 560 G_MODULE_LDFLAGS=
 561 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
 562 G_MODULE_NEED_USCORE=0
 563 G_MODULE_HAVE_DLERROR=0
 564 dnl *** dlopen() and dlsym() in system libraries
 565 if test -z "$G_MODULE_IMPL"; then
 566         AC_CHECK_FUNC(dlopen,
 567                       [AC_CHECK_FUNC(dlsym,
 568                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
 569                       [])
 570 fi
 571 dnl *** load_image (BeOS)
 572 if test -z "$G_MODULE_IMPL" -a "x$glib_native_beos" = "xyes"; then
 573   AC_CHECK_LIB(root, load_image,
 574       [G_MODULE_LIBS="-lbe -lroot -lglib"
 575       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
 576       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
 577       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
 578       [])
 579 fi
 580 # *** dlopen() and dlsym() in libdl
 581 if test -z "$G_MODULE_IMPL"; then
 582         AC_CHECK_LIB(dl, dlopen,
 583                      [AC_CHECK_LIB(dl, dlsym,
 584                                    [G_MODULE_LIBS=-ldl
 585                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
 586                      [])
 587 fi
 588 dnl *** shl_load() in libdld (HP-UX)
 589 if test -z "$G_MODULE_IMPL"; then
 590         AC_MSG_CHECKING(how to export all symbols)
 591         SAVED_LDFLAGS=$LDFLAGS
 592         LDFLAGS="$LDFLAGS -Wl,-E"
 593         AC_TRY_LINK(,[ return 0; ],
 594                 [ G_MODULE_LDFLAGS="-Wl,-E" ],[
 595                 LDFLAGS="$SAVED_LDFLAGS -bexpall"
 596                 AC_TRY_LINK(,[ return 0; ],
 597                         [G_MODULE_LDFLAGS="-bexpall"],
 598                         [G_MODULE_LDFLAGS="none"])
 599         ])
 600         LDFLAGS=$SAVED_LDFLAGS
 601         AC_MSG_RESULT($G_MODULE_LDFLAGS)
 602         if test "x$G_MODULE_LDFLAGS" = "xnone"; then
 603                 G_MODULE_LDFLAGS=
 604         fi
 605         AC_CHECK_LIB(dld, shl_load,
 606                 [G_MODULE_LIBS=-ldld
 607                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
 608                 [])
 609 fi
 610 dnl *** additional checks for G_MODULE_IMPL_DL
 611 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
 612         case "$host_os" in
 613           linux*)
 614             G_MODULE_LDFLAGS='-rdynamic'
 615             ;;
 616         esac
 617         LIBS_orig="$LIBS"
 618         LDFLAGS_orig="$LDFLAGS"
 619         LIBS="$LIBS $G_MODULE_LIBS"
 620         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
 621 dnl *** check whether we need preceeding underscores
 622         AC_CACHE_CHECK([for preceeding underscore in symbols],
 623                 glib_cv_uscore,[
 624                 AC_TRY_RUN([
 625                 #include <dlfcn.h>
 626                 int glib_underscore_test (void) { return 42; }
 627                 int main() {
 628                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
 629                   handle = dlopen ((void*)0, 0);
 630                   if (handle) {
 631                     f1 = dlsym (handle, "glib_underscore_test");
 632                     f2 = dlsym (handle, "_glib_underscore_test");
 633                   } return (!f2 || f1);
 634                 }],
 635                         [glib_cv_uscore=yes],
 636                         [glib_cv_uscore=no],
 637                         [])
 638                 rm -f plugin.c plugin.o plugin.lo
 639         ])
 640         if test "x$glib_cv_uscore" = "xyes"; then
 641                 G_MODULE_NEED_USCORE=1
 642         else
 643                 G_MODULE_NEED_USCORE=0
 644         fi
 645
 646         LDFLAGS="$LDFLAGS_orig"
 647 dnl *** check for having dlerror()
 648         AC_CHECK_FUNC(dlerror,
 649                 [G_MODULE_HAVE_DLERROR=1],
 650                 [G_MODULE_HAVE_DLERROR=0])
 651         LIBS="$LIBS_orig"
 652 fi
 653 dnl *** done, have e got an implementation?
 654 if test -z "$G_MODULE_IMPL"; then
 655         G_MODULE_IMPL=0
 656 fi
 657 AC_SUBST(G_MODULE_IMPL)
 658 AC_SUBST(G_MODULE_LIBS)
 659 AC_SUBST(G_MODULE_LIBS_EXTRA)
 660 AC_SUBST(G_MODULE_PLUGIN_LIBS)
 661 AC_SUBST(G_MODULE_LDFLAGS)
 662 AC_SUBST(G_MODULE_HAVE_DLERROR)
 663 AC_SUBST(G_MODULE_NEED_USCORE)
 664 AC_SUBST(GLIB_DEBUG_FLAGS)
 665
 666
 667 dnl ***********************
 668 dnl *** g_thread checks ***
 669 dnl ***********************
 670
 671 AC_ARG_WITH(threads, [  --with-threads=[none/posix/dce/solaris] specify a thread implementation to use],
 672         if test "x$with_threads" = x; then
 673                 want_threads=yes
 674         else
 675                 want_threads=$with_threads
 676         fi,
 677         want_threads=yes)
 678 if test "x$enable_threads" = "xno"; then
 679         want_threads=no
 680 fi
 681 if test "x$want_threads" = "xnone"; then
 682         want_threads=no
 683 fi
 684
 685 dnl error and warning message
 686 dnl *************************
 687
 688 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
 689                 computer. GLib will not have a default thread implementation."
 690
 691 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
 692                 platform (normaly it's "_REENTRANT"). I'll not use any flag on
 693                 compilation now, but then your programs might not work.
 694                 Please provide information on how it is done on your system."
 695
 696 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
 697                 "
 698
 699 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
 700                 provide information on your thread implementation.
 701                 You can also run 'configure --disable-threads'
 702                 to compile without thread support."
 703
 704 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
 705                 functions will not be MT-safe during their first call because
 706                 there is no working 'getpwuid_r' on your system."
 707
 708 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
 709                 because there is no 'localtime_r' on your system."
 710
 711 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
 712                 crude surrogate will be used. If you happen to know a
 713                 yield function for your system, please inform the GLib
 714                 developers."
 715
 716 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
 717                 threads on your system. Thus threads can only have the default
 718                 priority. If you happen to know these main/max
 719                 priorities, please inform the GLib developers."
 720
 721
 722 dnl determination of thread implementation
 723 dnl ***************************************
 724
 725 have_threads=none
 726 if test "x$want_threads" = xyes || test "x$want_threads" = xsolaris; then
 727         case $host in
 728                 *-*-solaris*)
 729                 AC_CHECK_LIB(thread, cond_init, have_threads=solaris)
 730                 ;;
 731         esac
 732 fi
 733 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
 734                                 || test "x$want_threads" = xdce; then
 735         # -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
 736         # -U_OSF_SOURCE is for Digital UNIX 4.0d
 737         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
 738         glib_save_CPPFLAGS="$CPPFLAGS"
 739         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
 740         if test "x$have_threads" = xnone; then
 741                 AC_EGREP_HEADER([(^|[^a-zA-Z_])pthread_attr_init[^a-zA-Z_]],
 742                         pthread.h,
 743                         have_threads=posix)
 744         fi
 745         if test "x$have_threads" = xnone; then
 746                 AC_EGREP_HEADER([(^|[^a-zA-Z_])pthread_attr_create[^a-zA-Z_]],
 747                         pthread.h,
 748                         have_threads=dce)
 749         fi
 750         CPPFLAGS="$glib_save_CPPFLAGS"
 751 fi
 752
 753 AC_MSG_CHECKING(for thread implementation)
 754
 755 if test "x$have_threads" = xnone && test "x$want_threads" != xno; then
 756         AC_MSG_RESULT(none available)
 757         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
 758 else
 759         AC_MSG_RESULT($have_threads)
 760 fi
 761
 762
 763 dnl determination of G_THREAD_CFLAGS
 764 dnl ********************************
 765
 766 G_THREAD_LIBS=
 767 G_THREAD_LIBS_EXTRA=
 768 G_THREAD_CFLAGS=
 769
 770 if test x"$have_threads" != xnone; then
 771
 772     G_THREAD_CFLAGS="-D_REENTRANT" # good default guess
 773
 774     case $host in
 775         *-aix*)
 776                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 777                 if test x"$GCC" = xyes; then
 778                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -mthreads"
 779                 fi
 780                 ;;
 781         *-freebsd2.2*)
 782                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 783
 784                 # FreeBSD 2.2.x shiped with gcc 2.7.2.x, which doesn't support
 785                 # -mthreads flag.
 786                 ;;
 787         *-sysv5uw7*)  # UnixWare 7
 788                 if test "$GCC" != "yes"; then
 789                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -Kthread"
 790                 else
 791                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -pthread"
 792                 fi
 793                 ;;
 794     esac
 795
 796     # if we are not finding the ctime_r function, then we probably are
 797     # not using the proper multithread flag
 798
 799     glib_save_CPPFLAGS="$CPPFLAGS"
 800     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
 801
 802     # Note: Digital UNIX 4.0d #defines ctime_r to _Pctime_r for gcc.
 803     AC_EGREP_HEADER([[^a-zA-Z_](_P)?ctime_r[^a-zA-Z_]], time.h, ,
 804         AC_MSG_WARN($FLAG_DOES_NOT_WORK))
 805
 806     CPPFLAGS="$glib_save_CPPFLAGS"
 807
 808     AC_MSG_CHECKING(thread related cflags)
 809     AC_MSG_RESULT($G_THREAD_CFLAGS)
 810     CFLAGS="$CFLAGS $G_THREAD_CFLAGS"
 811 fi
 812
 813 dnl determination of G_THREAD_LIBS
 814 dnl ******************************
 815
 816 mutex_has_default=no
 817 case $have_threads in
 818         posix|dce)
 819            G_THREAD_LIBS=error
 820            glib_save_LIBS="$LIBS"
 821            case $host in
 822              *-sysv5uw7*) # UnixWare 7
 823                 if test "$GCC" != "yes"; then
 824                         G_THREAD_LIBS="-Kthread"
 825                 else
 826                         G_THREAD_LIBS="-pthread"
 827                 fi
 828                 ;;
 829              *)
 830                 for thread_lib in "" pthread pthreads c_r thread dce; do
 831                         if test x"$thread_lib" = x; then
 832                                 add_thread_lib=""
 833                                 IN=""
 834                         else
 835                                 add_thread_lib="-l$thread_lib"
 836                                 IN=" in -l$thread_lib"
 837                         fi
 838                         if test x"$have_threads" = xposix; then
 839                                 defattr=NULL
 840                         else
 841                                 defattr=pthread_attr_default
 842                         fi
 843
 844                         LIBS="$glib_save_LIBS $add_thread_lib"
 845
 846                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
 847                         AC_TRY_RUN([#include <pthread.h>
 848                                 int check_me = 0;
 849                                 void* func(void* data) {check_me = 42;}
 850                                 main()
 851                                 { pthread_t t;
 852                                   void *ret;
 853                                   pthread_create (&t, $defattr, func, NULL);
 854                                   pthread_join (t, &ret);
 855                                   exit (check_me != 42);
 856                                 }],
 857                                 [AC_MSG_RESULT(yes)
 858                                 G_THREAD_LIBS="$add_thread_lib"
 859                                 break],
 860                                 [AC_MSG_RESULT(no)])
 861                 done
 862                 if test "x$G_THREAD_LIBS" = xerror; then
 863                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
 864                 fi
 865                 for thread_lib in "" rt; do
 866                         if test x"$thread_lib" = x; then
 867                                 add_thread_lib=""
 868                                 IN=""
 869                         else
 870                                 add_thread_lib="-l$thread_lib"
 871                                 IN=" in -l$thread_lib"
 872                         fi
 873                         LIBS="$glib_save_LIBS $add_thread_lib"
 874
 875                         AC_MSG_CHECKING(for sched_get_priority_min$IN)
 876                         AC_TRY_RUN([#include <sched.h>
 877                                 #include <errno.h>
 878                                 int main() {
 879                                 errno = 0;
 880                                 return sched_get_priority_min(SCHED_OTHER)==-1
 881                                         && errno != 0;
 882                                 }],
 883                                 [AC_MSG_RESULT(yes)
 884                                 G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
 885                                 posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
 886                                 posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
 887                                 break],
 888                                 [AC_MSG_RESULT(no)])
 889                 done
 890                 LIBS="$glib_save_LIBS"
 891                 ;;
 892            esac
 893            mutex_has_default=yes
 894            mutex_default_type='pthread_mutex_t'
 895            mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
 896            mutex_header_file='pthread.h'
 897            if test "x$have_threads" = "xposix"; then
 898              g_threads_impl="POSIX"
 899            else
 900              g_threads_impl="DCE"
 901              have_threads="posix"
 902            fi
 903            AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
 904            ;;
 905         solaris)
 906            G_THREAD_LIBS=error
 907            AC_CHECK_LIB(thread, cond_init, G_THREAD_LIBS="-lthread")
 908            mutex_has_default=yes
 909            mutex_default_type='mutex_t'
 910            mutex_default_init="DEFAULTMUTEX"
 911            mutex_header_file='thread.h'
 912            g_threads_impl="SOLARIS"
 913            ;;
 914         none)
 915            g_threads_impl="NONE"
 916            ;;
 917         *)
 918            g_threads_impl="NONE"
 919            G_THREAD_LIBS=error
 920            ;;
 921 esac
 922
 923 if test "x$G_THREAD_LIBS" = xerror; then
 924         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
 925 fi
 926
 927 case $host in
 928   *-*-beos*)
 929     G_THREAD_LIBS="-lbe -lroot -lglib "
 930     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
 931     ;;
 932   *)
 933     ;;
 934 esac
 935
 936 AC_MSG_CHECKING(thread related libraries)
 937 AC_MSG_RESULT($G_THREAD_LIBS)
 938
 939 dnl check for mt safe function variants and some posix functions
 940 dnl ************************************************************
 941
 942 if test x"$have_threads" != xnone; then
 943         glib_save_LIBS="$LIBS"
 944         # we are not doing the following for now, as this might require glib
 945         # to always be linked with the thread libs on some platforms.
 946         # LIBS="$LIBS $G_THREAD_LIBS"
 947         AC_CHECK_FUNCS(localtime_r)
 948         if test "$ac_cv_header_pwd_h" = "yes"; then
 949                 AC_CACHE_CHECK([for getpwuid_r],ac_cv_func_getpwuid_r,
 950                         [AC_TRY_RUN([#include <errno.h>
 951                                 int main () { char buffer[10000], *pointer;
 952                                 char getpwuid_r (long, void*, void*,
 953                                         int, void*);
 954                                 int error;
 955                                 errno = 0;
 956                                 error = getpwuid_r (0, &buffer, &buffer,
 957                                         sizeof (buffer), &pointer);
 958                                 return errno == ENOSYS || error == ENOSYS;}],
 959                                 [ac_cv_func_getpwuid_r=yes],
 960                                 [ac_cv_func_getpwuid_r=no])])
 961                 if test "$ac_cv_func_getpwuid_r" = yes; then
 962                         AC_DEFINE(HAVE_GETPWUID_R,1,[Have function getpwuid_r])
 963                 fi
 964                 if test "$ac_cv_func_getpwuid_r" = "yes"; then
 965                         AC_MSG_CHECKING(whether getpwuid_r is posix like)
 966                         # The signature for the POSIX version is:
 967                         # int getpwuid_r(uid_t, struct passwd *, char *, size_t, struct passwd **)
 968                         AC_TRY_COMPILE([#include <pwd.h>
 969                                 #include <sys/types.h>
 970                                 #include <stdlib.h>],
 971                                 [getpwuid_r((uid_t)0, NULL, NULL, (size_t)0, NULL);],
 972                                 [AC_DEFINE(HAVE_GETPWUID_R_POSIX,1,
 973                                  [Function getpwuid_r has the POSIX signature])
 974                                 AC_MSG_RESULT(yes)],
 975                                 [AC_MSG_RESULT(no)])
 976                 fi
 977         fi
 978         LIBS="$LIBS $G_THREAD_LIBS"
 979         if test x"$have_threads" = xposix; then
 980                 glib_save_CPPFLAGS="$CPPFLAGS"
 981                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
 982                 GLIB_SIZEOF([#include <pthread.h>],
 983                         pthread_t,
 984                         system_thread)
 985                 # This is not AC_CHECK_FUNC to also work with function
 986                 # name mangling in header files.
 987                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
 988                 AC_TRY_LINK([#include <pthread.h>],
 989                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
 990                         [AC_MSG_RESULT(yes)
 991                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
 992                                   [Have function pthread_attr_setstacksize])],
 993                         [AC_MSG_RESULT(no)])
 994                 AC_MSG_CHECKING(for minimal/maximal thread priority)
 995                 if test x"$posix_priority_min" = xnone; then
 996                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
 997                                 PX_PRIO_MIN],,[
 998                                 posix_priority_min=PX_PRIO_MIN
 999                                 posix_priority_max=PX_PRIO_MAX])
1000                 fi
1001                 if test x"$posix_priority_min" = xnone; then
1002                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
1003                                 PRI_OTHER_MIN],,[
1004                                 posix_priority_min=PRI_OTHER_MIN
1005                                 posix_priority_max=PRI_OTHER_MAX])
1006                 fi
1007                 if test x"$posix_priority_min" = x; then
1008                         AC_MSG_RESULT(none found)
1009                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
1010                         posix_priority_min=-1
1011                         posix_priority_max=-1
1012                 else
1013                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
1014                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
1015                         AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])
1016                 fi
1017                 posix_yield_func=none
1018                 AC_MSG_CHECKING(for posix yield function)
1019                 for yield_func in sched_yield pthread_yield_np pthread_yield \
1020                                                         thr_yield; do
1021                         AC_TRY_LINK([#include <pthread.h>],
1022                                 [$yield_func()],
1023                                 [posix_yield_func="$yield_func"
1024                                 break])
1025                 done
1026                 if test x"$posix_yield_func" = xnone; then
1027                         AC_MSG_RESULT(none found)
1028                         AC_MSG_WARN($POSIX_NO_YIELD)
1029                         posix_yield_func="g_usleep(1000)"
1030                 else
1031                         AC_MSG_RESULT($posix_yield_func)
1032                         posix_yield_func="$posix_yield_func()"
1033                 fi
1034                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
1035                 CPPFLAGS="$glib_save_CPPFLAGS"
1036         else # solaris threads
1037                 GLIB_SIZEOF([#include <thread.h>],
1038                         thread_t,
1039                         system_thread)
1040         fi
1041
1042         LIBS="$glib_save_LIBS"
1043
1044         # now spit out all the warnings.
1045         if test "$ac_cv_func_getpwuid_r" != "yes"; then
1046                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
1047         fi
1048         if test "$ac_cv_func_localtime_r" != "yes"; then
1049                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
1050         fi
1051 else
1052         # If no thread implementation exists, we will provide enough
1053         # space for a pointer
1054         GLIB_SIZEOF(, void*, system_thread)
1055 fi
1056
1057 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
1058                    [Source file containing theread implementation])
1059 AC_SUBST(G_THREAD_CFLAGS)
1060 AC_SUBST(G_THREAD_LIBS)
1061 AC_SUBST(G_THREAD_LIBS_EXTRA)
1062
1063 dnl **********************************************
1064 dnl *** GDefaultMutex setup and initialization ***
1065 dnl **********************************************
1066 dnl
1067 dnl if mutex_has_default = yes, we also got
1068 dnl mutex_default_type, mutex_default_init and mutex_header_file
1069 GLIB_IF_VAR_EQ(mutex_has_default, yes,
1070         glib_save_CPPFLAGS="$CPPFLAGS"
1071         glib_save_LIBS="$LIBS"
1072         LIBS="$LIBS $G_THREAD_LIBS"
1073         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1074         GLIB_SIZEOF([#include <$mutex_header_file>],
1075                     $mutex_default_type,
1076                     gmutex,
1077                     )
1078         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
1079                            $mutex_default_type,
1080                            gmutex,
1081                            $glib_cv_sizeof_gmutex,
1082                            $mutex_default_init)
1083         if test x"$glib_cv_byte_contents_gmutex" = xno; then
1084                 mutex_has_default=no
1085         fi
1086         CPPFLAGS="$glib_save_CPPFLAGS"
1087         LIBS="$glib_save_LIBS"
1088         ,
1089 )
1090
1091
1092 dnl ****************************************
1093 dnl *** GLib POLL* compatibility defines ***
1094 dnl ****************************************
1095 GLIB_SYSDEFS(
1096 [#include <sys/types.h>
1097 #include <sys/poll.h>],
1098         POLLIN:1 POLLOUT:4 POLLPRI:2 POLLERR:8 POLLHUP:16 POLLNVAL:32,
1099         glibconfig-sysdefs.h,
1100         =)
1101
1102 dnl ***********************
1103 dnl *** Tests for iconv ***
1104 dnl ***********************
1105
1106 AC_ARG_WITH(libiconv, [ --with-libiconv     Use the libiconv library ],,with_libiconv=maybe)
1107
1108 found_iconv=no
1109
1110 if test "x$with_libiconv" != "xyes" ; then
1111    #
1112    # Check in the C library
1113    #
1114    AC_CHECK_FUNC(iconv_open, with_libiconv=no; found_iconv=yes)
1115 fi
1116
1117 if test "x$with_libiconv" != "xno" ; then
1118    #
1119    # Check for libiconv
1120    #
1121    AC_CHECK_LIB(iconv, libiconv_open, with_libiconv=yes; found_iconv=yes)
1122 fi
1123
1124 if test "x$found_iconv" = "xno" ; then
1125    AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
1126 fi
1127
1128 if test "x$with_libiconv" = "xyes" ; then
1129   ICONV_LIBS="-liconv"
1130   AC_DEFINE(USE_LIBICONV)
1131 fi
1132 AC_SUBST(ICONV_LIBS)
1133
1134 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
1135 dnl since we need it for g_iconv()
1136
1137 AC_MSG_CHECKING([for EILSEQ])
1138 AC_TRY_COMPILE([
1139 #include <errno.h>
1140 ],
1141 [
1142 int error = EILSEQ;
1143 ], have_eilseq=yes, have_eilseq=no);
1144 AC_MSG_RESULT($have_eilseq)
1145
1146 dnl **************************
1147 dnl *** Checks for gtk-doc ***
1148 dnl **************************
1149
1150 AC_ARG_WITH(html-dir, [  --with-html-dir=PATH path to installed docs ])
1151
1152 if test "x$with_html_dir" = "x" ; then
1153   HTML_DIR='${datadir}/gtk-doc/html'
1154 else
1155   HTML_DIR=$with_html_dir
1156 fi
1157
1158 AC_SUBST(HTML_DIR)
1159
1160
1161 AC_CHECK_PROG(GTKDOC, gtkdoc-mkdb, true, false)
1162 AM_CONDITIONAL(HAVE_GTK_DOC, $GTKDOC)
1163 AC_SUBST(HAVE_GTK_DOC)
1164
1165 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1166 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1167
1168 dnl Let people disable the gtk-doc stuff.
1169 AC_ARG_ENABLE(gtk-doc, [  --enable-gtk-doc  Use gtk-doc to build documentation [default=auto]], enable_gtk_doc="$enableval", enable_gtk_doc=auto)
1170
1171 if test x$enable_gtk_doc = xauto ; then
1172   if test x$GTKDOC = xtrue ; then
1173     enable_gtk_doc=yes
1174   else
1175     enable_gtk_doc=no
1176   fi
1177 fi
1178
1179 dnl NOTE: We need to use a separate automake conditional for this
1180 dnl       to make this work with the tarballs.
1181 AM_CONDITIONAL(ENABLE_GTK_DOC, test x$enable_gtk_doc = xyes)
1182
1183 dnl ******************************
1184 dnl *** output the whole stuff ***
1185 dnl ******************************
1186
1187 AC_OUTPUT_COMMANDS([
1188
1189 ## Generate `glibconfig.h' in two cases
1190 ## 1. `config.status' is run either explicitly, or via configure.
1191 ##     Esp. not when it is run in `Makefile' to generate makefiles and
1192 ##     config.h
1193 ## 2. CONFIG_OTHER is set explicitly
1194 ##
1195 ## Case 1 is difficult.  We know that `automake' sets one of
1196 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
1197 ## only when AM_CONFIG_HEADER is set, however.
1198
1199 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
1200   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
1201   CONFIG_OTHER=${CONFIG_OTHER:-glibconfig.h}
1202 fi
1203 case "$CONFIG_OTHER" in
1204 *glibconfig.h*)
1205         echo creating glibconfig.h
1206         outfile=glibconfig.h-tmp
1207         cat > $outfile <<\_______EOF
1208 /* glibconfig.h
1209  *
1210  * This is a generated file.  Please modify 'configure.in'
1211  */
1212
1213 #ifndef __G_LIBCONFIG_H__
1214 #define __G_LIBCONFIG_H__
1215
1216 #include <gmacros.h>
1217
1218 _______EOF
1219
1220         if test x$glib_limits_h = xyes; then
1221           echo '#include <limits.h>' >> $outfile
1222         fi
1223         if test x$glib_float_h = xyes; then
1224           echo '#include <float.h>' >> $outfile
1225         fi
1226         if test x$glib_values_h = xyes; then
1227           echo '#include <values.h>' >> $outfile
1228         fi
1229         if test "$glib_header_alloca_h" = "yes"; then
1230           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
1231         fi
1232         if test x$glib_sys_poll_h = xyes; then
1233           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
1234         fi
1235
1236         cat >> $outfile <<_______EOF
1237
1238 G_BEGIN_DECLS
1239
1240 #define G_MINFLOAT      $glib_mf
1241 #define G_MAXFLOAT      $glib_Mf
1242 #define G_MINDOUBLE     $glib_md
1243 #define G_MAXDOUBLE     $glib_Md
1244 #define G_MINSHORT      $glib_ms
1245 #define G_MAXSHORT      $glib_Ms
1246 #define G_MAXUSHORT     $glib_Mus
1247 #define G_MININT        $glib_mi
1248 #define G_MAXINT        $glib_Mi
1249 #define G_MAXUINT       $glib_Mui
1250 #define G_MINLONG       $glib_ml
1251 #define G_MAXLONG       $glib_Ml
1252 #define G_MAXULONG      $glib_Mul
1253
1254 _______EOF
1255
1256
1257         ### this should always be true in a modern C/C++ compiler
1258         cat >>$outfile <<_______EOF
1259 typedef signed char gint8;
1260 typedef unsigned char guint8;
1261 _______EOF
1262
1263
1264         if test -n "$gint16"; then
1265           cat >>$outfile <<_______EOF
1266 typedef signed $gint16 gint16;
1267 typedef unsigned $gint16 guint16;
1268 #define G_GINT16_FORMAT $gint16_format
1269 #define G_GUINT16_FORMAT $guint16_format
1270 _______EOF
1271         fi
1272
1273
1274         if test -n "$gint32"; then
1275           cat >>$outfile <<_______EOF
1276 typedef signed $gint32 gint32;
1277 typedef unsigned $gint32 guint32;
1278 #define G_GINT32_FORMAT $gint32_format
1279 #define G_GUINT32_FORMAT $guint32_format
1280 _______EOF
1281         fi
1282
1283
1284         if test -n "$gint64"; then
1285           cat >>$outfile <<_______EOF
1286 #define G_HAVE_GINT64 1
1287
1288 ${glib_extension}typedef signed $gint64 gint64;
1289 ${glib_extension}typedef unsigned $gint64 guint64;
1290
1291 #define G_GINT64_CONSTANT(val)  $gint64_constant
1292 _______EOF
1293                 if test -n "$gint64_format"; then
1294           cat >>$outfile <<_______EOF
1295 #define G_GINT64_FORMAT $gint64_format
1296 #define G_GUINT64_FORMAT $guint64_format
1297 _______EOF
1298                 fi
1299         fi
1300
1301         case x$glib_size_t in
1302         x2) echo "typedef gint16  gssize;" >> $outfile
1303             echo "typedef guint16 gsize;"  >> $outfile
1304             ;;
1305         x4) echo "typedef gint32  gssize;" >> $outfile
1306             echo "typedef guint32 gsize;"  >> $outfile
1307             ;;
1308         x8) echo "typedef gint64  gssize;" >> $outfile
1309             echo "typedef guint64 gsize;"  >> $outfile
1310             ;;
1311         *)  echo "#error size of size_t is unknown" >> $outfile
1312             ;;
1313         esac
1314
1315         if test -z "$glib_unknown_void_p"; then
1316           cat >>$outfile <<_______EOF
1317
1318 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
1319 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
1320
1321 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
1322 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
1323 _______EOF
1324         else
1325           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
1326         fi
1327
1328
1329
1330         cat >>$outfile <<_______EOF
1331 $glib_atexit
1332 $glib_memmove
1333 $glib_defines
1334 $glib_os
1335
1336 $glib_vacopy
1337
1338 #ifdef  __cplusplus
1339 #define G_HAVE_INLINE   1
1340 #else   /* !__cplusplus */
1341 $glib_inline
1342 #endif  /* !__cplusplus */
1343 _______EOF
1344
1345         echo >>$outfile
1346         if test x$g_have_eilseq = xno; then
1347                 cat >>$outfile <<_______EOF
1348 #ifndef EILSEQ
1349 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
1350  * The correspondence between this and the corresponding definition
1351  * in libiconv is essential.
1352  */
1353 #  define EILSEQ ENOENT
1354 #endif
1355 _______EOF
1356
1357         fi
1358
1359         echo >>$outfile
1360         if test x$g_mutex_has_default = xyes; then
1361                 cat >>$outfile <<_______EOF
1362 $g_enable_threads_def G_THREADS_ENABLED
1363 #define G_THREADS_IMPL_$g_threads_impl_def
1364 typedef struct _GStaticMutex GStaticMutex;
1365 struct _GStaticMutex
1366 {
1367   struct _GMutex *runtime_mutex;
1368   struct {
1369     union {
1370       char   pad[$g_mutex_sizeof];
1371       double dummy_double;
1372       void  *dummy_pointer;
1373       long   dummy_long;
1374     } mutex;
1375     void *debug_info;
1376   } static_mutex;
1377 };
1378 #define G_STATIC_MUTEX_INIT     { NULL, { { { $g_mutex_contents} }, NULL } }
1379 #define g_static_mutex_get_mutex(mutex) \
1380   (g_thread_use_default_impl ? ((GMutex*) &((mutex)->static_mutex)) : \
1381    g_static_mutex_get_mutex_impl (&((mutex)->runtime_mutex)))
1382 _______EOF
1383         else
1384                 cat >>$outfile <<_______EOF
1385 $g_enable_threads_def G_THREADS_ENABLED
1386 #define G_THREADS_IMPL_$g_threads_impl_def
1387 typedef struct _GMutex* GStaticMutex;
1388 #define G_STATIC_MUTEX_INIT NULL
1389 #define g_static_mutex_get_mutex(mutex) (g_static_mutex_get_mutex_impl (mutex))
1390 _______EOF
1391         fi
1392
1393         cat >>$outfile <<_______EOF
1394 /* This represents a system thread as used by the implementation. An
1395  * alien implementaion, as loaded by g_thread_init can only count on
1396  * "sizeof (gpointer)" bytes to store their info. We however need more
1397  * for some of our native implementations. */
1398 typedef union _GSystemThread GSystemThread;
1399 union _GSystemThread
1400 {
1401   char   data[$g_system_thread_sizeof];
1402   double dummy_double;
1403   void  *dummy_pointer;
1404   long   dummy_long;
1405 };
1406 _______EOF
1407
1408         echo >>$outfile
1409         g_bit_sizes="16 32"
1410         if test -n "$gint64"; then
1411           g_bit_sizes="$g_bit_sizes 64"
1412         fi
1413         for bits in $g_bit_sizes; do
1414           cat >>$outfile <<_______EOF
1415 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
1416 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
1417 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
1418 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
1419 _______EOF
1420         done
1421
1422         cat >>$outfile <<_______EOF
1423 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
1424 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
1425 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
1426 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
1427 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
1428 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
1429 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
1430 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
1431 #define G_BYTE_ORDER $g_byte_order
1432
1433 _______EOF
1434
1435         if test -r glibconfig-sysdefs.h; then
1436           cat glibconfig-sysdefs.h >>$outfile
1437         fi
1438
1439         cat >>$outfile <<_______EOF
1440
1441 G_END_DECLS
1442
1443 #endif /* GLIBCONFIG_H */
1444 _______EOF
1445
1446
1447         if cmp -s $outfile glibconfig.h; then
1448           echo glibconfig.h is unchanged
1449           rm -f $outfile
1450         else
1451           mv $outfile glibconfig.h
1452         fi ;;
1453 esac
1454 ],[
1455
1456 # Note that if two cases are the same, case goes with the first one.
1457 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
1458 # on variable expansion in case labels.  Look at the generated config.status
1459 # for a hint.
1460
1461 glib_header_alloca_h="$ac_cv_header_alloca_h"
1462
1463 case xyes in
1464 x$ac_cv_header_float_h)
1465   glib_float_h=yes
1466   glib_mf=FLT_MIN glib_Mf=FLT_MAX
1467   glib_md=DBL_MIN glib_Md=DBL_MAX
1468   ;;
1469 x$ac_cv_header_values_h)
1470   glib_values_h=yes
1471   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
1472   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
1473   ;;
1474 esac
1475
1476 case xyes in
1477 x$ac_cv_header_limits_h)
1478   glib_limits_h=yes
1479   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
1480   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
1481   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
1482   ;;
1483 x$ac_cv_header_values_h)
1484   glib_values_h=yes
1485   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
1486   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
1487   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
1488   ;;
1489 esac
1490
1491 if test x$ac_cv_header_sys_poll_h = xyes ; then
1492   glib_sys_poll_h=yes
1493 fi
1494
1495 case 2 in
1496 $ac_cv_sizeof_short)
1497   gint16=short
1498   gint16_format='"hi"'
1499   guint16_format='"hu"'
1500   ;;
1501 $ac_cv_sizeof_int)
1502   gint16=int
1503   gint16_format='"i"'
1504   guint16_format='"u"'
1505   ;;
1506 esac
1507 case 4 in
1508 $ac_cv_sizeof_short)
1509   gint32=short
1510   gint32_format='"hi"'
1511   guint32_format='"hu"'
1512   ;;
1513 $ac_cv_sizeof_int)
1514   gint32=int
1515   gint32_format='"i"'
1516   guint32_format='"u"'
1517   ;;
1518 $ac_cv_sizeof_long)
1519   gint32=long
1520   gint32_format='"li"'
1521   guint32_format='"lu"'
1522   ;;
1523 esac
1524 case 8 in
1525 $ac_cv_sizeof_int)
1526   gint64=int
1527   gint64_format='"i"'
1528   guint64_format='"u"'
1529   glib_extension=
1530   gint64_constant='(val)'
1531   ;;
1532 $ac_cv_sizeof_long)
1533   gint64=long
1534   gint64_format='"li"'
1535   guint64_format='"lu"'
1536   glib_extension=
1537   gint64_constant='(val##L)'
1538   ;;
1539 $ac_cv_sizeof_long_long)
1540   gint64='long long'
1541   if test -n "$glib_cv_long_long_format"; then
1542     gint64_format='"'$glib_cv_long_long_format'i"'
1543     guint64_format='"'$glib_cv_long_long_format'u"'
1544   fi
1545   glib_extension='G_GNUC_EXTENSION '
1546   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
1547   ;;
1548 esac
1549 glib_size_t=$glib_cv_sizeof_size_t
1550
1551 gintbits=`expr $ac_cv_sizeof_int \* 8`
1552 glongbits=`expr $ac_cv_sizeof_long \* 8`
1553
1554
1555 case $ac_cv_sizeof_void_p in
1556 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
1557 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
1558 *)                      glib_unknown_void_p=yes ;;
1559 esac
1560
1561
1562 case xyes in
1563 x$ac_cv_func_atexit)
1564   glib_atexit="
1565 #ifdef NeXT /* @#%@! NeXTStep */
1566 # define g_ATEXIT(proc) (!atexit (proc))
1567 #else
1568 # define g_ATEXIT(proc) (atexit (proc))
1569 #endif"
1570   ;;
1571 x$ac_cv_func_on_exit)
1572   glib_atexit="
1573 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
1574   ;;
1575 esac
1576
1577 case xyes in
1578 x$ac_cv_func_memmove)
1579   glib_memmove='
1580 #define g_memmove(d,s,n) G_STMT_START { memmove ((d), (s), (n)); } G_STMT_END'
1581   ;;
1582 x$glib_cv_working_bcopy)
1583   glib_memmove="
1584 /* memmove isn't available, but bcopy can copy overlapping memory regions */
1585 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
1586   ;;
1587 *)
1588   glib_memmove="
1589 /* memmove isn't found and bcopy can't copy overlapping memory regions,
1590  * so we have to roll our own copy routine. */
1591 void g_memmove (void* dest, const void * src, unsigned long len);"
1592   ;;
1593 esac
1594
1595 glib_defines="
1596 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
1597 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
1598 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
1599 "
1600
1601 case xyes in
1602 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
1603 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
1604 *)                      glib_vacopy=''
1605 esac
1606
1607 if test x$glib_cv_va_val_copy = xno; then
1608   glib_vacopy="\$glib_vacopy
1609 #define G_VA_COPY_AS_ARRAY 1"
1610 fi
1611
1612 if test x$glib_cv_hasinline = xyes; then
1613     glib_inline='#define G_HAVE_INLINE 1'
1614 fi
1615 if test x$glib_cv_has__inline = xyes; then
1616     glib_inline="\$glib_inline
1617 #define G_HAVE___INLINE 1"
1618 fi
1619 if test x$glib_cv_has__inline__ = xyes; then
1620     glib_inline="\$glib_inline
1621 #define G_HAVE___INLINE__ 1"
1622 fi
1623
1624 case xyes in
1625 x$ac_cv_c_bigendian)
1626   g_byte_order=G_BIG_ENDIAN
1627   g_bs_native=BE
1628   g_bs_alien=LE
1629   ;;
1630 *)
1631   g_byte_order=G_LITTLE_ENDIAN
1632   g_bs_native=LE
1633   g_bs_alien=BE
1634   ;;
1635 esac
1636
1637 g_have_eilseq=$have_eilseq
1638
1639 case x$have_threads in
1640 xnone)  g_enable_threads_def="#undef";;
1641 *)      g_enable_threads_def="#define";;
1642 esac
1643
1644 g_threads_impl_def=$g_threads_impl
1645
1646 g_mutex_has_default="$mutex_has_default"
1647 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
1648 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
1649 g_mutex_contents="$glib_cv_byte_contents_gmutex"
1650
1651 case $host in
1652   *-*-beos*)
1653     glib_os="#define G_OS_BEOS"
1654     ;;
1655   *-*-cygwin*)
1656     glib_os="#define G_OS_UNIX
1657 #define G_WITH_CYGWIN"
1658 v    ;;
1659   *)
1660     glib_os="#define G_OS_UNIX"
1661     ;;
1662 esac
1663 ])
1664
1665 AC_OUTPUT([
1666 glib-2.0.pc
1667 gmodule-2.0.pc
1668 gthread-2.0.pc
1669 gobject-2.0.pc
1670 glib.spec
1671 Makefile
1672 glib-config-2.0
1673 build/Makefile
1674 build/win32/Makefile
1675 gmodule/gmoduleconf.h
1676 gmodule/Makefile
1677 gobject/Makefile
1678 gthread/Makefile
1679 docs/Makefile
1680 docs/glib-config.1
1681 docs/reference/Makefile
1682 docs/reference/glib/Makefile
1683 docs/reference/gobject/Makefile
1684 tests/Makefile
1685 ],[case "$CONFIG_FILES" in
1686 *glib-config-2.0*)chmod +x glib-config-2.0;;
1687 esac
1688 echo ""
1689 echo " *** IMPORTANT *** "
1690 echo ""
1691 echo "This is a development version of GLib.  You should be using a stable"
1692 echo "version, which is available at ftp://ftp.gtk.org/pub/gtk/v1.2/.  The"
1693 echo "version you just configured is meant for developers of GLib only:"
1694 echo ""
1695 echo "  * You should not base stable software on this version of GLib."
1696 echo "  * GNOME developers should use a stable version of GLib."
1697 echo ""
1698 echo "If you install this version of GLib, we strongly recommend that you"
1699 echo "install it in a different prefix than GLib 1.2.  Use --prefix as an"
1700 echo "argument to configure to do this.  Otherwise, you will not be able to"
1701 echo "do development with GLib 1.2 any longer."
1702 echo ""
1703 echo " *** You should be using GLib 1.2 instead. ***"
1704 ])